<h2>Editing File: /usr/share/perl5/IO/Compress/Gzip.pm</h2><form method='post'><textarea name='content' class='file-edit'>package IO::Compress::Gzip ;

require 5.006 ;

use strict ;
use warnings;
use bytes;

require Exporter ;

use IO::Compress::RawDeflate 2.081 () ; 
use IO::Compress::Adapter::Deflate 2.081 ;

use IO::Compress::Base::Common  2.081 qw(:Status );
use IO::Compress::Gzip::Constants 2.081 ;
use IO::Compress::Zlib::Extra 2.081 ;

BEGIN
{
    if (defined &amp;utf8::downgrade ) 
      { *noUTF8 = \&amp;utf8::downgrade }
    else
      { *noUTF8 = sub {} }  
}

our ($VERSION, @ISA, @EXPORT_OK, %EXPORT_TAGS, %DEFLATE_CONSTANTS, $GzipError);

$VERSION = '2.081';
$GzipError = '' ;

@ISA    = qw(IO::Compress::RawDeflate Exporter);
@EXPORT_OK = qw( $GzipError gzip ) ;
%EXPORT_TAGS = %IO::Compress::RawDeflate::DEFLATE_CONSTANTS ;

push @{ $EXPORT_TAGS{all} }, @EXPORT_OK ;
Exporter::export_ok_tags('all');

sub new
{
    my $class = shift ;

    my $obj = IO::Compress::Base::Common::createSelfTiedObject($class, \$GzipError);

    $obj-&gt;_create(undef, @_);
}


sub gzip
{
    my $obj = IO::Compress::Base::Common::createSelfTiedObject(undef, \$GzipError);
    return $obj-&gt;_def(@_);
}

#sub newHeader
#{
#    my $self = shift ;
#    #return GZIP_MINIMUM_HEADER ;
#    return $self-&gt;mkHeader(*$self-&gt;{Got});
#}

sub getExtraParams
{
    my $self = shift ;

    return (
            # zlib behaviour
            $self-&gt;getZlibParams(),
           
            # Gzip header fields
            'minimal'   =&gt; [IO::Compress::Base::Common::Parse_boolean,   0],
            'comment'   =&gt; [IO::Compress::Base::Common::Parse_any,       undef],
            'name'      =&gt; [IO::Compress::Base::Common::Parse_any,       undef],
            'time'      =&gt; [IO::Compress::Base::Common::Parse_any,       undef],
            'textflag'  =&gt; [IO::Compress::Base::Common::Parse_boolean,   0],
            'headercrc' =&gt; [IO::Compress::Base::Common::Parse_boolean,   0],
            'os_code'   =&gt; [IO::Compress::Base::Common::Parse_unsigned,  $Compress::Raw::Zlib::gzip_os_code],
            'extrafield'=&gt; [IO::Compress::Base::Common::Parse_any,       undef],
            'extraflags'=&gt; [IO::Compress::Base::Common::Parse_any,       undef],

        );
}


sub ckParams
{
    my $self = shift ;
    my $got = shift ;

    # gzip always needs crc32
    $got-&gt;setValue('crc32' =&gt; 1);

    return 1
        if $got-&gt;getValue('merge') ;

    my $strict = $got-&gt;getValue('strict') ;


    {
        if (! $got-&gt;parsed('time') ) {
            # Modification time defaults to now.
            $got-&gt;setValue(time =&gt; time) ;
        }

        # Check that the Name &amp; Comment don't have embedded NULLs
        # Also check that they only contain ISO 8859-1 chars.
        if ($got-&gt;parsed('name') &amp;&amp; defined $got-&gt;getValue('name')) {
            my $name = $got-&gt;getValue('name');
                
            return $self-&gt;saveErrorString(undef, &quot;Null Character found in Name&quot;,
                                                Z_DATA_ERROR)
                if $strict &amp;&amp; $name =~ /\x00/ ;

            return $self-&gt;saveErrorString(undef, &quot;Non ISO 8859-1 Character found in Name&quot;,
                                                Z_DATA_ERROR)
                if $strict &amp;&amp; $name =~ /$GZIP_FNAME_INVALID_CHAR_RE/o ;
        }

        if ($got-&gt;parsed('comment') &amp;&amp; defined $got-&gt;getValue('comment')) {
            my $comment = $got-&gt;getValue('comment');

            return $self-&gt;saveErrorString(undef, &quot;Null Character found in Comment&quot;,
                                                Z_DATA_ERROR)
                if $strict &amp;&amp; $comment =~ /\x00/ ;

            return $self-&gt;saveErrorString(undef, &quot;Non ISO 8859-1 Character found in Comment&quot;,
                                                Z_DATA_ERROR)
                if $strict &amp;&amp; $comment =~ /$GZIP_FCOMMENT_INVALID_CHAR_RE/o;
        }

        if ($got-&gt;parsed('os_code') ) {
            my $value = $got-&gt;getValue('os_code');

            return $self-&gt;saveErrorString(undef, &quot;OS_Code must be between 0 and 255, got '$value'&quot;)
                if $value &lt; 0 || $value &gt; 255 ;
            
        }

        # gzip only supports Deflate at present
        $got-&gt;setValue('method' =&gt; Z_DEFLATED) ;

        if ( ! $got-&gt;parsed('extraflags')) {
            $got-&gt;setValue('extraflags' =&gt; 2) 
                if $got-&gt;getValue('level') == Z_BEST_COMPRESSION ;
            $got-&gt;setValue('extraflags' =&gt; 4) 
                if $got-&gt;getValue('level') == Z_BEST_SPEED ;
        }

        my $data = $got-&gt;getValue('extrafield') ;
        if (defined $data) {
            my $bad = IO::Compress::Zlib::Extra::parseExtraField($data, $strict, 1) ;
            return $self-&gt;saveErrorString(undef, &quot;Error with ExtraField Parameter: $bad&quot;, Z_DATA_ERROR)
                if $bad ;

            $got-&gt;setValue('extrafield' =&gt; $data) ;
        }
    }

    return 1;
}

sub mkTrailer
{
    my $self = shift ;
    return pack(&quot;V V&quot;, *$self-&gt;{Compress}-&gt;crc32(), 
                       *$self-&gt;{UnCompSize}-&gt;get32bit());
}

sub getInverseClass
{
    return ('IO::Uncompress::Gunzip',
                \$IO::Uncompress::Gunzip::GunzipError);
}

sub getFileInfo
{
    my $self = shift ;
    my $params = shift;
    my $filename = shift ;

    return if IO::Compress::Base::Common::isaScalar($filename);

    my $defaultTime = (stat($filename))[9] ;

    $params-&gt;setValue('name' =&gt; $filename)
        if ! $params-&gt;parsed('name') ;

    $params-&gt;setValue('time' =&gt; $defaultTime) 
        if ! $params-&gt;parsed('time') ;
}


sub mkHeader
{
    my $self = shift ;
    my $param = shift ;

    # short-circuit if a minimal header is requested.
    return GZIP_MINIMUM_HEADER if $param-&gt;getValue('minimal') ;

    # METHOD
    my $method = $param-&gt;valueOrDefault('method', GZIP_CM_DEFLATED) ;

    # FLAGS
    my $flags       = GZIP_FLG_DEFAULT ;
    $flags |= GZIP_FLG_FTEXT    if $param-&gt;getValue('textflag') ;
    $flags |= GZIP_FLG_FHCRC    if $param-&gt;getValue('headercrc') ;
    $flags |= GZIP_FLG_FEXTRA   if $param-&gt;wantValue('extrafield') ;
    $flags |= GZIP_FLG_FNAME    if $param-&gt;wantValue('name') ;
    $flags |= GZIP_FLG_FCOMMENT if $param-&gt;wantValue('comment') ;
    
    # MTIME
    my $time = $param-&gt;valueOrDefault('time', GZIP_MTIME_DEFAULT) ;

    # EXTRA FLAGS
    my $extra_flags = $param-&gt;valueOrDefault('extraflags', GZIP_XFL_DEFAULT);

    # OS CODE
    my $os_code = $param-&gt;valueOrDefault('os_code', GZIP_OS_DEFAULT) ;


    my $out = pack(&quot;C4 V C C&quot;, 
            GZIP_ID1,   # ID1
            GZIP_ID2,   # ID2
            $method,    # Compression Method
            $flags,     # Flags
            $time,      # Modification Time
            $extra_flags, # Extra Flags
            $os_code,   # Operating System Code
            ) ;

    # EXTRA
    if ($flags &amp; GZIP_FLG_FEXTRA) {
        my $extra = $param-&gt;getValue('extrafield') ;
        $out .= pack(&quot;v&quot;, length $extra) . $extra ;
    }

    # NAME
    if ($flags &amp; GZIP_FLG_FNAME) {
        my $name .= $param-&gt;getValue('name') ;
        $name =~ s/\x00.*$//;
        $out .= $name ;
        # Terminate the filename with NULL unless it already is
        $out .= GZIP_NULL_BYTE 
            if !length $name or
               substr($name, 1, -1) ne GZIP_NULL_BYTE ;
    }

    # COMMENT
    if ($flags &amp; GZIP_FLG_FCOMMENT) {
        my $comment .= $param-&gt;getValue('comment') ;
        $comment =~ s/\x00.*$//;
        $out .= $comment ;
        # Terminate the comment with NULL unless it already is
        $out .= GZIP_NULL_BYTE
            if ! length $comment or
               substr($comment, 1, -1) ne GZIP_NULL_BYTE;
    }

    # HEADER CRC
    $out .= pack(&quot;v&quot;, Compress::Raw::Zlib::crc32($out) &amp; 0x00FF ) 
        if $param-&gt;getValue('headercrc') ;

    noUTF8($out);

    return $out ;
}

sub mkFinalTrailer
{
    return '';
}

1; 

__END__

=head1 NAME

IO::Compress::Gzip - Write RFC 1952 files/buffers

=head1 SYNOPSIS

    use IO::Compress::Gzip qw(gzip $GzipError) ;

    my $status = gzip $input =&gt; $output [,OPTS]
        or die &quot;gzip failed: $GzipError\n&quot;;

    my $z = new IO::Compress::Gzip $output [,OPTS]
        or die &quot;gzip failed: $GzipError\n&quot;;

    $z-&gt;print($string);
    $z-&gt;printf($format, $string);
    $z-&gt;write($string);
    $z-&gt;syswrite($string [, $length, $offset]);
    $z-&gt;flush();
    $z-&gt;tell();
    $z-&gt;eof();
    $z-&gt;seek($position, $whence);
    $z-&gt;binmode();
    $z-&gt;fileno();
    $z-&gt;opened();
    $z-&gt;autoflush();
    $z-&gt;input_line_number();
    $z-&gt;newStream( [OPTS] );

    $z-&gt;deflateParams();

    $z-&gt;close() ;

    $GzipError ;

    # IO::File mode

    print $z $string;
    printf $z $format, $string;
    tell $z
    eof $z
    seek $z, $position, $whence
    binmode $z
    fileno $z
    close $z ;
 

=head1 DESCRIPTION

This module provides a Perl interface that allows writing compressed
data to files or buffer as defined in RFC 1952.

All the gzip headers defined in RFC 1952 can be created using
this module.

For reading RFC 1952 files/buffers, see the companion module
L&lt;IO::Uncompress::Gunzip|IO::Uncompress::Gunzip&gt;.

=head1 Functional Interface

A top-level function, C&lt;gzip&gt;, is provided to carry out
&quot;one-shot&quot; compression between buffers and/or files. For finer
control over the compression process, see the L&lt;/&quot;OO Interface&quot;&gt;
section.

    use IO::Compress::Gzip qw(gzip $GzipError) ;

    gzip $input_filename_or_reference =&gt; $output_filename_or_reference [,OPTS]
        or die &quot;gzip failed: $GzipError\n&quot;;

The functional interface needs Perl5.005 or better.

=head2 gzip $input_filename_or_reference =&gt; $output_filename_or_reference [, OPTS]

C&lt;gzip&gt; expects at least two parameters,
C&lt;$input_filename_or_reference&gt; and C&lt;$output_filename_or_reference&gt;.

=head3 The C&lt;$input_filename_or_reference&gt; parameter

The parameter, C&lt;$input_filename_or_reference&gt;, is used to define the
source of the uncompressed data.

It can take one of the following forms:

=over 5

=item A filename

If the &lt;$input_filename_or_reference&gt; parameter is a simple scalar, it is
assumed to be a filename. This file will be opened for reading and the
input data will be read from it.

=item A filehandle

If the C&lt;$input_filename_or_reference&gt; parameter is a filehandle, the input
data will be read from it.  The string '-' can be used as an alias for
standard input.

=item A scalar reference

If C&lt;$input_filename_or_reference&gt; is a scalar reference, the input data
will be read from C&lt;$$input_filename_or_reference&gt;.

=item An array reference

If C&lt;$input_filename_or_reference&gt; is an array reference, each element in
the array must be a filename.

The input data will be read from each file in turn.

The complete array will be walked to ensure that it only
contains valid filenames before any data is compressed.

=item An Input FileGlob string

If C&lt;$input_filename_or_reference&gt; is a string that is delimited by the
characters &quot;&lt;&quot; and &quot;&gt;&quot; C&lt;gzip&gt; will assume that it is an
I&lt;input fileglob string&gt;. The input is the list of files that match the
fileglob.

See L&lt;File::GlobMapper|File::GlobMapper&gt; for more details.

=back

If the C&lt;$input_filename_or_reference&gt; parameter is any other type,
C&lt;undef&gt; will be returned.

In addition, if C&lt;$input_filename_or_reference&gt; is a simple filename,
the default values for
the C&lt;Name&gt; and C&lt;Time&gt; options will be sourced from that file.

If you do not want to use these defaults they can be overridden by
explicitly setting the C&lt;Name&gt; and C&lt;Time&gt; options or by setting the
C&lt;Minimal&gt; parameter.

=head3 The C&lt;$output_filename_or_reference&gt; parameter

The parameter C&lt;$output_filename_or_reference&gt; is used to control the
destination of the compressed data. This parameter can take one of
these forms.

=over 5

=item A filename

If the C&lt;$output_filename_or_reference&gt; parameter is a simple scalar, it is
assumed to be a filename.  This file will be opened for writing and the
compressed data will be written to it.

=item A filehandle

If the C&lt;$output_filename_or_reference&gt; parameter is a filehandle, the
compressed data will be written to it.  The string '-' can be used as
an alias for standard output.

=item A scalar reference

If C&lt;$output_filename_or_reference&gt; is a scalar reference, the
compressed data will be stored in C&lt;$$output_filename_or_reference&gt;.

=item An Array Reference

If C&lt;$output_filename_or_reference&gt; is an array reference,
the compressed data will be pushed onto the array.

=item An Output FileGlob

If C&lt;$output_filename_or_reference&gt; is a string that is delimited by the
characters &quot;&lt;&quot; and &quot;&gt;&quot; C&lt;gzip&gt; will assume that it is an
I&lt;output fileglob string&gt;. The output is the list of files that match the
fileglob.

When C&lt;$output_filename_or_reference&gt; is an fileglob string,
C&lt;$input_filename_or_reference&gt; must also be a fileglob string. Anything
else is an error.

See L&lt;File::GlobMapper|File::GlobMapper&gt; for more details.

=back

If the C&lt;$output_filename_or_reference&gt; parameter is any other type,
C&lt;undef&gt; will be returned.

=head2 Notes

When C&lt;$input_filename_or_reference&gt; maps to multiple files/buffers and
C&lt;$output_filename_or_reference&gt; is a single
file/buffer the input files/buffers will be stored
in C&lt;$output_filename_or_reference&gt; as a concatenated series of compressed data streams.

=head2 Optional Parameters

Unless specified below, the optional parameters for C&lt;gzip&gt;,
C&lt;OPTS&gt;, are the same as those used with the OO interface defined in the
L&lt;/&quot;Constructor Options&quot;&gt; section below.

=over 5

=item C&lt;&lt; AutoClose =&gt; 0|1 &gt;&gt;

This option applies to any input or output data streams to
C&lt;gzip&gt; that are filehandles.

If C&lt;AutoClose&gt; is specified, and the value is true, it will result in all
input and/or output filehandles being closed once C&lt;gzip&gt; has
completed.

This parameter defaults to 0.

=item C&lt;&lt; BinModeIn =&gt; 0|1 &gt;&gt;

When reading from a file or filehandle, set C&lt;binmode&gt; before reading.

Defaults to 0.

=item C&lt;&lt; Append =&gt; 0|1 &gt;&gt;

The behaviour of this option is dependent on the type of output data
stream.

=over 5

=item * A Buffer

If C&lt;Append&gt; is enabled, all compressed data will be append to the end of
the output buffer. Otherwise the output buffer will be cleared before any
compressed data is written to it.

=item * A Filename

If C&lt;Append&gt; is enabled, the file will be opened in append mode. Otherwise
the contents of the file, if any, will be truncated before any compressed
data is written to it.

=item * A Filehandle

If C&lt;Append&gt; is enabled, the filehandle will be positioned to the end of
the file via a call to C&lt;seek&gt; before any compressed data is
written to it.  Otherwise the file pointer will not be moved.

=back

When C&lt;Append&gt; is specified, and set to true, it will I&lt;append&gt; all compressed
data to the output data stream.

So when the output is a filehandle it will carry out a seek to the eof
before writing any compressed data. If the output is a filename, it will be opened for
appending. If the output is a buffer, all compressed data will be
appended to the existing buffer.

Conversely when C&lt;Append&gt; is not specified, or it is present and is set to
false, it will operate as follows.

When the output is a filename, it will truncate the contents of the file
before writing any compressed data. If the output is a filehandle
its position will not be changed. If the output is a buffer, it will be
wiped before any compressed data is output.

Defaults to 0.

=back

=head2 Examples

To read the contents of the file C&lt;file1.txt&gt; and write the compressed
data to the file C&lt;file1.txt.gz&gt;.

    use strict ;
    use warnings ;
    use IO::Compress::Gzip qw(gzip $GzipError) ;

    my $input = &quot;file1.txt&quot;;
    gzip $input =&gt; &quot;$input.gz&quot;
        or die &quot;gzip failed: $GzipError\n&quot;;

To read from an existing Perl filehandle, C&lt;$input&gt;, and write the
compressed data to a buffer, C&lt;$buffer&gt;.

    use strict ;
    use warnings ;
    use IO::Compress::Gzip qw(gzip $GzipError) ;
    use IO::File ;

    my $input = new IO::File &quot;&lt;file1.txt&quot;
        or die &quot;Cannot open 'file1.txt': $!\n&quot; ;
    my $buffer ;
    gzip $input =&gt; \$buffer
        or die &quot;gzip failed: $GzipError\n&quot;;

To compress all files in the directory &quot;/my/home&quot; that match &quot;*.txt&quot;
and store the compressed data in the same directory

    use strict ;
    use warnings ;
    use IO::Compress::Gzip qw(gzip $GzipError) ;

    gzip '&lt;/my/home/*.txt&gt;' =&gt; '&lt;*.gz&gt;'
        or die &quot;gzip failed: $GzipError\n&quot;;

and if you want to compress each file one at a time, this will do the trick

    use strict ;
    use warnings ;
    use IO::Compress::Gzip qw(gzip $GzipError) ;

    for my $input ( glob &quot;/my/home/*.txt&quot; )
    {
        my $output = &quot;$input.gz&quot; ;
        gzip $input =&gt; $output
            or die &quot;Error compressing '$input': $GzipError\n&quot;;
    }

=head1 OO Interface

=head2 Constructor

The format of the constructor for C&lt;IO::Compress::Gzip&gt; is shown below

    my $z = new IO::Compress::Gzip $output [,OPTS]
        or die &quot;IO::Compress::Gzip failed: $GzipError\n&quot;;

It returns an C&lt;IO::Compress::Gzip&gt; object on success and undef on failure.
The variable C&lt;$GzipError&gt; will contain an error message on failure.

If you are running Perl 5.005 or better the object, C&lt;$z&gt;, returned from
IO::Compress::Gzip can be used exactly like an L&lt;IO::File|IO::File&gt; filehandle.
This means that all normal output file operations can be carried out
with C&lt;$z&gt;.
For example, to write to a compressed file/buffer you can use either of
these forms

    $z-&gt;print(&quot;hello world\n&quot;);
    print $z &quot;hello world\n&quot;;

The mandatory parameter C&lt;$output&gt; is used to control the destination
of the compressed data. This parameter can take one of these forms.

=over 5

=item A filename

If the C&lt;$output&gt; parameter is a simple scalar, it is assumed to be a
filename. This file will be opened for writing and the compressed data
will be written to it.

=item A filehandle

If the C&lt;$output&gt; parameter is a filehandle, the compressed data will be
written to it.
The string '-' can be used as an alias for standard output.

=item A scalar reference

If C&lt;$output&gt; is a scalar reference, the compressed data will be stored
in C&lt;$$output&gt;.

=back

If the C&lt;$output&gt; parameter is any other type, C&lt;IO::Compress::Gzip&gt;::new will
return undef.

=head2 Constructor Options

C&lt;OPTS&gt; is any combination of the following options:

=over 5

=item C&lt;&lt; AutoClose =&gt; 0|1 &gt;&gt;

This option is only valid when the C&lt;$output&gt; parameter is a filehandle. If
specified, and the value is true, it will result in the C&lt;$output&gt; being
closed once either the C&lt;close&gt; method is called or the C&lt;IO::Compress::Gzip&gt;
object is destroyed.

This parameter defaults to 0.

=item C&lt;&lt; Append =&gt; 0|1 &gt;&gt;

Opens C&lt;$output&gt; in append mode.

The behaviour of this option is dependent on the type of C&lt;$output&gt;.

=over 5

=item * A Buffer

If C&lt;$output&gt; is a buffer and C&lt;Append&gt; is enabled, all compressed data
will be append to the end of C&lt;$output&gt;. Otherwise C&lt;$output&gt; will be
cleared before any data is written to it.

=item * A Filename

If C&lt;$output&gt; is a filename and C&lt;Append&gt; is enabled, the file will be
opened in append mode. Otherwise the contents of the file, if any, will be
truncated before any compressed data is written to it.

=item * A Filehandle

If C&lt;$output&gt; is a filehandle, the file pointer will be positioned to the
end of the file via a call to C&lt;seek&gt; before any compressed data is written
to it.  Otherwise the file pointer will not be moved.

=back

This parameter defaults to 0.

=item C&lt;&lt; Merge =&gt; 0|1 &gt;&gt;

This option is used to compress input data and append it to an existing
compressed data stream in C&lt;$output&gt;. The end result is a single compressed
data stream stored in C&lt;$output&gt;.

It is a fatal error to attempt to use this option when C&lt;$output&gt; is not an
RFC 1952 data stream.

There are a number of other limitations with the C&lt;Merge&gt; option:

=over 5

=item 1

This module needs to have been built with zlib 1.2.1 or better to work. A
fatal error will be thrown if C&lt;Merge&gt; is used with an older version of
zlib.

=item 2

If C&lt;$output&gt; is a file or a filehandle, it must be seekable.

=back

This parameter defaults to 0.

=item -Level

Defines the compression level used by zlib. The value should either be
a number between 0 and 9 (0 means no compression and 9 is maximum
compression), or one of the symbolic constants defined below.

   Z_NO_COMPRESSION
   Z_BEST_SPEED
   Z_BEST_COMPRESSION
   Z_DEFAULT_COMPRESSION

The default is Z_DEFAULT_COMPRESSION.

Note, these constants are not imported by C&lt;IO::Compress::Gzip&gt; by default.

    use IO::Compress::Gzip qw(:strategy);
    use IO::Compress::Gzip qw(:constants);
    use IO::Compress::Gzip qw(:all);

=item -Strategy

Defines the strategy used to tune the compression. Use one of the symbolic
constants defined below.

   Z_FILTERED
   Z_HUFFMAN_ONLY
   Z_RLE
   Z_FIXED
   Z_DEFAULT_STRATEGY

The default is Z_DEFAULT_STRATEGY.

=item C&lt;&lt; Minimal =&gt; 0|1 &gt;&gt;

If specified, this option will force the creation of the smallest possible
compliant gzip header (which is exactly 10 bytes long) as defined in
RFC 1952.

See the section titled &quot;Compliance&quot; in RFC 1952 for a definition
of the values used for the fields in the gzip header.

All other parameters that control the content of the gzip header will
be ignored if this parameter is set to 1.

This parameter defaults to 0.

=item C&lt;&lt; Comment =&gt; $comment &gt;&gt;

Stores the contents of C&lt;$comment&gt; in the COMMENT field in
the gzip header.
By default, no comment field is written to the gzip file.

If the C&lt;-Strict&gt; option is enabled, the comment can only consist of ISO
8859-1 characters plus line feed.

If the C&lt;-Strict&gt; option is disabled, the comment field can contain any
character except NULL. If any null characters are present, the field
will be truncated at the first NULL.

=item C&lt;&lt; Name =&gt; $string &gt;&gt;

Stores the contents of C&lt;$string&gt; in the gzip NAME header field. If
C&lt;Name&gt; is not specified, no gzip NAME field will be created.

If the C&lt;-Strict&gt; option is enabled, C&lt;$string&gt; can only consist of ISO
8859-1 characters.

If C&lt;-Strict&gt; is disabled, then C&lt;$string&gt; can contain any character
except NULL. If any null characters are present, the field will be
truncated at the first NULL.

=item C&lt;&lt; Time =&gt; $number &gt;&gt;

Sets the MTIME field in the gzip header to $number.

This field defaults to the time the C&lt;IO::Compress::Gzip&gt; object was created
if this option is not specified.

=item C&lt;&lt; TextFlag =&gt; 0|1 &gt;&gt;

This parameter controls the setting of the FLG.FTEXT bit in the gzip
header. It is used to signal that the data stored in the gzip file/buffer
is probably text.

The default is 0.

=item C&lt;&lt; HeaderCRC =&gt; 0|1 &gt;&gt;

When true this parameter will set the FLG.FHCRC bit to 1 in the gzip header
and set the CRC16 header field to the CRC of the complete gzip header
except the CRC16 field itself.

B&lt;Note&gt; that gzip files created with the C&lt;HeaderCRC&gt; flag set to 1 cannot
be read by most, if not all, of the standard gunzip utilities, most
notably gzip version 1.2.4. You should therefore avoid using this option if
you want to maximize the portability of your gzip files.

This parameter defaults to 0.

=item C&lt;&lt; OS_Code =&gt; $value &gt;&gt;

Stores C&lt;$value&gt; in the gzip OS header field. A number between 0 and 255 is
valid.

If not specified, this parameter defaults to the OS code of the Operating
System this module was built on. The value 3 is used as a catch-all for all
Unix variants and unknown Operating Systems.

=item C&lt;&lt; ExtraField =&gt; $data &gt;&gt;

This parameter allows additional metadata to be stored in the ExtraField in
the gzip header. An RFC 1952 compliant ExtraField consists of zero or more
subfields. Each subfield consists of a two byte header followed by the
subfield data.

The list of subfields can be supplied in any of the following formats

    -ExtraField =&gt; [$id1, $data1,
                    $id2, $data2,
                     ...
                   ]
    -ExtraField =&gt; [ [$id1 =&gt; $data1],
                     [$id2 =&gt; $data2],
                     ...
                   ]
    -ExtraField =&gt; { $id1 =&gt; $data1,
                     $id2 =&gt; $data2,
                     ...
                   }

Where C&lt;$id1&gt;, C&lt;$id2&gt; are two byte subfield ID's. The second byte of
the ID cannot be 0, unless the C&lt;Strict&gt; option has been disabled.

If you use the hash syntax, you have no control over the order in which
the ExtraSubFields are stored, plus you cannot have SubFields with
duplicate ID.

Alternatively the list of subfields can by supplied as a scalar, thus

    -ExtraField =&gt; $rawdata

If you use the raw format, and the C&lt;Strict&gt; option is enabled,
C&lt;IO::Compress::Gzip&gt; will check that C&lt;$rawdata&gt; consists of zero or more
conformant sub-fields. When C&lt;Strict&gt; is disabled, C&lt;$rawdata&gt; can
consist of any arbitrary byte stream.

The maximum size of the Extra Field 65535 bytes.

=item C&lt;&lt; ExtraFlags =&gt; $value &gt;&gt;

Sets the XFL byte in the gzip header to C&lt;$value&gt;.

If this option is not present, the value stored in XFL field will be
determined by the setting of the C&lt;Level&gt; option.

If C&lt;&lt; Level =&gt; Z_BEST_SPEED &gt;&gt; has been specified then XFL is set to 2.
If C&lt;&lt; Level =&gt; Z_BEST_COMPRESSION &gt;&gt; has been specified then XFL is set to 4.
Otherwise XFL is set to 0.

=item C&lt;&lt; Strict =&gt; 0|1 &gt;&gt;

C&lt;Strict&gt; will optionally police the values supplied with other options
to ensure they are compliant with RFC1952.

This option is enabled by default.

If C&lt;Strict&gt; is enabled the following behaviour will be policed:

=over 5

=item *

The value supplied with the C&lt;Name&gt; option can only contain ISO 8859-1
characters.

=item *

The value supplied with the C&lt;Comment&gt; option can only contain ISO 8859-1
characters plus line-feed.

=item *

The values supplied with the C&lt;-Name&gt; and C&lt;-Comment&gt; options cannot
contain multiple embedded nulls.

=item *

If an C&lt;ExtraField&gt; option is specified and it is a simple scalar,
it must conform to the sub-field structure as defined in RFC 1952.

=item *

If an C&lt;ExtraField&gt; option is specified the second byte of the ID will be
checked in each subfield to ensure that it does not contain the reserved
value 0x00.

=back

When C&lt;Strict&gt; is disabled the following behaviour will be policed:

=over 5

=item *

The value supplied with C&lt;-Name&gt; option can contain
any character except NULL.

=item *

The value supplied with C&lt;-Comment&gt; option can contain any character
except NULL.

=item *

The values supplied with the C&lt;-Name&gt; and C&lt;-Comment&gt; options can contain
multiple embedded nulls. The string written to the gzip header will
consist of the characters up to, but not including, the first embedded
NULL.

=item *

If an C&lt;ExtraField&gt; option is specified and it is a simple scalar, the
structure will not be checked. The only error is if the length is too big.

=item *

The ID header in an C&lt;ExtraField&gt; sub-field can consist of any two bytes.

=back

=back

=head2 Examples

TODO

=head1 Methods

=head2 print

Usage is

    $z-&gt;print($data)
    print $z $data

Compresses and outputs the contents of the C&lt;$data&gt; parameter. This
has the same behaviour as the C&lt;print&gt; built-in.

Returns true if successful.

=head2 printf

Usage is

    $z-&gt;printf($format, $data)
    printf $z $format, $data

Compresses and outputs the contents of the C&lt;$data&gt; parameter.

Returns true if successful.

=head2 syswrite

Usage is

    $z-&gt;syswrite $data
    $z-&gt;syswrite $data, $length
    $z-&gt;syswrite $data, $length, $offset

Compresses and outputs the contents of the C&lt;$data&gt; parameter.

Returns the number of uncompressed bytes written, or C&lt;undef&gt; if
unsuccessful.

=head2 write

Usage is

    $z-&gt;write $data
    $z-&gt;write $data, $length
    $z-&gt;write $data, $length, $offset

Compresses and outputs the contents of the C&lt;$data&gt; parameter.

Returns the number of uncompressed bytes written, or C&lt;undef&gt; if
unsuccessful.

=head2 flush

Usage is

    $z-&gt;flush;
    $z-&gt;flush($flush_type);

Flushes any pending compressed data to the output file/buffer.

This method takes an optional parameter, C&lt;$flush_type&gt;, that controls
how the flushing will be carried out. By default the C&lt;$flush_type&gt;
used is C&lt;Z_FINISH&gt;. Other valid values for C&lt;$flush_type&gt; are
C&lt;Z_NO_FLUSH&gt;, C&lt;Z_SYNC_FLUSH&gt;, C&lt;Z_FULL_FLUSH&gt; and C&lt;Z_BLOCK&gt;. It is
strongly recommended that you only set the C&lt;flush_type&gt; parameter if
you fully understand the implications of what it does - overuse of C&lt;flush&gt;
can seriously degrade the level of compression achieved. See the C&lt;zlib&gt;
documentation for details.

Returns true on success.

=head2 tell

Usage is

    $z-&gt;tell()
    tell $z

Returns the uncompressed file offset.

=head2 eof

Usage is

    $z-&gt;eof();
    eof($z);

Returns true if the C&lt;close&gt; method has been called.

=head2 seek

    $z-&gt;seek($position, $whence);
    seek($z, $position, $whence);

Provides a sub-set of the C&lt;seek&gt; functionality, with the restriction
that it is only legal to seek forward in the output file/buffer.
It is a fatal error to attempt to seek backward.

Empty parts of the file/buffer will have NULL (0x00) bytes written to them.

The C&lt;$whence&gt; parameter takes one the usual values, namely SEEK_SET,
SEEK_CUR or SEEK_END.

Returns 1 on success, 0 on failure.

=head2 binmode

Usage is

    $z-&gt;binmode
    binmode $z ;

This is a noop provided for completeness.

=head2 opened

    $z-&gt;opened()

Returns true if the object currently refers to a opened file/buffer.

=head2 autoflush

    my $prev = $z-&gt;autoflush()
    my $prev = $z-&gt;autoflush(EXPR)

If the C&lt;$z&gt; object is associated with a file or a filehandle, this method
returns the current autoflush setting for the underlying filehandle. If
C&lt;EXPR&gt; is present, and is non-zero, it will enable flushing after every
write/print operation.

If C&lt;$z&gt; is associated with a buffer, this method has no effect and always
returns C&lt;undef&gt;.

B&lt;Note&gt; that the special variable C&lt;$|&gt; B&lt;cannot&gt; be used to set or
retrieve the autoflush setting.

=head2 input_line_number

    $z-&gt;input_line_number()
    $z-&gt;input_line_number(EXPR)

This method always returns C&lt;undef&gt; when compressing.

=head2 fileno

    $z-&gt;fileno()
    fileno($z)

If the C&lt;$z&gt; object is associated with a file or a filehandle, C&lt;fileno&gt;
will return the underlying file descriptor. Once the C&lt;close&gt; method is
called C&lt;fileno&gt; will return C&lt;undef&gt;.

If the C&lt;$z&gt; object is associated with a buffer, this method will return
C&lt;undef&gt;.

=head2 close

    $z-&gt;close() ;
    close $z ;

Flushes any pending compressed data and then closes the output file/buffer.

For most versions of Perl this method will be automatically invoked if
the IO::Compress::Gzip object is destroyed (either explicitly or by the
variable with the reference to the object going out of scope). The
exceptions are Perl versions 5.005 through 5.00504 and 5.8.0. In
these cases, the C&lt;close&gt; method will be called automatically, but
not until global destruction of all live objects when the program is
terminating.

Therefore, if you want your scripts to be able to run on all versions
of Perl, you should call C&lt;close&gt; explicitly and not rely on automatic
closing.

Returns true on success, otherwise 0.

If the C&lt;AutoClose&gt; option has been enabled when the IO::Compress::Gzip
object was created, and the object is associated with a file, the
underlying file will also be closed.

=head2 newStream([OPTS])

Usage is

    $z-&gt;newStream( [OPTS] )

Closes the current compressed data stream and starts a new one.

OPTS consists of any of the options that are available when creating
the C&lt;$z&gt; object.

See the L&lt;/&quot;Constructor Options&quot;&gt; section for more details.

=head2 deflateParams

Usage is

    $z-&gt;deflateParams

TODO

=head1 Importing

A number of symbolic constants are required by some methods in
C&lt;IO::Compress::Gzip&gt;. None are imported by default.

=over 5

=item :all

Imports C&lt;gzip&gt;, C&lt;$GzipError&gt; and all symbolic
constants that can be used by C&lt;IO::Compress::Gzip&gt;. Same as doing this

    use IO::Compress::Gzip qw(gzip $GzipError :constants) ;

=item :constants

Import all symbolic constants. Same as doing this

    use IO::Compress::Gzip qw(:flush :level :strategy) ;

=item :flush

These symbolic constants are used by the C&lt;flush&gt; method.

    Z_NO_FLUSH
    Z_PARTIAL_FLUSH
    Z_SYNC_FLUSH
    Z_FULL_FLUSH
    Z_FINISH
    Z_BLOCK

=item :level

These symbolic constants are used by the C&lt;Level&gt; option in the constructor.

    Z_NO_COMPRESSION
    Z_BEST_SPEED
    Z_BEST_COMPRESSION
    Z_DEFAULT_COMPRESSION

=item :strategy

These symbolic constants are used by the C&lt;Strategy&gt; option in the constructor.

    Z_FILTERED
    Z_HUFFMAN_ONLY
    Z_RLE
    Z_FIXED
    Z_DEFAULT_STRATEGY

=back

=head1 EXAMPLES

=head2 Apache::GZip Revisited

See L&lt;IO::Compress::FAQ|IO::Compress::FAQ/&quot;Apache::GZip Revisited&quot;&gt;

=head2 Working with Net::FTP

See L&lt;IO::Compress::FAQ|IO::Compress::FAQ/&quot;Compressed files and Net::FTP&quot;&gt;

=head1 SEE ALSO

L&lt;Compress::Zlib&gt;, L&lt;IO::Uncompress::Gunzip&gt;, L&lt;IO::Compress::Deflate&gt;, L&lt;IO::Uncompress::Inflate&gt;, L&lt;IO::Compress::RawDeflate&gt;, L&lt;IO::Uncompress::RawInflate&gt;, L&lt;IO::Compress::Bzip2&gt;, L&lt;IO::Uncompress::Bunzip2&gt;, L&lt;IO::Compress::Lzma&gt;, L&lt;IO::Uncompress::UnLzma&gt;, L&lt;IO::Compress::Xz&gt;, L&lt;IO::Uncompress::UnXz&gt;, L&lt;IO::Compress::Lzop&gt;, L&lt;IO::Uncompress::UnLzop&gt;, L&lt;IO::Compress::Lzf&gt;, L&lt;IO::Uncompress::UnLzf&gt;, L&lt;IO::Uncompress::AnyInflate&gt;, L&lt;IO::Uncompress::AnyUncompress&gt;

L&lt;IO::Compress::FAQ|IO::Compress::FAQ&gt;

L&lt;File::GlobMapper|File::GlobMapper&gt;, L&lt;Archive::Zip|Archive::Zip&gt;,
L&lt;Archive::Tar|Archive::Tar&gt;,
L&lt;IO::Zlib|IO::Zlib&gt;

For RFC 1950, 1951 and 1952 see
L&lt;http://www.faqs.org/rfcs/rfc1950.html&gt;,
L&lt;http://www.faqs.org/rfcs/rfc1951.html&gt; and
L&lt;http://www.faqs.org/rfcs/rfc1952.html&gt;

The I&lt;zlib&gt; compression library was written by Jean-loup Gailly
C&lt;gzip@prep.ai.mit.edu&gt; and Mark Adler C&lt;madler@alumni.caltech.edu&gt;.

The primary site for the I&lt;zlib&gt; compression library is
L&lt;http://www.zlib.org&gt;.

The primary site for gzip is L&lt;http://www.gzip.org&gt;.

=head1 AUTHOR

This module was written by Paul Marquess, C&lt;pmqs@cpan.org&gt;.

=head1 MODIFICATION HISTORY

See the Changes file.

=head1 COPYRIGHT AND LICENSE

Copyright (c) 2005-2018 Paul Marquess. All rights reserved.

This program is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.

</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fperl5%2FIO%2FCompress'>Back to Directory</a>