<h2>Editing File: /usr/share/perl5/ExtUtils/Embed.pm</h2><form method='post'><textarea name='content' class='file-edit'>package ExtUtils::Embed;
require Exporter;
use Config;
require File::Spec;

use vars qw(@ISA @EXPORT $VERSION
	    @Extensions $Verbose $lib_ext
	    $opt_o $opt_s 
	    );
use strict;

# This is not a dual-life module, so no need for development version numbers
$VERSION = '1.34';

@ISA = qw(Exporter);
@EXPORT = qw(&amp;xsinit &amp;ldopts 
	     &amp;ccopts &amp;ccflags &amp;ccdlflags &amp;perl_inc
	     &amp;xsi_header &amp;xsi_protos &amp;xsi_body);

$Verbose = 0;
$lib_ext = $Config{lib_ext} || '.a';

sub is_cmd { $0 eq '-e' }

sub my_return {
    my $val = shift;
    if(is_cmd) {
	print $val;
    }
    else {
	return $val;
    }
}

sub xsinit { 
    my($file, $std, $mods) = @_;
    my($fh,@mods,%seen);
    $file ||= &quot;perlxsi.c&quot;;
    my $xsinit_proto = &quot;pTHX&quot;;

    if (@_) {
       @mods = @$mods if $mods;
    }
    else {
       require Getopt::Std;
       Getopt::Std::getopts('o:s:');
       $file = $opt_o if defined $opt_o;
       $std  = $opt_s  if defined $opt_s;
       @mods = @ARGV;
    }
    $std = 1 unless scalar @mods;

    if ($file eq &quot;STDOUT&quot;) {
	$fh = \*STDOUT;
    }
    else {
        open $fh, '&gt;', $file
            or die &quot;Can't open '$file': $!&quot;;
    }

    push(@mods, static_ext()) if defined $std;
    @mods = grep(!$seen{$_}++, @mods);

    print $fh &amp;xsi_header();
    print $fh &quot;\nEXTERN_C void xs_init ($xsinit_proto);\n\n&quot;;
    print $fh &amp;xsi_protos(@mods);

    print $fh &quot;\nEXTERN_C void\nxs_init($xsinit_proto)\n{\n&quot;;
    print $fh &amp;xsi_body(@mods);
    print $fh &quot;}\n&quot;;

}

sub xsi_header {
    return &lt;&lt;EOF;
#include &quot;EXTERN.h&quot;
#include &quot;perl.h&quot;
#include &quot;XSUB.h&quot;
EOF
}    

sub xsi_protos {
    my @exts = @_;
    my %seen;
    my $retval = '';
    foreach my $cname (canon('__', @exts)) {
        my $ccode = &quot;EXTERN_C void boot_${cname} (pTHX_ CV* cv);\n&quot;;
        $retval .= $ccode
            unless $seen{$ccode}++;
    }
    return $retval;
}

sub xsi_body {
    my @exts = @_;
    my %seen;
    my $retval;
    $retval .= &quot;    static const char file[] = __FILE__;\n&quot;
        if @exts;
    $retval .= &lt;&lt;'EOT';
    dXSUB_SYS;
    PERL_UNUSED_CONTEXT;
EOT
    $retval .= &quot;\n&quot;
        if @exts;

    foreach my $pname (canon('/', @exts)) {
        next
            if $seen{$pname}++;
        (my $mname = $pname) =~ s!/!::!g;
        (my $cname = $pname) =~ s!/!__!g;
        my $fname;
        if ($pname eq 'DynaLoader'){
            # Must NOT install 'DynaLoader::boot_DynaLoader' as 'bootstrap'!
            # boot_DynaLoader is called directly in DynaLoader.pm
            $retval .= &quot;    /* DynaLoader is a special case */\n&quot;;
            $fname = &quot;${mname}::boot_DynaLoader&quot;;
        } else {
            $fname = &quot;${mname}::bootstrap&quot;;
        }
        $retval .= &quot;    newXS(\&quot;$fname\&quot;, boot_${cname}, file);\n&quot;
    }
    return $retval;
}

sub static_ext {
    @Extensions = ('DynaLoader', sort $Config{static_ext} =~ /(\S+)/g)
        unless @Extensions;
    @Extensions;
}

sub _escape {
    my $arg = shift;
    return $$arg if $^O eq 'VMS'; # parens legal in qualifier lists
    $$arg =~ s/([\(\)])/\\$1/g;
}

sub _ldflags {
    my $ldflags = $Config{ldflags};
    _escape(\$ldflags);
    return $ldflags;
}

sub _ccflags {
    my $ccflags = $Config{ccflags};
    _escape(\$ccflags);
    return $ccflags;
}

sub _ccdlflags {
    my $ccdlflags = $Config{ccdlflags};
    _escape(\$ccdlflags);
    return $ccdlflags;
}

sub ldopts {
    require ExtUtils::MakeMaker;
    require ExtUtils::Liblist;
    my($std,$mods,$link_args,$path) = @_;
    my(@mods,@link_args,@argv);
    my($dllib,$config_libs,@potential_libs,@path);
    local($&quot;) = ' ' unless $&quot; eq ' ';
    if (scalar @_) {
       @link_args = @$link_args if $link_args;
       @mods = @$mods if $mods;
    }
    else {
       @argv = @ARGV;
       #hmm
       while($_ = shift @argv) {
	   /^-std$/  &amp;&amp; do { $std = 1; next; };
	   /^--$/    &amp;&amp; do { @link_args = @argv; last; };
	   /^-I(.*)/ &amp;&amp; do { $path = $1 || shift @argv; next; };
	   push(@mods, $_); 
       }
    }
    $std = 1 unless scalar @link_args;
    my $sep = $Config{path_sep} || ':';
    @path = $path ? split(/\Q$sep/, $path) : @INC;

    push(@potential_libs, @link_args)    if scalar @link_args;
    # makemaker includes std libs on windows by default
    if ($^O ne 'MSWin32' and defined($std)) {
	push(@potential_libs, $Config{perllibs});
    }

    push(@mods, static_ext()) if $std;

    my($mod,@ns,$root,$sub,$extra,$archive,@archives);
    print STDERR &quot;Searching (@path) for archives\n&quot; if $Verbose;
    foreach $mod (@mods) {
	@ns = split(/::|\/|\\/, $mod);
	$sub = $ns[-1];
	$root = File::Spec-&gt;catdir(@ns);
	
	print STDERR &quot;searching for '$sub${lib_ext}'\n&quot; if $Verbose;
	foreach (@path) {
	    next unless -e ($archive = File::Spec-&gt;catdir($_,&quot;auto&quot;,$root,&quot;$sub$lib_ext&quot;));
	    push @archives, $archive;
	    if(-e ($extra = File::Spec-&gt;catdir($_,&quot;auto&quot;,$root,&quot;extralibs.ld&quot;))) {
		local(*FH); 
		if(open(FH, '&lt;', $extra)) {
		    my($libs) = &lt;FH&gt;; chomp $libs;
		    push @potential_libs, split /\s+/, $libs;
		}
		else {  
		    warn &quot;Couldn't open '$extra'&quot;; 
		}
	    }
	    last;
	}
    }
    #print STDERR &quot;\@potential_libs = @potential_libs\n&quot;;

    my $libperl;
    if ($^O eq 'MSWin32') {
	$libperl = $Config{libperl};
    }
    elsif ($^O eq 'os390' &amp;&amp; $Config{usedl}) {
	# Nothing for OS/390 (z/OS) dynamic.
    } else {
	$libperl = (grep(/^-l\w*perl\w*$/, @link_args))[0]
	    || ($Config{libperl} =~ /^lib(\w+)(\Q$lib_ext\E|\.\Q$Config{dlext}\E)$/
		? &quot;-l$1&quot; : '')
		|| &quot;-lperl&quot;;
    }

    my $lpath = File::Spec-&gt;catdir($Config{archlibexp}, 'CORE');
    $lpath = qq[&quot;$lpath&quot;] if $^O eq 'MSWin32';
    my($extralibs, $bsloadlibs, $ldloadlibs, $ld_run_path) =
	MM-&gt;ext(join ' ', &quot;-L$lpath&quot;, $libperl, @potential_libs);

    my $ld_or_bs = $bsloadlibs || $ldloadlibs;
    print STDERR &quot;bs: $bsloadlibs ** ld: $ldloadlibs&quot; if $Verbose;
    my $ccdlflags = _ccdlflags();
    my $ldflags   = _ldflags();
    my $linkage = &quot;$ccdlflags $ldflags @archives $ld_or_bs&quot;;
    print STDERR &quot;ldopts: '$linkage'\n&quot; if $Verbose;

    return $linkage if scalar @_;
    my_return(&quot;$linkage\n&quot;);
}

sub ccflags {
    my $ccflags = _ccflags();
    my_return(&quot; $ccflags &quot;);
}

sub ccdlflags {
    my $ccdlflags = _ccdlflags();
    my_return(&quot; $ccdlflags &quot;);
}

sub perl_inc {
    my $dir = File::Spec-&gt;catdir($Config{archlibexp}, 'CORE');
    $dir = qq[&quot;$dir&quot;] if $^O eq 'MSWin32';
    my_return(&quot; -I$dir &quot;);
}

sub ccopts {
   ccflags . perl_inc;
}

sub canon {
    my($as, @ext) = @_;
    foreach(@ext) {
        # might be X::Y or lib/auto/X/Y/Y.a
        next
            if s!::!/!g;
        s!^(?:lib|ext|dist|cpan)/(?:auto/)?!!;
        s!/\w+\.\w+$!!;
    }
    if ($as ne '/') {
        s!/!$as!g
            foreach @ext;
    }
    @ext;
}

__END__

=head1 NAME

ExtUtils::Embed - Utilities for embedding Perl in C/C++ applications

=head1 SYNOPSIS

 perl -MExtUtils::Embed -e xsinit 
 perl -MExtUtils::Embed -e ccopts 
 perl -MExtUtils::Embed -e ldopts 

=head1 DESCRIPTION

C&lt;ExtUtils::Embed&gt; provides utility functions for embedding a Perl interpreter
and extensions in your C/C++ applications.  
Typically, an application F&lt;Makefile&gt; will invoke C&lt;ExtUtils::Embed&gt;
functions while building your application.  

=head1 @EXPORT

C&lt;ExtUtils::Embed&gt; exports the following functions:

xsinit(), ldopts(), ccopts(), perl_inc(), ccflags(), 
ccdlflags(), xsi_header(), xsi_protos(), xsi_body()

=head1 FUNCTIONS

=over 4

=item xsinit()

Generate C/C++ code for the XS initializer function.

When invoked as C&lt;`perl -MExtUtils::Embed -e xsinit --`&gt;
the following options are recognized:

B&lt;-o&gt; E&lt;lt&gt;output filenameE&lt;gt&gt; (Defaults to B&lt;perlxsi.c&gt;)

B&lt;-o STDOUT&gt; will print to STDOUT.

B&lt;-std&gt; (Write code for extensions that are linked with the current Perl.)

Any additional arguments are expected to be names of modules
to generate code for.

When invoked with parameters the following are accepted and optional:

C&lt;xsinit($filename,$std,[@modules])&gt;

Where,

B&lt;$filename&gt; is equivalent to the B&lt;-o&gt; option.

B&lt;$std&gt; is boolean, equivalent to the B&lt;-std&gt; option.  

B&lt;[@modules]&gt; is an array ref, same as additional arguments mentioned above.

=item Examples

 perl -MExtUtils::Embed -e xsinit -- -o xsinit.c Socket

This will generate code with an C&lt;xs_init&gt; function that glues the perl C&lt;Socket::bootstrap&gt; function 
to the C C&lt;boot_Socket&gt; function and writes it to a file named F&lt;xsinit.c&gt;.

Note that L&lt;DynaLoader&gt; is a special case where it must call C&lt;boot_DynaLoader&gt; directly.

 perl -MExtUtils::Embed -e xsinit

This will generate code for linking with C&lt;DynaLoader&gt; and
each static extension found in C&lt;$Config{static_ext}&gt;.
The code is written to the default file name F&lt;perlxsi.c&gt;.

 perl -MExtUtils::Embed -e xsinit -- -o xsinit.c \
                            -std DBI DBD::Oracle

Here, code is written for all the currently linked extensions along with code
for C&lt;DBI&gt; and C&lt;DBD::Oracle&gt;.

If you have a working C&lt;DynaLoader&gt; then there is rarely any need to statically link in any 
other extensions.

=item ldopts()

Output arguments for linking the Perl library and extensions to your
application.

When invoked as C&lt;`perl -MExtUtils::Embed -e ldopts --`&gt;
the following options are recognized:

B&lt;-std&gt; 

Output arguments for linking the Perl library and any extensions linked
with the current Perl.

B&lt;-I&gt; E&lt;lt&gt;path1:path2E&lt;gt&gt;

Search path for ModuleName.a archives.  
Default path is C&lt;@INC&gt;.
Library archives are expected to be found as 
F&lt;/some/path/auto/ModuleName/ModuleName.a&gt;
For example, when looking for F&lt;Socket.a&gt; relative to a search path,
we should find F&lt;auto/Socket/Socket.a&gt;

When looking for C&lt;DBD::Oracle&gt; relative to a search path,
we should find F&lt;auto/DBD/Oracle/Oracle.a&gt;

Keep in mind that you can always supply F&lt;/my/own/path/ModuleName.a&gt;
as an additional linker argument.

B&lt;--&gt;  E&lt;lt&gt;list of linker argsE&lt;gt&gt;

Additional linker arguments to be considered.

Any additional arguments found before the B&lt;--&gt; token 
are expected to be names of modules to generate code for.

When invoked with parameters the following are accepted and optional:

C&lt;ldopts($std,[@modules],[@link_args],$path)&gt;

Where:

B&lt;$std&gt; is boolean, equivalent to the B&lt;-std&gt; option.  

B&lt;[@modules]&gt; is equivalent to additional arguments found before the B&lt;--&gt; token.

B&lt;[@link_args]&gt; is equivalent to arguments found after the B&lt;--&gt; token.

B&lt;$path&gt; is equivalent to the B&lt;-I&gt; option.

In addition, when ldopts is called with parameters, it will return the argument string
rather than print it to STDOUT.

=item Examples

 perl -MExtUtils::Embed -e ldopts

This will print arguments for linking with C&lt;libperl&gt; and
extensions found in C&lt;$Config{static_ext}&gt;.  This includes libraries
found in C&lt;$Config{libs}&gt; and the first ModuleName.a library
for each extension that is found by searching C&lt;@INC&gt; or the path
specified by the B&lt;-I&gt; option.
In addition, when ModuleName.a is found, additional linker arguments
are picked up from the F&lt;extralibs.ld&gt; file in the same directory.

 perl -MExtUtils::Embed -e ldopts -- -std Socket

This will do the same as the above example, along with printing additional
arguments for linking with the C&lt;Socket&gt; extension.

 perl -MExtUtils::Embed -e ldopts -- -std Msql -- \
                        -L/usr/msql/lib -lmsql

Any arguments after the second '--' token are additional linker
arguments that will be examined for potential conflict.  If there is no
conflict, the additional arguments will be part of the output.  

=item perl_inc()

For including perl header files this function simply prints:

 -I$Config{archlibexp}/CORE  

So, rather than having to say:

 perl -MConfig -e 'print &quot;-I$Config{archlibexp}/CORE&quot;'

Just say:

 perl -MExtUtils::Embed -e perl_inc

=item ccflags(), ccdlflags()

These functions simply print $Config{ccflags} and $Config{ccdlflags}

=item ccopts()

This function combines C&lt;perl_inc()&gt;, C&lt;ccflags()&gt; and C&lt;ccdlflags()&gt; into one.

=item xsi_header()

This function simply returns a string defining the same C&lt;EXTERN_C&gt; macro as
F&lt;perlmain.c&gt; along with #including F&lt;perl.h&gt; and F&lt;EXTERN.h&gt;.

=item xsi_protos(@modules)

This function returns a string of C&lt;boot_$ModuleName&gt; prototypes for each @modules.

=item xsi_body(@modules)

This function returns a string of calls to C&lt;newXS()&gt; that glue the module I&lt;bootstrap&gt;
function to I&lt;boot_ModuleName&gt; for each @modules.

C&lt;xsinit()&gt; uses the xsi_* functions to generate most of its code.

=back

=head1 EXAMPLES

For examples on how to use C&lt;ExtUtils::Embed&gt; for building C/C++ applications
with embedded perl, see L&lt;perlembed&gt;.

=head1 SEE ALSO

L&lt;perlembed&gt;

=head1 AUTHOR

Doug MacEachern E&lt;lt&gt;C&lt;dougm@osf.org&gt;E&lt;gt&gt;

Based on ideas from Tim Bunce E&lt;lt&gt;C&lt;Tim.Bunce@ig.co.uk&gt;E&lt;gt&gt; and
F&lt;minimod.pl&gt; by Andreas Koenig E&lt;lt&gt;C&lt;k@anna.in-berlin.de&gt;E&lt;gt&gt; and Tim Bunce.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fperl5%2FExtUtils'>Back to Directory</a>