<h2>Editing File: /usr/share/perl5/Class/Struct.pm</h2><form method='post'><textarea name='content' class='file-edit'>package Class::Struct;

## See POD after __END__

use 5.006_001;

use strict;
use warnings::register;
our(@ISA, @EXPORT, $VERSION);

use Carp;

require Exporter;
@ISA = qw(Exporter);
@EXPORT = qw(struct);

$VERSION = '0.65';

my $print = 0;
sub printem {
    if (@_) { $print = shift }
    else    { $print++ }
}

{
    package Class::Struct::Tie_ISA;

    sub TIEARRAY {
        my $class = shift;
        return bless [], $class;
    }

    sub STORE {
        my ($self, $index, $value) = @_;
        Class::Struct::_subclass_error();
    }

    sub FETCH {
        my ($self, $index) = @_;
        $self-&gt;[$index];
    }

    sub FETCHSIZE {
        my $self = shift;
        return scalar(@$self);
    }

    sub DESTROY { }
}

sub import {
    my $self = shift;

    if ( @_ == 0 ) {
      $self-&gt;export_to_level( 1, $self, @EXPORT );
    } elsif ( @_ == 1 ) {
	# This is admittedly a little bit silly:
	# do we ever export anything else than 'struct'...?
      $self-&gt;export_to_level( 1, $self, @_ );
    } else {
      goto &amp;struct;
    }
}

sub struct {

    # Determine parameter list structure, one of:
    #   struct( class =&gt; [ element-list ])
    #   struct( class =&gt; { element-list })
    #   struct( element-list )
    # Latter form assumes current package name as struct name.

    my ($class, @decls);
    my $base_type = ref $_[1];
    if ( $base_type eq 'HASH' ) {
        $class = shift;
        @decls = %{shift()};
        _usage_error() if @_;
    }
    elsif ( $base_type eq 'ARRAY' ) {
        $class = shift;
        @decls = @{shift()};
        _usage_error() if @_;
    }
    else {
        $base_type = 'ARRAY';
        $class = (caller())[0];
        @decls = @_;
    }

    _usage_error() if @decls % 2 == 1;

    # Ensure we are not, and will not be, a subclass.

    my $isa = do {
        no strict 'refs';
        \@{$class . '::ISA'};
    };
    _subclass_error() if @$isa;
    tie @$isa, 'Class::Struct::Tie_ISA';

    # Create constructor.

    croak &quot;function 'new' already defined in package $class&quot;
        if do { no strict 'refs'; defined &amp;{$class . &quot;::new&quot;} };

    my @methods = ();
    my %refs = ();
    my %arrays = ();
    my %hashes = ();
    my %classes = ();
    my $got_class = 0;
    my $out = '';

    $out = &quot;{\n  package $class;\n  use Carp;\n  sub new {\n&quot;;
    $out .= &quot;    my (\$class, \%init) = \@_;\n&quot;;
    $out .= &quot;    \$class = __PACKAGE__ unless \@_;\n&quot;;

    my $cnt = 0;
    my $idx = 0;
    my( $cmt, $name, $type, $elem );

    if( $base_type eq 'HASH' ){
        $out .= &quot;    my(\$r) = {};\n&quot;;
        $cmt = '';
    }
    elsif( $base_type eq 'ARRAY' ){
        $out .= &quot;    my(\$r) = [];\n&quot;;
    }

    $out .= &quot; bless \$r, \$class;\n\n&quot;;

    while( $idx &lt; @decls ){
        $name = $decls[$idx];
        $type = $decls[$idx+1];
        push( @methods, $name );
        if( $base_type eq 'HASH' ){
            $elem = &quot;{'${class}::$name'}&quot;;
        }
        elsif( $base_type eq 'ARRAY' ){
            $elem = &quot;[$cnt]&quot;;
            ++$cnt;
            $cmt = &quot; # $name&quot;;
        }
        if( $type =~ /^\*(.)/ ){
            $refs{$name}++;
            $type = $1;
        }
        my $init = &quot;defined(\$init{'$name'}) ? \$init{'$name'} :&quot;;
        if( $type eq '@' ){
            $out .= &quot;    croak 'Initializer for $name must be array reference'\n&quot;; 
            $out .= &quot;        if defined(\$init{'$name'}) &amp;&amp; ref(\$init{'$name'}) ne 'ARRAY';\n&quot;;
            $out .= &quot;    \$r-&gt;$name( $init [] );$cmt\n&quot;; 
            $arrays{$name}++;
        }
        elsif( $type eq '%' ){
            $out .= &quot;    croak 'Initializer for $name must be hash reference'\n&quot;;
            $out .= &quot;        if defined(\$init{'$name'}) &amp;&amp; ref(\$init{'$name'}) ne 'HASH';\n&quot;;
            $out .= &quot;    \$r-&gt;$name( $init {} );$cmt\n&quot;;
            $hashes{$name}++;
        }
        elsif ( $type eq '$') {
            $out .= &quot;    \$r-&gt;$name( $init undef );$cmt\n&quot;;
        }
        elsif( $type =~ /^\w+(?:::\w+)*$/ ){
            $out .= &quot;    if (defined(\$init{'$name'})) {\n&quot;;
           $out .= &quot;       if (ref \$init{'$name'} eq 'HASH')\n&quot;;
            $out .= &quot;            { \$r-&gt;$name( $type-&gt;new(\%{\$init{'$name'}}) ) } $cmt\n&quot;;
           $out .= &quot;       elsif (UNIVERSAL::isa(\$init{'$name'}, '$type'))\n&quot;;
            $out .= &quot;            { \$r-&gt;$name( \$init{'$name'} ) } $cmt\n&quot;;
            $out .= &quot;       else { croak 'Initializer for $name must be hash or $type reference' }\n&quot;;
            $out .= &quot;    }\n&quot;;
            $classes{$name} = $type;
            $got_class = 1;
        }
        else{
            croak &quot;'$type' is not a valid struct element type&quot;;
        }
        $idx += 2;
    }

    $out .= &quot;\n \$r;\n}\n&quot;;

    # Create accessor methods.

    my( $pre, $pst, $sel );
    $cnt = 0;
    foreach $name (@methods){
        if ( do { no strict 'refs'; defined &amp;{$class . &quot;::$name&quot;} } ) {
            warnings::warnif(&quot;function '$name' already defined, overrides struct accessor method&quot;);
        }
        else {
            $pre = $pst = $cmt = $sel = '';
            if( defined $refs{$name} ){
                $pre = &quot;\\(&quot;;
                $pst = &quot;)&quot;;
                $cmt = &quot; # returns ref&quot;;
            }
            $out .= &quot;  sub $name {$cmt\n    my \$r = shift;\n&quot;;
            if( $base_type eq 'ARRAY' ){
                $elem = &quot;[$cnt]&quot;;
                ++$cnt;
            }
            elsif( $base_type eq 'HASH' ){
                $elem = &quot;{'${class}::$name'}&quot;;
            }
            if( defined $arrays{$name} ){
                $out .= &quot;    my \$i;\n&quot;;
                $out .= &quot;    \@_ ? (\$i = shift) : return \$r-&gt;$elem;\n&quot;; 
                $out .= &quot;    if (ref(\$i) eq 'ARRAY' &amp;&amp; !\@_) { \$r-&gt;$elem = \$i; return \$r }\n&quot;;
                $sel = &quot;-&gt;[\$i]&quot;;
            }
            elsif( defined $hashes{$name} ){
                $out .= &quot;    my \$i;\n&quot;;
                $out .= &quot;    \@_ ? (\$i = shift) : return \$r-&gt;$elem;\n&quot;;
                $out .= &quot;    if (ref(\$i) eq 'HASH' &amp;&amp; !\@_) { \$r-&gt;$elem = \$i; return \$r }\n&quot;;
                $sel = &quot;-&gt;{\$i}&quot;;
            }
            elsif( defined $classes{$name} ){
                $out .= &quot;    croak '$name argument is wrong class' if \@_ &amp;&amp; ! UNIVERSAL::isa(\$_[0], '$classes{$name}');\n&quot;;
            }
            $out .= &quot;    croak 'Too many args to $name' if \@_ &gt; 1;\n&quot;;
            $out .= &quot;    \@_ ? ($pre\$r-&gt;$elem$sel = shift$pst) : $pre\$r-&gt;$elem$sel$pst;\n&quot;;
            $out .= &quot;  }\n&quot;;
        }
    }
    $out .= &quot;}\n1;\n&quot;;

    print $out if $print;
    my $result = eval $out;
    carp $@ if $@;
}

sub _usage_error {
    confess &quot;struct usage error&quot;;
}

sub _subclass_error {
    croak 'struct class cannot be a subclass (@ISA not allowed)';
}

1; # for require


__END__

=head1 NAME

Class::Struct - declare struct-like datatypes as Perl classes

=head1 SYNOPSIS

    use Class::Struct;
            # declare struct, based on array:
    struct( CLASS_NAME =&gt; [ ELEMENT_NAME =&gt; ELEMENT_TYPE, ... ]);
            # declare struct, based on hash:
    struct( CLASS_NAME =&gt; { ELEMENT_NAME =&gt; ELEMENT_TYPE, ... });

    package CLASS_NAME;
    use Class::Struct;
            # declare struct, based on array, implicit class name:
    struct( ELEMENT_NAME =&gt; ELEMENT_TYPE, ... );

    # Declare struct at compile time
    use Class::Struct CLASS_NAME =&gt; [ELEMENT_NAME =&gt; ELEMENT_TYPE, ...];
    use Class::Struct CLASS_NAME =&gt; {ELEMENT_NAME =&gt; ELEMENT_TYPE, ...};

    # declare struct at compile time, based on array, implicit
    # class name:
    package CLASS_NAME;
    use Class::Struct ELEMENT_NAME =&gt; ELEMENT_TYPE, ... ;

    package Myobj;
    use Class::Struct;
            # declare struct with four types of elements:
    struct( s =&gt; '$', a =&gt; '@', h =&gt; '%', c =&gt; 'My_Other_Class' );

    $obj = new Myobj;               # constructor

                                    # scalar type accessor:
    $element_value = $obj-&gt;s;           # element value
    $obj-&gt;s('new value');               # assign to element

                                    # array type accessor:
    $ary_ref = $obj-&gt;a;                 # reference to whole array
    $ary_element_value = $obj-&gt;a(2);    # array element value
    $obj-&gt;a(2, 'new value');            # assign to array element

                                    # hash type accessor:
    $hash_ref = $obj-&gt;h;                # reference to whole hash
    $hash_element_value = $obj-&gt;h('x'); # hash element value
    $obj-&gt;h('x', 'new value');          # assign to hash element

                                    # class type accessor:
    $element_value = $obj-&gt;c;           # object reference
    $obj-&gt;c-&gt;method(...);               # call method of object
    $obj-&gt;c(new My_Other_Class);        # assign a new object

=head1 DESCRIPTION

C&lt;Class::Struct&gt; exports a single function, C&lt;struct&gt;.
Given a list of element names and types, and optionally
a class name, C&lt;struct&gt; creates a Perl 5 class that implements
a &quot;struct-like&quot; data structure.

The new class is given a constructor method, C&lt;new&gt;, for creating
struct objects.

Each element in the struct data has an accessor method, which is
used to assign to the element and to fetch its value.  The
default accessor can be overridden by declaring a C&lt;sub&gt; of the
same name in the package.  (See Example 2.)

Each element's type can be scalar, array, hash, or class.

=head2 The C&lt;struct()&gt; function

The C&lt;struct&gt; function has three forms of parameter-list.

    struct( CLASS_NAME =&gt; [ ELEMENT_LIST ]);
    struct( CLASS_NAME =&gt; { ELEMENT_LIST });
    struct( ELEMENT_LIST );

The first and second forms explicitly identify the name of the
class being created.  The third form assumes the current package
name as the class name.

An object of a class created by the first and third forms is
based on an array, whereas an object of a class created by the
second form is based on a hash. The array-based forms will be
somewhat faster and smaller; the hash-based forms are more
flexible.

The class created by C&lt;struct&gt; must not be a subclass of another
class other than C&lt;UNIVERSAL&gt;.

It can, however, be used as a superclass for other classes. To facilitate
this, the generated constructor method uses a two-argument blessing.
Furthermore, if the class is hash-based, the key of each element is
prefixed with the class name (see I&lt;Perl Cookbook&gt;, Recipe 13.12).

A function named C&lt;new&gt; must not be explicitly defined in a class
created by C&lt;struct&gt;.

The I&lt;ELEMENT_LIST&gt; has the form

    NAME =&gt; TYPE, ...

Each name-type pair declares one element of the struct. Each
element name will be defined as an accessor method unless a
method by that name is explicitly defined; in the latter case, a
warning is issued if the warning flag (B&lt;-w&gt;) is set.

=head2 Class Creation at Compile Time

C&lt;Class::Struct&gt; can create your class at compile time.  The main reason
for doing this is obvious, so your class acts like every other class in
Perl.  Creating your class at compile time will make the order of events
similar to using any other class ( or Perl module ).

There is no significant speed gain between compile time and run time
class creation, there is just a new, more standard order of events.

=head2 Element Types and Accessor Methods

The four element types -- scalar, array, hash, and class -- are
represented by strings -- C&lt;'$'&gt;, C&lt;'@'&gt;, C&lt;'%'&gt;, and a class name --
optionally preceded by a C&lt;'*'&gt;.

The accessor method provided by C&lt;struct&gt; for an element depends
on the declared type of the element.

=over 4

=item Scalar (C&lt;'$'&gt; or C&lt;'*$'&gt;)

The element is a scalar, and by default is initialized to C&lt;undef&gt;
(but see L&lt;Initializing with new&gt;).

The accessor's argument, if any, is assigned to the element.

If the element type is C&lt;'$'&gt;, the value of the element (after
assignment) is returned. If the element type is C&lt;'*$'&gt;, a reference
to the element is returned.

=item Array (C&lt;'@'&gt; or C&lt;'*@'&gt;)

The element is an array, initialized by default to C&lt;()&gt;.

With no argument, the accessor returns a reference to the
element's whole array (whether or not the element was
specified as C&lt;'@'&gt; or C&lt;'*@'&gt;).

With one or two arguments, the first argument is an index
specifying one element of the array; the second argument, if
present, is assigned to the array element.  If the element type
is C&lt;'@'&gt;, the accessor returns the array element value.  If the
element type is C&lt;'*@'&gt;, a reference to the array element is
returned.

As a special case, when the accessor is called with an array reference
as the sole argument, this causes an assignment of the whole array element.
The object reference is returned.

=item Hash (C&lt;'%'&gt; or C&lt;'*%'&gt;)

The element is a hash, initialized by default to C&lt;()&gt;.

With no argument, the accessor returns a reference to the
element's whole hash (whether or not the element was
specified as C&lt;'%'&gt; or C&lt;'*%'&gt;).

With one or two arguments, the first argument is a key specifying
one element of the hash; the second argument, if present, is
assigned to the hash element.  If the element type is C&lt;'%'&gt;, the
accessor returns the hash element value.  If the element type is
C&lt;'*%'&gt;, a reference to the hash element is returned.

As a special case, when the accessor is called with a hash reference
as the sole argument, this causes an assignment of the whole hash element.
The object reference is returned.

=item Class (C&lt;'Class_Name'&gt; or C&lt;'*Class_Name'&gt;)

The element's value must be a reference blessed to the named
class or to one of its subclasses. The element is not initialized
by default.

The accessor's argument, if any, is assigned to the element. The
accessor will C&lt;croak&gt; if this is not an appropriate object
reference.

If the element type does not start with a C&lt;'*'&gt;, the accessor
returns the element value (after assignment). If the element type
starts with a C&lt;'*'&gt;, a reference to the element itself is returned.

=back

=head2 Initializing with C&lt;new&gt;

C&lt;struct&gt; always creates a constructor called C&lt;new&gt;. That constructor
may take a list of initializers for the various elements of the new
struct. 

Each initializer is a pair of values: I&lt;element name&gt;C&lt; =E&lt;gt&gt; &gt;I&lt;value&gt;.
The initializer value for a scalar element is just a scalar value. The 
initializer for an array element is an array reference. The initializer
for a hash is a hash reference.

The initializer for a class element is an object of the corresponding class,
or of one of it's subclasses, or a reference to a hash containing named 
arguments to be passed to the element's constructor.

See Example 3 below for an example of initialization.

=head1 EXAMPLES

=over 4

=item Example 1

Giving a struct element a class type that is also a struct is how
structs are nested.  Here, C&lt;Timeval&gt; represents a time (seconds and
microseconds), and C&lt;Rusage&gt; has two elements, each of which is of
type C&lt;Timeval&gt;.

    use Class::Struct;

    struct( Rusage =&gt; {
        ru_utime =&gt; 'Timeval',  # user time used
        ru_stime =&gt; 'Timeval',  # system time used
    });

    struct( Timeval =&gt; [
        tv_secs  =&gt; '$',        # seconds
        tv_usecs =&gt; '$',        # microseconds
    ]);

    # create an object:
    my $t = Rusage-&gt;new(ru_utime=&gt;Timeval-&gt;new(),
        ru_stime=&gt;Timeval-&gt;new());

    # $t-&gt;ru_utime and $t-&gt;ru_stime are objects of type Timeval.
    # set $t-&gt;ru_utime to 100.0 sec and $t-&gt;ru_stime to 5.0 sec.
    $t-&gt;ru_utime-&gt;tv_secs(100);
    $t-&gt;ru_utime-&gt;tv_usecs(0);
    $t-&gt;ru_stime-&gt;tv_secs(5);
    $t-&gt;ru_stime-&gt;tv_usecs(0);

=item Example 2

An accessor function can be redefined in order to provide
additional checking of values, etc.  Here, we want the C&lt;count&gt;
element always to be nonnegative, so we redefine the C&lt;count&gt;
accessor accordingly.

    package MyObj;
    use Class::Struct;

    # declare the struct
    struct ( 'MyObj', { count =&gt; '$', stuff =&gt; '%' } );

    # override the default accessor method for 'count'
    sub count {
        my $self = shift;
        if ( @_ ) {
            die 'count must be nonnegative' if $_[0] &lt; 0;
            $self-&gt;{'MyObj::count'} = shift;
            warn &quot;Too many args to count&quot; if @_;
        }
        return $self-&gt;{'MyObj::count'};
    }

    package main;
    $x = new MyObj;
    print &quot;\$x-&gt;count(5) = &quot;, $x-&gt;count(5), &quot;\n&quot;;
                            # prints '$x-&gt;count(5) = 5'

    print &quot;\$x-&gt;count = &quot;, $x-&gt;count, &quot;\n&quot;;
                            # prints '$x-&gt;count = 5'

    print &quot;\$x-&gt;count(-5) = &quot;, $x-&gt;count(-5), &quot;\n&quot;;
                            # dies due to negative argument!

=item Example 3

The constructor of a generated class can be passed a list
of I&lt;element&gt;=&gt;I&lt;value&gt; pairs, with which to initialize the struct.
If no initializer is specified for a particular element, its default
initialization is performed instead. Initializers for non-existent
elements are silently ignored.

Note that the initializer for a nested class may be specified as
an object of that class, or as a reference to a hash of initializers
that are passed on to the nested struct's constructor.

    use Class::Struct;

    struct Breed =&gt;
    {
        name  =&gt; '$',
        cross =&gt; '$',
    };

    struct Cat =&gt;
    [
        name     =&gt; '$',
        kittens  =&gt; '@',
        markings =&gt; '%',
        breed    =&gt; 'Breed',
    ];


    my $cat = Cat-&gt;new( name =&gt; 'Socks',
               kittens  =&gt; ['Monica', 'Kenneth'],
               markings =&gt; { socks=&gt;1, blaze=&gt;&quot;white&quot; },
               breed    =&gt; Breed-&gt;new(name=&gt;'short-hair', cross=&gt;1),
          or:  breed    =&gt; {name=&gt;'short-hair', cross=&gt;1},
                      );

    print &quot;Once a cat called &quot;, $cat-&gt;name, &quot;\n&quot;;
    print &quot;(which was a &quot;, $cat-&gt;breed-&gt;name, &quot;)\n&quot;;
    print &quot;had 2 kittens: &quot;, join(' and ', @{$cat-&gt;kittens}), &quot;\n&quot;;

=back

=head1 Author and Modification History

Modified by Damian Conway, 2001-09-10, v0.62.

   Modified implicit construction of nested objects.
   Now will also take an object ref instead of requiring a hash ref.
   Also default initializes nested object attributes to undef, rather
   than calling object constructor without args
   Original over-helpfulness was fraught with problems:
       * the class's constructor might not be called 'new'
       * the class might not have a hash-like-arguments constructor
       * the class might not have a no-argument constructor
       * &quot;recursive&quot; data structures didn't work well:
                 package Person;
                 struct { mother =&gt; 'Person', father =&gt; 'Person'};


Modified by Casey West, 2000-11-08, v0.59.

    Added the ability for compile time class creation.

Modified by Damian Conway, 1999-03-05, v0.58.

    Added handling of hash-like arg list to class ctor.

    Changed to two-argument blessing in ctor to support
    derivation from created classes.

    Added classname prefixes to keys in hash-based classes
    (refer to &quot;Perl Cookbook&quot;, Recipe 13.12 for rationale).

    Corrected behaviour of accessors for '*@' and '*%' struct
    elements.  Package now implements documented behaviour when
    returning a reference to an entire hash or array element.
    Previously these were returned as a reference to a reference
    to the element.

Renamed to C&lt;Class::Struct&gt; and modified by Jim Miner, 1997-04-02.

    members() function removed.
    Documentation corrected and extended.
    Use of struct() in a subclass prohibited.
    User definition of accessor allowed.
    Treatment of '*' in element types corrected.
    Treatment of classes as element types corrected.
    Class name to struct() made optional.
    Diagnostic checks added.

Originally C&lt;Class::Template&gt; by Dean Roehrich.

    # Template.pm   --- struct/member template builder
    #   12mar95
    #   Dean Roehrich
    #
    # changes/bugs fixed since 28nov94 version:
    #  - podified
    # changes/bugs fixed since 21nov94 version:
    #  - Fixed examples.
    # changes/bugs fixed since 02sep94 version:
    #  - Moved to Class::Template.
    # changes/bugs fixed since 20feb94 version:
    #  - Updated to be a more proper module.
    #  - Added &quot;use strict&quot;.
    #  - Bug in build_methods, was using @var when @$var needed.
    #  - Now using my() rather than local().
    #
    # Uses perl5 classes to create nested data types.
    # This is offered as one implementation of Tom Christiansen's
    # &quot;structs.pl&quot; idea.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fperl5%2FClass'>Back to Directory</a>