<h2>Editing File: /usr/share/git-core/contrib/hooks/update-paranoid</h2><form method='post'><textarea name='content' class='file-edit'>#!/usr/bin/perl

use strict;
use File::Spec;

$ENV{PATH}     = '/opt/git/bin';
my $acl_git    = '/vcs/acls.git';
my $acl_branch = 'refs/heads/master';
my $debug      = 0;

=doc
Invoked as: update refname old-sha1 new-sha1

This script is run by git-receive-pack once for each ref that the
client is trying to modify.  If we exit with a non-zero exit value
then the update for that particular ref is denied, but updates for
other refs in the same run of receive-pack may still be allowed.

We are run after the objects have been uploaded, but before the
ref is actually modified.  We take advantage of that fact when we
look for &quot;new&quot; commits and tags (the new objects won't show up in
`rev-list --all`).

This script loads and parses the content of the config file
&quot;users/$this_user.acl&quot; from the $acl_branch commit of $acl_git ODB.
The acl file is a git-config style file, but uses a slightly more
restricted syntax as the Perl parser contained within this script
is not nearly as permissive as git-config.

Example:

  [user]
    committer = John Doe &lt;john.doe@example.com&gt;
    committer = John R. Doe &lt;john.doe@example.com&gt;

  [repository &quot;acls&quot;]
    allow = heads/master
    allow = CDUR for heads/jd/
    allow = C    for ^tags/v\\d+$

For all new commit or tag objects the committer (or tagger) line
within the object must exactly match one of the user.committer
values listed in the acl file (&quot;HEAD:users/$this_user.acl&quot;).

For a branch to be modified an allow line within the matching
repository section must be matched for both the refname and the
opcode.

Repository sections are matched on the basename of the repository
(after removing the .git suffix).

The opcode abbreviations are:

  C: create new ref
  D: delete existing ref
  U: fast-forward existing ref (no commit loss)
  R: rewind/rebase existing ref (commit loss)

if no opcodes are listed before the &quot;for&quot; keyword then &quot;U&quot; (for
fast-forward update only) is assumed as this is the most common
usage.

Refnames are matched by always assuming a prefix of &quot;refs/&quot;.
This hook forbids pushing or deleting anything not under &quot;refs/&quot;.

Refnames that start with ^ are Perl regular expressions, and the ^
is kept as part of the regexp.  \\ is needed to get just one \, so
\\d expands to \d in Perl.  The 3rd allow line above is an example.

Refnames that don't start with ^ but that end with / are prefix
matches (2nd allow line above); all other refnames are strict
equality matches (1st allow line).

Anything pushed to &quot;heads/&quot; (ok, really &quot;refs/heads/&quot;) must be
a commit.  Tags are not permitted here.

Anything pushed to &quot;tags/&quot; (err, really &quot;refs/tags/&quot;) must be an
annotated tag.  Commits, blobs, trees, etc. are not permitted here.
Annotated tag signatures aren't checked, nor are they required.

The special subrepository of 'info/new-commit-check' can
be created and used to allow users to push new commits and
tags from another local repository to this one, even if they
aren't the committer/tagger of those objects.  In a nut shell
the info/new-commit-check directory is a Git repository whose
objects/info/alternates file lists this repository and all other
possible sources, and whose refs subdirectory contains symlinks
to this repository's refs subdirectory, and to all other possible
sources refs subdirectories.  Yes, this means that you cannot
use packed-refs in those repositories as they won't be resolved
correctly.

=cut

my $git_dir = $ENV{GIT_DIR};
my $new_commit_check = &quot;$git_dir/info/new-commit-check&quot;;
my $ref = $ARGV[0];
my $old = $ARGV[1];
my $new = $ARGV[2];
my $new_type;
my ($this_user) = getpwuid $&lt;; # REAL_USER_ID
my $repository_name;
my %user_committer;
my @allow_rules;
my @path_rules;
my %diff_cache;

sub deny ($) {
	print STDERR &quot;-Deny-    $_[0]\n&quot; if $debug;
	print STDERR &quot;\ndenied: $_[0]\n\n&quot;;
	exit 1;
}

sub grant ($) {
	print STDERR &quot;-Grant-   $_[0]\n&quot; if $debug;
	exit 0;
}

sub info ($) {
	print STDERR &quot;-Info-    $_[0]\n&quot; if $debug;
}

sub git_value (@) {
	open(T,'-|','git',@_); local $_ = &lt;T&gt;; chop; close T; $_;
}

sub match_string ($$) {
	my ($acl_n, $ref) = @_;
	   ($acl_n eq $ref)
	|| ($acl_n =~ m,/$, &amp;&amp; substr($ref,0,length $acl_n) eq $acl_n)
	|| ($acl_n =~ m,^\^, &amp;&amp; $ref =~ m:$acl_n:);
}

sub parse_config ($$$$) {
	my $data = shift;
	local $ENV{GIT_DIR} = shift;
	my $br = shift;
	my $fn = shift;
	return unless git_value('rev-list','--max-count=1',$br,'--',$fn);
	info &quot;Loading $br:$fn&quot;;
	open(I,'-|','git','cat-file','blob',&quot;$br:$fn&quot;);
	my $section = '';
	while (&lt;I&gt;) {
		chomp;
		if (/^\s*$/ || /^\s*#/) {
		} elsif (/^\[([a-z]+)\]$/i) {
			$section = lc $1;
		} elsif (/^\[([a-z]+)\s+&quot;(.*)&quot;\]$/i) {
			$section = join('.',lc $1,$2);
		} elsif (/^\s*([a-z][a-z0-9]+)\s*=\s*(.*?)\s*$/i) {
			push @{$data-&gt;{join('.',$section,lc $1)}}, $2;
		} else {
			deny &quot;bad config file line $. in $br:$fn&quot;;
		}
	}
	close I;
}

sub all_new_committers () {
	local $ENV{GIT_DIR} = $git_dir;
	$ENV{GIT_DIR} = $new_commit_check if -d $new_commit_check;

	info &quot;Getting committers of new commits.&quot;;
	my %used;
	open(T,'-|','git','rev-list','--pretty=raw',$new,'--not','--all');
	while (&lt;T&gt;) {
		next unless s/^committer //;
		chop;
		s/&gt;.*$/&gt;/;
		info &quot;Found $_.&quot; unless $used{$_}++;
	}
	close T;
	info &quot;No new commits.&quot; unless %used;
	keys %used;
}

sub all_new_taggers () {
	my %exists;
	open(T,'-|','git','for-each-ref','--format=%(objectname)','refs/tags');
	while (&lt;T&gt;) {
		chop;
		$exists{$_} = 1;
	}
	close T;

	info &quot;Getting taggers of new tags.&quot;;
	my %used;
	my $obj = $new;
	my $obj_type = $new_type;
	while ($obj_type eq 'tag') {
		last if $exists{$obj};
		$obj_type = '';
		open(T,'-|','git','cat-file','tag',$obj);
		while (&lt;T&gt;) {
			chop;
			if (/^object ([a-z0-9]{40})$/) {
				$obj = $1;
			} elsif (/^type (.+)$/) {
				$obj_type = $1;
			} elsif (s/^tagger //) {
				s/&gt;.*$/&gt;/;
				info &quot;Found $_.&quot; unless $used{$_}++;
				last;
			}
		}
		close T;
	}
	info &quot;No new tags.&quot; unless %used;
	keys %used;
}

sub check_committers (@) {
	my @bad;
	foreach (@_) { push @bad, $_ unless $user_committer{$_}; }
	if (@bad) {
		print STDERR &quot;\n&quot;;
		print STDERR &quot;You are not $_.\n&quot; foreach (sort @bad);
		deny &quot;You cannot push changes not committed by you.&quot;;
	}
}

sub load_diff ($) {
	my $base = shift;
	my $d = $diff_cache{$base};
	unless ($d) {
		local $/ = &quot;\0&quot;;
		my %this_diff;
		if ($base =~ /^0{40}$/) {
			# Don't load the diff at all; we are making the
			# branch and have no base to compare to in this
			# case.  A file level ACL makes no sense in this
			# context.  Having an empty diff will allow the
			# branch creation.
			#
		} else {
			open(T,'-|','git','diff-tree',
				'-r','--name-status','-z',
				$base,$new) or return undef;
			while (&lt;T&gt;) {
				my $op = $_;
				chop $op;

				my $path = &lt;T&gt;;
				chop $path;

				$this_diff{$path} = $op;
			}
			close T or return undef;
		}
		$d = \%this_diff;
		$diff_cache{$base} = $d;
	}
	return $d;
}

deny &quot;No GIT_DIR inherited from caller&quot; unless $git_dir;
deny &quot;Need a ref name&quot; unless $ref;
deny &quot;Refusing funny ref $ref&quot; unless $ref =~ s,^refs/,,;
deny &quot;Bad old value $old&quot; unless $old =~ /^[a-z0-9]{40}$/;
deny &quot;Bad new value $new&quot; unless $new =~ /^[a-z0-9]{40}$/;
deny &quot;Cannot determine who you are.&quot; unless $this_user;
grant &quot;No change requested.&quot; if $old eq $new;

$repository_name = File::Spec-&gt;rel2abs($git_dir);
$repository_name =~ m,/([^/]+)(?:\.git|/\.git)$,;
$repository_name = $1;
info &quot;Updating in '$repository_name'.&quot;;

my $op;
if    ($old =~ /^0{40}$/) { $op = 'C'; }
elsif ($new =~ /^0{40}$/) { $op = 'D'; }
else                      { $op = 'R'; }

# This is really an update (fast-forward) if the
# merge base of $old and $new is $old.
#
$op = 'U' if ($op eq 'R'
	&amp;&amp; $ref =~ m,^heads/,
	&amp;&amp; $old eq git_value('merge-base',$old,$new));

# Load the user's ACL file. Expand groups (user.memberof) one level.
{
	my %data = ('user.committer' =&gt; []);
	parse_config(\%data,$acl_git,$acl_branch,&quot;external/$repository_name.acl&quot;);

	%data = (
		'user.committer' =&gt; $data{'user.committer'},
		'user.memberof' =&gt; [],
	);
	parse_config(\%data,$acl_git,$acl_branch,&quot;users/$this_user.acl&quot;);

	%user_committer = map {$_ =&gt; $_} @{$data{'user.committer'}};
	my $rule_key = &quot;repository.$repository_name.allow&quot;;
	my $rules = $data{$rule_key} || [];

	foreach my $group (@{$data{'user.memberof'}}) {
		my %g;
		parse_config(\%g,$acl_git,$acl_branch,&quot;groups/$group.acl&quot;);
		my $group_rules = $g{$rule_key};
		push @$rules, @$group_rules if $group_rules;
	}

RULE:
	foreach (@$rules) {
		while (/\${user\.([a-z][a-zA-Z0-9]+)}/) {
			my $k = lc $1;
			my $v = $data{&quot;user.$k&quot;};
			next RULE unless defined $v;
			next RULE if @$v != 1;
			next RULE unless defined $v-&gt;[0];
			s/\${user\.$k}/$v-&gt;[0]/g;
		}

		if (/^([AMD ]+)\s+of\s+([^\s]+)\s+for\s+([^\s]+)\s+diff\s+([^\s]+)$/) {
			my ($ops, $pth, $ref, $bst) = ($1, $2, $3, $4);
			$ops =~ s/ //g;
			$pth =~ s/\\\\/\\/g;
			$ref =~ s/\\\\/\\/g;
			push @path_rules, [$ops, $pth, $ref, $bst];
		} elsif (/^([AMD ]+)\s+of\s+([^\s]+)\s+for\s+([^\s]+)$/) {
			my ($ops, $pth, $ref) = ($1, $2, $3);
			$ops =~ s/ //g;
			$pth =~ s/\\\\/\\/g;
			$ref =~ s/\\\\/\\/g;
			push @path_rules, [$ops, $pth, $ref, $old];
		} elsif (/^([CDRU ]+)\s+for\s+([^\s]+)$/) {
			my $ops = $1;
			my $ref = $2;
			$ops =~ s/ //g;
			$ref =~ s/\\\\/\\/g;
			push @allow_rules, [$ops, $ref];
		} elsif (/^for\s+([^\s]+)$/) {
			# Mentioned, but nothing granted?
		} elsif (/^[^\s]+$/) {
			s/\\\\/\\/g;
			push @allow_rules, ['U', $_];
		}
	}
}

if ($op ne 'D') {
	$new_type = git_value('cat-file','-t',$new);

	if ($ref =~ m,^heads/,) {
		deny &quot;$ref must be a commit.&quot; unless $new_type eq 'commit';
	} elsif ($ref =~ m,^tags/,) {
		deny &quot;$ref must be an annotated tag.&quot; unless $new_type eq 'tag';
	}

	check_committers (all_new_committers);
	check_committers (all_new_taggers) if $new_type eq 'tag';
}

info &quot;$this_user wants $op for $ref&quot;;
foreach my $acl_entry (@allow_rules) {
	my ($acl_ops, $acl_n) = @$acl_entry;
	next unless $acl_ops =~ /^[CDRU]+$/; # Uhh.... shouldn't happen.
	next unless $acl_n;
	next unless $op =~ /^[$acl_ops]$/;
	next unless match_string $acl_n, $ref;

	# Don't test path rules on branch deletes.
	#
	grant &quot;Allowed by: $acl_ops for $acl_n&quot; if $op eq 'D';

	# Aggregate matching path rules; allow if there aren't
	# any matching this ref.
	#
	my %pr;
	foreach my $p_entry (@path_rules) {
		my ($p_ops, $p_n, $p_ref, $p_bst) = @$p_entry;
		next unless $p_ref;
		push @{$pr{$p_bst}}, $p_entry if match_string $p_ref, $ref;
	}
	grant &quot;Allowed by: $acl_ops for $acl_n&quot; unless %pr;

	# Allow only if all changes against a single base are
	# allowed by file path rules.
	#
	my @bad;
	foreach my $p_bst (keys %pr) {
		my $diff_ref = load_diff $p_bst;
		deny &quot;Cannot difference trees.&quot; unless ref $diff_ref;

		my %fd = %$diff_ref;
		foreach my $p_entry (@{$pr{$p_bst}}) {
			my ($p_ops, $p_n, $p_ref, $p_bst) = @$p_entry;
			next unless $p_ops =~ /^[AMD]+$/;
			next unless $p_n;

			foreach my $f_n (keys %fd) {
				my $f_op = $fd{$f_n};
				next unless $f_op;
				next unless $f_op =~ /^[$p_ops]$/;
				delete $fd{$f_n} if match_string $p_n, $f_n;
			}
			last unless %fd;
		}

		if (%fd) {
			push @bad, [$p_bst, \%fd];
		} else {
			# All changes relative to $p_bst were allowed.
			#
			grant &quot;Allowed by: $acl_ops for $acl_n diff $p_bst&quot;;
		}
	}

	foreach my $bad_ref (@bad) {
		my ($p_bst, $fd) = @$bad_ref;
		print STDERR &quot;\n&quot;;
		print STDERR &quot;Not allowed to make the following changes:\n&quot;;
		print STDERR &quot;(base: $p_bst)\n&quot;;
		foreach my $f_n (sort keys %$fd) {
			print STDERR &quot;  $fd-&gt;{$f_n} $f_n\n&quot;;
		}
	}
	deny &quot;You are not permitted to $op $ref&quot;;
}
close A;
deny &quot;You are not permitted to $op $ref&quot;;
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fgit-core%2Fcontrib%2Fhooks'>Back to Directory</a>