<h2>Editing File: /usr/share/aclocal-1.16/depend.m4</h2><form method='post'><textarea name='content' class='file-edit'>##                                                          -*- Autoconf -*-
# Copyright (C) 1999-2018 Free Software Foundation, Inc.
#
# This file is free software; the Free Software Foundation
# gives unlimited permission to copy and/or distribute it,
# with or without modifications, as long as this notice is preserved.


# There are a few dirty hacks below to avoid letting 'AC_PROG_CC' be
# written in clear, in which case automake, when reading aclocal.m4,
# will think it sees a *use*, and therefore will trigger all it's
# C support machinery.  Also note that it means that autoscan, seeing
# CC etc. in the Makefile, will ask for an AC_PROG_CC use...


# _AM_DEPENDENCIES(NAME)
# ----------------------
# See how the compiler implements dependency checking.
# NAME is &quot;CC&quot;, &quot;CXX&quot;, &quot;OBJC&quot;, &quot;OBJCXX&quot;, &quot;UPC&quot;, or &quot;GJC&quot;.
# We try a few techniques and use that to set a single cache variable.
#
# We don't AC_REQUIRE the corresponding AC_PROG_CC since the latter was
# modified to invoke _AM_DEPENDENCIES(CC); we would have a circular
# dependency, and given that the user is not expected to run this macro,
# just rely on AC_PROG_CC.
AC_DEFUN([_AM_DEPENDENCIES],
[AC_REQUIRE([AM_SET_DEPDIR])dnl
AC_REQUIRE([AM_OUTPUT_DEPENDENCY_COMMANDS])dnl
AC_REQUIRE([AM_MAKE_INCLUDE])dnl
AC_REQUIRE([AM_DEP_TRACK])dnl

m4_if([$1], [CC],   [depcc=&quot;$CC&quot;   am_compiler_list=],
      [$1], [CXX],  [depcc=&quot;$CXX&quot;  am_compiler_list=],
      [$1], [OBJC], [depcc=&quot;$OBJC&quot; am_compiler_list='gcc3 gcc'],
      [$1], [OBJCXX], [depcc=&quot;$OBJCXX&quot; am_compiler_list='gcc3 gcc'],
      [$1], [UPC],  [depcc=&quot;$UPC&quot;  am_compiler_list=],
      [$1], [GCJ],  [depcc=&quot;$GCJ&quot;  am_compiler_list='gcc3 gcc'],
                    [depcc=&quot;$$1&quot;   am_compiler_list=])

AC_CACHE_CHECK([dependency style of $depcc],
               [am_cv_$1_dependencies_compiler_type],
[if test -z &quot;$AMDEP_TRUE&quot; &amp;&amp; test -f &quot;$am_depcomp&quot;; then
  # We make a subdir and do the tests there.  Otherwise we can end up
  # making bogus files that we don't know about and never remove.  For
  # instance it was reported that on HP-UX the gcc test will end up
  # making a dummy file named 'D' -- because '-MD' means &quot;put the output
  # in D&quot;.
  rm -rf conftest.dir
  mkdir conftest.dir
  # Copy depcomp to subdir because otherwise we won't find it if we're
  # using a relative directory.
  cp &quot;$am_depcomp&quot; conftest.dir
  cd conftest.dir
  # We will build objects and dependencies in a subdirectory because
  # it helps to detect inapplicable dependency modes.  For instance
  # both Tru64's cc and ICC support -MD to output dependencies as a
  # side effect of compilation, but ICC will put the dependencies in
  # the current directory while Tru64 will put them in the object
  # directory.
  mkdir sub

  am_cv_$1_dependencies_compiler_type=none
  if test &quot;$am_compiler_list&quot; = &quot;&quot;; then
     am_compiler_list=`sed -n ['s/^#*\([a-zA-Z0-9]*\))$/\1/p'] &lt; ./depcomp`
  fi
  am__universal=false
  m4_case([$1], [CC],
    [case &quot; $depcc &quot; in #(
     *\ -arch\ *\ -arch\ *) am__universal=true ;;
     esac],
    [CXX],
    [case &quot; $depcc &quot; in #(
     *\ -arch\ *\ -arch\ *) am__universal=true ;;
     esac])

  for depmode in $am_compiler_list; do
    # Setup a source with many dependencies, because some compilers
    # like to wrap large dependency lists on column 80 (with \), and
    # we should not choose a depcomp mode which is confused by this.
    #
    # We need to recreate these files for each test, as the compiler may
    # overwrite some of them when testing with obscure command lines.
    # This happens at least with the AIX C compiler.
    : &gt; sub/conftest.c
    for i in 1 2 3 4 5 6; do
      echo '#include &quot;conftst'$i'.h&quot;' &gt;&gt; sub/conftest.c
      # Using &quot;: &gt; sub/conftst$i.h&quot; creates only sub/conftst1.h with
      # Solaris 10 /bin/sh.
      echo '/* dummy */' &gt; sub/conftst$i.h
    done
    echo &quot;${am__include} ${am__quote}sub/conftest.Po${am__quote}&quot; &gt; confmf

    # We check with '-c' and '-o' for the sake of the &quot;dashmstdout&quot;
    # mode.  It turns out that the SunPro C++ compiler does not properly
    # handle '-M -o', and we need to detect this.  Also, some Intel
    # versions had trouble with output in subdirs.
    am__obj=sub/conftest.${OBJEXT-o}
    am__minus_obj=&quot;-o $am__obj&quot;
    case $depmode in
    gcc)
      # This depmode causes a compiler race in universal mode.
      test &quot;$am__universal&quot; = false || continue
      ;;
    nosideeffect)
      # After this tag, mechanisms are not by side-effect, so they'll
      # only be used when explicitly requested.
      if test &quot;x$enable_dependency_tracking&quot; = xyes; then
	continue
      else
	break
      fi
      ;;
    msvc7 | msvc7msys | msvisualcpp | msvcmsys)
      # This compiler won't grok '-c -o', but also, the minuso test has
      # not run yet.  These depmodes are late enough in the game, and
      # so weak that their functioning should not be impacted.
      am__obj=conftest.${OBJEXT-o}
      am__minus_obj=
      ;;
    none) break ;;
    esac
    if depmode=$depmode \
       source=sub/conftest.c object=$am__obj \
       depfile=sub/conftest.Po tmpdepfile=sub/conftest.TPo \
       $SHELL ./depcomp $depcc -c $am__minus_obj sub/conftest.c \
         &gt;/dev/null 2&gt;conftest.err &amp;&amp;
       grep sub/conftst1.h sub/conftest.Po &gt; /dev/null 2&gt;&amp;1 &amp;&amp;
       grep sub/conftst6.h sub/conftest.Po &gt; /dev/null 2&gt;&amp;1 &amp;&amp;
       grep $am__obj sub/conftest.Po &gt; /dev/null 2&gt;&amp;1 &amp;&amp;
       ${MAKE-make} -s -f confmf &gt; /dev/null 2&gt;&amp;1; then
      # icc doesn't choke on unknown options, it will just issue warnings
      # or remarks (even with -Werror).  So we grep stderr for any message
      # that says an option was ignored or not supported.
      # When given -MP, icc 7.0 and 7.1 complain thusly:
      #   icc: Command line warning: ignoring option '-M'; no argument required
      # The diagnosis changed in icc 8.0:
      #   icc: Command line remark: option '-MP' not supported
      if (grep 'ignoring option' conftest.err ||
          grep 'not supported' conftest.err) &gt;/dev/null 2&gt;&amp;1; then :; else
        am_cv_$1_dependencies_compiler_type=$depmode
        break
      fi
    fi
  done

  cd ..
  rm -rf conftest.dir
else
  am_cv_$1_dependencies_compiler_type=none
fi
])
AC_SUBST([$1DEPMODE], [depmode=$am_cv_$1_dependencies_compiler_type])
AM_CONDITIONAL([am__fastdep$1], [
  test &quot;x$enable_dependency_tracking&quot; != xno \
  &amp;&amp; test &quot;$am_cv_$1_dependencies_compiler_type&quot; = gcc3])
])


# AM_SET_DEPDIR
# -------------
# Choose a directory name for dependency files.
# This macro is AC_REQUIREd in _AM_DEPENDENCIES.
AC_DEFUN([AM_SET_DEPDIR],
[AC_REQUIRE([AM_SET_LEADING_DOT])dnl
AC_SUBST([DEPDIR], [&quot;${am__leading_dot}deps&quot;])dnl
])


# AM_DEP_TRACK
# ------------
AC_DEFUN([AM_DEP_TRACK],
[AC_ARG_ENABLE([dependency-tracking], [dnl
AS_HELP_STRING(
  [--enable-dependency-tracking],
  [do not reject slow dependency extractors])
AS_HELP_STRING(
  [--disable-dependency-tracking],
  [speeds up one-time build])])
if test &quot;x$enable_dependency_tracking&quot; != xno; then
  am_depcomp=&quot;$ac_aux_dir/depcomp&quot;
  AMDEPBACKSLASH='\'
  am__nodep='_no'
fi
AM_CONDITIONAL([AMDEP], [test &quot;x$enable_dependency_tracking&quot; != xno])
AC_SUBST([AMDEPBACKSLASH])dnl
_AM_SUBST_NOTMAKE([AMDEPBACKSLASH])dnl
AC_SUBST([am__nodep])dnl
_AM_SUBST_NOTMAKE([am__nodep])dnl
])
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Faclocal-1.16'>Back to Directory</a>