<h2>Editing File: /usr/share/aclocal/libgcrypt.m4</h2><form method='post'><textarea name='content' class='file-edit'># libgcrypt.m4 - Autoconf macros to detect libgcrypt
# Copyright (C) 2002, 2003, 2004, 2011, 2014, 2018 g10 Code GmbH
#
# This file is free software; as a special exception the author gives
# unlimited permission to copy and/or distribute it, with or without
# modifications, as long as this notice is preserved.
#
# This file is distributed in the hope that it will be useful, but
# WITHOUT ANY WARRANTY, to the extent permitted by law; without even the
# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
#
# Last-changed: 2018-11-13


dnl AM_PATH_LIBGCRYPT([MINIMUM-VERSION,
dnl                   [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND ]]])
dnl Test for libgcrypt and define LIBGCRYPT_CFLAGS and LIBGCRYPT_LIBS.
dnl MINIMUN-VERSION is a string with the version number optionalliy prefixed
dnl with the API version to also check the API compatibility. Example:
dnl a MINIMUN-VERSION of 1:1.2.5 won't pass the test unless the installed
dnl version of libgcrypt is at least 1.2.5 *and* the API number is 1.  Using
dnl this features allows to prevent build against newer versions of libgcrypt
dnl with a changed API.
dnl
dnl If a prefix option is not used, the config script is first
dnl searched in $SYSROOT/bin and then along $PATH.  If the used
dnl config script does not match the host specification the script
dnl is added to the gpg_config_script_warn variable.
dnl
AC_DEFUN([AM_PATH_LIBGCRYPT],
[ AC_REQUIRE([AC_CANONICAL_HOST])
  AC_ARG_WITH(libgcrypt-prefix,
            AC_HELP_STRING([--with-libgcrypt-prefix=PFX],
                           [prefix where LIBGCRYPT is installed (optional)]),
     libgcrypt_config_prefix=&quot;$withval&quot;, libgcrypt_config_prefix=&quot;&quot;)
  if test x&quot;${LIBGCRYPT_CONFIG}&quot; = x ; then
     if test x&quot;${libgcrypt_config_prefix}&quot; != x ; then
        LIBGCRYPT_CONFIG=&quot;${libgcrypt_config_prefix}/bin/libgcrypt-config&quot;
     fi
  fi

  use_gpgrt_config=&quot;&quot;
  if test x&quot;${LIBGCRYPT_CONFIG}&quot; = x -a x&quot;$GPGRT_CONFIG&quot; != x -a &quot;$GPGRT_CONFIG&quot; != &quot;no&quot;; then
    if $GPGRT_CONFIG libgcrypt --exists; then
      LIBGCRYPT_CONFIG=&quot;$GPGRT_CONFIG libgcrypt&quot;
      AC_MSG_NOTICE([Use gpgrt-config as libgcrypt-config])
      use_gpgrt_config=yes
    fi
  fi
  if test -z &quot;$use_gpgrt_config&quot;; then
    if test x&quot;${LIBGCRYPT_CONFIG}&quot; = x ; then
      case &quot;${SYSROOT}&quot; in
         /*)
           if test -x &quot;${SYSROOT}/bin/libgcrypt-config&quot; ; then
             LIBGCRYPT_CONFIG=&quot;${SYSROOT}/bin/libgcrypt-config&quot;
           fi
           ;;
         '')
           ;;
          *)
           AC_MSG_WARN([Ignoring \$SYSROOT as it is not an absolute path.])
           ;;
      esac
    fi
    AC_PATH_PROG(LIBGCRYPT_CONFIG, libgcrypt-config, no)
  fi

  tmp=ifelse([$1], ,1:1.2.0,$1)
  if echo &quot;$tmp&quot; | grep ':' &gt;/dev/null 2&gt;/dev/null ; then
     req_libgcrypt_api=`echo &quot;$tmp&quot;     | sed 's/\(.*\):\(.*\)/\1/'`
     min_libgcrypt_version=`echo &quot;$tmp&quot; | sed 's/\(.*\):\(.*\)/\2/'`
  else
     req_libgcrypt_api=0
     min_libgcrypt_version=&quot;$tmp&quot;
  fi

  AC_MSG_CHECKING(for LIBGCRYPT - version &gt;= $min_libgcrypt_version)
  ok=no
  if test &quot;$LIBGCRYPT_CONFIG&quot; != &quot;no&quot; ; then
    req_major=`echo $min_libgcrypt_version | \
               sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\1/'`
    req_minor=`echo $min_libgcrypt_version | \
               sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\2/'`
    req_micro=`echo $min_libgcrypt_version | \
               sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\3/'`
    if test -z &quot;$use_gpgrt_config&quot;; then
      libgcrypt_config_version=`$LIBGCRYPT_CONFIG --version`
    else
      libgcrypt_config_version=`$LIBGCRYPT_CONFIG --modversion`
    fi
    major=`echo $libgcrypt_config_version | \
               sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
    minor=`echo $libgcrypt_config_version | \
               sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\2/'`
    micro=`echo $libgcrypt_config_version | \
               sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\3/'`
    if test &quot;$major&quot; -gt &quot;$req_major&quot;; then
        ok=yes
    else
        if test &quot;$major&quot; -eq &quot;$req_major&quot;; then
            if test &quot;$minor&quot; -gt &quot;$req_minor&quot;; then
               ok=yes
            else
               if test &quot;$minor&quot; -eq &quot;$req_minor&quot;; then
                   if test &quot;$micro&quot; -ge &quot;$req_micro&quot;; then
                     ok=yes
                   fi
               fi
            fi
        fi
    fi
  fi
  if test $ok = yes; then
    AC_MSG_RESULT([yes ($libgcrypt_config_version)])
  else
    AC_MSG_RESULT(no)
  fi
  if test $ok = yes; then
     # If we have a recent libgcrypt, we should also check that the
     # API is compatible
     if test &quot;$req_libgcrypt_api&quot; -gt 0 ; then
        if test -z &quot;$use_gpgrt_config&quot;; then
           tmp=`$LIBGCRYPT_CONFIG --api-version 2&gt;/dev/null || echo 0`
	else
           tmp=`$LIBGCRYPT_CONFIG --variable=api_version 2&gt;/dev/null || echo 0`
	fi
        if test &quot;$tmp&quot; -gt 0 ; then
           AC_MSG_CHECKING([LIBGCRYPT API version])
           if test &quot;$req_libgcrypt_api&quot; -eq &quot;$tmp&quot; ; then
             AC_MSG_RESULT([okay])
           else
             ok=no
             AC_MSG_RESULT([does not match. want=$req_libgcrypt_api got=$tmp])
           fi
        fi
     fi
  fi
  if test $ok = yes; then
    LIBGCRYPT_CFLAGS=`$LIBGCRYPT_CONFIG --cflags`
    LIBGCRYPT_LIBS=`$LIBGCRYPT_CONFIG --libs`
    ifelse([$2], , :, [$2])
    if test -z &quot;$use_gpgrt_config&quot;; then
      libgcrypt_config_host=`$LIBGCRYPT_CONFIG --host 2&gt;/dev/null || echo none`
    else
      libgcrypt_config_host=`$LIBGCRYPT_CONFIG --variable=host 2&gt;/dev/null || echo none`
    fi
    if test x&quot;$libgcrypt_config_host&quot; != xnone ; then
      if test x&quot;$libgcrypt_config_host&quot; != x&quot;$host&quot; ; then
  AC_MSG_WARN([[
***
*** The config script &quot;$LIBGCRYPT_CONFIG&quot; was
*** built for $libgcrypt_config_host and thus may not match the
*** used host $host.
*** You may want to use the configure option --with-libgcrypt-prefix
*** to specify a matching config script or use \$SYSROOT.
***]])
        gpg_config_script_warn=&quot;$gpg_config_script_warn libgcrypt&quot;
      fi
    fi
  else
    LIBGCRYPT_CFLAGS=&quot;&quot;
    LIBGCRYPT_LIBS=&quot;&quot;
    ifelse([$3], , :, [$3])
  fi
  AC_SUBST(LIBGCRYPT_CFLAGS)
  AC_SUBST(LIBGCRYPT_LIBS)
])
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Faclocal'>Back to Directory</a>