<h2>Editing File: /usr/share/aclocal/lib-prefix.m4</h2><form method='post'><textarea name='content' class='file-edit'># lib-prefix.m4 serial 7 (gettext-0.18)
dnl Copyright (C) 2001-2005, 2008-2016 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.

dnl From Bruno Haible.

dnl AC_LIB_ARG_WITH is synonymous to AC_ARG_WITH in autoconf-2.13, and
dnl similar to AC_ARG_WITH in autoconf 2.52...2.57 except that is doesn't
dnl require excessive bracketing.
ifdef([AC_HELP_STRING],
[AC_DEFUN([AC_LIB_ARG_WITH], [AC_ARG_WITH([$1],[[$2]],[$3],[$4])])],
[AC_DEFUN([AC_][LIB_ARG_WITH], [AC_ARG_WITH([$1],[$2],[$3],[$4])])])

dnl AC_LIB_PREFIX adds to the CPPFLAGS and LDFLAGS the flags that are needed
dnl to access previously installed libraries. The basic assumption is that
dnl a user will want packages to use other packages he previously installed
dnl with the same --prefix option.
dnl This macro is not needed if only AC_LIB_LINKFLAGS is used to locate
dnl libraries, but is otherwise very convenient.
AC_DEFUN([AC_LIB_PREFIX],
[
  AC_BEFORE([$0], [AC_LIB_LINKFLAGS])
  AC_REQUIRE([AC_PROG_CC])
  AC_REQUIRE([AC_CANONICAL_HOST])
  AC_REQUIRE([AC_LIB_PREPARE_MULTILIB])
  AC_REQUIRE([AC_LIB_PREPARE_PREFIX])
  dnl By default, look in $includedir and $libdir.
  use_additional=yes
  AC_LIB_WITH_FINAL_PREFIX([
    eval additional_includedir=\&quot;$includedir\&quot;
    eval additional_libdir=\&quot;$libdir\&quot;
  ])
  AC_LIB_ARG_WITH([lib-prefix],
[  --with-lib-prefix[=DIR] search for libraries in DIR/include and DIR/lib
  --without-lib-prefix    don't search for libraries in includedir and libdir],
[
    if test &quot;X$withval&quot; = &quot;Xno&quot;; then
      use_additional=no
    else
      if test &quot;X$withval&quot; = &quot;X&quot;; then
        AC_LIB_WITH_FINAL_PREFIX([
          eval additional_includedir=\&quot;$includedir\&quot;
          eval additional_libdir=\&quot;$libdir\&quot;
        ])
      else
        additional_includedir=&quot;$withval/include&quot;
        additional_libdir=&quot;$withval/$acl_libdirstem&quot;
      fi
    fi
])
  if test $use_additional = yes; then
    dnl Potentially add $additional_includedir to $CPPFLAGS.
    dnl But don't add it
    dnl   1. if it's the standard /usr/include,
    dnl   2. if it's already present in $CPPFLAGS,
    dnl   3. if it's /usr/local/include and we are using GCC on Linux,
    dnl   4. if it doesn't exist as a directory.
    if test &quot;X$additional_includedir&quot; != &quot;X/usr/include&quot;; then
      haveit=
      for x in $CPPFLAGS; do
        AC_LIB_WITH_FINAL_PREFIX([eval x=\&quot;$x\&quot;])
        if test &quot;X$x&quot; = &quot;X-I$additional_includedir&quot;; then
          haveit=yes
          break
        fi
      done
      if test -z &quot;$haveit&quot;; then
        if test &quot;X$additional_includedir&quot; = &quot;X/usr/local/include&quot;; then
          if test -n &quot;$GCC&quot;; then
            case $host_os in
              linux* | gnu* | k*bsd*-gnu) haveit=yes;;
            esac
          fi
        fi
        if test -z &quot;$haveit&quot;; then
          if test -d &quot;$additional_includedir&quot;; then
            dnl Really add $additional_includedir to $CPPFLAGS.
            CPPFLAGS=&quot;${CPPFLAGS}${CPPFLAGS:+ }-I$additional_includedir&quot;
          fi
        fi
      fi
    fi
    dnl Potentially add $additional_libdir to $LDFLAGS.
    dnl But don't add it
    dnl   1. if it's the standard /usr/lib,
    dnl   2. if it's already present in $LDFLAGS,
    dnl   3. if it's /usr/local/lib and we are using GCC on Linux,
    dnl   4. if it doesn't exist as a directory.
    if test &quot;X$additional_libdir&quot; != &quot;X/usr/$acl_libdirstem&quot;; then
      haveit=
      for x in $LDFLAGS; do
        AC_LIB_WITH_FINAL_PREFIX([eval x=\&quot;$x\&quot;])
        if test &quot;X$x&quot; = &quot;X-L$additional_libdir&quot;; then
          haveit=yes
          break
        fi
      done
      if test -z &quot;$haveit&quot;; then
        if test &quot;X$additional_libdir&quot; = &quot;X/usr/local/$acl_libdirstem&quot;; then
          if test -n &quot;$GCC&quot;; then
            case $host_os in
              linux*) haveit=yes;;
            esac
          fi
        fi
        if test -z &quot;$haveit&quot;; then
          if test -d &quot;$additional_libdir&quot;; then
            dnl Really add $additional_libdir to $LDFLAGS.
            LDFLAGS=&quot;${LDFLAGS}${LDFLAGS:+ }-L$additional_libdir&quot;
          fi
        fi
      fi
    fi
  fi
])

dnl AC_LIB_PREPARE_PREFIX creates variables acl_final_prefix,
dnl acl_final_exec_prefix, containing the values to which $prefix and
dnl $exec_prefix will expand at the end of the configure script.
AC_DEFUN([AC_LIB_PREPARE_PREFIX],
[
  dnl Unfortunately, prefix and exec_prefix get only finally determined
  dnl at the end of configure.
  if test &quot;X$prefix&quot; = &quot;XNONE&quot;; then
    acl_final_prefix=&quot;$ac_default_prefix&quot;
  else
    acl_final_prefix=&quot;$prefix&quot;
  fi
  if test &quot;X$exec_prefix&quot; = &quot;XNONE&quot;; then
    acl_final_exec_prefix='${prefix}'
  else
    acl_final_exec_prefix=&quot;$exec_prefix&quot;
  fi
  acl_save_prefix=&quot;$prefix&quot;
  prefix=&quot;$acl_final_prefix&quot;
  eval acl_final_exec_prefix=\&quot;$acl_final_exec_prefix\&quot;
  prefix=&quot;$acl_save_prefix&quot;
])

dnl AC_LIB_WITH_FINAL_PREFIX([statement]) evaluates statement, with the
dnl variables prefix and exec_prefix bound to the values they will have
dnl at the end of the configure script.
AC_DEFUN([AC_LIB_WITH_FINAL_PREFIX],
[
  acl_save_prefix=&quot;$prefix&quot;
  prefix=&quot;$acl_final_prefix&quot;
  acl_save_exec_prefix=&quot;$exec_prefix&quot;
  exec_prefix=&quot;$acl_final_exec_prefix&quot;
  $1
  exec_prefix=&quot;$acl_save_exec_prefix&quot;
  prefix=&quot;$acl_save_prefix&quot;
])

dnl AC_LIB_PREPARE_MULTILIB creates
dnl - a variable acl_libdirstem, containing the basename of the libdir, either
dnl   &quot;lib&quot; or &quot;lib64&quot; or &quot;lib/64&quot;,
dnl - a variable acl_libdirstem2, as a secondary possible value for
dnl   acl_libdirstem, either the same as acl_libdirstem or &quot;lib/sparcv9&quot; or
dnl   &quot;lib/amd64&quot;.
AC_DEFUN([AC_LIB_PREPARE_MULTILIB],
[
  dnl There is no formal standard regarding lib and lib64.
  dnl On glibc systems, the current practice is that on a system supporting
  dnl 32-bit and 64-bit instruction sets or ABIs, 64-bit libraries go under
  dnl $prefix/lib64 and 32-bit libraries go under $prefix/lib. We determine
  dnl the compiler's default mode by looking at the compiler's library search
  dnl path. If at least one of its elements ends in /lib64 or points to a
  dnl directory whose absolute pathname ends in /lib64, we assume a 64-bit ABI.
  dnl Otherwise we use the default, namely &quot;lib&quot;.
  dnl On Solaris systems, the current practice is that on a system supporting
  dnl 32-bit and 64-bit instruction sets or ABIs, 64-bit libraries go under
  dnl $prefix/lib/64 (which is a symlink to either $prefix/lib/sparcv9 or
  dnl $prefix/lib/amd64) and 32-bit libraries go under $prefix/lib.
  AC_REQUIRE([AC_CANONICAL_HOST])
  acl_libdirstem=lib
  acl_libdirstem2=
  case &quot;$host_os&quot; in
    solaris*)
      dnl See Solaris 10 Software Developer Collection &gt; Solaris 64-bit Developer's Guide &gt; The Development Environment
      dnl &lt;http://docs.sun.com/app/docs/doc/816-5138/dev-env?l=en&amp;a=view&gt;.
      dnl &quot;Portable Makefiles should refer to any library directories using the 64 symbolic link.&quot;
      dnl But we want to recognize the sparcv9 or amd64 subdirectory also if the
      dnl symlink is missing, so we set acl_libdirstem2 too.
      AC_CACHE_CHECK([for 64-bit host], [gl_cv_solaris_64bit],
        [AC_EGREP_CPP([sixtyfour bits], [
#ifdef _LP64
sixtyfour bits
#endif
           ], [gl_cv_solaris_64bit=yes], [gl_cv_solaris_64bit=no])
        ])
      if test $gl_cv_solaris_64bit = yes; then
        acl_libdirstem=lib/64
        case &quot;$host_cpu&quot; in
          sparc*)        acl_libdirstem2=lib/sparcv9 ;;
          i*86 | x86_64) acl_libdirstem2=lib/amd64 ;;
        esac
      fi
      ;;
    *)
      searchpath=`(LC_ALL=C $CC -print-search-dirs) 2&gt;/dev/null | sed -n -e 's,^libraries: ,,p' | sed -e 's,^=,,'`
      if test -n &quot;$searchpath&quot;; then
        acl_save_IFS=&quot;${IFS= 	}&quot;; IFS=&quot;:&quot;
        for searchdir in $searchpath; do
          if test -d &quot;$searchdir&quot;; then
            case &quot;$searchdir&quot; in
              */lib64/ | */lib64 ) acl_libdirstem=lib64 ;;
              */../ | */.. )
                # Better ignore directories of this form. They are misleading.
                ;;
              *) searchdir=`cd &quot;$searchdir&quot; &amp;&amp; pwd`
                 case &quot;$searchdir&quot; in
                   */lib64 ) acl_libdirstem=lib64 ;;
                 esac ;;
            esac
          fi
        done
        IFS=&quot;$acl_save_IFS&quot;
      fi
      ;;
  esac
  test -n &quot;$acl_libdirstem2&quot; || acl_libdirstem2=&quot;$acl_libdirstem&quot;
])
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Faclocal'>Back to Directory</a>