<h2>Editing File: /usr/share/aclocal/lib-link.m4</h2><form method='post'><textarea name='content' class='file-edit'># lib-link.m4 serial 26 (gettext-0.18.2)
dnl Copyright (C) 2001-2016 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.

dnl From Bruno Haible.

AC_PREREQ([2.54])

dnl AC_LIB_LINKFLAGS(name [, dependencies]) searches for libname and
dnl the libraries corresponding to explicit and implicit dependencies.
dnl Sets and AC_SUBSTs the LIB${NAME} and LTLIB${NAME} variables and
dnl augments the CPPFLAGS variable.
dnl Sets and AC_SUBSTs the LIB${NAME}_PREFIX variable to nonempty if libname
dnl was found in ${LIB${NAME}_PREFIX}/$acl_libdirstem.
AC_DEFUN([AC_LIB_LINKFLAGS],
[
  AC_REQUIRE([AC_LIB_PREPARE_PREFIX])
  AC_REQUIRE([AC_LIB_RPATH])
  pushdef([Name],[m4_translit([$1],[./+-], [____])])
  pushdef([NAME],[m4_translit([$1],[abcdefghijklmnopqrstuvwxyz./+-],
                                   [ABCDEFGHIJKLMNOPQRSTUVWXYZ____])])
  AC_CACHE_CHECK([how to link with lib[]$1], [ac_cv_lib[]Name[]_libs], [
    AC_LIB_LINKFLAGS_BODY([$1], [$2])
    ac_cv_lib[]Name[]_libs=&quot;$LIB[]NAME&quot;
    ac_cv_lib[]Name[]_ltlibs=&quot;$LTLIB[]NAME&quot;
    ac_cv_lib[]Name[]_cppflags=&quot;$INC[]NAME&quot;
    ac_cv_lib[]Name[]_prefix=&quot;$LIB[]NAME[]_PREFIX&quot;
  ])
  LIB[]NAME=&quot;$ac_cv_lib[]Name[]_libs&quot;
  LTLIB[]NAME=&quot;$ac_cv_lib[]Name[]_ltlibs&quot;
  INC[]NAME=&quot;$ac_cv_lib[]Name[]_cppflags&quot;
  LIB[]NAME[]_PREFIX=&quot;$ac_cv_lib[]Name[]_prefix&quot;
  AC_LIB_APPENDTOVAR([CPPFLAGS], [$INC]NAME)
  AC_SUBST([LIB]NAME)
  AC_SUBST([LTLIB]NAME)
  AC_SUBST([LIB]NAME[_PREFIX])
  dnl Also set HAVE_LIB[]NAME so that AC_LIB_HAVE_LINKFLAGS can reuse the
  dnl results of this search when this library appears as a dependency.
  HAVE_LIB[]NAME=yes
  popdef([NAME])
  popdef([Name])
])

dnl AC_LIB_HAVE_LINKFLAGS(name, dependencies, includes, testcode, [missing-message])
dnl searches for libname and the libraries corresponding to explicit and
dnl implicit dependencies, together with the specified include files and
dnl the ability to compile and link the specified testcode. The missing-message
dnl defaults to 'no' and may contain additional hints for the user.
dnl If found, it sets and AC_SUBSTs HAVE_LIB${NAME}=yes and the LIB${NAME}
dnl and LTLIB${NAME} variables and augments the CPPFLAGS variable, and
dnl #defines HAVE_LIB${NAME} to 1. Otherwise, it sets and AC_SUBSTs
dnl HAVE_LIB${NAME}=no and LIB${NAME} and LTLIB${NAME} to empty.
dnl Sets and AC_SUBSTs the LIB${NAME}_PREFIX variable to nonempty if libname
dnl was found in ${LIB${NAME}_PREFIX}/$acl_libdirstem.
AC_DEFUN([AC_LIB_HAVE_LINKFLAGS],
[
  AC_REQUIRE([AC_LIB_PREPARE_PREFIX])
  AC_REQUIRE([AC_LIB_RPATH])
  pushdef([Name],[m4_translit([$1],[./+-], [____])])
  pushdef([NAME],[m4_translit([$1],[abcdefghijklmnopqrstuvwxyz./+-],
                                   [ABCDEFGHIJKLMNOPQRSTUVWXYZ____])])

  dnl Search for lib[]Name and define LIB[]NAME, LTLIB[]NAME and INC[]NAME
  dnl accordingly.
  AC_LIB_LINKFLAGS_BODY([$1], [$2])

  dnl Add $INC[]NAME to CPPFLAGS before performing the following checks,
  dnl because if the user has installed lib[]Name and not disabled its use
  dnl via --without-lib[]Name-prefix, he wants to use it.
  ac_save_CPPFLAGS=&quot;$CPPFLAGS&quot;
  AC_LIB_APPENDTOVAR([CPPFLAGS], [$INC]NAME)

  AC_CACHE_CHECK([for lib[]$1], [ac_cv_lib[]Name], [
    ac_save_LIBS=&quot;$LIBS&quot;
    dnl If $LIB[]NAME contains some -l options, add it to the end of LIBS,
    dnl because these -l options might require -L options that are present in
    dnl LIBS. -l options benefit only from the -L options listed before it.
    dnl Otherwise, add it to the front of LIBS, because it may be a static
    dnl library that depends on another static library that is present in LIBS.
    dnl Static libraries benefit only from the static libraries listed after
    dnl it.
    case &quot; $LIB[]NAME&quot; in
      *&quot; -l&quot;*) LIBS=&quot;$LIBS $LIB[]NAME&quot; ;;
      *)       LIBS=&quot;$LIB[]NAME $LIBS&quot; ;;
    esac
    AC_LINK_IFELSE(
      [AC_LANG_PROGRAM([[$3]], [[$4]])],
      [ac_cv_lib[]Name=yes],
      [ac_cv_lib[]Name='m4_if([$5], [], [no], [[$5]])'])
    LIBS=&quot;$ac_save_LIBS&quot;
  ])
  if test &quot;$ac_cv_lib[]Name&quot; = yes; then
    HAVE_LIB[]NAME=yes
    AC_DEFINE([HAVE_LIB]NAME, 1, [Define if you have the lib][$1 library.])
    AC_MSG_CHECKING([how to link with lib[]$1])
    AC_MSG_RESULT([$LIB[]NAME])
  else
    HAVE_LIB[]NAME=no
    dnl If $LIB[]NAME didn't lead to a usable library, we don't need
    dnl $INC[]NAME either.
    CPPFLAGS=&quot;$ac_save_CPPFLAGS&quot;
    LIB[]NAME=
    LTLIB[]NAME=
    LIB[]NAME[]_PREFIX=
  fi
  AC_SUBST([HAVE_LIB]NAME)
  AC_SUBST([LIB]NAME)
  AC_SUBST([LTLIB]NAME)
  AC_SUBST([LIB]NAME[_PREFIX])
  popdef([NAME])
  popdef([Name])
])

dnl Determine the platform dependent parameters needed to use rpath:
dnl   acl_libext,
dnl   acl_shlibext,
dnl   acl_libname_spec,
dnl   acl_library_names_spec,
dnl   acl_hardcode_libdir_flag_spec,
dnl   acl_hardcode_libdir_separator,
dnl   acl_hardcode_direct,
dnl   acl_hardcode_minus_L.
AC_DEFUN([AC_LIB_RPATH],
[
  dnl Tell automake &gt;= 1.10 to complain if config.rpath is missing.
  m4_ifdef([AC_REQUIRE_AUX_FILE], [AC_REQUIRE_AUX_FILE([config.rpath])])
  AC_REQUIRE([AC_PROG_CC])                dnl we use $CC, $GCC, $LDFLAGS
  AC_REQUIRE([AC_LIB_PROG_LD])            dnl we use $LD, $with_gnu_ld
  AC_REQUIRE([AC_CANONICAL_HOST])         dnl we use $host
  AC_REQUIRE([AC_CONFIG_AUX_DIR_DEFAULT]) dnl we use $ac_aux_dir
  AC_CACHE_CHECK([for shared library run path origin], [acl_cv_rpath], [
    CC=&quot;$CC&quot; GCC=&quot;$GCC&quot; LDFLAGS=&quot;$LDFLAGS&quot; LD=&quot;$LD&quot; with_gnu_ld=&quot;$with_gnu_ld&quot; \
    ${CONFIG_SHELL-/bin/sh} &quot;$ac_aux_dir/config.rpath&quot; &quot;$host&quot; &gt; conftest.sh
    . ./conftest.sh
    rm -f ./conftest.sh
    acl_cv_rpath=done
  ])
  wl=&quot;$acl_cv_wl&quot;
  acl_libext=&quot;$acl_cv_libext&quot;
  acl_shlibext=&quot;$acl_cv_shlibext&quot;
  acl_libname_spec=&quot;$acl_cv_libname_spec&quot;
  acl_library_names_spec=&quot;$acl_cv_library_names_spec&quot;
  acl_hardcode_libdir_flag_spec=&quot;$acl_cv_hardcode_libdir_flag_spec&quot;
  acl_hardcode_libdir_separator=&quot;$acl_cv_hardcode_libdir_separator&quot;
  acl_hardcode_direct=&quot;$acl_cv_hardcode_direct&quot;
  acl_hardcode_minus_L=&quot;$acl_cv_hardcode_minus_L&quot;
  dnl Determine whether the user wants rpath handling at all.
  AC_ARG_ENABLE([rpath],
    [  --disable-rpath         do not hardcode runtime library paths],
    :, enable_rpath=yes)
])

dnl AC_LIB_FROMPACKAGE(name, package)
dnl declares that libname comes from the given package. The configure file
dnl will then not have a --with-libname-prefix option but a
dnl --with-package-prefix option. Several libraries can come from the same
dnl package. This declaration must occur before an AC_LIB_LINKFLAGS or similar
dnl macro call that searches for libname.
AC_DEFUN([AC_LIB_FROMPACKAGE],
[
  pushdef([NAME],[m4_translit([$1],[abcdefghijklmnopqrstuvwxyz./+-],
                                   [ABCDEFGHIJKLMNOPQRSTUVWXYZ____])])
  define([acl_frompackage_]NAME, [$2])
  popdef([NAME])
  pushdef([PACK],[$2])
  pushdef([PACKUP],[m4_translit(PACK,[abcdefghijklmnopqrstuvwxyz./+-],
                                     [ABCDEFGHIJKLMNOPQRSTUVWXYZ____])])
  define([acl_libsinpackage_]PACKUP,
    m4_ifdef([acl_libsinpackage_]PACKUP, [m4_defn([acl_libsinpackage_]PACKUP)[, ]],)[lib$1])
  popdef([PACKUP])
  popdef([PACK])
])

dnl AC_LIB_LINKFLAGS_BODY(name [, dependencies]) searches for libname and
dnl the libraries corresponding to explicit and implicit dependencies.
dnl Sets the LIB${NAME}, LTLIB${NAME} and INC${NAME} variables.
dnl Also, sets the LIB${NAME}_PREFIX variable to nonempty if libname was found
dnl in ${LIB${NAME}_PREFIX}/$acl_libdirstem.
AC_DEFUN([AC_LIB_LINKFLAGS_BODY],
[
  AC_REQUIRE([AC_LIB_PREPARE_MULTILIB])
  pushdef([NAME],[m4_translit([$1],[abcdefghijklmnopqrstuvwxyz./+-],
                                   [ABCDEFGHIJKLMNOPQRSTUVWXYZ____])])
  pushdef([PACK],[m4_ifdef([acl_frompackage_]NAME, [acl_frompackage_]NAME, lib[$1])])
  pushdef([PACKUP],[m4_translit(PACK,[abcdefghijklmnopqrstuvwxyz./+-],
                                     [ABCDEFGHIJKLMNOPQRSTUVWXYZ____])])
  pushdef([PACKLIBS],[m4_ifdef([acl_frompackage_]NAME, [acl_libsinpackage_]PACKUP, lib[$1])])
  dnl Autoconf &gt;= 2.61 supports dots in --with options.
  pushdef([P_A_C_K],[m4_if(m4_version_compare(m4_defn([m4_PACKAGE_VERSION]),[2.61]),[-1],[m4_translit(PACK,[.],[_])],PACK)])
  dnl By default, look in $includedir and $libdir.
  use_additional=yes
  AC_LIB_WITH_FINAL_PREFIX([
    eval additional_includedir=\&quot;$includedir\&quot;
    eval additional_libdir=\&quot;$libdir\&quot;
  ])
  AC_ARG_WITH(P_A_C_K[-prefix],
[[  --with-]]P_A_C_K[[-prefix[=DIR]  search for ]PACKLIBS[ in DIR/include and DIR/lib
  --without-]]P_A_C_K[[-prefix     don't search for ]PACKLIBS[ in includedir and libdir]],
[
    if test &quot;X$withval&quot; = &quot;Xno&quot;; then
      use_additional=no
    else
      if test &quot;X$withval&quot; = &quot;X&quot;; then
        AC_LIB_WITH_FINAL_PREFIX([
          eval additional_includedir=\&quot;$includedir\&quot;
          eval additional_libdir=\&quot;$libdir\&quot;
        ])
      else
        additional_includedir=&quot;$withval/include&quot;
        additional_libdir=&quot;$withval/$acl_libdirstem&quot;
        if test &quot;$acl_libdirstem2&quot; != &quot;$acl_libdirstem&quot; \
           &amp;&amp; ! test -d &quot;$withval/$acl_libdirstem&quot;; then
          additional_libdir=&quot;$withval/$acl_libdirstem2&quot;
        fi
      fi
    fi
])
  dnl Search the library and its dependencies in $additional_libdir and
  dnl $LDFLAGS. Using breadth-first-seach.
  LIB[]NAME=
  LTLIB[]NAME=
  INC[]NAME=
  LIB[]NAME[]_PREFIX=
  dnl HAVE_LIB${NAME} is an indicator that LIB${NAME}, LTLIB${NAME} have been
  dnl computed. So it has to be reset here.
  HAVE_LIB[]NAME=
  rpathdirs=
  ltrpathdirs=
  names_already_handled=
  names_next_round='$1 $2'
  while test -n &quot;$names_next_round&quot;; do
    names_this_round=&quot;$names_next_round&quot;
    names_next_round=
    for name in $names_this_round; do
      already_handled=
      for n in $names_already_handled; do
        if test &quot;$n&quot; = &quot;$name&quot;; then
          already_handled=yes
          break
        fi
      done
      if test -z &quot;$already_handled&quot;; then
        names_already_handled=&quot;$names_already_handled $name&quot;
        dnl See if it was already located by an earlier AC_LIB_LINKFLAGS
        dnl or AC_LIB_HAVE_LINKFLAGS call.
        uppername=`echo &quot;$name&quot; | sed -e 'y|abcdefghijklmnopqrstuvwxyz./+-|ABCDEFGHIJKLMNOPQRSTUVWXYZ____|'`
        eval value=\&quot;\$HAVE_LIB$uppername\&quot;
        if test -n &quot;$value&quot;; then
          if test &quot;$value&quot; = yes; then
            eval value=\&quot;\$LIB$uppername\&quot;
            test -z &quot;$value&quot; || LIB[]NAME=&quot;${LIB[]NAME}${LIB[]NAME:+ }$value&quot;
            eval value=\&quot;\$LTLIB$uppername\&quot;
            test -z &quot;$value&quot; || LTLIB[]NAME=&quot;${LTLIB[]NAME}${LTLIB[]NAME:+ }$value&quot;
          else
            dnl An earlier call to AC_LIB_HAVE_LINKFLAGS has determined
            dnl that this library doesn't exist. So just drop it.
            :
          fi
        else
          dnl Search the library lib$name in $additional_libdir and $LDFLAGS
          dnl and the already constructed $LIBNAME/$LTLIBNAME.
          found_dir=
          found_la=
          found_so=
          found_a=
          eval libname=\&quot;$acl_libname_spec\&quot;    # typically: libname=lib$name
          if test -n &quot;$acl_shlibext&quot;; then
            shrext=&quot;.$acl_shlibext&quot;             # typically: shrext=.so
          else
            shrext=
          fi
          if test $use_additional = yes; then
            dir=&quot;$additional_libdir&quot;
            dnl The same code as in the loop below:
            dnl First look for a shared library.
            if test -n &quot;$acl_shlibext&quot;; then
              if test -f &quot;$dir/$libname$shrext&quot;; then
                found_dir=&quot;$dir&quot;
                found_so=&quot;$dir/$libname$shrext&quot;
              else
                if test &quot;$acl_library_names_spec&quot; = '$libname$shrext$versuffix'; then
                  ver=`(cd &quot;$dir&quot; &amp;&amp; \
                        for f in &quot;$libname$shrext&quot;.*; do echo &quot;$f&quot;; done \
                        | sed -e &quot;s,^$libname$shrext\\\\.,,&quot; \
                        | sort -t '.' -n -r -k1,1 -k2,2 -k3,3 -k4,4 -k5,5 \
                        | sed 1q ) 2&gt;/dev/null`
                  if test -n &quot;$ver&quot; &amp;&amp; test -f &quot;$dir/$libname$shrext.$ver&quot;; then
                    found_dir=&quot;$dir&quot;
                    found_so=&quot;$dir/$libname$shrext.$ver&quot;
                  fi
                else
                  eval library_names=\&quot;$acl_library_names_spec\&quot;
                  for f in $library_names; do
                    if test -f &quot;$dir/$f&quot;; then
                      found_dir=&quot;$dir&quot;
                      found_so=&quot;$dir/$f&quot;
                      break
                    fi
                  done
                fi
              fi
            fi
            dnl Then look for a static library.
            if test &quot;X$found_dir&quot; = &quot;X&quot;; then
              if test -f &quot;$dir/$libname.$acl_libext&quot;; then
                found_dir=&quot;$dir&quot;
                found_a=&quot;$dir/$libname.$acl_libext&quot;
              fi
            fi
            if test &quot;X$found_dir&quot; != &quot;X&quot;; then
              if test -f &quot;$dir/$libname.la&quot;; then
                found_la=&quot;$dir/$libname.la&quot;
              fi
            fi
          fi
          if test &quot;X$found_dir&quot; = &quot;X&quot;; then
            for x in $LDFLAGS $LTLIB[]NAME; do
              AC_LIB_WITH_FINAL_PREFIX([eval x=\&quot;$x\&quot;])
              case &quot;$x&quot; in
                -L*)
                  dir=`echo &quot;X$x&quot; | sed -e 's/^X-L//'`
                  dnl First look for a shared library.
                  if test -n &quot;$acl_shlibext&quot;; then
                    if test -f &quot;$dir/$libname$shrext&quot;; then
                      found_dir=&quot;$dir&quot;
                      found_so=&quot;$dir/$libname$shrext&quot;
                    else
                      if test &quot;$acl_library_names_spec&quot; = '$libname$shrext$versuffix'; then
                        ver=`(cd &quot;$dir&quot; &amp;&amp; \
                              for f in &quot;$libname$shrext&quot;.*; do echo &quot;$f&quot;; done \
                              | sed -e &quot;s,^$libname$shrext\\\\.,,&quot; \
                              | sort -t '.' -n -r -k1,1 -k2,2 -k3,3 -k4,4 -k5,5 \
                              | sed 1q ) 2&gt;/dev/null`
                        if test -n &quot;$ver&quot; &amp;&amp; test -f &quot;$dir/$libname$shrext.$ver&quot;; then
                          found_dir=&quot;$dir&quot;
                          found_so=&quot;$dir/$libname$shrext.$ver&quot;
                        fi
                      else
                        eval library_names=\&quot;$acl_library_names_spec\&quot;
                        for f in $library_names; do
                          if test -f &quot;$dir/$f&quot;; then
                            found_dir=&quot;$dir&quot;
                            found_so=&quot;$dir/$f&quot;
                            break
                          fi
                        done
                      fi
                    fi
                  fi
                  dnl Then look for a static library.
                  if test &quot;X$found_dir&quot; = &quot;X&quot;; then
                    if test -f &quot;$dir/$libname.$acl_libext&quot;; then
                      found_dir=&quot;$dir&quot;
                      found_a=&quot;$dir/$libname.$acl_libext&quot;
                    fi
                  fi
                  if test &quot;X$found_dir&quot; != &quot;X&quot;; then
                    if test -f &quot;$dir/$libname.la&quot;; then
                      found_la=&quot;$dir/$libname.la&quot;
                    fi
                  fi
                  ;;
              esac
              if test &quot;X$found_dir&quot; != &quot;X&quot;; then
                break
              fi
            done
          fi
          if test &quot;X$found_dir&quot; != &quot;X&quot;; then
            dnl Found the library.
            LTLIB[]NAME=&quot;${LTLIB[]NAME}${LTLIB[]NAME:+ }-L$found_dir -l$name&quot;
            if test &quot;X$found_so&quot; != &quot;X&quot;; then
              dnl Linking with a shared library. We attempt to hardcode its
              dnl directory into the executable's runpath, unless it's the
              dnl standard /usr/lib.
              if test &quot;$enable_rpath&quot; = no \
                 || test &quot;X$found_dir&quot; = &quot;X/usr/$acl_libdirstem&quot; \
                 || test &quot;X$found_dir&quot; = &quot;X/usr/$acl_libdirstem2&quot;; then
                dnl No hardcoding is needed.
                LIB[]NAME=&quot;${LIB[]NAME}${LIB[]NAME:+ }$found_so&quot;
              else
                dnl Use an explicit option to hardcode DIR into the resulting
                dnl binary.
                dnl Potentially add DIR to ltrpathdirs.
                dnl The ltrpathdirs will be appended to $LTLIBNAME at the end.
                haveit=
                for x in $ltrpathdirs; do
                  if test &quot;X$x&quot; = &quot;X$found_dir&quot;; then
                    haveit=yes
                    break
                  fi
                done
                if test -z &quot;$haveit&quot;; then
                  ltrpathdirs=&quot;$ltrpathdirs $found_dir&quot;
                fi
                dnl The hardcoding into $LIBNAME is system dependent.
                if test &quot;$acl_hardcode_direct&quot; = yes; then
                  dnl Using DIR/libNAME.so during linking hardcodes DIR into the
                  dnl resulting binary.
                  LIB[]NAME=&quot;${LIB[]NAME}${LIB[]NAME:+ }$found_so&quot;
                else
                  if test -n &quot;$acl_hardcode_libdir_flag_spec&quot; &amp;&amp; test &quot;$acl_hardcode_minus_L&quot; = no; then
                    dnl Use an explicit option to hardcode DIR into the resulting
                    dnl binary.
                    LIB[]NAME=&quot;${LIB[]NAME}${LIB[]NAME:+ }$found_so&quot;
                    dnl Potentially add DIR to rpathdirs.
                    dnl The rpathdirs will be appended to $LIBNAME at the end.
                    haveit=
                    for x in $rpathdirs; do
                      if test &quot;X$x&quot; = &quot;X$found_dir&quot;; then
                        haveit=yes
                        break
                      fi
                    done
                    if test -z &quot;$haveit&quot;; then
                      rpathdirs=&quot;$rpathdirs $found_dir&quot;
                    fi
                  else
                    dnl Rely on &quot;-L$found_dir&quot;.
                    dnl But don't add it if it's already contained in the LDFLAGS
                    dnl or the already constructed $LIBNAME
                    haveit=
                    for x in $LDFLAGS $LIB[]NAME; do
                      AC_LIB_WITH_FINAL_PREFIX([eval x=\&quot;$x\&quot;])
                      if test &quot;X$x&quot; = &quot;X-L$found_dir&quot;; then
                        haveit=yes
                        break
                      fi
                    done
                    if test -z &quot;$haveit&quot;; then
                      LIB[]NAME=&quot;${LIB[]NAME}${LIB[]NAME:+ }-L$found_dir&quot;
                    fi
                    if test &quot;$acl_hardcode_minus_L&quot; != no; then
                      dnl FIXME: Not sure whether we should use
                      dnl &quot;-L$found_dir -l$name&quot; or &quot;-L$found_dir $found_so&quot;
                      dnl here.
                      LIB[]NAME=&quot;${LIB[]NAME}${LIB[]NAME:+ }$found_so&quot;
                    else
                      dnl We cannot use $acl_hardcode_runpath_var and LD_RUN_PATH
                      dnl here, because this doesn't fit in flags passed to the
                      dnl compiler. So give up. No hardcoding. This affects only
                      dnl very old systems.
                      dnl FIXME: Not sure whether we should use
                      dnl &quot;-L$found_dir -l$name&quot; or &quot;-L$found_dir $found_so&quot;
                      dnl here.
                      LIB[]NAME=&quot;${LIB[]NAME}${LIB[]NAME:+ }-l$name&quot;
                    fi
                  fi
                fi
              fi
            else
              if test &quot;X$found_a&quot; != &quot;X&quot;; then
                dnl Linking with a static library.
                LIB[]NAME=&quot;${LIB[]NAME}${LIB[]NAME:+ }$found_a&quot;
              else
                dnl We shouldn't come here, but anyway it's good to have a
                dnl fallback.
                LIB[]NAME=&quot;${LIB[]NAME}${LIB[]NAME:+ }-L$found_dir -l$name&quot;
              fi
            fi
            dnl Assume the include files are nearby.
            additional_includedir=
            case &quot;$found_dir&quot; in
              */$acl_libdirstem | */$acl_libdirstem/)
                basedir=`echo &quot;X$found_dir&quot; | sed -e 's,^X,,' -e &quot;s,/$acl_libdirstem/&quot;'*$,,'`
                if test &quot;$name&quot; = '$1'; then
                  LIB[]NAME[]_PREFIX=&quot;$basedir&quot;
                fi
                additional_includedir=&quot;$basedir/include&quot;
                ;;
              */$acl_libdirstem2 | */$acl_libdirstem2/)
                basedir=`echo &quot;X$found_dir&quot; | sed -e 's,^X,,' -e &quot;s,/$acl_libdirstem2/&quot;'*$,,'`
                if test &quot;$name&quot; = '$1'; then
                  LIB[]NAME[]_PREFIX=&quot;$basedir&quot;
                fi
                additional_includedir=&quot;$basedir/include&quot;
                ;;
            esac
            if test &quot;X$additional_includedir&quot; != &quot;X&quot;; then
              dnl Potentially add $additional_includedir to $INCNAME.
              dnl But don't add it
              dnl   1. if it's the standard /usr/include,
              dnl   2. if it's /usr/local/include and we are using GCC on Linux,
              dnl   3. if it's already present in $CPPFLAGS or the already
              dnl      constructed $INCNAME,
              dnl   4. if it doesn't exist as a directory.
              if test &quot;X$additional_includedir&quot; != &quot;X/usr/include&quot;; then
                haveit=
                if test &quot;X$additional_includedir&quot; = &quot;X/usr/local/include&quot;; then
                  if test -n &quot;$GCC&quot;; then
                    case $host_os in
                      linux* | gnu* | k*bsd*-gnu) haveit=yes;;
                    esac
                  fi
                fi
                if test -z &quot;$haveit&quot;; then
                  for x in $CPPFLAGS $INC[]NAME; do
                    AC_LIB_WITH_FINAL_PREFIX([eval x=\&quot;$x\&quot;])
                    if test &quot;X$x&quot; = &quot;X-I$additional_includedir&quot;; then
                      haveit=yes
                      break
                    fi
                  done
                  if test -z &quot;$haveit&quot;; then
                    if test -d &quot;$additional_includedir&quot;; then
                      dnl Really add $additional_includedir to $INCNAME.
                      INC[]NAME=&quot;${INC[]NAME}${INC[]NAME:+ }-I$additional_includedir&quot;
                    fi
                  fi
                fi
              fi
            fi
            dnl Look for dependencies.
            if test -n &quot;$found_la&quot;; then
              dnl Read the .la file. It defines the variables
              dnl dlname, library_names, old_library, dependency_libs, current,
              dnl age, revision, installed, dlopen, dlpreopen, libdir.
              save_libdir=&quot;$libdir&quot;
              case &quot;$found_la&quot; in
                */* | *\\*) . &quot;$found_la&quot; ;;
                *) . &quot;./$found_la&quot; ;;
              esac
              libdir=&quot;$save_libdir&quot;
              dnl We use only dependency_libs.
              for dep in $dependency_libs; do
                case &quot;$dep&quot; in
                  -L*)
                    additional_libdir=`echo &quot;X$dep&quot; | sed -e 's/^X-L//'`
                    dnl Potentially add $additional_libdir to $LIBNAME and $LTLIBNAME.
                    dnl But don't add it
                    dnl   1. if it's the standard /usr/lib,
                    dnl   2. if it's /usr/local/lib and we are using GCC on Linux,
                    dnl   3. if it's already present in $LDFLAGS or the already
                    dnl      constructed $LIBNAME,
                    dnl   4. if it doesn't exist as a directory.
                    if test &quot;X$additional_libdir&quot; != &quot;X/usr/$acl_libdirstem&quot; \
                       &amp;&amp; test &quot;X$additional_libdir&quot; != &quot;X/usr/$acl_libdirstem2&quot;; then
                      haveit=
                      if test &quot;X$additional_libdir&quot; = &quot;X/usr/local/$acl_libdirstem&quot; \
                         || test &quot;X$additional_libdir&quot; = &quot;X/usr/local/$acl_libdirstem2&quot;; then
                        if test -n &quot;$GCC&quot;; then
                          case $host_os in
                            linux* | gnu* | k*bsd*-gnu) haveit=yes;;
                          esac
                        fi
                      fi
                      if test -z &quot;$haveit&quot;; then
                        haveit=
                        for x in $LDFLAGS $LIB[]NAME; do
                          AC_LIB_WITH_FINAL_PREFIX([eval x=\&quot;$x\&quot;])
                          if test &quot;X$x&quot; = &quot;X-L$additional_libdir&quot;; then
                            haveit=yes
                            break
                          fi
                        done
                        if test -z &quot;$haveit&quot;; then
                          if test -d &quot;$additional_libdir&quot;; then
                            dnl Really add $additional_libdir to $LIBNAME.
                            LIB[]NAME=&quot;${LIB[]NAME}${LIB[]NAME:+ }-L$additional_libdir&quot;
                          fi
                        fi
                        haveit=
                        for x in $LDFLAGS $LTLIB[]NAME; do
                          AC_LIB_WITH_FINAL_PREFIX([eval x=\&quot;$x\&quot;])
                          if test &quot;X$x&quot; = &quot;X-L$additional_libdir&quot;; then
                            haveit=yes
                            break
                          fi
                        done
                        if test -z &quot;$haveit&quot;; then
                          if test -d &quot;$additional_libdir&quot;; then
                            dnl Really add $additional_libdir to $LTLIBNAME.
                            LTLIB[]NAME=&quot;${LTLIB[]NAME}${LTLIB[]NAME:+ }-L$additional_libdir&quot;
                          fi
                        fi
                      fi
                    fi
                    ;;
                  -R*)
                    dir=`echo &quot;X$dep&quot; | sed -e 's/^X-R//'`
                    if test &quot;$enable_rpath&quot; != no; then
                      dnl Potentially add DIR to rpathdirs.
                      dnl The rpathdirs will be appended to $LIBNAME at the end.
                      haveit=
                      for x in $rpathdirs; do
                        if test &quot;X$x&quot; = &quot;X$dir&quot;; then
                          haveit=yes
                          break
                        fi
                      done
                      if test -z &quot;$haveit&quot;; then
                        rpathdirs=&quot;$rpathdirs $dir&quot;
                      fi
                      dnl Potentially add DIR to ltrpathdirs.
                      dnl The ltrpathdirs will be appended to $LTLIBNAME at the end.
                      haveit=
                      for x in $ltrpathdirs; do
                        if test &quot;X$x&quot; = &quot;X$dir&quot;; then
                          haveit=yes
                          break
                        fi
                      done
                      if test -z &quot;$haveit&quot;; then
                        ltrpathdirs=&quot;$ltrpathdirs $dir&quot;
                      fi
                    fi
                    ;;
                  -l*)
                    dnl Handle this in the next round.
                    names_next_round=&quot;$names_next_round &quot;`echo &quot;X$dep&quot; | sed -e 's/^X-l//'`
                    ;;
                  *.la)
                    dnl Handle this in the next round. Throw away the .la's
                    dnl directory; it is already contained in a preceding -L
                    dnl option.
                    names_next_round=&quot;$names_next_round &quot;`echo &quot;X$dep&quot; | sed -e 's,^X.*/,,' -e 's,^lib,,' -e 's,\.la$,,'`
                    ;;
                  *)
                    dnl Most likely an immediate library name.
                    LIB[]NAME=&quot;${LIB[]NAME}${LIB[]NAME:+ }$dep&quot;
                    LTLIB[]NAME=&quot;${LTLIB[]NAME}${LTLIB[]NAME:+ }$dep&quot;
                    ;;
                esac
              done
            fi
          else
            dnl Didn't find the library; assume it is in the system directories
            dnl known to the linker and runtime loader. (All the system
            dnl directories known to the linker should also be known to the
            dnl runtime loader, otherwise the system is severely misconfigured.)
            LIB[]NAME=&quot;${LIB[]NAME}${LIB[]NAME:+ }-l$name&quot;
            LTLIB[]NAME=&quot;${LTLIB[]NAME}${LTLIB[]NAME:+ }-l$name&quot;
          fi
        fi
      fi
    done
  done
  if test &quot;X$rpathdirs&quot; != &quot;X&quot;; then
    if test -n &quot;$acl_hardcode_libdir_separator&quot;; then
      dnl Weird platform: only the last -rpath option counts, the user must
      dnl pass all path elements in one option. We can arrange that for a
      dnl single library, but not when more than one $LIBNAMEs are used.
      alldirs=
      for found_dir in $rpathdirs; do
        alldirs=&quot;${alldirs}${alldirs:+$acl_hardcode_libdir_separator}$found_dir&quot;
      done
      dnl Note: acl_hardcode_libdir_flag_spec uses $libdir and $wl.
      acl_save_libdir=&quot;$libdir&quot;
      libdir=&quot;$alldirs&quot;
      eval flag=\&quot;$acl_hardcode_libdir_flag_spec\&quot;
      libdir=&quot;$acl_save_libdir&quot;
      LIB[]NAME=&quot;${LIB[]NAME}${LIB[]NAME:+ }$flag&quot;
    else
      dnl The -rpath options are cumulative.
      for found_dir in $rpathdirs; do
        acl_save_libdir=&quot;$libdir&quot;
        libdir=&quot;$found_dir&quot;
        eval flag=\&quot;$acl_hardcode_libdir_flag_spec\&quot;
        libdir=&quot;$acl_save_libdir&quot;
        LIB[]NAME=&quot;${LIB[]NAME}${LIB[]NAME:+ }$flag&quot;
      done
    fi
  fi
  if test &quot;X$ltrpathdirs&quot; != &quot;X&quot;; then
    dnl When using libtool, the option that works for both libraries and
    dnl executables is -R. The -R options are cumulative.
    for found_dir in $ltrpathdirs; do
      LTLIB[]NAME=&quot;${LTLIB[]NAME}${LTLIB[]NAME:+ }-R$found_dir&quot;
    done
  fi
  popdef([P_A_C_K])
  popdef([PACKLIBS])
  popdef([PACKUP])
  popdef([PACK])
  popdef([NAME])
])

dnl AC_LIB_APPENDTOVAR(VAR, CONTENTS) appends the elements of CONTENTS to VAR,
dnl unless already present in VAR.
dnl Works only for CPPFLAGS, not for LIB* variables because that sometimes
dnl contains two or three consecutive elements that belong together.
AC_DEFUN([AC_LIB_APPENDTOVAR],
[
  for element in [$2]; do
    haveit=
    for x in $[$1]; do
      AC_LIB_WITH_FINAL_PREFIX([eval x=\&quot;$x\&quot;])
      if test &quot;X$x&quot; = &quot;X$element&quot;; then
        haveit=yes
        break
      fi
    done
    if test -z &quot;$haveit&quot;; then
      [$1]=&quot;${[$1]}${[$1]:+ }$element&quot;
    fi
  done
])

dnl For those cases where a variable contains several -L and -l options
dnl referring to unknown libraries and directories, this macro determines the
dnl necessary additional linker options for the runtime path.
dnl AC_LIB_LINKFLAGS_FROM_LIBS([LDADDVAR], [LIBSVALUE], [USE-LIBTOOL])
dnl sets LDADDVAR to linker options needed together with LIBSVALUE.
dnl If USE-LIBTOOL evaluates to non-empty, linking with libtool is assumed,
dnl otherwise linking without libtool is assumed.
AC_DEFUN([AC_LIB_LINKFLAGS_FROM_LIBS],
[
  AC_REQUIRE([AC_LIB_RPATH])
  AC_REQUIRE([AC_LIB_PREPARE_MULTILIB])
  $1=
  if test &quot;$enable_rpath&quot; != no; then
    if test -n &quot;$acl_hardcode_libdir_flag_spec&quot; &amp;&amp; test &quot;$acl_hardcode_minus_L&quot; = no; then
      dnl Use an explicit option to hardcode directories into the resulting
      dnl binary.
      rpathdirs=
      next=
      for opt in $2; do
        if test -n &quot;$next&quot;; then
          dir=&quot;$next&quot;
          dnl No need to hardcode the standard /usr/lib.
          if test &quot;X$dir&quot; != &quot;X/usr/$acl_libdirstem&quot; \
             &amp;&amp; test &quot;X$dir&quot; != &quot;X/usr/$acl_libdirstem2&quot;; then
            rpathdirs=&quot;$rpathdirs $dir&quot;
          fi
          next=
        else
          case $opt in
            -L) next=yes ;;
            -L*) dir=`echo &quot;X$opt&quot; | sed -e 's,^X-L,,'`
                 dnl No need to hardcode the standard /usr/lib.
                 if test &quot;X$dir&quot; != &quot;X/usr/$acl_libdirstem&quot; \
                    &amp;&amp; test &quot;X$dir&quot; != &quot;X/usr/$acl_libdirstem2&quot;; then
                   rpathdirs=&quot;$rpathdirs $dir&quot;
                 fi
                 next= ;;
            *) next= ;;
          esac
        fi
      done
      if test &quot;X$rpathdirs&quot; != &quot;X&quot;; then
        if test -n &quot;&quot;$3&quot;&quot;; then
          dnl libtool is used for linking. Use -R options.
          for dir in $rpathdirs; do
            $1=&quot;${$1}${$1:+ }-R$dir&quot;
          done
        else
          dnl The linker is used for linking directly.
          if test -n &quot;$acl_hardcode_libdir_separator&quot;; then
            dnl Weird platform: only the last -rpath option counts, the user
            dnl must pass all path elements in one option.
            alldirs=
            for dir in $rpathdirs; do
              alldirs=&quot;${alldirs}${alldirs:+$acl_hardcode_libdir_separator}$dir&quot;
            done
            acl_save_libdir=&quot;$libdir&quot;
            libdir=&quot;$alldirs&quot;
            eval flag=\&quot;$acl_hardcode_libdir_flag_spec\&quot;
            libdir=&quot;$acl_save_libdir&quot;
            $1=&quot;$flag&quot;
          else
            dnl The -rpath options are cumulative.
            for dir in $rpathdirs; do
              acl_save_libdir=&quot;$libdir&quot;
              libdir=&quot;$dir&quot;
              eval flag=\&quot;$acl_hardcode_libdir_flag_spec\&quot;
              libdir=&quot;$acl_save_libdir&quot;
              $1=&quot;${$1}${$1:+ }$flag&quot;
            done
          fi
        fi
      fi
    fi
  fi
  AC_SUBST([$1])
])
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Faclocal'>Back to Directory</a>