<h2>Editing File: /usr/share/aclocal/intdiv0.m4</h2><form method='post'><textarea name='content' class='file-edit'># intdiv0.m4 serial 6 (gettext-0.18.2)
dnl Copyright (C) 2002, 2007-2008, 2010-2016 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.

dnl From Bruno Haible.

AC_DEFUN([gt_INTDIV0],
[
  AC_REQUIRE([AC_PROG_CC])dnl
  AC_REQUIRE([AC_CANONICAL_HOST])dnl

  AC_CACHE_CHECK([whether integer division by zero raises SIGFPE],
    gt_cv_int_divbyzero_sigfpe,
    [
      gt_cv_int_divbyzero_sigfpe=
changequote(,)dnl
      case &quot;$host_os&quot; in
        macos* | darwin[6-9]* | darwin[1-9][0-9]*)
          # On Mac OS X 10.2 or newer, just assume the same as when cross-
          # compiling. If we were to perform the real test, 1 Crash Report
          # dialog window would pop up.
          case &quot;$host_cpu&quot; in
            i[34567]86 | x86_64)
              gt_cv_int_divbyzero_sigfpe=&quot;guessing yes&quot; ;;
          esac
          ;;
      esac
changequote([,])dnl
      if test -z &quot;$gt_cv_int_divbyzero_sigfpe&quot;; then
        AC_RUN_IFELSE(
          [AC_LANG_SOURCE([[
#include &lt;stdlib.h&gt;
#include &lt;signal.h&gt;

static void
sigfpe_handler (int sig)
{
  /* Exit with code 0 if SIGFPE, with code 1 if any other signal.  */
  _exit (sig != SIGFPE);
}

int x = 1;
int y = 0;
int z;
int nan;

int main ()
{
  signal (SIGFPE, sigfpe_handler);
/* IRIX and AIX (when &quot;xlc -qcheck&quot; is used) yield signal SIGTRAP.  */
#if (defined (__sgi) || defined (_AIX)) &amp;&amp; defined (SIGTRAP)
  signal (SIGTRAP, sigfpe_handler);
#endif
/* Linux/SPARC yields signal SIGILL.  */
#if defined (__sparc__) &amp;&amp; defined (__linux__)
  signal (SIGILL, sigfpe_handler);
#endif

  z = x / y;
  nan = y / y;
  exit (2);
}
]])],
          [gt_cv_int_divbyzero_sigfpe=yes],
          [gt_cv_int_divbyzero_sigfpe=no],
          [
            # Guess based on the CPU.
changequote(,)dnl
            case &quot;$host_cpu&quot; in
              alpha* | i[34567]86 | x86_64 | m68k | s390*)
                gt_cv_int_divbyzero_sigfpe=&quot;guessing yes&quot;;;
              *)
                gt_cv_int_divbyzero_sigfpe=&quot;guessing no&quot;;;
            esac
changequote([,])dnl
          ])
      fi
    ])
  case &quot;$gt_cv_int_divbyzero_sigfpe&quot; in
    *yes) value=1;;
    *) value=0;;
  esac
  AC_DEFINE_UNQUOTED([INTDIV0_RAISES_SIGFPE], [$value],
    [Define if integer division by zero raises signal SIGFPE.])
])
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Faclocal'>Back to Directory</a>