<h2>Editing File: /usr/local/share/perl5/alienfile.pm</h2><form method='post'><textarea name='content' class='file-edit'>package alienfile;

use strict;
use warnings;
use 5.008004;
use Alien::Build;
use Exporter ();
use Path::Tiny ();
use Carp ();

sub _path { Path::Tiny::path(@_) }

# ABSTRACT: Specification for defining an external dependency for CPAN
our $VERSION = '2.83'; # VERSION


our @EXPORT = qw( requires on plugin probe configure share sys download fetch decode prefer extract patch patch_ffi build build_ffi gather gather_ffi meta_prop ffi log test start_url before after digest );


sub requires
{
  my($module, $version) = @_;
  $version ||= 0;
  my $caller = caller;
  my $meta = $caller-&gt;meta;
  $meta-&gt;add_requires($meta-&gt;{phase}, $module, $version);
  ();
}


sub plugin
{
  my($name, @args) = @_;

  my $caller = caller;
  $caller-&gt;meta-&gt;apply_plugin($name, @args);
  return;
}


sub probe
{
  my($instr) = @_;
  my $caller = caller;
  if(my $phase = $caller-&gt;meta-&gt;{phase})
  {
    Carp::croak &quot;probe must not be in a $phase block&quot; if $phase ne 'any';
  }
  $caller-&gt;meta-&gt;register_hook(probe =&gt; $instr);
  return;
}


sub _phase
{
  my($code, $phase) = @_;
  my $caller = caller(1);
  my $meta = $caller-&gt;meta;
  local $meta-&gt;{phase} = $phase;
  $code-&gt;();
  return;
}

sub configure (&amp;)
{
  _phase($_[0], 'configure');
}


sub sys (&amp;)
{
  _phase($_[0], 'system');
}


sub share (&amp;)
{
  _phase($_[0], 'share');
}


sub _in_phase
{
  my($phase) = @_;
  my $caller = caller(1);
  my(undef, undef, undef, $sub) = caller(1);
  my $meta = $caller-&gt;meta;
  $sub =~ s/^.*:://;
  Carp::croak &quot;$sub must be in a $phase block&quot;
    unless $meta-&gt;{phase} eq $phase;
}

sub start_url
{
  my($url) = @_;
  _in_phase 'share';
  my $caller = caller;
  my $meta = $caller-&gt;meta;
  $meta-&gt;prop-&gt;{start_url} = $url;
  $meta-&gt;add_requires('configure' =&gt; 'Alien::Build' =&gt; '1.19');
  return;
}


sub digest
{
  my($algo, $digest) = @_;

  my $caller = caller;
  $caller-&gt;meta-&gt;apply_plugin('Digest', [$algo, $digest]);
  return;
}


sub download
{
  my($instr) = @_;
  _in_phase 'share';
  my $caller = caller;
  $caller-&gt;meta-&gt;register_hook(download =&gt; $instr);
  return;
}


sub fetch
{
  my($instr) = @_;
  _in_phase 'share';
  my $caller = caller;
  $caller-&gt;meta-&gt;register_hook(fetch =&gt; $instr);
  return;
}


sub decode
{
  my($instr) = @_;
  _in_phase 'share';
  my $caller = caller;
  $caller-&gt;meta-&gt;register_hook(decode =&gt; $instr);
  return;
}


sub prefer
{
  my($instr) = @_;
  _in_phase 'share';
  my $caller = caller;
  $caller-&gt;meta-&gt;register_hook(prefer =&gt; $instr);
  return;
}


sub extract
{
  my($instr) = @_;
  _in_phase 'share';
  my $caller = caller;
  $caller-&gt;meta-&gt;register_hook(extract =&gt; $instr);
  return;
}


sub patch
{
  my($instr) = @_;
  _in_phase 'share';
  my $caller = caller;
  my $suffix = $caller-&gt;meta-&gt;{build_suffix};
  $caller-&gt;meta-&gt;register_hook(&quot;patch$suffix&quot; =&gt; $instr);
  return;
}


sub patch_ffi
{
  my($instr) = @_;
  Carp::carp(&quot;patch_ffi is deprecated, use ffi { patch ... } } instead&quot;);
  _in_phase 'share';
  my $caller = caller;
  $caller-&gt;meta-&gt;register_hook(patch_ffi =&gt; $instr);
  return;
}


sub build
{
  my($instr) = @_;
  _in_phase 'share';
  my $caller = caller;
  my $suffix = $caller-&gt;meta-&gt;{build_suffix};
  $caller-&gt;meta-&gt;register_hook(&quot;build$suffix&quot; =&gt; $instr);
  return;
}


sub build_ffi
{
  my($instr) = @_;
  Carp::carp(&quot;build_ffi is deprecated, use ffi { build ... } } instead&quot;);
  _in_phase 'share';
  my $caller = caller;
  $caller-&gt;meta-&gt;register_hook(build_ffi =&gt; $instr);
  return;
}


sub gather
{
  my($instr) = @_;
  my $caller = caller;
  my $meta = $caller-&gt;meta;
  my $phase = $meta-&gt;{phase};
  Carp::croak &quot;gather is not allowed in configure block&quot;
    if $phase eq 'configure';
  my $suffix = $caller-&gt;meta-&gt;{build_suffix};
  if($suffix eq '_ffi')
  {
    $meta-&gt;register_hook(gather_ffi =&gt; $instr)
  }
  else
  {
    $meta-&gt;register_hook(gather_system =&gt; $instr) if $phase =~ /^(any|system)$/;
    $meta-&gt;register_hook(gather_share =&gt; $instr)  if $phase =~ /^(any|share)$/;
  }
  return;
}


sub gather_ffi
{
  my($instr) = @_;
  Carp::carp(&quot;gather_ffi is deprecated, use ffi { gather ... } } instead&quot;);
  _in_phase 'share';
  my $caller = caller;
  $caller-&gt;meta-&gt;register_hook(gather_ffi =&gt; $instr);
  return;
}


sub ffi (&amp;)
{
  my($code) = @_;
  _in_phase 'share';
  my $caller = caller;
  local $caller-&gt;meta-&gt;{build_suffix} = '_ffi';
  $code-&gt;();
  return;
}


sub meta_prop
{
  my $caller = caller;
  my $meta = $caller-&gt;meta;
  $meta-&gt;prop;
}


sub log
{
  unshift @_, 'Alien::Build';
  goto &amp;Alien::Build::log;
}


sub test
{
  my($instr) = @_;
  my $caller = caller;
  my $meta = $caller-&gt;meta;
  my $phase = $meta-&gt;{phase};
  Carp::croak &quot;test is not allowed in $phase block&quot;
    if $phase eq 'any' || $phase eq 'configure';

  $meta-&gt;add_requires('configure' =&gt; 'Alien::Build' =&gt; '1.14');

  if($phase eq 'share')
  {
    my $suffix = $caller-&gt;meta-&gt;{build_suffix} || '_share';
    $meta-&gt;register_hook(
      &quot;test$suffix&quot; =&gt; $instr,
    );
  }
  elsif($phase eq 'system')
  {
    $meta-&gt;register_hook(
      &quot;test_system&quot; =&gt; $instr,
    );
  }
  else
  {
    die &quot;unknown phase: $phase&quot;;
  }
}


my %modifiers = (
  probe    =&gt; { any   =&gt; 'probe'    },
  download =&gt; { share =&gt; 'download' },
  fetch    =&gt; { share =&gt; 'fetch'    },
  decode   =&gt; { share =&gt; 'fetch'    },
  prefer   =&gt; { share =&gt; 'prefer'   },
  extract  =&gt; { share =&gt; 'extract'  },
  patch    =&gt; { share =&gt; 'patch$'   },
  build    =&gt; { share =&gt; 'build$'   },
  test     =&gt; { share =&gt; 'test$'    },
  # Note: below special case gather_ffi for the ffi block :P
  gather   =&gt; { share =&gt; 'gather_share', system =&gt; 'gather_system', any =&gt; 'gather_share,gather_system' },
);

sub _add_modifier
{
  my($type, $stage, $sub) = @_;

  my $method = &quot;${type}_hook&quot;;

  Carp::croak &quot;No such stage $stage&quot; unless defined $modifiers{$stage};
  Carp::croak &quot;$type $stage argument must be a code reference&quot; unless defined $sub &amp;&amp; ref($sub) eq 'CODE';

  my $caller = caller;
  my $meta = $caller-&gt;meta;
  Carp::croak &quot;$type $stage is not allowed in sys block&quot; unless defined $modifiers{$stage}-&gt;{$meta-&gt;{phase}};

  $meta-&gt;add_requires('configure' =&gt; 'Alien::Build' =&gt; '1.40');

  my $suffix = $meta-&gt;{build_suffix};
  if($suffix eq '_ffi' &amp;&amp; $stage eq 'gather')
  {
    $meta-&gt;$method('gather_ffi' =&gt; $sub);
  }

  foreach my $hook (
    map { split /,/, $_ }                        # split on , for when multiple hooks must be attached (gather in any)
    map { my $x = $_ ; $x =~ s/\$/$suffix/; $x } # substitute $ at the end for a suffix (_ffi) if any
    $modifiers{$stage}-&gt;{$meta-&gt;{phase}})        # get the list of modifiers
  {
    $meta-&gt;$method($hook =&gt; $sub);
  }

  return;
}

sub before
{
  my($stage, $sub) = @_;
  @_ = ('before', @_);
  goto &amp;alienfile::_add_modifier;
}


sub after
{
  my($stage, $sub) = @_;
  @_ = ('after', @_);
  goto &amp;alienfile::_add_modifier;
}

sub import
{
  strict-&gt;import;
  warnings-&gt;import;
  goto &amp;Exporter::import;
}

1;

__END__

=pod

=encoding UTF-8

=head1 NAME

alienfile - Specification for defining an external dependency for CPAN

=head1 VERSION

version 2.83

=head1 SYNOPSIS

Do-it-yourself approach:

 use alienfile;
 
 probe [ 'pkg-config --exists libarchive' ];
 
 share {
 
   start_url 'http://libarchive.org/downloads/libarchive-3.2.2.tar.gz';
 
   # the first one which succeeds will be used
   download [ 'wget %{.meta.start_url}' ];
   download [ 'curl -o %{.meta.start_url}' ];
 
   extract [ 'tar xf %{.install.download}' ];
 
   build [
     # Note: will not work on Windows, better to use Build::Autoconf plugin
     # if you need windows support
     './configure --prefix=%{.install.prefix} --disable-shared',
     '%{make}',
     '%{make} install',
   ];
 }
 
 gather [
   [ 'pkg-config', '--modversion', 'libarchive', \'%{.runtime.version}' ],
   [ 'pkg-config', '--cflags',     'libarchive', \'%{.runtime.cflags}'  ],
   [ 'pkg-config', '--libs',       'libarchive', \'%{.runtime.libs}'    ],
 ];

With plugins (better):

 use alienfile;
 
 plugin 'PkgConfig' =&gt; 'libarchive';
 
 share {
   start_url 'http://libarchive.org/downloads/';
   plugin Download =&gt; (
     filter =&gt; qr/^libarchive-.*\.tar\.gz$/,
     version =&gt; qr/([0-9\.]+)/,
   );
   plugin Extract =&gt; 'tar.gz';
   plugin 'Build::Autoconf';
   plugin 'Gather::IsolateDynamic';
   build [
     '%{configure}',
     '%{make}',
     '%{make} install',
   ];
 };

=head1 DESCRIPTION

An alienfile is a recipe used by L&lt;Alien::Build&gt; to, probe for system libraries or download from the internet, and build source
for those libraries.  This document acts as reference for the alienfile system, but if you are starting out writing your own Alien
you should read L&lt;Alien::Build::Manual::AlienAuthor&gt;, which will teach you how to write your own complete Alien using alienfile +
L&lt;Alien::Build&gt; + L&lt;ExtUtils::MakeMaker&gt;.  Special attention should be taken to the section &quot;a note about dynamic vs. static
libraries&quot;.

=head1 DIRECTIVES

=head2 requires

&quot;any&quot; requirement (either share or system):

 requires $module;
 requires $module =&gt; $version;

configure time requirement:

 configure {
   requires $module;
   requires $module =&gt; $version;
 };

system requirement:

 sys {
   requires $module;
   requires $module =&gt; $version;
 };

share requirement:

 share {
   requires $module;
   requires $module =&gt; $version;
 };

specifies a requirement.  L&lt;Alien::Build&gt; takes advantage of dynamic requirements, so only
modules that are needed for the specific type of install need to be loaded.  Here are the
different types of requirements:

=over

=item configure

Configure requirements should already be installed before the alienfile is loaded.

=item any

&quot;Any&quot; requirements are those that are needed either for the probe stage, or in either the
system or share installs.

=item share

Share requirements are those modules needed when downloading and building from source.

=item system

System requirements are those modules needed when the system provides the library or tool.

=back

=head2 plugin

 plugin $name =&gt; (%args);
 plugin $name =&gt; $arg;

Load the given plugin.  If you prefix the plugin name with an C&lt;=&gt; sign,
then it will be assumed to be a fully qualified path name.  Otherwise the
plugin will be assumed to live in the C&lt;Alien::Build::Plugin&gt; namespace.
If there is an appropriate negotiate plugin, that one will be loaded.
Examples:

 # Loads Alien::Build::Plugin::Fetch::Negotiate
 # which will pick the best Alien::Build::Plugin::Fetch
 # plugin based on the URL, and system configuration
 plugin 'Fetch' =&gt; 'http://ftp.gnu.org/gnu/gcc';
 
 # loads the plugin with the badly named class!
 plugin '=Badly::Named::Plugin::Not::In::Alien::Build::Namespace';
 
 # explicitly loads Alien::Build::Plugin::Prefer::SortVersions
 plugin 'Prefer::SortVersions' =&gt; (
   filter =&gt; qr/^gcc-.*\.tar\.gz$/,
   version =&gt; qr/([0-9\.]+)/,
 );

=head2 probe

 probe \&amp;code;
 probe \@commandlist;

Instructions for the probe stage.  May be either a code reference, or a command list.
Multiple probes and probe plugins can be given.  These will be used in sequence,
stopping at the first that detects a system installation.  L&lt;Alien::Build&gt; will use
a share install if no system installation is detected by the probes.

=head2 configure

 configure {
   ...
 };

Configure block.  The only directive allowed in a configure block is
requires.

=head2 sys

 sys {
   ...
 };

System block.  Allowed directives are: requires and gather.

=head2 share

 share {
   ...
 };

System block.  Allowed directives are: download, fetch, decode, prefer, extract, build, gather.

=head2 start_url

 share {
   start_url $url;
 };

Set the start URL for download.  This should be the URL to an index page, or the actual tarball of the source.

=head2 digest

[experimental]

 share {
   digest $algorithm, $digest;
 };

Check fetched and downloaded files against the given algorithm and
digest.  Typically you will want to use SHA256 as the algorithm.

=head2 download

 share {
   download \&amp;code;
   download \@commandlist;
 };

Instructions for the download stage.  May be either a
code reference, or a command list.

=head2 fetch

 share {
   fetch \&amp;code;
   fetch \@commandlist;
 };

Instructions for the fetch stage.  May be either a
code reference, or a command list.

=head2 decode

 share {
   decode \&amp;code;
   decode \@commandlist;
 };

Instructions for the decode stage.  May be either a
code reference, or a command list.

=head2 prefer

 share {
   prefer \&amp;code;
   prefer \@commandlist;
 };

Instructions for the prefer stage.  May be either a
code reference, or a command list.

=head2 extract

 share {
   extract \&amp;code;
   extract \@commandlist;
 };

Instructions for the extract stage.  May be either a
code reference, or a command list.

=head2 patch

 share {
   patch \&amp;code;
   patch \@commandlist;
 };

Instructions for the patch stage.  May be either a
code reference, or a command list.

=head2 patch_ffi

 share {
   patch_ffi \&amp;code;
   patch_ffi \@commandlist;
 };

[DEPRECATED]

Instructions for the patch_ffi stage.  May be either a
code reference, or a command list.

=head2 build

 share {
   build \&amp;code;
   build \@commandlist;
 };

Instructions for the build stage.  May be either a
code reference, or a command list.

=head2 build_ffi

 share {
   build \&amp;code;
   build \@commandlist;
 };

[DEPRECATED]

Instructions for the build FFI stage.  Builds shared libraries instead of static.
This is optional, and is only necessary if a fresh and separate build needs to be
done for FFI.

=head2 gather

 gather \&amp;code;
 gather \@commandlist;
 
 share {
   gather \&amp;code;
   gather \@commandlist;
 };
 
 sys {
   gather \&amp;code;
   gather \@commandlist;
 };

Instructions for the gather stage.  May be either a code reference, or a command list.
In the root block of the alienfile it will trigger in both share and system build.
In the share or sys block it will only trigger in the corresponding build.

=head2 gather_ffi

 share {
   gather_ffi \&amp;code;
   gather_ffi \@commandlist;
 }

[DEPRECATED]

Gather specific to C&lt;build_ffi&gt;.  Not usually necessary.

=head2 ffi

 share {
   ffi {
     patch \&amp;code;
     patch \@commandlist;
     build \&amp;code;
     build \@commandlist;
     gather \&amp;code;
     gather \@commandlist;
   }
 }

Specify patch, build or gather stages related to FFI.

=head2 meta_prop

 my $hash = meta_prop;

Get the meta_prop hash reference.

=head2 meta

 my $meta = meta;

Returns the meta object for your L&lt;alienfile&gt;.  For methods that can be used on the
meta object, see L&lt;Alien::Build/&quot;META METHODS&quot;&gt;.

=head2 log

 log($message);

Prints the given log to stdout.

=head2 test

 share {
   test \&amp;code;
   test \@commandlist;
 };
 sys {
   test \&amp;code;
   test \@commandlist;
 };

Run the tests

=head2 before

 before $stage =&gt; \&amp;code;

Execute the given code before the given stage.  Stage should be one of
C&lt;probe&gt;, C&lt;download&gt;, C&lt;fetch&gt;, C&lt;decode&gt;, C&lt;prefer&gt;, C&lt;extract&gt;,
C&lt;patch&gt;, C&lt;build&gt;, C&lt;test&gt;, and C&lt;gather&gt;.

The before directive is only legal in the same blocks as the stage would
normally be legal in.  For example, you can't do this:

 use alienfile;
 
 sys {
   before 'build' =&gt; sub {
     ...
   };
 };

Because a C&lt;build&gt; wouldn't be legal inside a C&lt;sys&gt; block.

=head2 after

 after $stage =&gt; \&amp;code;

Execute the given code after the given stage.  Stage should be one of
C&lt;probe&gt;, C&lt;download&gt;, C&lt;fetch&gt;, C&lt;decode&gt;, C&lt;prefer&gt;, C&lt;extract&gt;,
C&lt;patch&gt;, C&lt;build&gt;, C&lt;test&gt;, and C&lt;gather&gt;.

The after directive is only legal in the same blocks as the stage would
normally be legal in.  For example, you can't do this:

 use alienfile;
 
 sys {
   after 'build' =&gt; sub {
     ...
   };
 };

Because a C&lt;build&gt; wouldn't be legal inside a C&lt;sys&gt; block.

=head1 SEE ALSO

=over 4

=item L&lt;Alien&gt;

=item L&lt;Alien::Build&gt;

=item L&lt;Alien::Build::MM&gt;

=item L&lt;Alien::Base&gt;

=back

=head1 AUTHOR

Author: Graham Ollis E&lt;lt&gt;plicease@cpan.orgE&lt;gt&gt;

Contributors:

Diab Jerius (DJERIUS)

Roy Storey (KIWIROY)

Ilya Pavlov

David Mertens (run4flat)

Mark Nunberg (mordy, mnunberg)

Christian Walde (Mithaldu)

Brian Wightman (MidLifeXis)

Zaki Mughal (zmughal)

mohawk (mohawk2, ETJ)

Vikas N Kumar (vikasnkumar)

Flavio Poletti (polettix)

Salvador Fandiño (salva)

Gianni Ceccarelli (dakkar)

Pavel Shaydo (zwon, trinitum)

Kang-min Liu (劉康民, gugod)

Nicholas Shipp (nshp)

Juan Julián Merelo Guervós (JJ)

Joel Berger (JBERGER)

Petr Písař (ppisar)

Lance Wicks (LANCEW)

Ahmad Fatoum (a3f, ATHREEF)

José Joaquín Atria (JJATRIA)

Duke Leto (LETO)

Shoichi Kaji (SKAJI)

Shawn Laffan (SLAFFAN)

Paul Evans (leonerd, PEVANS)

Håkon Hægland (hakonhagland, HAKONH)

nick nauwelaerts (INPHOBIA)

Florian Weimer

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2011-2022 by Graham Ollis.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fshare%2Fperl5'>Back to Directory</a>