<h2>Editing File: /usr/local/share/perl5/XML/SAX.pm</h2><form method='post'><textarea name='content' class='file-edit'># $Id$

package XML::SAX;

use strict;
use vars qw($VERSION @ISA @EXPORT_OK);

$VERSION = '1.02';

use Exporter ();
@ISA = ('Exporter');

@EXPORT_OK = qw(Namespaces Validation);

use File::Basename qw(dirname);
use File::Spec ();
use Symbol qw(gensym);
use XML::SAX::ParserFactory (); # loaded for simplicity

use constant PARSER_DETAILS =&gt; &quot;ParserDetails.ini&quot;;

use constant Namespaces =&gt; &quot;http://xml.org/sax/features/namespaces&quot;;
use constant Validation =&gt; &quot;http://xml.org/sax/features/validation&quot;;

my $known_parsers = undef;

# load_parsers takes the ParserDetails.ini file out of the same directory
# that XML::SAX is in, and looks at it. Format in POD below

=begin EXAMPLE

[XML::SAX::PurePerl]
http://xml.org/sax/features/namespaces = 1
http://xml.org/sax/features/validation = 0
# a comment

# blank lines ignored

[XML::SAX::AnotherParser]
http://xml.org/sax/features/namespaces = 0
http://xml.org/sax/features/validation = 1

=end EXAMPLE

=cut

sub load_parsers {
    my $class = shift;
    my $dir = shift;
    
    # reset parsers
    $known_parsers = [];
    
    # get directory from wherever XML::SAX is installed
    if (!$dir) {
        $dir = $INC{'XML/SAX.pm'};
        $dir = dirname($dir);
    }
    
    my $fh = gensym();
    if (!open($fh, File::Spec-&gt;catfile($dir, &quot;SAX&quot;, PARSER_DETAILS))) {
        XML::SAX-&gt;do_warn(&quot;could not find &quot; . PARSER_DETAILS . &quot; in $dir/SAX\n&quot;);
        return $class;
    }

    $known_parsers = $class-&gt;_parse_ini_file($fh);

    return $class;
}

sub _parse_ini_file {
    my $class = shift;
    my ($fh) = @_;

    my @config;
    
    my $lineno = 0;
    while (defined(my $line = &lt;$fh&gt;)) {
        $lineno++;
        my $original = $line;
        # strip whitespace
        $line =~ s/\s*$//m;
        $line =~ s/^\s*//m;
        # strip comments
        $line =~ s/[#;].*$//m;
        # ignore blanks
        next if $line =~ /^$/m;
        
        # heading
        if ($line =~ /^\[\s*(.*)\s*\]$/m) {
            push @config, { Name =&gt; $1 };
            next;
        }
        
        # instruction
        elsif ($line =~ /^(.*?)\s*?=\s*(.*)$/) {
            unless(@config) {
                push @config, { Name =&gt; '' };
            }
            $config[-1]{Features}{$1} = $2;
        }

        # not whitespace, comment, or instruction
        else {
            die &quot;Invalid line in ini: $lineno\n&gt;&gt;&gt; $original\n&quot;;
        }
    }

    return \@config;
}

sub parsers {
    my $class = shift;
    if (!$known_parsers) {
        $class-&gt;load_parsers();
    }
    return $known_parsers;
}

sub remove_parser {
    my $class = shift;
    my ($parser_module) = @_;

    if (!$known_parsers) {
        $class-&gt;load_parsers();
    }
    
    @$known_parsers = grep { $_-&gt;{Name} ne $parser_module } @$known_parsers;

    return $class;
}
 
sub add_parser {
    my $class = shift;
    my ($parser_module) = @_;

    if (!$known_parsers) {
        $class-&gt;load_parsers();
    }
    
    # first load module, then query features, then push onto known_parsers,
    
    my $parser_file = $parser_module;
    $parser_file =~ s/::/\//g;
    $parser_file .= &quot;.pm&quot;;

    require $parser_file;

    my @features = $parser_module-&gt;supported_features();
    
    my $new = { Name =&gt; $parser_module };
    foreach my $feature (@features) {
        $new-&gt;{Features}{$feature} = 1;
    }

    # If exists in list already, move to end.
    my $done = 0;
    my $pos = undef;
    for (my $i = 0; $i &lt; @$known_parsers; $i++) {
        my $p = $known_parsers-&gt;[$i];
        if ($p-&gt;{Name} eq $parser_module) {
            $pos = $i;
        }
    }
    if (defined $pos) {
        splice(@$known_parsers, $pos, 1);
        push @$known_parsers, $new;
        $done++;
    }

    # Otherwise (not in list), add at end of list.
    if (!$done) {
        push @$known_parsers, $new;
    }
    
    return $class;
}

sub save_parsers {
    my $class = shift;
    
    # get directory from wherever XML::SAX is installed
    my $dir = $INC{'XML/SAX.pm'};
    $dir = dirname($dir);
    
    my $file = File::Spec-&gt;catfile($dir, &quot;SAX&quot;, PARSER_DETAILS);
    chmod 0644, $file;
    unlink($file);
    
    my $fh = gensym();
    open($fh, &quot;&gt;$file&quot;) ||
        die &quot;Cannot write to $file: $!&quot;;

    foreach my $p (@$known_parsers) {
        print $fh &quot;[$p-&gt;{Name}]\n&quot;;
        foreach my $key (keys %{$p-&gt;{Features}}) {
            print $fh &quot;$key = $p-&gt;{Features}{$key}\n&quot;;
        }
        print $fh &quot;\n&quot;;
    }

    print $fh &quot;\n&quot;;

    close $fh;

    return $class;
}

sub do_warn {
    my $class = shift;
    # Don't output warnings if running under Test::Harness
    warn(@_) unless $ENV{HARNESS_ACTIVE};
}

1;
__END__

=head1 NAME

XML::SAX - Simple API for XML

=head1 SYNOPSIS

  use XML::SAX;
  
  # get a list of known parsers
  my $parsers = XML::SAX-&gt;parsers();
  
  # add/update a parser
  XML::SAX-&gt;add_parser(q(XML::SAX::PurePerl));

  # remove parser
  XML::SAX-&gt;remove_parser(q(XML::SAX::Foodelberry));

  # save parsers
  XML::SAX-&gt;save_parsers();

=head1 DESCRIPTION

XML::SAX is a SAX parser access API for Perl. It includes classes
and APIs required for implementing SAX drivers, along with a factory
class for returning any SAX parser installed on the user's system.

=head1 USING A SAX2 PARSER

The factory class is XML::SAX::ParserFactory. Please see the
documentation of that module for how to instantiate a SAX parser:
L&lt;XML::SAX::ParserFactory&gt;. However if you don't want to load up
another manual page, here's a short synopsis:

  use XML::SAX::ParserFactory;
  use XML::SAX::XYZHandler;
  my $handler = XML::SAX::XYZHandler-&gt;new();
  my $p = XML::SAX::ParserFactory-&gt;parser(Handler =&gt; $handler);
  $p-&gt;parse_uri(&quot;foo.xml&quot;);
  # or $p-&gt;parse_string(&quot;&lt;foo/&gt;&quot;) or $p-&gt;parse_file($fh);

This will automatically load a SAX2 parser (defaulting to
XML::SAX::PurePerl if no others are found) and return it to you.

In order to learn how to use SAX to parse XML, you will need to read
L&lt;XML::SAX::Intro&gt; and for reference, L&lt;XML::SAX::Specification&gt;.

=head1 WRITING A SAX2 PARSER

The first thing to remember in writing a SAX2 parser is to subclass
XML::SAX::Base. This will make your life infinitely easier, by providing
a number of methods automagically for you. See L&lt;XML::SAX::Base&gt; for more
details.

When writing a SAX2 parser that is compatible with XML::SAX, you need
to inform XML::SAX of the presence of that driver when you install it.
In order to do that, XML::SAX contains methods for saving the fact that
the parser exists on your system to a &quot;INI&quot; file, which is then loaded
to determine which parsers are installed.

The best way to do this is to follow these rules:

=over 4

=item * Add XML::SAX as a prerequisite in Makefile.PL:

  WriteMakefile(
      ...
      PREREQ_PM =&gt; { 'XML::SAX' =&gt; 0 },
      ...
  );

Alternatively you may wish to check for it in other ways that will
cause more than just a warning.

=item * Add the following code snippet to your Makefile.PL:

  sub MY::install {
    package MY;
    my $script = shift-&gt;SUPER::install(@_);
    if (ExtUtils::MakeMaker::prompt(
      &quot;Do you want to modify ParserDetails.ini?&quot;, 'Y')
      =~ /^y/i) {
      $script =~ s/install :: (.*)$/install :: $1 install_sax_driver/m;
      $script .= &lt;&lt;&quot;INSTALL&quot;;
  
  install_sax_driver :
  \t\@\$(PERL) -MXML::SAX -e &quot;XML::SAX-&gt;add_parser(q(\$(NAME)))-&gt;save_parsers()&quot;
  
  INSTALL
    }
    return $script;
  }

Note that you should check the output of this - \$(NAME) will use the name of
your distribution, which may not be exactly what you want. For example XML::LibXML
has a driver called XML::LibXML::SAX::Generator, which is used in place of
\$(NAME) in the above.

=item * Add an XML::SAX test:

A test file should be added to your t/ directory containing something like the
following:

  use Test;
  BEGIN { plan tests =&gt; 3 }
  use XML::SAX;
  use XML::SAX::PurePerl::DebugHandler;
  XML::SAX-&gt;add_parser(q(XML::SAX::MyDriver));
  local $XML::SAX::ParserPackage = 'XML::SAX::MyDriver';
  eval {
    my $handler = XML::SAX::PurePerl::DebugHandler-&gt;new();
    ok($handler);
    my $parser = XML::SAX::ParserFactory-&gt;parser(Handler =&gt; $handler);
    ok($parser);
    ok($parser-&gt;isa('XML::SAX::MyDriver');
    $parser-&gt;parse_string(&quot;&lt;tag/&gt;&quot;);
    ok($handler-&gt;{seen}{start_element});
  };

=back

=head1 EXPORTS

By default, XML::SAX exports nothing into the caller's namespace. However you
can request the symbols C&lt;Namespaces&gt; and C&lt;Validation&gt; which are the
URIs for those features, allowing an easier way to request those features
via ParserFactory:

  use XML::SAX qw(Namespaces Validation);
  my $factory = XML::SAX::ParserFactory-&gt;new();
  $factory-&gt;require_feature(Namespaces);
  $factory-&gt;require_feature(Validation);
  my $parser = $factory-&gt;parser();

=head1 AUTHOR

Current maintainer: Grant McLean, grantm@cpan.org

Originally written by:

Matt Sergeant, matt@sergeant.org

Kip Hampton, khampton@totalcinema.com

Robin Berjon, robin@knowscape.com

=head1 LICENSE

This is free software, you may use it and distribute it under
the same terms as Perl itself.

=head1 SEE ALSO

L&lt;XML::SAX::Base&gt; for writing SAX Filters and Parsers

L&lt;XML::SAX::PurePerl&gt; for an XML parser written in 100%
pure perl.

L&lt;XML::SAX::Exception&gt; for details on exception handling

=cut

</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fshare%2Fperl5%2FXML'>Back to Directory</a>