<h2>Editing File: /usr/local/share/perl5/Test/Alien.pm</h2><form method='post'><textarea name='content' class='file-edit'>package Test::Alien;

use strict;
use warnings;
use 5.008004;
use Env qw( @PATH );
use File::Which 1.10 qw( which );
use Capture::Tiny qw( capture capture_merged );
use Alien::Build::Temp;
use File::Copy qw( move );
use Text::ParseWords qw( shellwords );
use Test2::API qw( context run_subtest );
use Exporter qw( import );
use Path::Tiny qw( path );
use Alien::Build::Util qw( _dump );
use Config;

our @EXPORT = qw( alien_ok run_ok xs_ok ffi_ok with_subtest synthetic helper_ok interpolate_template_is interpolate_run_ok plugin_ok );

# ABSTRACT: Testing tools for Alien modules
our $VERSION = '2.83'; # VERSION


our @aliens;

sub alien_ok ($;$)
{
  my($alien, $message) = @_;

  my $name = ref $alien ? ref($alien) . '[instance]' : $alien;
  $name = 'undef' unless defined $name;
  my @methods = qw( cflags libs dynamic_libs bin_dir );
  $message ||= &quot;$name responds to: @methods&quot;;

  my $ok;
  my @diag;

  if(defined $alien)
  {
    my @missing = grep { ! $alien-&gt;can($_) } @methods;

    $ok = !@missing;
    push @diag, map { &quot;  missing method $_&quot; } @missing;

    if($ok)
    {
      push @aliens, $alien;
      if($^O eq 'MSWin32' &amp;&amp; $alien-&gt;isa('Alien::MSYS'))
      {
        unshift @PATH, Alien::MSYS::msys_path();
      }
      else
      {
        unshift @PATH, $alien-&gt;bin_dir;
      }
    }

    if($alien-&gt;can('alien_helper'))
    {
      my($intr) = _interpolator();

      my $help = eval { $alien-&gt;alien_helper };

      if(my $error = $@)
      {
        $ok = 0;
        push @diag, &quot;  error getting helpers: $error&quot;;
      }

      foreach my $name (keys %$help)
      {
        my $code = $help-&gt;{$name};
        $intr-&gt;replace_helper($name, $code);
      }
    }
  }
  else
  {
    $ok = 0;
    push @diag, &quot;  undefined alien&quot;;
  }

  my $ctx = context();
  $ctx-&gt;ok($ok, $message);
  $ctx-&gt;diag($_) for @diag;
  $ctx-&gt;release;

  $ok;
}


sub synthetic
{
  my($opt) = @_;
  $opt ||= {};
  my %alien = %$opt;
  require Test::Alien::Synthetic;
  bless \%alien, 'Test::Alien::Synthetic',
}


sub run_ok
{
  my($command, $message) = @_;

  my(@command) = ref $command ? @$command : (do {
    my $command = $command; # make a copy

    # Double the backslashes so that when they are unescaped by shellwords(),
    # they become a single backslash. This should be fine on Windows since
    # backslashes are not used to escape metacharacters in cmd.exe.
    $command =~ s/\\/\\\\/g if $^O eq 'MSWin32';
    shellwords $command;
  });
  $message ||= ref $command ? &quot;run @command&quot; : &quot;run $command&quot;;

  require Test::Alien::Run;
  my $run = bless {
    out    =&gt; '',
    err    =&gt; '',
    exit   =&gt; 0,
    sig    =&gt; 0,
    cmd    =&gt; [@command],
  }, 'Test::Alien::Run';

  my $ctx = context();
  my $exe = which $command[0];
  if(defined $exe)
  {
    if(ref $command)
    {
      shift @command;
      $run-&gt;{cmd} = [$exe, @command];
    }
    else
    {
      $run-&gt;{cmd} = [$command];
    }
    my @diag;
    my $ok = 1;
    my($exit, $errno);
    ($run-&gt;{out}, $run-&gt;{err}, $exit, $errno) = capture {

      if(ref $command)
      {
        system $exe, @command;
      }
      else
      {
        system $command;
      }

      ($?,$!);
    };

    if($exit == -1)
    {
      $ok = 0;
      $run-&gt;{fail} = &quot;failed to execute: $errno&quot;;
      push @diag, &quot;  failed to execute: $errno&quot;;
    }
    elsif($exit &amp; 127)
    {
      $ok = 0;
      push @diag, &quot;  killed with signal: @{[ $exit &amp; 127 ]}&quot;;
      $run-&gt;{sig} = $exit &amp; 127;
    }
    else
    {
      $run-&gt;{exit} = $exit &gt;&gt; 8;
    }

    $ctx-&gt;ok($ok, $message);
    $ok
      ? $ctx-&gt;note(&quot;  using $exe&quot;)
      : $ctx-&gt;diag(&quot;  using $exe&quot;);
    $ctx-&gt;diag(@diag) for @diag;

  }
  else
  {
    $ctx-&gt;ok(0, $message);
    $ctx-&gt;diag(&quot;  command not found&quot;);
    $run-&gt;{fail} = 'command not found';
  }

  unless(@aliens || $ENV{TEST_ALIEN_ALIENS_MISSING})
  {
    $ctx-&gt;diag(&quot;run_ok called without any aliens, you may want to call alien_ok&quot;);
  }

  $ctx-&gt;release;

  $run;
}


sub _flags
{
  my($class, $method) = @_;
  my $static = &quot;${method}_static&quot;;
  $class-&gt;can($static) &amp;&amp; $class-&gt;can('install_type') &amp;&amp; $class-&gt;install_type eq 'share' &amp;&amp; (!$class-&gt;can('xs_load'))
    ? $class-&gt;$static
    : $class-&gt;$method;
}

sub xs_ok
{
  my $cb;
  $cb = pop if defined $_[-1] &amp;&amp; ref $_[-1] eq 'CODE';
  my($xs, $message) = @_;
  $message ||= 'xs';

  $xs = { xs =&gt; $xs } unless ref $xs;
  # make sure this is a copy because we may
  # modify it.
  $xs-&gt;{xs} = &quot;@{[ $xs-&gt;{xs} ]}&quot;;
  $xs-&gt;{pxs}              ||= {};
  $xs-&gt;{cbuilder_check}   ||= 'have_compiler';
  $xs-&gt;{cbuilder_config}  ||= {};
  $xs-&gt;{cbuilder_compile} ||= {};
  $xs-&gt;{cbuilder_link}    ||= {};

  require ExtUtils::CBuilder;
  my $skip = do {
    my $have_compiler = $xs-&gt;{cbuilder_check};
    my %config = %{ $xs-&gt;{cbuilder_config} };
    !ExtUtils::CBuilder-&gt;new( config =&gt; \%config )-&gt;$have_compiler;
  };

  if($skip)
  {
    my $ctx = context();
    $ctx-&gt;skip($message, 'test requires a compiler');
    $ctx-&gt;skip(&quot;$message subtest&quot;, 'test requires a compiler') if $cb;
    $ctx-&gt;release;
    return;
  }

  if($xs-&gt;{cpp} || $xs-&gt;{'C++'})
  {
    my $ctx = context();
    $ctx-&gt;bail(&quot;The cpp and C++ options have been removed from xs_ok&quot;);
  }
  else
  {
    $xs-&gt;{c_ext} ||= 'c';
  }

  my $verbose = $xs-&gt;{verbose} || 0;
  my $ok = 1;
  my @diag;
  my $dir = Alien::Build::Temp-&gt;newdir(
    TEMPLATE =&gt; 'test-alien-XXXXXX',
    CLEANUP  =&gt; $^O =~ /^(MSWin32|cygwin|msys)$/ ? 0 : 1,
  );

  my $xs_filename = path($dir)-&gt;child('test.xs')-&gt;stringify;
  my $c_filename  = path($dir)-&gt;child(&quot;test.@{[ $xs-&gt;{c_ext} ]}&quot;)-&gt;stringify;

  my $ctx = context();
  my $module;

  if($ENV{TEST_ALIEN_ALWAYS_KEEP})
  {
    $dir-&gt;unlink_on_destroy(0);
    $ctx-&gt;note(&quot;keeping XS temporary directory $dir at user request&quot;);
  }

  if($xs-&gt;{xs} =~ /\bTA_MODULE\b/)
  {
    our $count;
    $count = 0 unless defined $count;
    my $name = sprintf &quot;Test::Alien::XS::Mod%s%s&quot;, $count, chr(65 + $count % 26 ) x 4;
    $count++;
    my $code = $xs-&gt;{xs};
    $code =~ s{\bTA_MODULE\b}{$name}g;
    $xs-&gt;{xs} = $code;
  }

  # this regex copied shamefully from ExtUtils::ParseXS
  # in part because we need the module name to do the bootstrap
  # and also because if this regex doesn't match then ParseXS
  # does an exit() which we don't want.
  if($xs-&gt;{xs} =~ /^MODULE\s*=\s*([\w:]+)(?:\s+PACKAGE\s*=\s*([\w:]+))?(?:\s+PREFIX\s*=\s*(\S+))?\s*$/m)
  {
    $module = $1;
    $ctx-&gt;note(&quot;detect module name $module&quot;) if $verbose;
  }
  else
  {
    $ok = 0;
    push @diag, '  XS does not have a module decleration that we could find';
  }

  if($ok)
  {
    open my $fh, '&gt;', $xs_filename;
    print $fh $xs-&gt;{xs};
    close $fh;

    require ExtUtils::ParseXS;
    my $pxs = ExtUtils::ParseXS-&gt;new;

    my($out, $err) = capture_merged {
      eval {
        $pxs-&gt;process_file(
          filename     =&gt; $xs_filename,
          output       =&gt; $c_filename,
          versioncheck =&gt; 0,
          prototypes   =&gt; 0,
          %{ $xs-&gt;{pxs} },
        );
      };
      $@;
    };

    $ctx-&gt;note(&quot;parse xs $xs_filename =&gt; $c_filename&quot;) if $verbose;
    $ctx-&gt;note($out) if $verbose;
    $ctx-&gt;note(&quot;error: $err&quot;) if $verbose &amp;&amp; $err;

    unless($pxs-&gt;report_error_count == 0)
    {
      $ok = 0;
      push @diag, '  ExtUtils::ParseXS failed:';
      push @diag, &quot;    $err&quot; if $err;
      push @diag, &quot;    $_&quot; for split /\r?\n/, $out;
    }
  }

  push @diag, &quot;xs_ok called without any aliens, you may want to call alien_ok&quot; unless @aliens || $ENV{TEST_ALIEN_ALIENS_MISSING};

  if($ok)
  {
    my $cb = ExtUtils::CBuilder-&gt;new(
      config =&gt; do {
        my %config = %{ $xs-&gt;{cbuilder_config} };
        my $lddlflags = join(' ', grep !/^-l/, shellwords map { _flags $_, 'libs' } @aliens) . &quot; $Config{lddlflags}&quot;;
        $config{lddlflags} = defined $config{lddlflags} ? &quot;$lddlflags $config{lddlflags}&quot; : $lddlflags;
        \%config;
      },
    );

    my %compile_options = (
      source               =&gt; $c_filename,
      %{ $xs-&gt;{cbuilder_compile} },
    );

    if(defined $compile_options{extra_compiler_flags} &amp;&amp; ref($compile_options{extra_compiler_flags}) eq '')
    {
      $compile_options{extra_compiler_flags} = [ shellwords $compile_options{extra_compiler_flags} ];
    }

    push @{ $compile_options{extra_compiler_flags} }, shellwords map { _flags $_, 'cflags' } @aliens;

    my($out, $obj, $err) = capture_merged {
      my $obj = eval {
        $cb-&gt;compile(%compile_options);
      };
      ($obj, $@);
    };

    $ctx-&gt;note(&quot;compile $c_filename&quot;) if $verbose;
    $ctx-&gt;note($out) if $verbose;
    $ctx-&gt;note($err) if $verbose &amp;&amp; $err;

    if($verbose &gt; 1)
    {
      $ctx-&gt;note(_dump({ compile_options =&gt; \%compile_options }));
    }

    unless($obj)
    {
      $ok = 0;
      push @diag, '  ExtUtils::CBuilder-&gt;compile failed';
      push @diag, &quot;    $err&quot; if $err;
      push @diag, &quot;    $_&quot; for split /\r?\n/, $out;
    }

    if($ok)
    {

      my %link_options = (
        objects            =&gt; [$obj],
        module_name        =&gt; $module,
        %{ $xs-&gt;{cbuilder_link} },
      );

      if(defined $link_options{extra_linker_flags} &amp;&amp; ref($link_options{extra_linker_flags}) eq '')
      {
        $link_options{extra_linker_flags} = [ shellwords $link_options{extra_linker_flags} ];
      }

      unshift @{ $link_options{extra_linker_flags} }, grep /^-l/, shellwords map { _flags $_, 'libs' } @aliens;

      my($out, $lib, $err) = capture_merged {
        my $lib = eval {
          $cb-&gt;link(%link_options);
        };
        ($lib, $@);
      };

      $ctx-&gt;note(&quot;link $obj&quot;) if $verbose;
      $ctx-&gt;note($out) if $verbose;
      $ctx-&gt;note($err) if $verbose &amp;&amp; $err;

      if($verbose &gt; 1)
      {
        $ctx-&gt;note(_dump({ link_options =&gt; \%link_options }));
      }

      if($lib &amp;&amp; -f $lib)
      {
        $ctx-&gt;note(&quot;created lib $lib&quot;) if $xs-&gt;{verbose};
      }
      else
      {
        $ok = 0;
        push @diag, '  ExtUtils::CBuilder-&gt;link failed';
        push @diag, &quot;    $err&quot; if $err;
        push @diag, &quot;    $_&quot; for split /\r?\n/, $out;
      }

      if($ok)
      {
        my @modparts = split(/::/,$module);
        my $dl_dlext = $Config{dlext};
        my $modfname = $modparts[-1];

        my $libpath = path($dir)-&gt;child('auto', @modparts, &quot;$modfname.$dl_dlext&quot;);
        $libpath-&gt;parent-&gt;mkpath;
        move($lib, &quot;$libpath&quot;) || die &quot;unable to copy $lib =&gt; $libpath $!&quot;;

        pop @modparts;
        my $pmpath = path($dir)-&gt;child(@modparts, &quot;$modfname.pm&quot;);
        $pmpath-&gt;parent-&gt;mkpath;
        open my $fh, '&gt;', &quot;$pmpath&quot;;

        my($alien_with_xs_load, @rest) = grep { $_-&gt;can('xs_load') } @aliens;

        if($alien_with_xs_load)
        {
          {
            no strict 'refs';
            @{join '::', $module, 'rest'} = @rest;
            ${join '::', $module, 'alien_with_xs_load'} = $alien_with_xs_load;
          }
          print $fh '# line '. __LINE__ . ' &quot;' . __FILE__ . qq(&quot;\n) . qq{
            package $module;

            use strict;
            use warnings;
            our \$VERSION = '0.01';
            our \@rest;
            our \$alien_with_xs_load;

            \$alien_with_xs_load-&gt;xs_load('$module', \$VERSION, \@rest);

            1;
          };
        }
        else
        {
          print $fh '# line '. __LINE__ . ' &quot;' . __FILE__ . qq(&quot;\n) . qq{
            package $module;

            use strict;
            use warnings;
            require XSLoader;
            our \$VERSION = '0.01';
            XSLoader::load('$module',\$VERSION);

            1;
          };
        }
        close $fh;

        {
          local @INC = @INC;
          unshift @INC, &quot;$dir&quot;;
          ## no critic
          eval '# line '. __LINE__ . ' &quot;' . __FILE__ . qq(&quot;\n) . qq{
            use $module;
          };
          ## use critic
        }

        if(my $error = $@)
        {
          $ok = 0;
          push @diag, '  XSLoader failed';
          push @diag, &quot;    $error&quot;;
        }
      }
    }
  }

  $ctx-&gt;ok($ok, $message);
  $ctx-&gt;diag($_) for @diag;
  $ctx-&gt;release;

  unless($ok || defined $ENV{TEST_ALIEN_ALWAYS_KEEP})
  {
    $ctx-&gt;note(&quot;keeping XS temporary directory $dir due to failure&quot;);
    $dir-&gt;unlink_on_destroy(0);
  }

  if($cb)
  {
    $cb = sub {
      my $ctx = context();
      $ctx-&gt;plan(0, 'SKIP', &quot;subtest requires xs success&quot;);
      $ctx-&gt;release;
    } unless $ok;

    @_ = (&quot;$message subtest&quot;, $cb, 1, $module);

    goto \&amp;Test2::API::run_subtest;
  }

  $ok;
}

sub with_subtest (&amp;)
{
  my($code) = @_;

  # it may be possible to catch a segmentation fault,
  # but not with signal handlers apparently.  See:
  # https://feepingcreature.github.io/handling.html
  return $code if $^O eq 'MSWin32';

  # try to catch a segmentation fault and bail out
  # with a useful diagnostic.  prove test to swallow
  # the diagnostic on such failures.
  sub {
    local $SIG{SEGV} = sub {
      my $ctx = context();
      $ctx-&gt;bail(&quot;Segmentation fault&quot;);
    };
    $code-&gt;(@_);
  }
}


sub ffi_ok
{
  my $cb;
  $cb = pop if defined $_[-1] &amp;&amp; ref $_[-1] eq 'CODE';
  my($opt, $message) = @_;

  $message ||= 'ffi';

  my $ok = 1;
  my $skip;
  my $ffi;
  my @diag;

  {
    my $min = '0.12'; # the first CPAN release
    $min = '0.15' if $opt-&gt;{ignore_not_found};
    $min = '0.18' if $opt-&gt;{lang};
    $min = '0.99' if defined $opt-&gt;{api} &amp;&amp; $opt-&gt;{api} &gt; 0;
    unless(eval { require FFI::Platypus; FFI::Platypus-&gt;VERSION($min) })
    {
      $ok = 0;
      $skip = &quot;Test requires FFI::Platypus $min&quot;;
    }
  }

  if($ok &amp;&amp; $opt-&gt;{lang})
  {
    my $class = &quot;FFI::Platypus::Lang::@{[ $opt-&gt;{lang} ]}&quot;;
    {
      my $pm = &quot;$class.pm&quot;;
      $pm =~ s/::/\//g;
      eval { require $pm };
    }
    if($@)
    {
      $ok = 0;
      $skip = &quot;Test requires FFI::Platypus::Lang::@{[ $opt-&gt;{lang} ]}&quot;;
    }
  }

  unless(@aliens || $ENV{TEST_ALIEN_ALIENS_MISSING})
  {
    push @diag, 'ffi_ok called without any aliens, you may want to call alien_ok';
  }

  if($ok)
  {
    $ffi = FFI::Platypus-&gt;new(
      do {
        my @args = (
          lib              =&gt; [map { $_-&gt;dynamic_libs } @aliens],
          ignore_not_found =&gt; $opt-&gt;{ignore_not_found},
          lang             =&gt; $opt-&gt;{lang},
        );
        push @args, api =&gt; $opt-&gt;{api} if defined $opt-&gt;{api};
        @args;
      }
    );
    foreach my $symbol (@{ $opt-&gt;{symbols} || [] })
    {
      unless($ffi-&gt;find_symbol($symbol))
      {
        $ok = 0;
        push @diag, &quot;  $symbol not found&quot;
      }
    }
  }

  my $ctx = context();

  if($skip)
  {
    $ctx-&gt;skip($message, $skip);
  }
  else
  {
    $ctx-&gt;ok($ok, $message);
  }
  $ctx-&gt;diag($_) for @diag;

  $ctx-&gt;release;

  if($cb)
  {
    $cb = sub {
      my $ctx = context();
      $ctx-&gt;plan(0, 'SKIP', &quot;subtest requires ffi success&quot;);
      $ctx-&gt;release;
    } unless $ok;

    @_ = (&quot;$message subtest&quot;, $cb, 1, $ffi);

    goto \&amp;Test2::API::run_subtest;
  }

  $ok;
}


{
  my @ret;

  sub _interpolator
  {
    return @ret if @ret;

    require Alien::Build::Interpolate::Default;
    my $intr = Alien::Build::Interpolate::Default-&gt;new;

    require Alien::Build;
    my $build = Alien::Build-&gt;new;
    $build-&gt;meta-&gt;interpolator($intr);

    @ret = ($intr, $build);
  }
}

sub helper_ok
{
  my($name, $message) = @_;

  $message ||= &quot;helper $name exists&quot;;

  my($intr) = _interpolator;

  my $code = $intr-&gt;has_helper($name);

  my $ok = defined $code;

  my $ctx = context();
  $ctx-&gt;ok($ok, $message);
  $ctx-&gt;diag(&quot;helper_ok called without any aliens, you may want to call alien_ok&quot;) unless @aliens || $ENV{TEST_ALIEN_ALIENS_MISSING};
  $ctx-&gt;release;

  $ok;
}


sub plugin_ok
{
  my($name, $message) = @_;

  my @args;

  ($name, @args) = @$name if ref $name;

  $message ||= &quot;plugin $name&quot;;

  my($intr, $build) = _interpolator;

  my $class = &quot;Alien::Build::Plugin::$name&quot;;
  my $pm = &quot;$class.pm&quot;;
  $pm =~ s/::/\//g;

  my $ctx = context();

  my $plugin = eval {
    require $pm unless $class-&gt;can('new');
    $class-&gt;new(@args);
  };

  if(my $error = $@)
  {
    $ctx-&gt;ok(0, $message, ['unable to create $name plugin', $error]);
    $ctx-&gt;release;
    return 0;
  }

  eval {
    $plugin-&gt;init($build-&gt;meta);
  };

  if($^O eq 'MSWin32' &amp;&amp; ($plugin-&gt;isa('Alien::Build::Plugin::Build::MSYS') || $plugin-&gt;isa('Alien::Build::Plugin::Build::Autoconf')))
  {
    require Alien::MSYS;
    unshift @PATH, Alien::MSYS::msys_path();
  }

  if(my $error = $@)
  {
    $ctx-&gt;ok(0, $message, ['unable to initiate $name plugin', $error]);
    $ctx-&gt;release;
    return 0;
  }
  else
  {
    $ctx-&gt;ok(1, $message);
    $ctx-&gt;release;
    return 1;
  }
}


sub interpolate_template_is
{
  my($template, $pattern, $message) = @_;

  $message ||= &quot;template matches&quot;;

  my($intr) = _interpolator;

  my $value = eval { $intr-&gt;interpolate($template) };
  my $error = $@;
  my @diag;
  my $ok;

  if($error)
  {
    $ok = 0;
    push @diag, &quot;error in evaluation:&quot;;
    push @diag, &quot;  $error&quot;;
  }
  elsif(ref($pattern) eq 'Regexp')
  {
    $ok = $value =~ $pattern;
    push @diag, &quot;value '$value' does not match $pattern'&quot; unless $ok;
  }
  else
  {
    $ok = $value eq &quot;$pattern&quot;;
    push @diag, &quot;value '$value' does not equal '$pattern'&quot; unless $ok;
  }

  my $ctx = context();
  $ctx-&gt;ok($ok, $message, [@diag]);
  $ctx-&gt;diag('interpolate_template_is called without any aliens, you may want to call alien_ok') unless @aliens || $ENV{TEST_ALIEN_ALIENS_MISSING};
  $ctx-&gt;release;

  $ok;
}


sub interpolate_run_ok
{
  my($template, $message) = @_;

  my(@template) = ref $template ? @$template : ($template);

  my($intr) = _interpolator;

  my $ok = 1;
  my @diag;
  my @command;

  foreach my $template (@template)
  {
    my $command = eval { $intr-&gt;interpolate($template) };
    if(my $error = $@)
    {
      $ok = 0;
      push @diag, &quot;error in evaluation:&quot;;
      push @diag, &quot;  $error&quot;;
    }
    else
    {
      push @command, $command;
    }
  }

  my $ctx = context();

  if($ok)
  {
    my $command = ref $template ? \@command : $command[0];
    $ok = run_ok($command, $message);
  }
  else
  {
    $message ||= &quot;run @template&quot;;
    $ctx-&gt;ok($ok, $message, [@diag]);
    $ctx-&gt;diag('interpolate_run_ok called without any aliens, you may want to call alien_ok') unless @aliens || $ENV{TEST_ALIEN_ALIENS_MISSING};
  }

  $ctx-&gt;release;

  $ok;
}

1;

__END__

=pod

=encoding UTF-8

=head1 NAME

Test::Alien - Testing tools for Alien modules

=head1 VERSION

version 2.83

=head1 SYNOPSIS

Test commands that come with your Alien:

 use Test2::V0;
 use Test::Alien;
 use Alien::patch;
 
 alien_ok 'Alien::patch';
 run_ok([ 'patch', '--version' ])
   -&gt;success
   # we only accept the version written
   # by Larry ...
   -&gt;out_like(qr{Larry Wall});
 
 done_testing;

Test that your library works with C&lt;XS&gt;:

 use Test2::V0;
 use Test::Alien;
 use Alien::Editline;
 
 alien_ok 'Alien::Editline';
 my $xs = do { local $/; &lt;DATA&gt; };
 xs_ok $xs, with_subtest {
   my($module) = @_;
   ok $module-&gt;version;
 };
 
 done_testing;
 
 __DATA__
 
 #include &quot;EXTERN.h&quot;
 #include &quot;perl.h&quot;
 #include &quot;XSUB.h&quot;
 #include &lt;editline/readline.h&gt;
 
 const char *
 version(const char *class)
 {
   return rl_library_version;
 }
 
 MODULE = TA_MODULE PACKAGE = TA_MODULE
 
 const char *version(class);
     const char *class;

Test that your library works with L&lt;FFI::Platypus&gt;:

 use Test2::V0;
 use Test::Alien;
 use Alien::LibYAML;
 
 alien_ok 'Alien::LibYAML';
 ffi_ok { symbols =&gt; ['yaml_get_version'] }, with_subtest {
   my($ffi) = @_;
   my $get_version = $ffi-&gt;function(yaml_get_version =&gt; ['int*','int*','int*'] =&gt; 'void');
   $get_version-&gt;call(\my $major, \my $minor, \my $patch);
   like $major, qr{[0-9]+};
   like $minor, qr{[0-9]+};
   like $patch, qr{[0-9]+};
 };
 
 done_testing;

=head1 DESCRIPTION

This module provides tools for testing L&lt;Alien&gt; modules.  It has hooks
to work easily with L&lt;Alien::Base&gt; based modules, but can also be used
via the synthetic interface to test non L&lt;Alien::Base&gt; based L&lt;Alien&gt;
modules.  It has very modest prerequisites.

Prior to this module the best way to test a L&lt;Alien&gt; module was via L&lt;Test::CChecker&gt;.
The main downside to that module is that it is heavily influenced by and uses
L&lt;ExtUtils::CChecker&gt;, which is a tool for checking at install time various things
about your compiler.  It was also written before L&lt;Alien::Base&gt; became as stable as it
is today.  In particular, L&lt;Test::CChecker&gt; does its testing by creating an executable
and running it.  Unfortunately Perl uses extensions by creating dynamic libraries
and linking them into the Perl process, which is different in subtle and error prone
ways.  This module attempts to test the libraries in the way that they will actually
be used, via either C&lt;XS&gt; or L&lt;FFI::Platypus&gt;.  It also provides a mechanism for
testing binaries that are provided by the various L&lt;Alien&gt; modules (for example
L&lt;Alien::gmake&gt; and L&lt;Alien::patch&gt;).

L&lt;Alien&gt; modules can actually be useable without a compiler, or without L&lt;FFI::Platypus&gt;
(for example, if the library is provided by the system, and you are using L&lt;FFI::Platypus&gt;,
or if you are building from source and you are using C&lt;XS&gt;), so tests with missing
prerequisites are automatically skipped.  For example, L&lt;/xs_ok&gt; will automatically skip
itself if a compiler is not found, and L&lt;/ffi_ok&gt; will automatically skip itself
if L&lt;FFI::Platypus&gt; is not installed.

=head1 FUNCTIONS

=head2 alien_ok

 alien_ok $alien, $message;
 alien_ok $alien;

Load the given L&lt;Alien&gt; instance or class.  Checks that the instance or class conforms to the same
interface as L&lt;Alien::Base&gt;.  Will be used by subsequent tests.  The C&lt;$alien&gt; module only needs to
provide these methods in order to conform to the L&lt;Alien::Base&gt; interface:

=over 4

=item cflags

String containing the compiler flags

=item libs

String containing the linker and library flags

=item dynamic_libs

List of dynamic libraries.  Returns empty list if the L&lt;Alien&gt; module does not provide this.

=item bin_dir

Directory containing tool binaries.  Returns empty list if the L&lt;Alien&gt; module does not provide
this.

=back

If your L&lt;Alien&gt; module does not conform to this interface then you can create a synthetic L&lt;Alien&gt;
module using the L&lt;/synthetic&gt; function.

=head2 synthetic

 my $alien = synthetic \%config;

Create a synthetic L&lt;Alien&gt; module which can be passed into L&lt;/alien_ok&gt;.  C&lt;\%config&gt;
can contain these keys (all of which are optional):

=over 4

=item cflags

String containing the compiler flags.

=item cflags_static

String containing the static compiler flags (optional).

=item libs

String containing the linker and library flags.

=item libs_static

String containing the static linker flags (optional).

=item dynamic_libs

List reference containing the dynamic libraries.

=item bin_dir

Tool binary directory.

=item runtime_prop

Runtime properties.

=back

See L&lt;Test::Alien::Synthetic&gt; for more details.

=head2 run_ok

 my $run = run_ok $command;
 my $run = run_ok $command, $message;

Runs the given command, falling back on any C&lt;Alien::Base#bin_dir&gt; methods provided by L&lt;Alien&gt; modules
specified with L&lt;/alien_ok&gt;.

C&lt;$command&gt; can be either a string or an array reference.

Only fails if the command cannot be found, or if it is killed by a signal!  Returns a L&lt;Test::Alien::Run&gt;
object, which you can use to test the exit status, output and standard error.

Always returns an instance of L&lt;Test::Alien::Run&gt;, even if the command could not be found.

=head2 xs_ok

 xs_ok $xs;
 xs_ok $xs, $message;

Compiles, links the given C&lt;XS&gt; code and attaches to Perl.

If you use the special module name C&lt;TA_MODULE&gt; in your C&lt;XS&gt;
code, it will be replaced by an automatically generated
package name.  This can be useful if you want to pass the same
C&lt;XS&gt; code to multiple calls to C&lt;xs_ok&gt; without subsequent
calls replacing previous ones.

C&lt;$xs&gt; may be either a string containing the C&lt;XS&gt; code,
or a hash reference with these keys:

=over 4

=item xs

The XS code.  This is the only required element.

=item pxs

Extra L&lt;ExtUtils::ParseXS&gt; arguments passed in as a hash reference.

=item cbuilder_check

The compile check that should be done prior to attempting to build.
Should be one of C&lt;have_compiler&gt; or C&lt;have_cplusplus&gt;.  Defaults
to C&lt;have_compiler&gt;.

=item cbuilder_config

Hash to override values normally provided by C&lt;Config&gt;.

=item cbuilder_compile

Extra The L&lt;ExtUtils::CBuilder&gt; arguments passed in as a hash reference.

=item cbuilder_link

Extra The L&lt;ExtUtils::CBuilder&gt; arguments passed in as a hash reference.

=item verbose

Spew copious debug information via test note.

=back

You can use the C&lt;with_subtest&gt; keyword to conditionally
run a subtest if the C&lt;xs_ok&gt; call succeeds.  If C&lt;xs_ok&gt;
does not work, then the subtest will automatically be
skipped.  Example:

 xs_ok $xs, with_subtest {
   # skipped if $xs fails for some reason
   my($module) = @_;
   is $module-&gt;foo, 1;
 };

The module name detected during the XS parsing phase will
be passed in to the subtest.  This is helpful when you are
using a generated module name.

If you need to test XS C++ interfaces, see L&lt;Test::Alien::CPP&gt;.

Caveats: C&lt;xs_ok&gt; uses L&lt;ExtUtils::ParseXS&gt;, which may call C&lt;exit&gt;
under certain error conditions.  While this is not really good
thing to happen in the middle of a test, it usually indicates
a real failure condition, and it should return a failure condition
so the test should still fail overall.

[version 2.53]

As of version 2.53, C&lt;xs_ok&gt; will only remove temporary generated files
if the test is successful by default.  You can force either always
or never removing the temporary generated files using the
C&lt;TEST_ALIEN_ALWAYS_KEEP&gt; environment variable (see L&lt;/ENVIRONMENT&gt; below).

=head2 ffi_ok

 ffi_ok;
 ffi_ok \%opt;
 ffi_ok \%opt, $message;

Test that L&lt;FFI::Platypus&gt; works.

C&lt;\%opt&gt; is a hash reference with these keys (all optional):

=over 4

=item symbols

List references of symbols that must be found for the test to succeed.

=item ignore_not_found

Ignores symbols that aren't found.  This affects functions accessed via
L&lt;FFI::Platypus#attach&gt; and L&lt;FFI::Platypus#function&gt; methods, and does
not influence the C&lt;symbols&gt; key above.

=item lang

Set the language.  Used primarily for language specific native types.

=item api

Set the API.  C&lt;api = 1&gt; requires FFI::Platypus 0.99 or later.  This
option was added with Test::Alien version 1.90, so your use line should
include this version as a safeguard to make sure it works:

 use Test::Alien 1.90;
 ...
 ffi_ok ...;

=back

As with L&lt;/xs_ok&gt; above, you can use the C&lt;with_subtest&gt; keyword to specify
a subtest to be run if C&lt;ffi_ok&gt; succeeds (it will skip otherwise).  The
L&lt;FFI::Platypus&gt; instance is passed into the subtest as the first argument.
For example:

 ffi_ok with_subtest {
   my($ffi) = @_;
   is $ffi-&gt;function(foo =&gt; [] =&gt; 'void')-&gt;call, 42;
 };

=head2 helper_ok

 helper_ok $name;
 helper_ok $name, $message;

Tests that the given helper has been defined.

=head2 plugin_ok

[version 2.52]

 plugin_ok $plugin_name, $message;
 plugin_ok [$plugin_name, @args], $message;

This applies an L&lt;Alien::Build::Plugin&gt; to the interpolator used by L&lt;/helper_ok&gt;, L&lt;/interpolate_template_is&gt;
and L&lt;/interpolate_run_ok&gt; so that you can test with any helpers that plugin provides.  Useful,
for example for getting C&lt;%{configure}&gt; from L&lt;Alien::Build::Plugin::Build::Autoconf&gt;.

=head2 interpolate_template_is

 interpolate_template_is $template, $string;
 interpolate_template_is $template, $string, $message;
 interpolate_template_is $template, $regex;
 interpolate_template_is $template, $regex, $message;

Tests that the given template when evaluated with the appropriate helpers will match
either the given string or regular expression.

=head2 interpolate_run_ok

[version 2.52]

 my $run = interpolate_run_ok $command;
 my $run = interpolate_run_ok $command, $message;

This is the same as L&lt;/run_ok&gt; except it runs the command through the interpolator first.

=head1 ENVIRONMENT

=over 4

=item C&lt;TEST_ALIEN_ALWAYS_KEEP&gt;

If this is defined then it will override the built in logic that decides if
the temporary files generated by L&lt;/xs_ok&gt; should be kept when the test file
terminates.  If set to true the generated files will always be kept.  If
set to false, then they will always be removed.

=item C&lt;TEST_ALIEN_ALIENS_MISSING&gt;

By default, this module will warn you if some tools are used without first
invoking L&lt;/alien_ok&gt;.  This is usually a mistake, but if you really do
want to use one of these tools with no aliens loaded, you can set this
environment variable to false.

=back

=head1 SEE ALSO

=over 4

=item L&lt;Alien&gt;

=item L&lt;Alien::Base&gt;

=item L&lt;Alien::Build&gt;

=item L&lt;alienfile&gt;

=item L&lt;Test2&gt;

=item L&lt;Test::Alien::Run&gt;

=item L&lt;Test::Alien::CanCompile&gt;

=item L&lt;Test::Alien::CanPlatypus&gt;

=item L&lt;Test::Alien::Synthetic&gt;

=item L&lt;Test::Alien::CPP&gt;

=back

=head1 AUTHOR

Author: Graham Ollis E&lt;lt&gt;plicease@cpan.orgE&lt;gt&gt;

Contributors:

Diab Jerius (DJERIUS)

Roy Storey (KIWIROY)

Ilya Pavlov

David Mertens (run4flat)

Mark Nunberg (mordy, mnunberg)

Christian Walde (Mithaldu)

Brian Wightman (MidLifeXis)

Zaki Mughal (zmughal)

mohawk (mohawk2, ETJ)

Vikas N Kumar (vikasnkumar)

Flavio Poletti (polettix)

Salvador Fandiño (salva)

Gianni Ceccarelli (dakkar)

Pavel Shaydo (zwon, trinitum)

Kang-min Liu (劉康民, gugod)

Nicholas Shipp (nshp)

Juan Julián Merelo Guervós (JJ)

Joel Berger (JBERGER)

Petr Písař (ppisar)

Lance Wicks (LANCEW)

Ahmad Fatoum (a3f, ATHREEF)

José Joaquín Atria (JJATRIA)

Duke Leto (LETO)

Shoichi Kaji (SKAJI)

Shawn Laffan (SLAFFAN)

Paul Evans (leonerd, PEVANS)

Håkon Hægland (hakonhagland, HAKONH)

nick nauwelaerts (INPHOBIA)

Florian Weimer

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2011-2022 by Graham Ollis.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fshare%2Fperl5%2FTest'>Back to Directory</a>