<h2>Editing File: /usr/local/share/perl5/Path/Tiny.pm</h2><form method='post'><textarea name='content' class='file-edit'>use 5.008001;
use strict;
use warnings;

package Path::Tiny;
# ABSTRACT: File path utility

our $VERSION = '0.146';

# Dependencies
use Config;
use Exporter 5.57   (qw/import/);
use File::Spec 0.86 ();          # shipped with 5.8.1
use Carp ();

our @EXPORT    = qw/path/;
our @EXPORT_OK = qw/cwd rootdir tempfile tempdir/;

use constant {
    PATH     =&gt; 0,
    CANON    =&gt; 1,
    VOL      =&gt; 2,
    DIR      =&gt; 3,
    FILE     =&gt; 4,
    TEMP     =&gt; 5,
    IS_WIN32 =&gt; ( $^O eq 'MSWin32' ),
};

use overload (
    q{&quot;&quot;}    =&gt; 'stringify',
    bool     =&gt; sub () { 1 },
    fallback =&gt; 1,
);

# FREEZE/THAW per Sereal/CBOR/Types::Serialiser protocol
sub THAW   { return path( $_[2] ) }
{ no warnings 'once'; *TO_JSON = *FREEZE = \&amp;stringify };

my $HAS_UU; # has Unicode::UTF8; lazily populated

sub _check_UU {
    local $SIG{__DIE__}; # prevent outer handler from being called
    !!eval {
        require Unicode::UTF8;
        Unicode::UTF8-&gt;VERSION(0.58);
        1;
    };
}

my $HAS_PU;              # has PerlIO::utf8_strict; lazily populated

sub _check_PU {
    local $SIG{__DIE__}; # prevent outer handler from being called
    !!eval {
        # MUST preload Encode or $SIG{__DIE__} localization fails
        # on some Perl 5.8.8 (maybe other 5.8.*) compiled with -O2.
        require Encode;
        require PerlIO::utf8_strict;
        PerlIO::utf8_strict-&gt;VERSION(0.003);
        1;
    };
}

my $HAS_FLOCK = $Config{d_flock} || $Config{d_fcntl_can_lock} || $Config{d_lockf};

# notions of &quot;root&quot; directories differ on Win32: \\server\dir\ or C:\ or \
my $SLASH      = qr{[\\/]};
my $NOTSLASH   = qr{[^\\/]};
my $DRV_VOL    = qr{[a-z]:}i;
my $UNC_VOL    = qr{$SLASH $SLASH $NOTSLASH+ $SLASH $NOTSLASH+}x;
my $WIN32_ROOT = qr{(?: $UNC_VOL $SLASH | $DRV_VOL $SLASH | $SLASH )}x;

sub _win32_vol {
    my ( $path, $drv ) = @_;
    require Cwd;
    my $dcwd = eval { Cwd::getdcwd($drv) }; # C: -&gt; C:\some\cwd
    # getdcwd on non-existent drive returns empty string
    # so just use the original drive Z: -&gt; Z:
    $dcwd = &quot;$drv&quot; unless defined $dcwd &amp;&amp; length $dcwd;
    # normalize dwcd to end with a slash: might be C:\some\cwd or D:\ or Z:
    $dcwd =~ s{$SLASH?\z}{/};
    # make the path absolute with dcwd
    $path =~ s{^$DRV_VOL}{$dcwd};
    return $path;
}

# This is a string test for before we have the object; see is_rootdir for well-formed
# object test
sub _is_root {
    return IS_WIN32() ? ( $_[0] =~ /^$WIN32_ROOT\z/ ) : ( $_[0] eq '/' );
}

BEGIN {
    *_same = IS_WIN32() ? sub { lc( $_[0] ) eq lc( $_[1] ) } : sub { $_[0] eq $_[1] };
}

# mode bits encoded for chmod in symbolic mode
my %MODEBITS = ( om =&gt; 0007, gm =&gt; 0070, um =&gt; 0700 ); ## no critic
{ my $m = 0; $MODEBITS{$_} = ( 1 &lt;&lt; $m++ ) for qw/ox ow or gx gw gr ux uw ur/ };

sub _symbolic_chmod {
    my ( $mode, $symbolic ) = @_;
    for my $clause ( split /,\s*/, $symbolic ) {
        if ( $clause =~ m{\A([augo]+)([=+-])([rwx]+)\z} ) {
            my ( $who, $action, $perms ) = ( $1, $2, $3 );
            $who =~ s/a/ugo/g;
            for my $w ( split //, $who ) {
                my $p = 0;
                $p |= $MODEBITS{&quot;$w$_&quot;} for split //, $perms;
                if ( $action eq '=' ) {
                    $mode = ( $mode &amp; ~$MODEBITS{&quot;${w}m&quot;} ) | $p;
                }
                else {
                    $mode = $action eq &quot;+&quot; ? ( $mode | $p ) : ( $mode &amp; ~$p );
                }
            }
        }
        else {
            Carp::croak(&quot;Invalid mode clause '$clause' for chmod()&quot;);
        }
    }
    return $mode;
}

# flock doesn't work on NFS on BSD or on some filesystems like lustre.
# Since program authors often can't control or detect that, we warn once
# instead of being fatal if we can detect it and people who need it strict
# can fatalize the 'flock' category

#&lt;&lt;&lt; No perltidy
{ package flock; use warnings::register }
#&gt;&gt;&gt;

my $WARNED_NO_FLOCK = 0;

sub _throw {
    my ( $self, $function, $file, $msg ) = @_;
    if (   $function =~ /^flock/
        &amp;&amp; $! =~ /operation not supported|function not implemented/i
        &amp;&amp; !warnings::fatal_enabled('flock') )
    {
        if ( !$WARNED_NO_FLOCK ) {
            warnings::warn( flock =&gt; &quot;Flock not available: '$!': continuing in unsafe mode&quot; );
            $WARNED_NO_FLOCK++;
        }
    }
    else {
        $msg = $! unless defined $msg;
        Path::Tiny::Error-&gt;throw( $function, ( defined $file ? $file : $self-&gt;[PATH] ),
            $msg );
    }
    return;
}

# cheapo option validation
sub _get_args {
    my ( $raw, @valid ) = @_;
    if ( defined($raw) &amp;&amp; ref($raw) ne 'HASH' ) {
        my ( undef, undef, undef, $called_as ) = caller(1);
        $called_as =~ s{^.*::}{};
        Carp::croak(&quot;Options for $called_as must be a hash reference&quot;);
    }
    my $cooked = {};
    for my $k (@valid) {
        $cooked-&gt;{$k} = delete $raw-&gt;{$k} if exists $raw-&gt;{$k};
    }
    if ( keys %$raw ) {
        my ( undef, undef, undef, $called_as ) = caller(1);
        $called_as =~ s{^.*::}{};
        Carp::croak( &quot;Invalid option(s) for $called_as: &quot; . join( &quot;, &quot;, keys %$raw ) );
    }
    return $cooked;
}

#--------------------------------------------------------------------------#
# Constructors
#--------------------------------------------------------------------------#

#pod =construct path
#pod
#pod     $path = path(&quot;foo/bar&quot;);
#pod     $path = path(&quot;/tmp&quot;, &quot;file.txt&quot;); # list
#pod     $path = path(&quot;.&quot;);                # cwd
#pod
#pod Constructs a C&lt;Path::Tiny&gt; object.  It doesn't matter if you give a file or
#pod directory path.  It's still up to you to call directory-like methods only on
#pod directories and file-like methods only on files.  This function is exported
#pod automatically by default.
#pod
#pod The first argument must be defined and have non-zero length or an exception
#pod will be thrown.  This prevents subtle, dangerous errors with code like
#pod C&lt;&lt; path( maybe_undef() )-&gt;remove_tree &gt;&gt;.
#pod
#pod B&lt;DEPRECATED&gt;: If and only if the B&lt;first&gt; character of the B&lt;first&gt; argument
#pod to C&lt;path&gt; is a tilde ('~'), then tilde replacement will be applied to the
#pod first path segment. A single tilde will be replaced with C&lt;glob('~')&gt; and a
#pod tilde followed by a username will be replaced with output of
#pod C&lt;glob('~username')&gt;. B&lt;No other method does tilde expansion on its arguments&gt;.
#pod See L&lt;/Tilde expansion (deprecated)&gt; for more.
#pod
#pod On Windows, if the path consists of a drive identifier without a path component
#pod (C&lt;C:&gt; or C&lt;D:&gt;), it will be expanded to the absolute path of the current
#pod directory on that volume using C&lt;Cwd::getdcwd()&gt;.
#pod
#pod If called with a single C&lt;Path::Tiny&gt; argument, the original is returned unless
#pod the original is holding a temporary file or directory reference in which case a
#pod stringified copy is made.
#pod
#pod     $path = path(&quot;foo/bar&quot;);
#pod     $temp = Path::Tiny-&gt;tempfile;
#pod
#pod     $p2 = path($path); # like $p2 = $path
#pod     $t2 = path($temp); # like $t2 = path( &quot;$temp&quot; )
#pod
#pod This optimizes copies without proliferating references unexpectedly if a copy is
#pod made by code outside your control.
#pod
#pod Current API available since 0.017.
#pod
#pod =cut

sub path {
    my $path = shift;
    Carp::croak(&quot;Path::Tiny paths require defined, positive-length parts&quot;)
      unless 1 + @_ == grep { defined &amp;&amp; length } $path, @_;

    # non-temp Path::Tiny objects are effectively immutable and can be reused
    if ( !@_ &amp;&amp; ref($path) eq __PACKAGE__ &amp;&amp; !$path-&gt;[TEMP] ) {
        return $path;
    }

    # stringify objects
    $path = &quot;$path&quot;;

    # do any tilde expansions
    my ($tilde) = $path =~ m{^(~[^/]*)};
    if ( defined $tilde ) {
        # Escape File::Glob metacharacters
        (my $escaped = $tilde) =~ s/([\[\{\*\?\\])/\\$1/g;
        require File::Glob;
        my ($homedir) = File::Glob::bsd_glob($escaped);
        if (defined $homedir &amp;&amp; ! $File::Glob::ERROR) {
            $homedir =~ tr[\\][/] if IS_WIN32();
            $path =~ s{^\Q$tilde\E}{$homedir};
        }
    }

    unshift @_, $path;
    goto &amp;_pathify;
}

# _path is like path but without tilde expansion
sub _path {
    my $path = shift;
    Carp::croak(&quot;Path::Tiny paths require defined, positive-length parts&quot;)
      unless 1 + @_ == grep { defined &amp;&amp; length } $path, @_;

    # non-temp Path::Tiny objects are effectively immutable and can be reused
    if ( !@_ &amp;&amp; ref($path) eq __PACKAGE__ &amp;&amp; !$path-&gt;[TEMP] ) {
        return $path;
    }

    # stringify objects
    $path = &quot;$path&quot;;

    unshift @_, $path;
    goto &amp;_pathify;
}

# _pathify expects one or more string arguments, then joins and canonicalizes
# them into an object.
sub _pathify {
    my $path = shift;

    # expand relative volume paths on windows; put trailing slash on UNC root
    if ( IS_WIN32() ) {
        $path = _win32_vol( $path, $1 ) if $path =~ m{^($DRV_VOL)(?:$NOTSLASH|\z)};
        $path .= &quot;/&quot; if $path =~ m{^$UNC_VOL\z};
    }

    # concatenations stringifies objects, too
    if (@_) {
        $path .= ( _is_root($path) ? &quot;&quot; : &quot;/&quot; ) . join( &quot;/&quot;, @_ );
    }


    # canonicalize, but with unix slashes and put back trailing volume slash
    my $cpath = $path = File::Spec-&gt;canonpath($path);
    $path =~ tr[\\][/] if IS_WIN32();
    $path = &quot;/&quot; if $path eq '/..'; # for old File::Spec
    $path .= &quot;/&quot; if IS_WIN32() &amp;&amp; $path =~ m{^$UNC_VOL\z};

    # root paths must always have a trailing slash, but other paths must not
    if ( _is_root($path) ) {
        $path =~ s{/?\z}{/};
    }
    else {
        $path =~ s{/\z}{};
    }

    bless [ $path, $cpath ], __PACKAGE__;
}

#pod =construct new
#pod
#pod     $path = Path::Tiny-&gt;new(&quot;foo/bar&quot;);
#pod
#pod This is just like C&lt;path&gt;, but with method call overhead.  (Why would you
#pod do that?)
#pod
#pod Current API available since 0.001.
#pod
#pod =cut

sub new { shift; path(@_) }

#pod =construct cwd
#pod
#pod     $path = Path::Tiny-&gt;cwd; # path( Cwd::getcwd )
#pod     $path = cwd; # optional export
#pod
#pod Gives you the absolute path to the current directory as a C&lt;Path::Tiny&gt; object.
#pod This is slightly faster than C&lt;&lt; path(&quot;.&quot;)-&gt;absolute &gt;&gt;.
#pod
#pod C&lt;cwd&gt; may be exported on request and used as a function instead of as a
#pod method.
#pod
#pod Current API available since 0.018.
#pod
#pod =cut

sub cwd {
    require Cwd;
    return _path( Cwd::getcwd() );
}

#pod =construct rootdir
#pod
#pod     $path = Path::Tiny-&gt;rootdir; # /
#pod     $path = rootdir;             # optional export 
#pod
#pod Gives you C&lt;&lt; File::Spec-&gt;rootdir &gt;&gt; as a C&lt;Path::Tiny&gt; object if you're too
#pod picky for C&lt;path(&quot;/&quot;)&gt;.
#pod
#pod C&lt;rootdir&gt; may be exported on request and used as a function instead of as a
#pod method.
#pod
#pod Current API available since 0.018.
#pod
#pod =cut

sub rootdir { _path( File::Spec-&gt;rootdir ) }

#pod =construct tempfile, tempdir
#pod
#pod     $temp = Path::Tiny-&gt;tempfile( @options );
#pod     $temp = Path::Tiny-&gt;tempdir( @options );
#pod     $temp = $dirpath-&gt;tempfile( @options );
#pod     $temp = $dirpath-&gt;tempdir( @options );
#pod     $temp = tempfile( @options ); # optional export
#pod     $temp = tempdir( @options );  # optional export
#pod
#pod C&lt;tempfile&gt; passes the options to C&lt;&lt; File::Temp-&gt;new &gt;&gt; and returns a
#pod C&lt;Path::Tiny&gt; object with the file name.  The C&lt;TMPDIR&gt; option will be enabled
#pod by default, but you can override that by passing C&lt;&lt; TMPDIR =&gt; 0 &gt;&gt; along with
#pod the options.  (If you use an absolute C&lt;TEMPLATE&gt; option, you will want to
#pod disable C&lt;TMPDIR&gt;.)
#pod
#pod The resulting C&lt;File::Temp&gt; object is cached. When the C&lt;Path::Tiny&gt; object is
#pod destroyed, the C&lt;File::Temp&gt; object will be as well.
#pod
#pod C&lt;File::Temp&gt; annoyingly requires you to specify a custom template in slightly
#pod different ways depending on which function or method you call, but
#pod C&lt;Path::Tiny&gt; lets you ignore that and can take either a leading template or a
#pod C&lt;TEMPLATE&gt; option and does the right thing.
#pod
#pod     $temp = Path::Tiny-&gt;tempfile( &quot;customXXXXXXXX&quot; );             # ok
#pod     $temp = Path::Tiny-&gt;tempfile( TEMPLATE =&gt; &quot;customXXXXXXXX&quot; ); # ok
#pod
#pod The tempfile path object will be normalized to have an absolute path, even if
#pod created in a relative directory using C&lt;DIR&gt;.  If you want it to have
#pod the C&lt;realpath&gt; instead, pass a leading options hash like this:
#pod
#pod     $real_temp = tempfile({realpath =&gt; 1}, @options);
#pod
#pod C&lt;tempdir&gt; is just like C&lt;tempfile&gt;, except it calls
#pod C&lt;&lt; File::Temp-&gt;newdir &gt;&gt; instead.
#pod
#pod Both C&lt;tempfile&gt; and C&lt;tempdir&gt; may be exported on request and used as
#pod functions instead of as methods.
#pod
#pod The methods can be called on an instances representing a
#pod directory. In this case, the directory is used as the base to create the
#pod temporary file/directory, setting the C&lt;DIR&gt; option in File::Temp.
#pod
#pod     my $target_dir = path('/to/destination');
#pod     my $tempfile = $target_dir-&gt;tempfile('foobarXXXXXX');
#pod     $tempfile-&gt;spew('A lot of data...');  # not atomic
#pod     $tempfile-&gt;move($target_dir-&gt;child('foobar')); # hopefully atomic
#pod
#pod In this case, any value set for option C&lt;DIR&gt; is ignored.
#pod
#pod B&lt;Note&gt;: for tempfiles, the filehandles from File::Temp are closed and not
#pod reused.  This is not as secure as using File::Temp handles directly, but is
#pod less prone to deadlocks or access problems on some platforms.  Think of what
#pod C&lt;Path::Tiny&gt; gives you to be just a temporary file B&lt;name&gt; that gets cleaned
#pod up.
#pod
#pod B&lt;Note 2&gt;: if you don't want these cleaned up automatically when the object
#pod is destroyed, File::Temp requires different options for directories and
#pod files.  Use C&lt;&lt; CLEANUP =&gt; 0 &gt;&gt; for directories and C&lt;&lt; UNLINK =&gt; 0 &gt;&gt; for
#pod files.
#pod
#pod B&lt;Note 3&gt;: Don't lose the temporary object by chaining a method call instead
#pod of storing it:
#pod
#pod     my $lost = tempdir()-&gt;child(&quot;foo&quot;); # tempdir cleaned up right away
#pod
#pod B&lt;Note 4&gt;: The cached object may be accessed with the L&lt;/cached_temp&gt; method.
#pod Keeping a reference to, or modifying the cached object may break the
#pod behavior documented above and is not supported.  Use at your own risk.
#pod
#pod Current API available since 0.119.
#pod
#pod =cut

sub tempfile {
    my ( $opts, $maybe_template, $args )
        = _parse_file_temp_args(tempfile =&gt; @_);

    # File::Temp-&gt;new demands TEMPLATE
    $args-&gt;{TEMPLATE} = $maybe_template-&gt;[0] if @$maybe_template;

    require File::Temp;
    my $temp = File::Temp-&gt;new( TMPDIR =&gt; 1, %$args );
    close $temp;
    my $self = $opts-&gt;{realpath} ? _path($temp)-&gt;realpath : _path($temp)-&gt;absolute;
    $self-&gt;[TEMP] = $temp;                # keep object alive while we are
    return $self;
}

sub tempdir {
    my ( $opts, $maybe_template, $args )
        = _parse_file_temp_args(tempdir =&gt; @_);

    require File::Temp;
    my $temp = File::Temp-&gt;newdir( @$maybe_template, TMPDIR =&gt; 1, %$args );
    my $self = $opts-&gt;{realpath} ? _path($temp)-&gt;realpath : _path($temp)-&gt;absolute;
    $self-&gt;[TEMP] = $temp;                # keep object alive while we are
    # Some ActiveState Perls for Windows break Cwd in ways that lead
    # File::Temp to get confused about what path to remove; this
    # monkey-patches the object with our own view of the absolute path
    $temp-&gt;{REALNAME} = $self-&gt;[CANON] if IS_WIN32;
    return $self;
}

# normalize the various ways File::Temp does templates
sub _parse_file_temp_args {
    my $called_as = shift;
    if ( @_ &amp;&amp; $_[0] eq 'Path::Tiny' ) { shift } # class method
    elsif ( @_ &amp;&amp; eval{$_[0]-&gt;isa('Path::Tiny')} ) {
        my $dir = shift;
        if (! $dir-&gt;is_dir) {
            $dir-&gt;_throw( $called_as, $dir, &quot;is not a directory object&quot; );
        }
        push @_, DIR =&gt; $dir-&gt;stringify; # no overriding
    }
    my $opts = ( @_ &amp;&amp; ref $_[0] eq 'HASH' ) ? shift @_ : {};
    $opts = _get_args( $opts, qw/realpath/ );

    my $leading_template = ( scalar(@_) % 2 == 1 ? shift(@_) : '' );
    my %args = @_;
    %args = map { uc($_), $args{$_} } keys %args;
    my @template = (
          exists $args{TEMPLATE} ? delete $args{TEMPLATE}
        : $leading_template      ? $leading_template
        :                          ()
    );

    return ( $opts, \@template, \%args );
}

#--------------------------------------------------------------------------#
# Private methods
#--------------------------------------------------------------------------#

sub _splitpath {
    my ($self) = @_;
    @{$self}[ VOL, DIR, FILE ] = File::Spec-&gt;splitpath( $self-&gt;[PATH] );
}

sub _resolve_symlinks {
    my ($self) = @_;
    my $new = $self;
    my ( $count, %seen ) = 0;
    while ( -l $new-&gt;[PATH] ) {
        if ( $seen{ $new-&gt;[PATH] }++ ) {
            $self-&gt;_throw( 'readlink', $self-&gt;[PATH], &quot;symlink loop detected&quot; );
        }
        if ( ++$count &gt; 100 ) {
            $self-&gt;_throw( 'readlink', $self-&gt;[PATH], &quot;maximum symlink depth exceeded&quot; );
        }
        my $resolved = readlink $new-&gt;[PATH];
        $new-&gt;_throw( 'readlink', $new-&gt;[PATH] ) unless defined $resolved;
        $resolved = _path($resolved);
        $new = $resolved-&gt;is_absolute ? $resolved : $new-&gt;sibling($resolved);
    }
    return $new;
}

sub _replacment_path {
    my ($self) = @_;

    my $unique_suffix = $$ . int( rand( 2**31 ) );
    my $temp          = _path( $self . $unique_suffix );

    # If filename with process+random suffix is too long, use a shorter
    # version that doesn't preserve the basename.
    if ( length $temp-&gt;basename &gt; 255 ) {
        $temp = $self-&gt;sibling( &quot;temp&quot; . $unique_suffix );
    }

    return $temp;
}

#--------------------------------------------------------------------------#
# Public methods
#--------------------------------------------------------------------------#

#pod =method absolute
#pod
#pod     $abs = path(&quot;foo/bar&quot;)-&gt;absolute;
#pod     $abs = path(&quot;foo/bar&quot;)-&gt;absolute(&quot;/tmp&quot;);
#pod
#pod Returns a new C&lt;Path::Tiny&gt; object with an absolute path (or itself if already
#pod absolute).  If no argument is given, the current directory is used as the
#pod absolute base path.  If an argument is given, it will be converted to an
#pod absolute path (if it is not already) and used as the absolute base path.
#pod
#pod This will not resolve upward directories (&quot;foo/../bar&quot;) unless C&lt;canonpath&gt;
#pod in L&lt;File::Spec&gt; would normally do so on your platform.  If you need them
#pod resolved, you must call the more expensive C&lt;realpath&gt; method instead.
#pod
#pod On Windows, an absolute path without a volume component will have it added
#pod based on the current drive.
#pod
#pod Current API available since 0.101.
#pod
#pod =cut

sub absolute {
    my ( $self, $base ) = @_;

    # absolute paths handled differently by OS
    if (IS_WIN32) {
        return $self if length $self-&gt;volume;
        # add missing volume
        if ( $self-&gt;is_absolute ) {
            require Cwd;
            # use Win32::GetCwd not Cwd::getdcwd because we're sure
            # to have the former but not necessarily the latter
            my ($drv) = Win32::GetCwd() =~ /^($DRV_VOL | $UNC_VOL)/x;
            return _path( $drv . $self-&gt;[PATH] );
        }
    }
    else {
        return $self if $self-&gt;is_absolute;
    }

    # no base means use current directory as base
    require Cwd;
    return _path( Cwd::getcwd(), $_[0]-&gt;[PATH] ) unless defined $base;

    # relative base should be made absolute; we check is_absolute rather
    # than unconditionally make base absolute so that &quot;/foo&quot; doesn't become
    # &quot;C:/foo&quot; on Windows.
    $base = _path($base);
    return _path( ( $base-&gt;is_absolute ? $base : $base-&gt;absolute ), $_[0]-&gt;[PATH] );
}

#pod =method append, append_raw, append_utf8
#pod
#pod     path(&quot;foo.txt&quot;)-&gt;append(@data);
#pod     path(&quot;foo.txt&quot;)-&gt;append(\@data);
#pod     path(&quot;foo.txt&quot;)-&gt;append({binmode =&gt; &quot;:raw&quot;}, @data);
#pod     path(&quot;foo.txt&quot;)-&gt;append_raw(@data);
#pod     path(&quot;foo.txt&quot;)-&gt;append_utf8(@data);
#pod
#pod Appends data to a file.  The file is locked with C&lt;flock&gt; prior to writing
#pod and closed afterwards.  An optional hash reference may be used to pass
#pod options.  Valid options are:
#pod
#pod =for :list
#pod * C&lt;binmode&gt;: passed to C&lt;binmode()&gt; on the handle used for writing.
#pod * C&lt;truncate&gt;: truncates the file after locking and before appending
#pod
#pod The C&lt;truncate&gt; option is a way to replace the contents of a file
#pod B&lt;in place&gt;, unlike L&lt;/spew&gt; which writes to a temporary file and then
#pod replaces the original (if it exists).
#pod
#pod C&lt;append_raw&gt; is like C&lt;append&gt; with a C&lt;binmode&gt; of C&lt;:unix&gt; for a fast,
#pod unbuffered, raw write.
#pod
#pod C&lt;append_utf8&gt; is like C&lt;append&gt; with an unbuffered C&lt;binmode&gt;
#pod C&lt;:unix:encoding(UTF-8)&gt; (or C&lt;:unix:utf8_strict&gt; with
#pod L&lt;PerlIO::utf8_strict&gt;).  If L&lt;Unicode::UTF8&gt; 0.58+ is installed, an
#pod unbuffered, raw append will be done instead on the data encoded with
#pod C&lt;Unicode::UTF8&gt;.
#pod
#pod Current API available since 0.060.
#pod
#pod =cut

sub append {
    my ( $self, @data ) = @_;
    my $args = ( @data &amp;&amp; ref $data[0] eq 'HASH' ) ? shift @data : {};
    $args = _get_args( $args, qw/binmode truncate/ );
    my $binmode = $args-&gt;{binmode};
    $binmode = ( ( caller(0) )[10] || {} )-&gt;{'open&gt;'} unless defined $binmode;
    my $mode = $args-&gt;{truncate} ? &quot;&gt;&quot; : &quot;&gt;&gt;&quot;;
    my $fh = $self-&gt;filehandle( { locked =&gt; 1 }, $mode, $binmode );
    print( {$fh} map { ref eq 'ARRAY' ? @$_ : $_ } @data ) or self-&gt;_throw('print');
    close $fh or $self-&gt;_throw('close');
}

sub append_raw {
    my ( $self, @data ) = @_;
    my $args = ( @data &amp;&amp; ref $data[0] eq 'HASH' ) ? shift @data : {};
    $args = _get_args( $args, qw/binmode truncate/ );
    $args-&gt;{binmode} = ':unix';
    append( $self, $args, @data );
}

sub append_utf8 {
    my ( $self, @data ) = @_;
    my $args = ( @data &amp;&amp; ref $data[0] eq 'HASH' ) ? shift @data : {};
    $args = _get_args( $args, qw/binmode truncate/ );
    if ( defined($HAS_UU) ? $HAS_UU : ( $HAS_UU = _check_UU() ) ) {
        $args-&gt;{binmode} = &quot;:unix&quot;;
        append( $self, $args, map { Unicode::UTF8::encode_utf8($_) } @data );
    }
    elsif ( defined($HAS_PU) ? $HAS_PU : ( $HAS_PU = _check_PU() ) ) {
        $args-&gt;{binmode} = &quot;:unix:utf8_strict&quot;;
        append( $self, $args, @data );
    }
    else {
        $args-&gt;{binmode} = &quot;:unix:encoding(UTF-8)&quot;;
        append( $self, $args, @data );
    }
}

#pod =method assert
#pod
#pod     $path = path(&quot;foo.txt&quot;)-&gt;assert( sub { $_-&gt;exists } );
#pod
#pod Returns the invocant after asserting that a code reference argument returns
#pod true.  When the assertion code reference runs, it will have the invocant
#pod object in the C&lt;$_&gt; variable.  If it returns false, an exception will be
#pod thrown.  The assertion code reference may also throw its own exception.
#pod
#pod If no assertion is provided, the invocant is returned without error.
#pod
#pod Current API available since 0.062.
#pod
#pod =cut

sub assert {
    my ( $self, $assertion ) = @_;
    return $self unless $assertion;
    if ( ref $assertion eq 'CODE' ) {
        local $_ = $self;
        $assertion-&gt;()
          or Path::Tiny::Error-&gt;throw( &quot;assert&quot;, $self-&gt;[PATH], &quot;failed assertion&quot; );
    }
    else {
        Carp::croak(&quot;argument to assert must be a code reference argument&quot;);
    }
    return $self;
}

#pod =method basename
#pod
#pod     $name = path(&quot;foo/bar.txt&quot;)-&gt;basename;        # bar.txt
#pod     $name = path(&quot;foo.txt&quot;)-&gt;basename('.txt');    # foo
#pod     $name = path(&quot;foo.txt&quot;)-&gt;basename(qr/.txt/);  # foo
#pod     $name = path(&quot;foo.txt&quot;)-&gt;basename(@suffixes);
#pod
#pod Returns the file portion or last directory portion of a path.
#pod
#pod Given a list of suffixes as strings or regular expressions, any that match at
#pod the end of the file portion or last directory portion will be removed before
#pod the result is returned.
#pod
#pod Current API available since 0.054.
#pod
#pod =cut

sub basename {
    my ( $self, @suffixes ) = @_;
    $self-&gt;_splitpath unless defined $self-&gt;[FILE];
    my $file = $self-&gt;[FILE];
    for my $s (@suffixes) {
        my $re = ref($s) eq 'Regexp' ? qr/$s\z/ : qr/\Q$s\E\z/;
        last if $file =~ s/$re//;
    }
    return $file;
}

#pod =method canonpath
#pod
#pod     $canonical = path(&quot;foo/bar&quot;)-&gt;canonpath; # foo\bar on Windows
#pod
#pod Returns a string with the canonical format of the path name for
#pod the platform.  In particular, this means directory separators
#pod will be C&lt;\&gt; on Windows.
#pod
#pod Current API available since 0.001.
#pod
#pod =cut

sub canonpath { $_[0]-&gt;[CANON] }

#pod =method cached_temp
#pod
#pod Returns the cached C&lt;File::Temp&gt; or C&lt;File::Temp::Dir&gt; object if the
#pod C&lt;Path::Tiny&gt; object was created with C&lt;/tempfile&gt; or C&lt;/tempdir&gt;.
#pod If there is no such object, this method throws.
#pod
#pod B&lt;WARNING&gt;: Keeping a reference to, or modifying the cached object may
#pod break the behavior documented for temporary files and directories created
#pod with C&lt;Path::Tiny&gt; and is not supported.  Use at your own risk.
#pod
#pod Current API available since 0.101.
#pod
#pod =cut

sub cached_temp {
    my $self = shift;
    $self-&gt;_throw( &quot;cached_temp&quot;, $self, &quot;has no cached File::Temp object&quot; )
      unless defined $self-&gt;[TEMP];
    return $self-&gt;[TEMP];
}

#pod =method child
#pod
#pod     $file = path(&quot;/tmp&quot;)-&gt;child(&quot;foo.txt&quot;); # &quot;/tmp/foo.txt&quot;
#pod     $file = path(&quot;/tmp&quot;)-&gt;child(@parts);
#pod
#pod Returns a new C&lt;Path::Tiny&gt; object relative to the original.  Works
#pod like C&lt;catfile&gt; or C&lt;catdir&gt; from File::Spec, but without caring about
#pod file or directories.
#pod
#pod B&lt;WARNING&gt;: because the argument could contain C&lt;..&gt; or refer to symlinks,
#pod there is no guarantee that the new path refers to an actual descendent of
#pod the original.  If this is important to you, transform parent and child with
#pod L&lt;/realpath&gt; and check them with L&lt;/subsumes&gt;.
#pod
#pod Current API available since 0.001.
#pod
#pod =cut

sub child {
    my ( $self, @parts ) = @_;
    return _path( $self-&gt;[PATH], @parts );
}

#pod =method children
#pod
#pod     @paths = path(&quot;/tmp&quot;)-&gt;children;
#pod     @paths = path(&quot;/tmp&quot;)-&gt;children( qr/\.txt\z/ );
#pod
#pod Returns a list of C&lt;Path::Tiny&gt; objects for all files and directories
#pod within a directory.  Excludes &quot;.&quot; and &quot;..&quot; automatically.
#pod
#pod If an optional C&lt;qr//&gt; argument is provided, it only returns objects for child
#pod names that match the given regular expression.  Only the base name is used
#pod for matching:
#pod
#pod     @paths = path(&quot;/tmp&quot;)-&gt;children( qr/^foo/ );
#pod     # matches children like the glob foo*
#pod
#pod Current API available since 0.028.
#pod
#pod =cut

sub children {
    my ( $self, $filter ) = @_;
    my $dh;
    opendir $dh, $self-&gt;[PATH] or $self-&gt;_throw('opendir');
    my @children = readdir $dh;
    closedir $dh or $self-&gt;_throw('closedir');

    if ( not defined $filter ) {
        @children = grep { $_ ne '.' &amp;&amp; $_ ne '..' } @children;
    }
    elsif ( $filter &amp;&amp; ref($filter) eq 'Regexp' ) {
        @children = grep { $_ ne '.' &amp;&amp; $_ ne '..' &amp;&amp; $_ =~ $filter } @children;
    }
    else {
        Carp::croak(&quot;Invalid argument '$filter' for children()&quot;);
    }

    return map { _path( $self-&gt;[PATH], $_ ) } @children;
}

#pod =method chmod
#pod
#pod     path(&quot;foo.txt&quot;)-&gt;chmod(0777);
#pod     path(&quot;foo.txt&quot;)-&gt;chmod(&quot;0755&quot;);
#pod     path(&quot;foo.txt&quot;)-&gt;chmod(&quot;go-w&quot;);
#pod     path(&quot;foo.txt&quot;)-&gt;chmod(&quot;a=r,u+wx&quot;);
#pod
#pod Sets file or directory permissions.  The argument can be a numeric mode, a
#pod octal string beginning with a &quot;0&quot; or a limited subset of the symbolic mode use
#pod by F&lt;/bin/chmod&gt;.
#pod
#pod The symbolic mode must be a comma-delimited list of mode clauses.  Clauses must
#pod match C&lt;&lt; qr/\A([augo]+)([=+-])([rwx]+)\z/ &gt;&gt;, which defines &quot;who&quot;, &quot;op&quot; and
#pod &quot;perms&quot; parameters for each clause.  Unlike F&lt;/bin/chmod&gt;, all three parameters
#pod are required for each clause, multiple ops are not allowed and permissions
#pod C&lt;stugoX&gt; are not supported.  (See L&lt;File::chmod&gt; for more complex needs.)
#pod
#pod Current API available since 0.053.
#pod
#pod =cut

sub chmod {
    my ( $self, $new_mode ) = @_;

    my $mode;
    if ( $new_mode =~ /\d/ ) {
        $mode = ( $new_mode =~ /^0/ ? oct($new_mode) : $new_mode );
    }
    elsif ( $new_mode =~ /[=+-]/ ) {
        $mode = _symbolic_chmod( $self-&gt;stat-&gt;mode &amp; 07777, $new_mode ); ## no critic
    }
    else {
        Carp::croak(&quot;Invalid mode argument '$new_mode' for chmod()&quot;);
    }

    CORE::chmod( $mode, $self-&gt;[PATH] ) or $self-&gt;_throw(&quot;chmod&quot;);

    return 1;
}

#pod =method copy
#pod
#pod     path(&quot;/tmp/foo.txt&quot;)-&gt;copy(&quot;/tmp/bar.txt&quot;);
#pod
#pod Copies the current path to the given destination using L&lt;File::Copy&gt;'s
#pod C&lt;copy&gt; function. Upon success, returns the C&lt;Path::Tiny&gt; object for the
#pod newly copied file.
#pod
#pod Current API available since 0.070.
#pod
#pod =cut

# XXX do recursively for directories?
sub copy {
    my ( $self, $dest ) = @_;
    require File::Copy;
    File::Copy::copy( $self-&gt;[PATH], $dest )
      or Carp::croak(&quot;copy failed for $self to $dest: $!&quot;);

    return -d $dest ? _path( $dest, $self-&gt;basename ) : _path($dest);
}

#pod =method digest
#pod
#pod     $obj = path(&quot;/tmp/foo.txt&quot;)-&gt;digest;        # SHA-256
#pod     $obj = path(&quot;/tmp/foo.txt&quot;)-&gt;digest(&quot;MD5&quot;); # user-selected
#pod     $obj = path(&quot;/tmp/foo.txt&quot;)-&gt;digest( { chunk_size =&gt; 1e6 }, &quot;MD5&quot; );
#pod
#pod Returns a hexadecimal digest for a file.  An optional hash reference of options may
#pod be given.  The only option is C&lt;chunk_size&gt;.  If C&lt;chunk_size&gt; is given, that many
#pod bytes will be read at a time.  If not provided, the entire file will be slurped
#pod into memory to compute the digest.
#pod
#pod Any subsequent arguments are passed to the constructor for L&lt;Digest&gt; to select
#pod an algorithm.  If no arguments are given, the default is SHA-256.
#pod
#pod Current API available since 0.056.
#pod
#pod =cut

sub digest {
    my ( $self, @opts ) = @_;
    my $args = ( @opts &amp;&amp; ref $opts[0] eq 'HASH' ) ? shift @opts : {};
    $args = _get_args( $args, qw/chunk_size/ );
    unshift @opts, 'SHA-256' unless @opts;
    require Digest;
    my $digest = Digest-&gt;new(@opts);
    if ( $args-&gt;{chunk_size} ) {
        my $fh = $self-&gt;filehandle( { locked =&gt; 1 }, &quot;&lt;&quot;, &quot;:unix&quot; );
        my $buf;
        while (!eof($fh)) {
            my $rc = read $fh, $buf, $args-&gt;{chunk_size};
            $self-&gt;_throw('read') unless defined $rc;
            $digest-&gt;add($buf);
        }
    }
    else {
        $digest-&gt;add( $self-&gt;slurp_raw );
    }
    return $digest-&gt;hexdigest;
}

#pod =method dirname (deprecated)
#pod
#pod     $name = path(&quot;/tmp/foo.txt&quot;)-&gt;dirname; # &quot;/tmp/&quot;
#pod
#pod Returns the directory portion you would get from calling
#pod C&lt;&lt; File::Spec-&gt;splitpath( $path-&gt;stringify ) &gt;&gt; or C&lt;&quot;.&quot;&gt; for a path without a
#pod parent directory portion.  Because L&lt;File::Spec&gt; is inconsistent, the result
#pod might or might not have a trailing slash.  Because of this, this method is
#pod B&lt;deprecated&gt;.
#pod
#pod A better, more consistently approach is likely C&lt;&lt; $path-&gt;parent-&gt;stringify &gt;&gt;,
#pod which will not have a trailing slash except for a root directory.
#pod
#pod Deprecated in 0.056.
#pod
#pod =cut

sub dirname {
    my ($self) = @_;
    $self-&gt;_splitpath unless defined $self-&gt;[DIR];
    return length $self-&gt;[DIR] ? $self-&gt;[DIR] : &quot;.&quot;;
}

#pod =method edit, edit_raw, edit_utf8
#pod
#pod     path(&quot;foo.txt&quot;)-&gt;edit( \&amp;callback, $options );
#pod     path(&quot;foo.txt&quot;)-&gt;edit_utf8( \&amp;callback );
#pod     path(&quot;foo.txt&quot;)-&gt;edit_raw( \&amp;callback );
#pod
#pod These are convenience methods that allow &quot;editing&quot; a file using a single
#pod callback argument. They slurp the file using C&lt;slurp&gt;, place the contents
#pod inside a localized C&lt;$_&gt; variable, call the callback function (without
#pod arguments), and then write C&lt;$_&gt; (presumably mutated) back to the
#pod file with C&lt;spew&gt;.
#pod
#pod An optional hash reference may be used to pass options.  The only option is
#pod C&lt;binmode&gt;, which is passed to C&lt;slurp&gt; and C&lt;spew&gt;.
#pod
#pod C&lt;edit_utf8&gt; and C&lt;edit_raw&gt; act like their respective C&lt;slurp_*&gt; and
#pod C&lt;spew_*&gt; methods.
#pod
#pod Current API available since 0.077.
#pod
#pod =cut

sub edit {
    my $self = shift;
    my $cb   = shift;
    my $args = _get_args( shift, qw/binmode/ );
    Carp::croak(&quot;Callback for edit() must be a code reference&quot;)
      unless defined($cb) &amp;&amp; ref($cb) eq 'CODE';

    local $_ =
      $self-&gt;slurp( exists( $args-&gt;{binmode} ) ? { binmode =&gt; $args-&gt;{binmode} } : () );
    $cb-&gt;();
    $self-&gt;spew( $args, $_ );

    return;
}

# this is done long-hand to benefit from slurp_utf8 optimizations
sub edit_utf8 {
    my ( $self, $cb ) = @_;
    Carp::croak(&quot;Callback for edit_utf8() must be a code reference&quot;)
      unless defined($cb) &amp;&amp; ref($cb) eq 'CODE';

    local $_ = $self-&gt;slurp_utf8;
    $cb-&gt;();
    $self-&gt;spew_utf8($_);

    return;
}

sub edit_raw { $_[2] = { binmode =&gt; &quot;:unix&quot; }; goto &amp;edit }

#pod =method edit_lines, edit_lines_utf8, edit_lines_raw
#pod
#pod     path(&quot;foo.txt&quot;)-&gt;edit_lines( \&amp;callback, $options );
#pod     path(&quot;foo.txt&quot;)-&gt;edit_lines_utf8( \&amp;callback );
#pod     path(&quot;foo.txt&quot;)-&gt;edit_lines_raw( \&amp;callback );
#pod
#pod These are convenience methods that allow &quot;editing&quot; a file's lines using a
#pod single callback argument.  They iterate over the file: for each line, the
#pod line is put into a localized C&lt;$_&gt; variable, the callback function is
#pod executed (without arguments) and then C&lt;$_&gt; is written to a temporary file.
#pod When iteration is finished, the temporary file is atomically renamed over
#pod the original.
#pod
#pod An optional hash reference may be used to pass options.  The only option is
#pod C&lt;binmode&gt;, which is passed to the method that open handles for reading and
#pod writing.
#pod
#pod C&lt;edit_lines_raw&gt; is like C&lt;edit_lines&gt; with a buffered C&lt;binmode&gt; of
#pod C&lt;:raw&gt;.
#pod
#pod C&lt;edit_lines_utf8&gt; is like C&lt;edit_lines&gt; with a buffered C&lt;binmode&gt;
#pod C&lt;:raw:encoding(UTF-8)&gt; (or C&lt;:raw:utf8_strict&gt; with
#pod L&lt;PerlIO::utf8_strict&gt;).
#pod
#pod Current API available since 0.077.
#pod
#pod =cut

sub edit_lines {
    my $self = shift;
    my $cb   = shift;
    my $args = _get_args( shift, qw/binmode/ );
    Carp::croak(&quot;Callback for edit_lines() must be a code reference&quot;)
      unless defined($cb) &amp;&amp; ref($cb) eq 'CODE';

    my $binmode = $args-&gt;{binmode};
    # get default binmode from caller's lexical scope (see &quot;perldoc open&quot;)
    $binmode = ( ( caller(0) )[10] || {} )-&gt;{'open&gt;'} unless defined $binmode;

    # writing needs to follow the link and create the tempfile in the same
    # dir for later atomic rename
    my $resolved_path = $self-&gt;_resolve_symlinks;
    my $temp          = $resolved_path-&gt;_replacment_path;

    my $temp_fh = $temp-&gt;filehandle( { exclusive =&gt; 1, locked =&gt; 1 }, &quot;&gt;&quot;, $binmode );
    my $in_fh = $self-&gt;filehandle( { locked =&gt; 1 }, '&lt;', $binmode );

    local $_;
    while (! eof($in_fh) ) {
        defined( $_ = readline($in_fh) ) or $self-&gt;_throw('readline');
        $cb-&gt;();
        $temp_fh-&gt;print($_) or self-&gt;_throw('print', $temp);
    }

    close $temp_fh or $self-&gt;_throw( 'close', $temp );
    close $in_fh or $self-&gt;_throw('close');

    return $temp-&gt;move($resolved_path);
}

sub edit_lines_raw { $_[2] = { binmode =&gt; &quot;:raw&quot; }; goto &amp;edit_lines }

sub edit_lines_utf8 {
    if ( defined($HAS_PU) ? $HAS_PU : ( $HAS_PU = _check_PU() ) ) {
        $_[2] = { binmode =&gt; &quot;:raw:utf8_strict&quot; };
    }
    else {
        $_[2] = { binmode =&gt; &quot;:raw:encoding(UTF-8)&quot; };
    }
    goto &amp;edit_lines;
}

#pod =method exists, is_file, is_dir
#pod
#pod     if ( path(&quot;/tmp&quot;)-&gt;exists ) { ... }     # -e
#pod     if ( path(&quot;/tmp&quot;)-&gt;is_dir ) { ... }     # -d
#pod     if ( path(&quot;/tmp&quot;)-&gt;is_file ) { ... }    # -e &amp;&amp; ! -d
#pod
#pod Implements file test operations, this means the file or directory actually has
#pod to exist on the filesystem.  Until then, it's just a path.
#pod
#pod B&lt;Note&gt;: C&lt;is_file&gt; is not C&lt;-f&gt; because C&lt;-f&gt; is not the opposite of C&lt;-d&gt;.
#pod C&lt;-f&gt; means &quot;plain file&quot;, excluding symlinks, devices, etc. that often can be
#pod read just like files.
#pod
#pod Use C&lt;-f&gt; instead if you really mean to check for a plain file.
#pod
#pod Current API available since 0.053.
#pod
#pod =cut

sub exists { -e $_[0]-&gt;[PATH] }

sub is_file { -e $_[0]-&gt;[PATH] &amp;&amp; !-d _ }

sub is_dir { -d $_[0]-&gt;[PATH] }

#pod =method filehandle
#pod
#pod     $fh = path(&quot;/tmp/foo.txt&quot;)-&gt;filehandle($mode, $binmode);
#pod     $fh = path(&quot;/tmp/foo.txt&quot;)-&gt;filehandle({ locked =&gt; 1 }, $mode, $binmode);
#pod     $fh = path(&quot;/tmp/foo.txt&quot;)-&gt;filehandle({ exclusive =&gt; 1  }, $mode, $binmode);
#pod
#pod Returns an open file handle.  The C&lt;$mode&gt; argument must be a Perl-style
#pod read/write mode string (&quot;&lt;&quot; ,&quot;&gt;&quot;, &quot;&gt;&gt;&quot;, etc.).  If a C&lt;$binmode&gt;
#pod is given, it is set during the C&lt;open&gt; call.
#pod
#pod An optional hash reference may be used to pass options.
#pod
#pod The C&lt;locked&gt; option governs file locking; if true, handles opened for writing,
#pod appending or read-write are locked with C&lt;LOCK_EX&gt;; otherwise, they are
#pod locked with C&lt;LOCK_SH&gt;.  When using C&lt;locked&gt;, &quot;&gt;&quot; or &quot;+&gt;&quot; modes will delay
#pod truncation until after the lock is acquired.
#pod
#pod The C&lt;exclusive&gt; option causes the open() call to fail if the file already
#pod exists.  This corresponds to the O_EXCL flag to sysopen / open(2).
#pod C&lt;exclusive&gt; implies C&lt;locked&gt; and will set it for you if you forget it.
#pod
#pod See C&lt;openr&gt;, C&lt;openw&gt;, C&lt;openrw&gt;, and C&lt;opena&gt; for sugar.
#pod
#pod Current API available since 0.066.
#pod
#pod =cut

# Note: must put binmode on open line, not subsequent binmode() call, so things
# like &quot;:unix&quot; actually stop perlio/crlf from being added

sub filehandle {
    my ( $self, @args ) = @_;
    my $args = ( @args &amp;&amp; ref $args[0] eq 'HASH' ) ? shift @args : {};
    $args = _get_args( $args, qw/locked exclusive/ );
    $args-&gt;{locked} = 1 if $args-&gt;{exclusive};
    my ( $opentype, $binmode ) = @args;

    $opentype = &quot;&lt;&quot; unless defined $opentype;
    Carp::croak(&quot;Invalid file mode '$opentype'&quot;)
      unless grep { $opentype eq $_ } qw/&lt; +&lt; &gt; +&gt; &gt;&gt; +&gt;&gt;/;

    $binmode = ( ( caller(0) )[10] || {} )-&gt;{ 'open' . substr( $opentype, -1, 1 ) }
      unless defined $binmode;
    $binmode = &quot;&quot; unless defined $binmode;

    my ( $fh, $lock, $trunc );
    if ( $HAS_FLOCK &amp;&amp; $args-&gt;{locked} &amp;&amp; !$ENV{PERL_PATH_TINY_NO_FLOCK} ) {
        require Fcntl;
        # truncating file modes shouldn't truncate until lock acquired
        if ( grep { $opentype eq $_ } qw( &gt; +&gt; ) ) {
            # sysopen in write mode without truncation
            my $flags = $opentype eq &quot;&gt;&quot; ? Fcntl::O_WRONLY() : Fcntl::O_RDWR();
            $flags |= Fcntl::O_CREAT();
            $flags |= Fcntl::O_EXCL() if $args-&gt;{exclusive};
            sysopen( $fh, $self-&gt;[PATH], $flags ) or $self-&gt;_throw(&quot;sysopen&quot;);

            # fix up the binmode since sysopen() can't specify layers like
            # open() and binmode() can't start with just :unix like open()
            if ( $binmode =~ s/^:unix// ) {
                # eliminate pseudo-layers
                binmode( $fh, &quot;:raw&quot; ) or $self-&gt;_throw(&quot;binmode (:raw)&quot;);
                # strip off real layers until only :unix is left
                while ( 1 &lt; ( my $layers =()= PerlIO::get_layers( $fh, output =&gt; 1 ) ) ) {
                    binmode( $fh, &quot;:pop&quot; ) or $self-&gt;_throw(&quot;binmode (:pop)&quot;);
                }
            }

            # apply any remaining binmode layers
            if ( length $binmode ) {
                binmode( $fh, $binmode ) or $self-&gt;_throw(&quot;binmode ($binmode)&quot;);
            }

            # ask for lock and truncation
            $lock  = Fcntl::LOCK_EX();
            $trunc = 1;
        }
        elsif ( $^O eq 'aix' &amp;&amp; $opentype eq &quot;&lt;&quot; ) {
            # AIX can only lock write handles, so upgrade to RW and LOCK_EX if
            # the file is writable; otherwise give up on locking.  N.B.
            # checking -w before open to determine the open mode is an
            # unavoidable race condition
            if ( -w $self-&gt;[PATH] ) {
                $opentype = &quot;+&lt;&quot;;
                $lock     = Fcntl::LOCK_EX();
            }
        }
        else {
            $lock = $opentype eq &quot;&lt;&quot; ? Fcntl::LOCK_SH() : Fcntl::LOCK_EX();
        }
    }

    unless ($fh) {
        my $mode = $opentype . $binmode;
        open $fh, $mode, $self-&gt;[PATH] or $self-&gt;_throw(&quot;open ($mode)&quot;);
    }

    do { flock( $fh, $lock ) or $self-&gt;_throw(&quot;flock ($lock)&quot;) } if $lock;
    do { truncate( $fh, 0 ) or $self-&gt;_throw(&quot;truncate&quot;) } if $trunc;

    return $fh;
}

#pod =method has_same_bytes
#pod
#pod     if ( path(&quot;foo.txt&quot;)-&gt;has_same_bytes(&quot;bar.txt&quot;) ) {
#pod        # ...
#pod     }
#pod
#pod This method returns true if both the invocant and the argument can be opened as
#pod file handles and the handles contain the same bytes.  It returns false if their
#pod contents differ.  If either can't be opened as a file (e.g. a directory or
#pod non-existent file), the method throws an exception.  If both can be opened and
#pod both have the same C&lt;realpath&gt;, the method returns true without scanning any
#pod data.
#pod
#pod Current API available since 0.125.
#pod
#pod =cut

sub has_same_bytes {
    my ($self, $other_path) = @_;
    my $other = _path($other_path);

    my $fh1 = $self-&gt;openr_raw({ locked =&gt; 1 });
    my $fh2 = $other-&gt;openr_raw({ locked =&gt; 1 });

    # check for directories
    if (-d $fh1) {
        $self-&gt;_throw('has_same_bytes', $self-&gt;[PATH], &quot;directory not allowed&quot;);
    }
    if (-d $fh2) {
        $self-&gt;_throw('has_same_bytes', $other-&gt;[PATH], &quot;directory not allowed&quot;);
    }

    # Now that handles are open, we know the inputs are readable files that
    # exist, so it's safe to compare via realpath
    if ($self-&gt;realpath eq $other-&gt;realpath) {
        return 1
    }

    # result is 0 for equal, 1 for unequal, -1 for error
    require File::Compare;
    my $res = File::Compare::compare($fh1, $fh2, 65536);
    if ($res &lt; 0) {
        $self-&gt;_throw('has_same_bytes')
    }

    return $res == 0;
}

#pod =method is_absolute, is_relative
#pod
#pod     if ( path(&quot;/tmp&quot;)-&gt;is_absolute ) { ... }
#pod     if ( path(&quot;/tmp&quot;)-&gt;is_relative ) { ... }
#pod
#pod Booleans for whether the path appears absolute or relative.
#pod
#pod Current API available since 0.001.
#pod
#pod =cut

sub is_absolute { substr( $_[0]-&gt;dirname, 0, 1 ) eq '/' }

sub is_relative { substr( $_[0]-&gt;dirname, 0, 1 ) ne '/' }

#pod =method is_rootdir
#pod
#pod     while ( ! $path-&gt;is_rootdir ) {
#pod         $path = $path-&gt;parent;
#pod         ...
#pod     }
#pod
#pod Boolean for whether the path is the root directory of the volume.  I.e. the
#pod C&lt;dirname&gt; is C&lt;q[/]&gt; and the C&lt;basename&gt; is C&lt;q[]&gt;.
#pod
#pod This works even on C&lt;MSWin32&gt; with drives and UNC volumes:
#pod
#pod     path(&quot;C:/&quot;)-&gt;is_rootdir;             # true
#pod     path(&quot;//server/share/&quot;)-&gt;is_rootdir; #true
#pod
#pod Current API available since 0.038.
#pod
#pod =cut

sub is_rootdir {
    my ($self) = @_;
    $self-&gt;_splitpath unless defined $self-&gt;[DIR];
    return $self-&gt;[DIR] eq '/' &amp;&amp; $self-&gt;[FILE] eq '';
}

#pod =method iterator
#pod
#pod     $iter = path(&quot;/tmp&quot;)-&gt;iterator( \%options );
#pod
#pod Returns a code reference that walks a directory lazily.  Each invocation
#pod returns a C&lt;Path::Tiny&gt; object or undef when the iterator is exhausted.
#pod
#pod     $iter = path(&quot;/tmp&quot;)-&gt;iterator;
#pod     while ( $path = $iter-&gt;() ) {
#pod         ...
#pod     }
#pod
#pod The current and parent directory entries (&quot;.&quot; and &quot;..&quot;) will not
#pod be included.
#pod
#pod If the C&lt;recurse&gt; option is true, the iterator will walk the directory
#pod recursively, breadth-first.  If the C&lt;follow_symlinks&gt; option is also true,
#pod directory links will be followed recursively.  There is no protection against
#pod loops when following links. If a directory is not readable, it will not be
#pod followed.
#pod
#pod The default is the same as:
#pod
#pod     $iter = path(&quot;/tmp&quot;)-&gt;iterator( {
#pod         recurse         =&gt; 0,
#pod         follow_symlinks =&gt; 0,
#pod     } );
#pod
#pod For a more powerful, recursive iterator with built-in loop avoidance, see
#pod L&lt;Path::Iterator::Rule&gt;.
#pod
#pod See also L&lt;/visit&gt;.
#pod
#pod Current API available since 0.016.
#pod
#pod =cut

sub iterator {
    my $self = shift;
    my $args = _get_args( shift, qw/recurse follow_symlinks/ );
    my @dirs = $self;
    my $current;
    return sub {
        my $next;
        while (@dirs) {
            if ( ref $dirs[0] eq 'Path::Tiny' ) {
                if ( !-r $dirs[0] ) {
                    # Directory is missing or not readable, so skip it.  There
                    # is still a race condition possible between the check and
                    # the opendir, but we can't easily differentiate between
                    # error cases that are OK to skip and those that we want
                    # to be exceptions, so we live with the race and let opendir
                    # be fatal.
                    shift @dirs and next;
                }
                $current = $dirs[0];
                my $dh;
                opendir( $dh, $current-&gt;[PATH] )
                  or $self-&gt;_throw( 'opendir', $current-&gt;[PATH] );
                $dirs[0] = $dh;
                if ( -l $current-&gt;[PATH] &amp;&amp; !$args-&gt;{follow_symlinks} ) {
                    # Symlink attack! It was a real dir, but is now a symlink!
                    # N.B. we check *after* opendir so the attacker has to win
                    # two races: replace dir with symlink before opendir and
                    # replace symlink with dir before -l check above
                    shift @dirs and next;
                }
            }
            while ( defined( $next = readdir $dirs[0] ) ) {
                next if $next eq '.' || $next eq '..';
                my $path = $current-&gt;child($next);
                push @dirs, $path
                  if $args-&gt;{recurse} &amp;&amp; -d $path &amp;&amp; !( !$args-&gt;{follow_symlinks} &amp;&amp; -l $path );
                return $path;
            }
            shift @dirs;
        }
        return;
    };
}

#pod =method lines, lines_raw, lines_utf8
#pod
#pod     @contents = path(&quot;/tmp/foo.txt&quot;)-&gt;lines;
#pod     @contents = path(&quot;/tmp/foo.txt&quot;)-&gt;lines(\%options);
#pod     @contents = path(&quot;/tmp/foo.txt&quot;)-&gt;lines_raw;
#pod     @contents = path(&quot;/tmp/foo.txt&quot;)-&gt;lines_utf8;
#pod
#pod     @contents = path(&quot;/tmp/foo.txt&quot;)-&gt;lines( { chomp =&gt; 1, count =&gt; 4 } );
#pod
#pod Returns a list of lines from a file.  Optionally takes a hash-reference of
#pod options.  Valid options are C&lt;binmode&gt;, C&lt;count&gt; and C&lt;chomp&gt;.
#pod
#pod If C&lt;binmode&gt; is provided, it will be set on the handle prior to reading.
#pod
#pod If a positive C&lt;count&gt; is provided, that many lines will be returned from the
#pod start of the file.  If a negative C&lt;count&gt; is provided, the entire file will be
#pod read, but only C&lt;abs(count)&gt; will be kept and returned.  If C&lt;abs(count)&gt;
#pod exceeds the number of lines in the file, all lines will be returned.
#pod
#pod If C&lt;chomp&gt; is set, any end-of-line character sequences (C&lt;CR&gt;, C&lt;CRLF&gt;, or
#pod C&lt;LF&gt;) will be removed from the lines returned.
#pod
#pod Because the return is a list, C&lt;lines&gt; in scalar context will return the number
#pod of lines (and throw away the data).
#pod
#pod     $number_of_lines = path(&quot;/tmp/foo.txt&quot;)-&gt;lines;
#pod
#pod C&lt;lines_raw&gt; is like C&lt;lines&gt; with a C&lt;binmode&gt; of C&lt;:raw&gt;.  We use C&lt;:raw&gt;
#pod instead of C&lt;:unix&gt; so PerlIO buffering can manage reading by line.
#pod
#pod C&lt;lines_utf8&gt; is like C&lt;lines&gt; with a C&lt;binmode&gt; of C&lt;:raw:encoding(UTF-8)&gt;
#pod (or C&lt;:raw:utf8_strict&gt; with L&lt;PerlIO::utf8_strict&gt;).  If L&lt;Unicode::UTF8&gt;
#pod 0.58+ is installed, a raw, unbuffered UTF-8 slurp will be done and then the
#pod lines will be split.  This is actually faster than relying on
#pod IO layers, though a bit memory intensive.  If memory use is a
#pod concern, consider C&lt;openr_utf8&gt; and iterating directly on the handle.
#pod
#pod Current API available since 0.065.
#pod
#pod =cut

sub lines {
    my $self    = shift;
    my $args    = _get_args( shift, qw/binmode chomp count/ );
    my $binmode = $args-&gt;{binmode};
    $binmode = ( ( caller(0) )[10] || {} )-&gt;{'open&lt;'} unless defined $binmode;
    my $fh = $self-&gt;filehandle( { locked =&gt; 1 }, &quot;&lt;&quot;, $binmode );
    my $chomp = $args-&gt;{chomp};
    # XXX more efficient to read @lines then chomp(@lines) vs map?
    if ( $args-&gt;{count} ) {
        my ( $counter, $mod, @result ) = ( 0, abs( $args-&gt;{count} ) );
        my $line;
        while ( !eof($fh) ) {
            defined( $line = readline($fh) ) or $self-&gt;_throw('readline');

            $line =~ s/(?:\x{0d}?\x{0a}|\x{0d})\z// if $chomp;
            $result[ $counter++ ] = $line;
            # for positive count, terminate after right number of lines
            last if $counter == $args-&gt;{count};
            # for negative count, eventually wrap around in the result array
            $counter %= $mod;
        }
        # reorder results if full and wrapped somewhere in the middle
        splice( @result, 0, 0, splice( @result, $counter ) )
          if @result == $mod &amp;&amp; $counter % $mod;
        return @result;
    }
    elsif ($chomp) {
        local $!;
        my @lines = map { s/(?:\x{0d}?\x{0a}|\x{0d})\z//; $_ } &lt;$fh&gt;; ## no critic
        $self-&gt;_throw('readline') if $!;
        return @lines;
    }
    else {
        if ( wantarray ) {
            local $!;
            my @lines = &lt;$fh&gt;;
            $self-&gt;_throw('readline') if $!;
            return @lines;
        } else {
            local $!;
            my $count =()= &lt;$fh&gt;;
            $self-&gt;_throw('readline') if $!;
            return $count;
        }
    }
}

sub lines_raw {
    my $self = shift;
    my $args = _get_args( shift, qw/binmode chomp count/ );
    if ( $args-&gt;{chomp} &amp;&amp; !$args-&gt;{count} ) {
        return split /\n/, slurp_raw($self);                    ## no critic
    }
    else {
        $args-&gt;{binmode} = &quot;:raw&quot;;
        return lines( $self, $args );
    }
}

my $CRLF = qr/(?:\x{0d}?\x{0a}|\x{0d})/;

sub lines_utf8 {
    my $self = shift;
    my $args = _get_args( shift, qw/binmode chomp count/ );
    if (   ( defined($HAS_UU) ? $HAS_UU : ( $HAS_UU = _check_UU() ) )
        &amp;&amp; $args-&gt;{chomp}
        &amp;&amp; !$args-&gt;{count} )
    {
        my $slurp = slurp_utf8($self);
        $slurp =~ s/$CRLF\z//; # like chomp, but full CR?LF|CR
        return split $CRLF, $slurp, -1; ## no critic
    }
    elsif ( defined($HAS_PU) ? $HAS_PU : ( $HAS_PU = _check_PU() ) ) {
        $args-&gt;{binmode} = &quot;:raw:utf8_strict&quot;;
        return lines( $self, $args );
    }
    else {
        $args-&gt;{binmode} = &quot;:raw:encoding(UTF-8)&quot;;
        return lines( $self, $args );
    }
}

#pod =method mkdir
#pod
#pod     path(&quot;foo/bar/baz&quot;)-&gt;mkdir;
#pod     path(&quot;foo/bar/baz&quot;)-&gt;mkdir( \%options );
#pod
#pod Like calling C&lt;make_path&gt; from L&lt;File::Path&gt;.  An optional hash reference
#pod is passed through to C&lt;make_path&gt;.  Errors will be trapped and an exception
#pod thrown.  Returns the the path object to facilitate chaining.
#pod
#pod B&lt;NOTE&gt;: unlike Perl's builtin C&lt;mkdir&gt;, this will create intermediate paths
#pod similar to the Unix C&lt;mkdir -p&gt; command.  It will not error if applied to an
#pod existing directory.
#pod
#pod Current API available since 0.125.
#pod
#pod =cut

sub mkdir {
    my ( $self, $args ) = @_;
    $args = {} unless ref $args eq 'HASH';
    my $err;
    $args-&gt;{error} = \$err unless defined $args-&gt;{error};
    require File::Path;
    my @dirs;
    my $ok = eval {
        File::Path::make_path( $self-&gt;[PATH], $args );
        1;
    };
    if (!$ok) {
        $self-&gt;_throw('mkdir', $self-&gt;[PATH], &quot;error creating path: $@&quot;);
    }
    if ( $err &amp;&amp; @$err ) {
        my ( $file, $message ) = %{ $err-&gt;[0] };
        $self-&gt;_throw('mkdir', $file, $message);
    }
    return $self;
}

#pod =method mkpath (deprecated)
#pod
#pod Like calling C&lt;mkdir&gt;, but returns the list of directories created or an empty list if
#pod the directories already exist, just like C&lt;make_path&gt;.
#pod
#pod Deprecated in 0.125.
#pod
#pod =cut

sub mkpath {
    my ( $self, $args ) = @_;
    $args = {} unless ref $args eq 'HASH';
    my $err;
    $args-&gt;{error} = \$err unless defined $args-&gt;{error};
    require File::Path;
    my @dirs = File::Path::make_path( $self-&gt;[PATH], $args );
    if ( $err &amp;&amp; @$err ) {
        my ( $file, $message ) = %{ $err-&gt;[0] };
        Carp::croak(&quot;mkpath failed for $file: $message&quot;);
    }
    return @dirs;
}

#pod =method move
#pod
#pod     path(&quot;foo.txt&quot;)-&gt;move(&quot;bar.txt&quot;);
#pod
#pod Moves the current path to the given destination using L&lt;File::Copy&gt;'s
#pod C&lt;move&gt; function. Upon success, returns the C&lt;Path::Tiny&gt; object for the
#pod newly moved file.
#pod
#pod If the destination already exists and is a directory, and the source is not a
#pod directory, then the source file will be renamed into the directory
#pod specified by the destination.
#pod
#pod If possible, move() will simply rename the file. Otherwise, it
#pod copies the file to the new location and deletes the original. If an
#pod error occurs during this copy-and-delete process, you may be left
#pod with a (possibly partial) copy of the file under the destination
#pod name.
#pod
#pod Current API available since 0.124. Prior versions used Perl's
#pod -built-in (and less robust) L&lt;rename|perlfunc/rename&gt; function
#pod and did not return an object.
#pod
#pod =cut

sub move {
    my ( $self, $dest ) = @_;
    require File::Copy;
    File::Copy::move( $self-&gt;[PATH], $dest )
      or $self-&gt;_throw( 'move', $self-&gt;[PATH] . &quot;' -&gt; '$dest&quot; );

    return -d $dest ? _path( $dest, $self-&gt;basename ) : _path($dest);
}

#pod =method openr, openw, openrw, opena
#pod
#pod     $fh = path(&quot;foo.txt&quot;)-&gt;openr($binmode);  # read
#pod     $fh = path(&quot;foo.txt&quot;)-&gt;openr_raw;
#pod     $fh = path(&quot;foo.txt&quot;)-&gt;openr_utf8;
#pod
#pod     $fh = path(&quot;foo.txt&quot;)-&gt;openw($binmode);  # write
#pod     $fh = path(&quot;foo.txt&quot;)-&gt;openw_raw;
#pod     $fh = path(&quot;foo.txt&quot;)-&gt;openw_utf8;
#pod
#pod     $fh = path(&quot;foo.txt&quot;)-&gt;opena($binmode);  # append
#pod     $fh = path(&quot;foo.txt&quot;)-&gt;opena_raw;
#pod     $fh = path(&quot;foo.txt&quot;)-&gt;opena_utf8;
#pod
#pod     $fh = path(&quot;foo.txt&quot;)-&gt;openrw($binmode); # read/write
#pod     $fh = path(&quot;foo.txt&quot;)-&gt;openrw_raw;
#pod     $fh = path(&quot;foo.txt&quot;)-&gt;openrw_utf8;
#pod
#pod Returns a file handle opened in the specified mode.  The C&lt;openr&gt; style methods
#pod take a single C&lt;binmode&gt; argument.  All of the C&lt;open*&gt; methods have
#pod C&lt;open*_raw&gt; and C&lt;open*_utf8&gt; equivalents that use buffered I/O layers C&lt;:raw&gt;
#pod and C&lt;:raw:encoding(UTF-8)&gt; (or C&lt;:raw:utf8_strict&gt; with
#pod L&lt;PerlIO::utf8_strict&gt;).
#pod
#pod An optional hash reference may be used to pass options.  The only option is
#pod C&lt;locked&gt;.  If true, handles opened for writing, appending or read-write are
#pod locked with C&lt;LOCK_EX&gt;; otherwise, they are locked for C&lt;LOCK_SH&gt;.
#pod
#pod     $fh = path(&quot;foo.txt&quot;)-&gt;openrw_utf8( { locked =&gt; 1 } );
#pod
#pod See L&lt;/filehandle&gt; for more on locking.
#pod
#pod Current API available since 0.011.
#pod
#pod =cut

# map method names to corresponding open mode
my %opens = (
    opena  =&gt; &quot;&gt;&gt;&quot;,
    openr  =&gt; &quot;&lt;&quot;,
    openw  =&gt; &quot;&gt;&quot;,
    openrw =&gt; &quot;+&lt;&quot;
);

while ( my ( $k, $v ) = each %opens ) {
    no strict 'refs';
    # must check for lexical IO mode hint
    *{$k} = sub {
        my ( $self, @args ) = @_;
        my $args = ( @args &amp;&amp; ref $args[0] eq 'HASH' ) ? shift @args : {};
        $args = _get_args( $args, qw/locked/ );
        my ($binmode) = @args;
        $binmode = ( ( caller(0) )[10] || {} )-&gt;{ 'open' . substr( $v, -1, 1 ) }
          unless defined $binmode;
        $self-&gt;filehandle( $args, $v, $binmode );
    };
    *{ $k . &quot;_raw&quot; } = sub {
        my ( $self, @args ) = @_;
        my $args = ( @args &amp;&amp; ref $args[0] eq 'HASH' ) ? shift @args : {};
        $args = _get_args( $args, qw/locked/ );
        $self-&gt;filehandle( $args, $v, &quot;:raw&quot; );
    };
    *{ $k . &quot;_utf8&quot; } = sub {
        my ( $self, @args ) = @_;
        my $args = ( @args &amp;&amp; ref $args[0] eq 'HASH' ) ? shift @args : {};
        $args = _get_args( $args, qw/locked/ );
        my $layer;
        if ( defined($HAS_PU) ? $HAS_PU : ( $HAS_PU = _check_PU() ) ) {
            $layer = &quot;:raw:utf8_strict&quot;;
        }
        else {
            $layer = &quot;:raw:encoding(UTF-8)&quot;;
        }
        $self-&gt;filehandle( $args, $v, $layer );
    };
}

#pod =method parent
#pod
#pod     $parent = path(&quot;foo/bar/baz&quot;)-&gt;parent; # foo/bar
#pod     $parent = path(&quot;foo/wibble.txt&quot;)-&gt;parent; # foo
#pod
#pod     $parent = path(&quot;foo/bar/baz&quot;)-&gt;parent(2); # foo
#pod
#pod Returns a C&lt;Path::Tiny&gt; object corresponding to the parent directory of the
#pod original directory or file. An optional positive integer argument is the number
#pod of parent directories upwards to return.  C&lt;parent&gt; by itself is equivalent to
#pod C&lt;parent(1)&gt;.
#pod
#pod Current API available since 0.014.
#pod
#pod =cut

# XXX this is ugly and coverage is incomplete.  I think it's there for windows
# so need to check coverage there and compare
sub parent {
    my ( $self, $level ) = @_;
    $level = 1 unless defined $level &amp;&amp; $level &gt; 0;
    $self-&gt;_splitpath unless defined $self-&gt;[FILE];
    my $parent;
    if ( length $self-&gt;[FILE] ) {
        if ( $self-&gt;[FILE] eq '.' || $self-&gt;[FILE] eq &quot;..&quot; ) {
            $parent = _path( $self-&gt;[PATH] . &quot;/..&quot; );
        }
        else {
            $parent = _path( _non_empty( $self-&gt;[VOL] . $self-&gt;[DIR] ) );
        }
    }
    elsif ( length $self-&gt;[DIR] ) {
        # because of symlinks, any internal updir requires us to
        # just add more updirs at the end
        if ( $self-&gt;[DIR] =~ m{(?:^\.\./|/\.\./|/\.\.\z)} ) {
            $parent = _path( $self-&gt;[VOL] . $self-&gt;[DIR] . &quot;/..&quot; );
        }
        else {
            ( my $dir = $self-&gt;[DIR] ) =~ s{/[^\/]+/\z}{/};
            $parent = _path( $self-&gt;[VOL] . $dir );
        }
    }
    else {
        $parent = _path( _non_empty( $self-&gt;[VOL] ) );
    }
    return $level == 1 ? $parent : $parent-&gt;parent( $level - 1 );
}

sub _non_empty {
    my ($string) = shift;
    return ( ( defined($string) &amp;&amp; length($string) ) ? $string : &quot;.&quot; );
}

#pod =method realpath
#pod
#pod     $real = path(&quot;/baz/foo/../bar&quot;)-&gt;realpath;
#pod     $real = path(&quot;foo/../bar&quot;)-&gt;realpath;
#pod
#pod Returns a new C&lt;Path::Tiny&gt; object with all symbolic links and upward directory
#pod parts resolved using L&lt;Cwd&gt;'s C&lt;realpath&gt;.  Compared to C&lt;absolute&gt;, this is
#pod more expensive as it must actually consult the filesystem.
#pod
#pod If the parent path can't be resolved (e.g. if it includes directories that
#pod don't exist), an exception will be thrown:
#pod
#pod     $real = path(&quot;doesnt_exist/foo&quot;)-&gt;realpath; # dies
#pod
#pod However, if the parent path exists and only the last component (e.g. filename)
#pod doesn't exist, the realpath will be the realpath of the parent plus the
#pod non-existent last component:
#pod
#pod     $real = path(&quot;./aasdlfasdlf&quot;)-&gt;realpath; # works
#pod
#pod The underlying L&lt;Cwd&gt; module usually worked this way on Unix, but died on
#pod Windows (and some Unixes) if the full path didn't exist.  As of version 0.064,
#pod it's safe to use anywhere.
#pod
#pod Current API available since 0.001.
#pod
#pod =cut

# Win32 and some Unixes need parent path resolved separately so realpath
# doesn't throw an error resolving non-existent basename
sub realpath {
    my $self = shift;
    $self = $self-&gt;_resolve_symlinks;
    require Cwd;
    $self-&gt;_splitpath if !defined $self-&gt;[FILE];
    my $check_parent =
      length $self-&gt;[FILE] &amp;&amp; $self-&gt;[FILE] ne '.' &amp;&amp; $self-&gt;[FILE] ne '..';
    my $realpath = eval {
        # pure-perl Cwd can carp
        local $SIG{__WARN__} = sub { };
        Cwd::realpath( $check_parent ? $self-&gt;parent-&gt;[PATH] : $self-&gt;[PATH] );
    };
    # parent realpath must exist; not all Cwd::realpath will error if it doesn't
    $self-&gt;_throw(&quot;resolving realpath&quot;)
      unless defined $realpath &amp;&amp; length $realpath &amp;&amp; -e $realpath;
    return ( $check_parent ? _path( $realpath, $self-&gt;[FILE] ) : _path($realpath) );
}

#pod =method relative
#pod
#pod     $rel = path(&quot;/tmp/foo/bar&quot;)-&gt;relative(&quot;/tmp&quot;); # foo/bar
#pod
#pod Returns a C&lt;Path::Tiny&gt; object with a path relative to a new base path
#pod given as an argument.  If no argument is given, the current directory will
#pod be used as the new base path.
#pod
#pod If either path is already relative, it will be made absolute based on the
#pod current directly before determining the new relative path.
#pod
#pod The algorithm is roughly as follows:
#pod
#pod =for :list
#pod * If the original and new base path are on different volumes, an exception
#pod   will be thrown.
#pod * If the original and new base are identical, the relative path is C&lt;&quot;.&quot;&gt;.
#pod * If the new base subsumes the original, the relative path is the original
#pod   path with the new base chopped off the front
#pod * If the new base does not subsume the original, a common prefix path is
#pod   determined (possibly the root directory) and the relative path will
#pod   consist of updirs (C&lt;&quot;..&quot;&gt;) to reach the common prefix, followed by the
#pod   original path less the common prefix.
#pod
#pod Unlike C&lt;File::Spec::abs2rel&gt;, in the last case above, the calculation based
#pod on a common prefix takes into account symlinks that could affect the updir
#pod process.  Given an original path &quot;/A/B&quot; and a new base &quot;/A/C&quot;,
#pod (where &quot;A&quot;, &quot;B&quot; and &quot;C&quot; could each have multiple path components):
#pod
#pod =for :list
#pod * Symlinks in &quot;A&quot; don't change the result unless the last component of A is
#pod   a symlink and the first component of &quot;C&quot; is an updir.
#pod * Symlinks in &quot;B&quot; don't change the result and will exist in the result as
#pod   given.
#pod * Symlinks and updirs in &quot;C&quot; must be resolved to actual paths, taking into
#pod   account the possibility that not all path components might exist on the
#pod   filesystem.
#pod
#pod Current API available since 0.001.  New algorithm (that accounts for
#pod symlinks) available since 0.079.
#pod
#pod =cut

sub relative {
    my ( $self, $base ) = @_;
    $base = _path( defined $base &amp;&amp; length $base ? $base : '.' );

    # relative paths must be converted to absolute first
    $self = $self-&gt;absolute if $self-&gt;is_relative;
    $base = $base-&gt;absolute if $base-&gt;is_relative;

    # normalize volumes if they exist
    $self = $self-&gt;absolute if !length $self-&gt;volume &amp;&amp; length $base-&gt;volume;
    $base = $base-&gt;absolute if length $self-&gt;volume  &amp;&amp; !length $base-&gt;volume;

    # can't make paths relative across volumes
    if ( !_same( $self-&gt;volume, $base-&gt;volume ) ) {
        Carp::croak(&quot;relative() can't cross volumes: '$self' vs '$base'&quot;);
    }

    # if same absolute path, relative is current directory
    return _path(&quot;.&quot;) if _same( $self-&gt;[PATH], $base-&gt;[PATH] );

    # if base is a prefix of self, chop prefix off self
    if ( $base-&gt;subsumes($self) ) {
        $base = &quot;&quot; if $base-&gt;is_rootdir;
        my $relative = &quot;$self&quot;;
        $relative =~ s{\A\Q$base/}{};
        return _path(&quot;.&quot;, $relative);
    }

    # base is not a prefix, so must find a common prefix (even if root)
    my ( @common, @self_parts, @base_parts );
    @base_parts = split /\//, $base-&gt;_just_filepath;

    # if self is rootdir, then common directory is root (shown as empty
    # string for later joins); otherwise, must be computed from path parts.
    if ( $self-&gt;is_rootdir ) {
        @common = (&quot;&quot;);
        shift @base_parts;
    }
    else {
        @self_parts = split /\//, $self-&gt;_just_filepath;

        while ( @self_parts &amp;&amp; @base_parts &amp;&amp; _same( $self_parts[0], $base_parts[0] ) ) {
            push @common, shift @base_parts;
            shift @self_parts;
        }
    }

    # if there are any symlinks from common to base, we have a problem, as
    # you can't guarantee that updir from base reaches the common prefix;
    # we must resolve symlinks and try again; likewise, any updirs are
    # a problem as it throws off calculation of updirs needed to get from
    # self's path to the common prefix.
    if ( my $new_base = $self-&gt;_resolve_between( \@common, \@base_parts ) ) {
        return $self-&gt;relative($new_base);
    }

    # otherwise, symlinks in common or from common to A don't matter as
    # those don't involve updirs
    my @new_path = ( (&quot;..&quot;) x ( 0+ @base_parts ), @self_parts );
    return _path(@new_path);
}

sub _just_filepath {
    my $self     = shift;
    my $self_vol = $self-&gt;volume;
    return &quot;$self&quot; if !length $self_vol;

    ( my $self_path = &quot;$self&quot; ) =~ s{\A\Q$self_vol}{};

    return $self_path;
}

sub _resolve_between {
    my ( $self, $common, $base ) = @_;
    my $path = $self-&gt;volume . join( &quot;/&quot;, @$common );
    my $changed = 0;
    for my $p (@$base) {
        $path .= &quot;/$p&quot;;
        if ( $p eq '..' ) {
            $changed = 1;
            if ( -e $path ) {
                $path = _path($path)-&gt;realpath-&gt;[PATH];
            }
            else {
                $path =~ s{/[^/]+/..\z}{/};
            }
        }
        if ( -l $path ) {
            $changed = 1;
            $path    = _path($path)-&gt;realpath-&gt;[PATH];
        }
    }
    return $changed ? _path($path) : undef;
}

#pod =method remove
#pod
#pod     path(&quot;foo.txt&quot;)-&gt;remove;
#pod
#pod This is just like C&lt;unlink&gt;, except for its error handling: if the path does
#pod not exist, it returns false; if deleting the file fails, it throws an
#pod exception.
#pod
#pod Current API available since 0.012.
#pod
#pod =cut

sub remove {
    my $self = shift;

    return 0 if !-e $self-&gt;[PATH] &amp;&amp; !-l $self-&gt;[PATH];

    return unlink( $self-&gt;[PATH] ) || $self-&gt;_throw('unlink');
}

#pod =method remove_tree
#pod
#pod     # directory
#pod     path(&quot;foo/bar/baz&quot;)-&gt;remove_tree;
#pod     path(&quot;foo/bar/baz&quot;)-&gt;remove_tree( \%options );
#pod     path(&quot;foo/bar/baz&quot;)-&gt;remove_tree( { safe =&gt; 0 } ); # force remove
#pod
#pod Like calling C&lt;remove_tree&gt; from L&lt;File::Path&gt;, but defaults to C&lt;safe&gt; mode.
#pod An optional hash reference is passed through to C&lt;remove_tree&gt;.  Errors will be
#pod trapped and an exception thrown.  Returns the number of directories deleted,
#pod just like C&lt;remove_tree&gt;.
#pod
#pod If you want to remove a directory only if it is empty, use the built-in
#pod C&lt;rmdir&gt; function instead.
#pod
#pod     rmdir path(&quot;foo/bar/baz/&quot;);
#pod
#pod Current API available since 0.013.
#pod
#pod =cut

sub remove_tree {
    my ( $self, $args ) = @_;
    return 0 if !-e $self-&gt;[PATH] &amp;&amp; !-l $self-&gt;[PATH];
    $args = {} unless ref $args eq 'HASH';
    my $err;
    $args-&gt;{error} = \$err unless defined $args-&gt;{error};
    $args-&gt;{safe}  = 1     unless defined $args-&gt;{safe};
    require File::Path;
    my $count = File::Path::remove_tree( $self-&gt;[PATH], $args );

    if ( $err &amp;&amp; @$err ) {
        my ( $file, $message ) = %{ $err-&gt;[0] };
        Carp::croak(&quot;remove_tree failed for $file: $message&quot;);
    }
    return $count;
}

#pod =method sibling
#pod
#pod     $foo = path(&quot;/tmp/foo.txt&quot;);
#pod     $sib = $foo-&gt;sibling(&quot;bar.txt&quot;);        # /tmp/bar.txt
#pod     $sib = $foo-&gt;sibling(&quot;baz&quot;, &quot;bam.txt&quot;); # /tmp/baz/bam.txt
#pod
#pod Returns a new C&lt;Path::Tiny&gt; object relative to the parent of the original.
#pod This is slightly more efficient than C&lt;&lt; $path-&gt;parent-&gt;child(...) &gt;&gt;.
#pod
#pod Current API available since 0.058.
#pod
#pod =cut

sub sibling {
    my $self = shift;
    return _path( $self-&gt;parent-&gt;[PATH], @_ );
}

#pod =method size, size_human
#pod
#pod     my $p = path(&quot;foo&quot;); # with size 1025 bytes
#pod
#pod     $p-&gt;size;                            # &quot;1025&quot;
#pod     $p-&gt;size_human;                      # &quot;1.1 K&quot;
#pod     $p-&gt;size_human( {format =&gt; &quot;iec&quot;} ); # &quot;1.1 KiB&quot;
#pod
#pod Returns the size of a file.  The C&lt;size&gt; method is just a wrapper around C&lt;-s&gt;.
#pod
#pod The C&lt;size_human&gt; method provides a human-readable string similar to
#pod C&lt;ls -lh&gt;.  Like C&lt;ls&gt;, it rounds upwards and provides one decimal place for
#pod single-digit sizes and no decimal places for larger sizes.  The only available
#pod option is C&lt;format&gt;, which has three valid values:
#pod
#pod =for :list
#pod * 'ls' (the default): base-2 sizes, with C&lt;ls&gt; style single-letter suffixes (K, M, etc.)
#pod * 'iec': base-2 sizes, with IEC binary suffixes (KiB, MiB, etc.)
#pod * 'si': base-10 sizes, with SI decimal suffixes (kB, MB, etc.)
#pod
#pod If C&lt;-s&gt; would return C&lt;undef&gt;, C&lt;size_human&gt; returns the empty string.
#pod
#pod Current API available since 0.122.
#pod
#pod =cut

sub size { -s $_[0]-&gt;[PATH] }

my %formats = (
    'ls'  =&gt; [ 1024, log(1024), [ &quot;&quot;, map { &quot; $_&quot; } qw/K M G T/ ] ],
    'iec' =&gt; [ 1024, log(1024), [ &quot;&quot;, map { &quot; $_&quot; } qw/KiB MiB GiB TiB/ ] ],
    'si'  =&gt; [ 1000, log(1000), [ &quot;&quot;, map { &quot; $_&quot; } qw/kB MB GB TB/ ] ],
);

sub _formats { return $formats{$_[0]} }

sub size_human {
    my $self     = shift;
    my $args     = _get_args( shift, qw/format/ );
    my $format   = defined $args-&gt;{format} ? $args-&gt;{format} : &quot;ls&quot;;
    my $fmt_opts = $formats{$format}
      or Carp::croak(&quot;Invalid format '$format' for size_human()&quot;);
    my $size = -s $self-&gt;[PATH];
    return defined $size ? _human_size( $size, @$fmt_opts ) : &quot;&quot;;
}

sub _ceil {
    return $_[0] == int($_[0]) ? $_[0] : int($_[0]+1);
}

sub _human_size {
    my ( $size, $base, $log_base, $suffixes ) = @_;
    return &quot;0&quot; if $size == 0;

    my $mag = int( log($size) / $log_base );
    $size /= $base**$mag;
    $size =
        $mag == 0               ? $size
      : length( int($size) ) == 1 ? _ceil( $size * 10 ) / 10
      :                             _ceil($size);
    if ( $size &gt;= $base ) {
        $size /= $base;
        $mag++;
    }

    my $fmt = ( $mag == 0 || length( int($size) ) &gt; 1 ) ? &quot;%.0f%s&quot; : &quot;%.1f%s&quot;;
    return sprintf( $fmt, $size, $suffixes-&gt;[$mag] );
}

#pod =method slurp, slurp_raw, slurp_utf8
#pod
#pod     $data = path(&quot;foo.txt&quot;)-&gt;slurp;
#pod     $data = path(&quot;foo.txt&quot;)-&gt;slurp( {binmode =&gt; &quot;:raw&quot;} );
#pod     $data = path(&quot;foo.txt&quot;)-&gt;slurp_raw;
#pod     $data = path(&quot;foo.txt&quot;)-&gt;slurp_utf8;
#pod
#pod Reads file contents into a scalar.  Takes an optional hash reference which may
#pod be used to pass options.  The only available option is C&lt;binmode&gt;, which is
#pod passed to C&lt;binmode()&gt; on the handle used for reading.
#pod
#pod C&lt;slurp_raw&gt; is like C&lt;slurp&gt; with a C&lt;binmode&gt; of C&lt;:unix&gt; for
#pod a fast, unbuffered, raw read.
#pod
#pod C&lt;slurp_utf8&gt; is like C&lt;slurp&gt; with a C&lt;binmode&gt; of
#pod C&lt;:unix:encoding(UTF-8)&gt; (or C&lt;:unix:utf8_strict&gt; with
#pod L&lt;PerlIO::utf8_strict&gt;).  If L&lt;Unicode::UTF8&gt; 0.58+ is installed, a
#pod unbuffered, raw slurp will be done instead and the result decoded with
#pod C&lt;Unicode::UTF8&gt;. This is just as strict and is roughly an order of
#pod magnitude faster than using C&lt;:encoding(UTF-8)&gt;.
#pod
#pod B&lt;Note&gt;: C&lt;slurp&gt; and friends lock the filehandle before slurping.  If
#pod you plan to slurp from a file created with L&lt;File::Temp&gt;, be sure to
#pod close other handles or open without locking to avoid a deadlock:
#pod
#pod     my $tempfile = File::Temp-&gt;new(EXLOCK =&gt; 0);
#pod     my $guts = path($tempfile)-&gt;slurp;
#pod
#pod Current API available since 0.004.
#pod
#pod =cut

sub slurp {
    my $self    = shift;
    my $args    = _get_args( shift, qw/binmode/ );
    my $binmode = $args-&gt;{binmode};
    $binmode = ( ( caller(0) )[10] || {} )-&gt;{'open&lt;'} unless defined $binmode;
    my $fh = $self-&gt;filehandle( { locked =&gt; 1 }, &quot;&lt;&quot;, $binmode );
    if ( ( defined($binmode) ? $binmode : &quot;&quot; ) eq &quot;:unix&quot;
        and my $size = -s $fh )
    {
        my $buf;
        my $rc = read $fh, $buf, $size; # File::Slurp in a nutshell
        $self-&gt;_throw('read') unless defined $rc;
        return $buf;
    }
    else {
        local $/;
        my $buf = scalar &lt;$fh&gt;;
        $self-&gt;_throw('read') unless defined $buf;
        return $buf;
    }
}

sub slurp_raw { $_[1] = { binmode =&gt; &quot;:unix&quot; }; goto &amp;slurp }

sub slurp_utf8 {
    if ( defined($HAS_UU) ? $HAS_UU : ( $HAS_UU = _check_UU() ) ) {
        return Unicode::UTF8::decode_utf8( slurp( $_[0], { binmode =&gt; &quot;:unix&quot; } ) );
    }
    elsif ( defined($HAS_PU) ? $HAS_PU : ( $HAS_PU = _check_PU() ) ) {
        $_[1] = { binmode =&gt; &quot;:unix:utf8_strict&quot; };
        goto &amp;slurp;
    }
    else {
        $_[1] = { binmode =&gt; &quot;:unix:encoding(UTF-8)&quot; };
        goto &amp;slurp;
    }
}

#pod =method spew, spew_raw, spew_utf8
#pod
#pod     path(&quot;foo.txt&quot;)-&gt;spew(@data);
#pod     path(&quot;foo.txt&quot;)-&gt;spew(\@data);
#pod     path(&quot;foo.txt&quot;)-&gt;spew({binmode =&gt; &quot;:raw&quot;}, @data);
#pod     path(&quot;foo.txt&quot;)-&gt;spew_raw(@data);
#pod     path(&quot;foo.txt&quot;)-&gt;spew_utf8(@data);
#pod
#pod Writes data to a file atomically.  The file is written to a temporary file in
#pod the same directory, then renamed over the original.  An optional hash reference
#pod may be used to pass options.  The only option is C&lt;binmode&gt;, which is passed to
#pod C&lt;binmode()&gt; on the handle used for writing.
#pod
#pod C&lt;spew_raw&gt; is like C&lt;spew&gt; with a C&lt;binmode&gt; of C&lt;:unix&gt; for a fast,
#pod unbuffered, raw write.
#pod
#pod C&lt;spew_utf8&gt; is like C&lt;spew&gt; with a C&lt;binmode&gt; of C&lt;:unix:encoding(UTF-8)&gt;
#pod (or C&lt;:unix:utf8_strict&gt; with L&lt;PerlIO::utf8_strict&gt;).  If L&lt;Unicode::UTF8&gt;
#pod 0.58+ is installed, a raw, unbuffered spew will be done instead on the data
#pod encoded with C&lt;Unicode::UTF8&gt;.
#pod
#pod B&lt;NOTE&gt;: because the file is written to a temporary file and then renamed, the
#pod new file will wind up with permissions based on your current umask.  This is a
#pod feature to protect you from a race condition that would otherwise give
#pod different permissions than you might expect.  If you really want to keep the
#pod original mode flags, use L&lt;/append&gt; with the C&lt;truncate&gt; option.
#pod
#pod Current API available since 0.011.
#pod
#pod =cut

sub spew {
    my ( $self, @data ) = @_;
    my $args = ( @data &amp;&amp; ref $data[0] eq 'HASH' ) ? shift @data : {};
    $args = _get_args( $args, qw/binmode/ );
    my $binmode = $args-&gt;{binmode};
    # get default binmode from caller's lexical scope (see &quot;perldoc open&quot;)
    $binmode = ( ( caller(0) )[10] || {} )-&gt;{'open&gt;'} unless defined $binmode;

    # writing needs to follow the link and create the tempfile in the same
    # dir for later atomic rename
    my $resolved_path = $self-&gt;_resolve_symlinks;
    my $temp          = $resolved_path-&gt;_replacment_path;

    my $fh;
    my $ok = eval { $fh = $temp-&gt;filehandle( { exclusive =&gt; 1, locked =&gt; 1 }, &quot;&gt;&quot;, $binmode ); 1 };
    if (!$ok) {
        my $msg = ref($@) eq 'Path::Tiny::Error'
            ? &quot;error opening temp file '$@-&gt;{file}' for atomic write: $@-&gt;{err}&quot;
            : &quot;error opening temp file for atomic write: $@&quot;;
        $self-&gt;_throw('spew', $self-&gt;[PATH], $msg);
    }
    print( {$fh} map { ref eq 'ARRAY' ? @$_ : $_ } @data) or self-&gt;_throw('print', $temp-&gt;[PATH]);
    close $fh or $self-&gt;_throw( 'close', $temp-&gt;[PATH] );

    return $temp-&gt;move($resolved_path);
}

sub spew_raw { splice @_, 1, 0, { binmode =&gt; &quot;:unix&quot; }; goto &amp;spew }

sub spew_utf8 {
    if ( defined($HAS_UU) ? $HAS_UU : ( $HAS_UU = _check_UU() ) ) {
        my $self = shift;
        spew(
            $self,
            { binmode =&gt; &quot;:unix&quot; },
            map { Unicode::UTF8::encode_utf8($_) } map { ref eq 'ARRAY' ? @$_ : $_ } @_
        );
    }
    elsif ( defined($HAS_PU) ? $HAS_PU : ( $HAS_PU = _check_PU() ) ) {
        splice @_, 1, 0, { binmode =&gt; &quot;:unix:utf8_strict&quot; };
        goto &amp;spew;
    }
    else {
        splice @_, 1, 0, { binmode =&gt; &quot;:unix:encoding(UTF-8)&quot; };
        goto &amp;spew;
    }
}

#pod =method stat, lstat
#pod
#pod     $stat = path(&quot;foo.txt&quot;)-&gt;stat;
#pod     $stat = path(&quot;/some/symlink&quot;)-&gt;lstat;
#pod
#pod Like calling C&lt;stat&gt; or C&lt;lstat&gt; from L&lt;File::stat&gt;.
#pod
#pod Current API available since 0.001.
#pod
#pod =cut

# XXX break out individual stat() components as subs?
sub stat {
    my $self = shift;
    require File::stat;
    return File::stat::stat( $self-&gt;[PATH] ) || $self-&gt;_throw('stat');
}

sub lstat {
    my $self = shift;
    require File::stat;
    return File::stat::lstat( $self-&gt;[PATH] ) || $self-&gt;_throw('lstat');
}

#pod =method stringify
#pod
#pod     $path = path(&quot;foo.txt&quot;);
#pod     say $path-&gt;stringify; # same as &quot;$path&quot;
#pod
#pod Returns a string representation of the path.  Unlike C&lt;canonpath&gt;, this method
#pod returns the path standardized with Unix-style C&lt;/&gt; directory separators.
#pod
#pod Current API available since 0.001.
#pod
#pod =cut

sub stringify { $_[0]-&gt;[PATH] =~ /^~/ ? './' . $_[0]-&gt;[PATH] : $_[0]-&gt;[PATH] }

#pod =method subsumes
#pod
#pod     path(&quot;foo/bar&quot;)-&gt;subsumes(&quot;foo/bar/baz&quot;); # true
#pod     path(&quot;/foo/bar&quot;)-&gt;subsumes(&quot;/foo/baz&quot;);   # false
#pod
#pod Returns true if the first path is a prefix of the second path at a directory
#pod boundary.
#pod
#pod This B&lt;does not&gt; resolve parent directory entries (C&lt;..&gt;) or symlinks:
#pod
#pod     path(&quot;foo/bar&quot;)-&gt;subsumes(&quot;foo/bar/../baz&quot;); # true
#pod
#pod If such things are important to you, ensure that both paths are resolved to
#pod the filesystem with C&lt;realpath&gt;:
#pod
#pod     my $p1 = path(&quot;foo/bar&quot;)-&gt;realpath;
#pod     my $p2 = path(&quot;foo/bar/../baz&quot;)-&gt;realpath;
#pod     if ( $p1-&gt;subsumes($p2) ) { ... }
#pod
#pod Current API available since 0.048.
#pod
#pod =cut

sub subsumes {
    my $self = shift;
    Carp::croak(&quot;subsumes() requires a defined, positive-length argument&quot;)
      unless defined $_[0];
    my $other = _path(shift);

    # normalize absolute vs relative
    if ( $self-&gt;is_absolute &amp;&amp; !$other-&gt;is_absolute ) {
        $other = $other-&gt;absolute;
    }
    elsif ( $other-&gt;is_absolute &amp;&amp; !$self-&gt;is_absolute ) {
        $self = $self-&gt;absolute;
    }

    # normalize volume vs non-volume; do this after absolute path
    # adjustments above since that might add volumes already
    if ( length $self-&gt;volume &amp;&amp; !length $other-&gt;volume ) {
        $other = $other-&gt;absolute;
    }
    elsif ( length $other-&gt;volume &amp;&amp; !length $self-&gt;volume ) {
        $self = $self-&gt;absolute;
    }

    if ( $self-&gt;[PATH] eq '.' ) {
        return !!1; # cwd subsumes everything relative
    }
    elsif ( $self-&gt;is_rootdir ) {
        # a root directory (&quot;/&quot;, &quot;c:/&quot;) already ends with a separator
        return $other-&gt;[PATH] =~ m{^\Q$self-&gt;[PATH]\E};
    }
    else {
        # exact match or prefix breaking at a separator
        return $other-&gt;[PATH] =~ m{^\Q$self-&gt;[PATH]\E(?:/|\z)};
    }
}

#pod =method touch
#pod
#pod     path(&quot;foo.txt&quot;)-&gt;touch;
#pod     path(&quot;foo.txt&quot;)-&gt;touch($epoch_secs);
#pod
#pod Like the Unix C&lt;touch&gt; utility.  Creates the file if it doesn't exist, or else
#pod changes the modification and access times to the current time.  If the first
#pod argument is the epoch seconds then it will be used.
#pod
#pod Returns the path object so it can be easily chained with other methods:
#pod
#pod     # won't die if foo.txt doesn't exist
#pod     $content = path(&quot;foo.txt&quot;)-&gt;touch-&gt;slurp;
#pod
#pod Current API available since 0.015.
#pod
#pod =cut

sub touch {
    my ( $self, $epoch ) = @_;
    if ( !-e $self-&gt;[PATH] ) {
        my $fh = $self-&gt;openw;
        close $fh or $self-&gt;_throw('close');
    }
    if ( defined $epoch ) {
        utime $epoch, $epoch, $self-&gt;[PATH]
          or $self-&gt;_throw(&quot;utime ($epoch)&quot;);
    }
    else {
        # literal undef prevents warnings :-(
        utime undef, undef, $self-&gt;[PATH]
          or $self-&gt;_throw(&quot;utime ()&quot;);
    }
    return $self;
}

#pod =method touchpath
#pod
#pod     path(&quot;bar/baz/foo.txt&quot;)-&gt;touchpath;
#pod
#pod Combines C&lt;mkdir&gt; and C&lt;touch&gt;.  Creates the parent directory if it doesn't exist,
#pod before touching the file.  Returns the path object like C&lt;touch&gt; does.
#pod
#pod If you need to pass options, use C&lt;mkdir&gt; and C&lt;touch&gt; separately:
#pod
#pod     path(&quot;bar/baz&quot;)-&gt;mkdir( \%options )-&gt;child(&quot;foo.txt&quot;)-&gt;touch($epoch_secs);
#pod
#pod Current API available since 0.022.
#pod
#pod =cut

sub touchpath {
    my ($self) = @_;
    my $parent = $self-&gt;parent;
    $parent-&gt;mkdir unless $parent-&gt;exists;
    $self-&gt;touch;
}

#pod =method visit
#pod
#pod     path(&quot;/tmp&quot;)-&gt;visit( \&amp;callback, \%options );
#pod
#pod Executes a callback for each child of a directory.  It returns a hash
#pod reference with any state accumulated during iteration.
#pod
#pod The options are the same as for L&lt;/iterator&gt; (which it uses internally):
#pod C&lt;recurse&gt; and C&lt;follow_symlinks&gt;.  Both default to false.
#pod
#pod The callback function will receive a C&lt;Path::Tiny&gt; object as the first argument
#pod and a hash reference to accumulate state as the second argument.  For example:
#pod
#pod     # collect files sizes
#pod     my $sizes = path(&quot;/tmp&quot;)-&gt;visit(
#pod         sub {
#pod             my ($path, $state) = @_;
#pod             return if $path-&gt;is_dir;
#pod             $state-&gt;{$path} = -s $path;
#pod         },
#pod         { recurse =&gt; 1 }
#pod     );
#pod
#pod For convenience, the C&lt;Path::Tiny&gt; object will also be locally aliased as the
#pod C&lt;$_&gt; global variable:
#pod
#pod     # print paths matching /foo/
#pod     path(&quot;/tmp&quot;)-&gt;visit( sub { say if /foo/ }, { recurse =&gt; 1} );
#pod
#pod If the callback returns a B&lt;reference&gt; to a false scalar value, iteration will
#pod terminate.  This is not the same as &quot;pruning&quot; a directory search; this just
#pod stops all iteration and returns the state hash reference.
#pod
#pod     # find up to 10 files larger than 100K
#pod     my $files = path(&quot;/tmp&quot;)-&gt;visit(
#pod         sub {
#pod             my ($path, $state) = @_;
#pod             $state-&gt;{$path}++ if -s $path &gt; 102400
#pod             return \0 if keys %$state == 10;
#pod         },
#pod         { recurse =&gt; 1 }
#pod     );
#pod
#pod If you want more flexible iteration, use a module like L&lt;Path::Iterator::Rule&gt;.
#pod
#pod Current API available since 0.062.
#pod
#pod =cut

sub visit {
    my $self = shift;
    my $cb   = shift;
    my $args = _get_args( shift, qw/recurse follow_symlinks/ );
    Carp::croak(&quot;Callback for visit() must be a code reference&quot;)
      unless defined($cb) &amp;&amp; ref($cb) eq 'CODE';
    my $next  = $self-&gt;iterator($args);
    my $state = {};
    while ( my $file = $next-&gt;() ) {
        local $_ = $file;
        my $r = $cb-&gt;( $file, $state );
        last if ref($r) eq 'SCALAR' &amp;&amp; !$$r;
    }
    return $state;
}

#pod =method volume
#pod
#pod     $vol = path(&quot;/tmp/foo.txt&quot;)-&gt;volume;   # &quot;&quot;
#pod     $vol = path(&quot;C:/tmp/foo.txt&quot;)-&gt;volume; # &quot;C:&quot;
#pod
#pod Returns the volume portion of the path.  This is equivalent
#pod to what L&lt;File::Spec&gt; would give from C&lt;splitpath&gt; and thus
#pod usually is the empty string on Unix-like operating systems or the
#pod drive letter for an absolute path on C&lt;MSWin32&gt;.
#pod
#pod Current API available since 0.001.
#pod
#pod =cut

sub volume {
    my ($self) = @_;
    $self-&gt;_splitpath unless defined $self-&gt;[VOL];
    return $self-&gt;[VOL];
}

package Path::Tiny::Error;

our @CARP_NOT = qw/Path::Tiny/;

use overload ( q{&quot;&quot;} =&gt; sub { (shift)-&gt;{msg} }, fallback =&gt; 1 );

sub throw {
    my ( $class, $op, $file, $err ) = @_;
    chomp( my $trace = Carp::shortmess );
    my $msg = &quot;Error $op on '$file': $err$trace\n&quot;;
    die bless { op =&gt; $op, file =&gt; $file, err =&gt; $err, msg =&gt; $msg }, $class;
}

1;


# vim: ts=4 sts=4 sw=4 et:

__END__

=pod

=encoding UTF-8

=head1 NAME

Path::Tiny - File path utility

=head1 VERSION

version 0.146

=head1 SYNOPSIS

  use Path::Tiny;

  # Creating Path::Tiny objects

  my $dir = path(&quot;/tmp&quot;);
  my $foo = path(&quot;foo.txt&quot;);

  my $subdir = $dir-&gt;child(&quot;foo&quot;);
  my $bar = $subdir-&gt;child(&quot;bar.txt&quot;);

  # Stringifies as cleaned up path

  my $file = path(&quot;./foo.txt&quot;);
  print $file; # &quot;foo.txt&quot;

  # Reading files

  my $guts = $file-&gt;slurp;
     $guts = $file-&gt;slurp_utf8;

  my @lines = $file-&gt;lines;
     @lines = $file-&gt;lines_utf8;

  my ($head) = $file-&gt;lines( {count =&gt; 1} );
  my ($tail) = $file-&gt;lines( {count =&gt; -1} );

  # Writing files

  $bar-&gt;spew( @data );
  $bar-&gt;spew_utf8( @data );

  # Reading directories

  for ( $dir-&gt;children ) { ... }

  my $iter = $dir-&gt;iterator;
  while ( my $next = $iter-&gt;() ) { ... }

=head1 DESCRIPTION

This module provides a small, fast utility for working with file paths.  It is
friendlier to use than L&lt;File::Spec&gt; and provides easy access to functions from
several other core file handling modules.  It aims to be smaller and faster
than many alternatives on CPAN, while helping people do many common things in
consistent and less error-prone ways.

Path::Tiny does not try to work for anything except Unix-like and Win32
platforms.  Even then, it might break if you try something particularly obscure
or tortuous.  (Quick!  What does this mean:
C&lt;&lt; ///../../..//./././a//b/.././c/././ &gt;&gt;?  And how does it differ on Win32?)

All paths are forced to have Unix-style forward slashes.  Stringifying
the object gives you back the path (after some clean up).

File input/output methods C&lt;flock&gt; handles before reading or writing,
as appropriate (if supported by the platform and/or filesystem).

The C&lt;*_utf8&gt; methods (C&lt;slurp_utf8&gt;, C&lt;lines_utf8&gt;, etc.) operate in raw
mode.  On Windows, that means they will not have CRLF translation from the
C&lt;:crlf&gt; IO layer.  Installing L&lt;Unicode::UTF8&gt; 0.58 or later will speed up
C&lt;*_utf8&gt; situations in many cases and is highly recommended.
Alternatively, installing L&lt;PerlIO::utf8_strict&gt; 0.003 or later will be
used in place of the default C&lt;:encoding(UTF-8)&gt;.

This module depends heavily on PerlIO layers for correct operation and thus
requires Perl 5.008001 or later.

=head1 CONSTRUCTORS

=head2 path

    $path = path(&quot;foo/bar&quot;);
    $path = path(&quot;/tmp&quot;, &quot;file.txt&quot;); # list
    $path = path(&quot;.&quot;);                # cwd

Constructs a C&lt;Path::Tiny&gt; object.  It doesn't matter if you give a file or
directory path.  It's still up to you to call directory-like methods only on
directories and file-like methods only on files.  This function is exported
automatically by default.

The first argument must be defined and have non-zero length or an exception
will be thrown.  This prevents subtle, dangerous errors with code like
C&lt;&lt; path( maybe_undef() )-&gt;remove_tree &gt;&gt;.

B&lt;DEPRECATED&gt;: If and only if the B&lt;first&gt; character of the B&lt;first&gt; argument
to C&lt;path&gt; is a tilde ('~'), then tilde replacement will be applied to the
first path segment. A single tilde will be replaced with C&lt;glob('~')&gt; and a
tilde followed by a username will be replaced with output of
C&lt;glob('~username')&gt;. B&lt;No other method does tilde expansion on its arguments&gt;.
See L&lt;/Tilde expansion (deprecated)&gt; for more.

On Windows, if the path consists of a drive identifier without a path component
(C&lt;C:&gt; or C&lt;D:&gt;), it will be expanded to the absolute path of the current
directory on that volume using C&lt;Cwd::getdcwd()&gt;.

If called with a single C&lt;Path::Tiny&gt; argument, the original is returned unless
the original is holding a temporary file or directory reference in which case a
stringified copy is made.

    $path = path(&quot;foo/bar&quot;);
    $temp = Path::Tiny-&gt;tempfile;

    $p2 = path($path); # like $p2 = $path
    $t2 = path($temp); # like $t2 = path( &quot;$temp&quot; )

This optimizes copies without proliferating references unexpectedly if a copy is
made by code outside your control.

Current API available since 0.017.

=head2 new

    $path = Path::Tiny-&gt;new(&quot;foo/bar&quot;);

This is just like C&lt;path&gt;, but with method call overhead.  (Why would you
do that?)

Current API available since 0.001.

=head2 cwd

    $path = Path::Tiny-&gt;cwd; # path( Cwd::getcwd )
    $path = cwd; # optional export

Gives you the absolute path to the current directory as a C&lt;Path::Tiny&gt; object.
This is slightly faster than C&lt;&lt; path(&quot;.&quot;)-&gt;absolute &gt;&gt;.

C&lt;cwd&gt; may be exported on request and used as a function instead of as a
method.

Current API available since 0.018.

=head2 rootdir

    $path = Path::Tiny-&gt;rootdir; # /
    $path = rootdir;             # optional export 

Gives you C&lt;&lt; File::Spec-&gt;rootdir &gt;&gt; as a C&lt;Path::Tiny&gt; object if you're too
picky for C&lt;path(&quot;/&quot;)&gt;.

C&lt;rootdir&gt; may be exported on request and used as a function instead of as a
method.

Current API available since 0.018.

=head2 tempfile, tempdir

    $temp = Path::Tiny-&gt;tempfile( @options );
    $temp = Path::Tiny-&gt;tempdir( @options );
    $temp = $dirpath-&gt;tempfile( @options );
    $temp = $dirpath-&gt;tempdir( @options );
    $temp = tempfile( @options ); # optional export
    $temp = tempdir( @options );  # optional export

C&lt;tempfile&gt; passes the options to C&lt;&lt; File::Temp-&gt;new &gt;&gt; and returns a
C&lt;Path::Tiny&gt; object with the file name.  The C&lt;TMPDIR&gt; option will be enabled
by default, but you can override that by passing C&lt;&lt; TMPDIR =&gt; 0 &gt;&gt; along with
the options.  (If you use an absolute C&lt;TEMPLATE&gt; option, you will want to
disable C&lt;TMPDIR&gt;.)

The resulting C&lt;File::Temp&gt; object is cached. When the C&lt;Path::Tiny&gt; object is
destroyed, the C&lt;File::Temp&gt; object will be as well.

C&lt;File::Temp&gt; annoyingly requires you to specify a custom template in slightly
different ways depending on which function or method you call, but
C&lt;Path::Tiny&gt; lets you ignore that and can take either a leading template or a
C&lt;TEMPLATE&gt; option and does the right thing.

    $temp = Path::Tiny-&gt;tempfile( &quot;customXXXXXXXX&quot; );             # ok
    $temp = Path::Tiny-&gt;tempfile( TEMPLATE =&gt; &quot;customXXXXXXXX&quot; ); # ok

The tempfile path object will be normalized to have an absolute path, even if
created in a relative directory using C&lt;DIR&gt;.  If you want it to have
the C&lt;realpath&gt; instead, pass a leading options hash like this:

    $real_temp = tempfile({realpath =&gt; 1}, @options);

C&lt;tempdir&gt; is just like C&lt;tempfile&gt;, except it calls
C&lt;&lt; File::Temp-&gt;newdir &gt;&gt; instead.

Both C&lt;tempfile&gt; and C&lt;tempdir&gt; may be exported on request and used as
functions instead of as methods.

The methods can be called on an instances representing a
directory. In this case, the directory is used as the base to create the
temporary file/directory, setting the C&lt;DIR&gt; option in File::Temp.

    my $target_dir = path('/to/destination');
    my $tempfile = $target_dir-&gt;tempfile('foobarXXXXXX');
    $tempfile-&gt;spew('A lot of data...');  # not atomic
    $tempfile-&gt;move($target_dir-&gt;child('foobar')); # hopefully atomic

In this case, any value set for option C&lt;DIR&gt; is ignored.

B&lt;Note&gt;: for tempfiles, the filehandles from File::Temp are closed and not
reused.  This is not as secure as using File::Temp handles directly, but is
less prone to deadlocks or access problems on some platforms.  Think of what
C&lt;Path::Tiny&gt; gives you to be just a temporary file B&lt;name&gt; that gets cleaned
up.

B&lt;Note 2&gt;: if you don't want these cleaned up automatically when the object
is destroyed, File::Temp requires different options for directories and
files.  Use C&lt;&lt; CLEANUP =&gt; 0 &gt;&gt; for directories and C&lt;&lt; UNLINK =&gt; 0 &gt;&gt; for
files.

B&lt;Note 3&gt;: Don't lose the temporary object by chaining a method call instead
of storing it:

    my $lost = tempdir()-&gt;child(&quot;foo&quot;); # tempdir cleaned up right away

B&lt;Note 4&gt;: The cached object may be accessed with the L&lt;/cached_temp&gt; method.
Keeping a reference to, or modifying the cached object may break the
behavior documented above and is not supported.  Use at your own risk.

Current API available since 0.119.

=head1 METHODS

=head2 absolute

    $abs = path(&quot;foo/bar&quot;)-&gt;absolute;
    $abs = path(&quot;foo/bar&quot;)-&gt;absolute(&quot;/tmp&quot;);

Returns a new C&lt;Path::Tiny&gt; object with an absolute path (or itself if already
absolute).  If no argument is given, the current directory is used as the
absolute base path.  If an argument is given, it will be converted to an
absolute path (if it is not already) and used as the absolute base path.

This will not resolve upward directories (&quot;foo/../bar&quot;) unless C&lt;canonpath&gt;
in L&lt;File::Spec&gt; would normally do so on your platform.  If you need them
resolved, you must call the more expensive C&lt;realpath&gt; method instead.

On Windows, an absolute path without a volume component will have it added
based on the current drive.

Current API available since 0.101.

=head2 append, append_raw, append_utf8

    path(&quot;foo.txt&quot;)-&gt;append(@data);
    path(&quot;foo.txt&quot;)-&gt;append(\@data);
    path(&quot;foo.txt&quot;)-&gt;append({binmode =&gt; &quot;:raw&quot;}, @data);
    path(&quot;foo.txt&quot;)-&gt;append_raw(@data);
    path(&quot;foo.txt&quot;)-&gt;append_utf8(@data);

Appends data to a file.  The file is locked with C&lt;flock&gt; prior to writing
and closed afterwards.  An optional hash reference may be used to pass
options.  Valid options are:

=over 4

=item *

C&lt;binmode&gt;: passed to C&lt;binmode()&gt; on the handle used for writing.

=item *

C&lt;truncate&gt;: truncates the file after locking and before appending

=back

The C&lt;truncate&gt; option is a way to replace the contents of a file
B&lt;in place&gt;, unlike L&lt;/spew&gt; which writes to a temporary file and then
replaces the original (if it exists).

C&lt;append_raw&gt; is like C&lt;append&gt; with a C&lt;binmode&gt; of C&lt;:unix&gt; for a fast,
unbuffered, raw write.

C&lt;append_utf8&gt; is like C&lt;append&gt; with an unbuffered C&lt;binmode&gt;
C&lt;:unix:encoding(UTF-8)&gt; (or C&lt;:unix:utf8_strict&gt; with
L&lt;PerlIO::utf8_strict&gt;).  If L&lt;Unicode::UTF8&gt; 0.58+ is installed, an
unbuffered, raw append will be done instead on the data encoded with
C&lt;Unicode::UTF8&gt;.

Current API available since 0.060.

=head2 assert

    $path = path(&quot;foo.txt&quot;)-&gt;assert( sub { $_-&gt;exists } );

Returns the invocant after asserting that a code reference argument returns
true.  When the assertion code reference runs, it will have the invocant
object in the C&lt;$_&gt; variable.  If it returns false, an exception will be
thrown.  The assertion code reference may also throw its own exception.

If no assertion is provided, the invocant is returned without error.

Current API available since 0.062.

=head2 basename

    $name = path(&quot;foo/bar.txt&quot;)-&gt;basename;        # bar.txt
    $name = path(&quot;foo.txt&quot;)-&gt;basename('.txt');    # foo
    $name = path(&quot;foo.txt&quot;)-&gt;basename(qr/.txt/);  # foo
    $name = path(&quot;foo.txt&quot;)-&gt;basename(@suffixes);

Returns the file portion or last directory portion of a path.

Given a list of suffixes as strings or regular expressions, any that match at
the end of the file portion or last directory portion will be removed before
the result is returned.

Current API available since 0.054.

=head2 canonpath

    $canonical = path(&quot;foo/bar&quot;)-&gt;canonpath; # foo\bar on Windows

Returns a string with the canonical format of the path name for
the platform.  In particular, this means directory separators
will be C&lt;\&gt; on Windows.

Current API available since 0.001.

=head2 cached_temp

Returns the cached C&lt;File::Temp&gt; or C&lt;File::Temp::Dir&gt; object if the
C&lt;Path::Tiny&gt; object was created with C&lt;/tempfile&gt; or C&lt;/tempdir&gt;.
If there is no such object, this method throws.

B&lt;WARNING&gt;: Keeping a reference to, or modifying the cached object may
break the behavior documented for temporary files and directories created
with C&lt;Path::Tiny&gt; and is not supported.  Use at your own risk.

Current API available since 0.101.

=head2 child

    $file = path(&quot;/tmp&quot;)-&gt;child(&quot;foo.txt&quot;); # &quot;/tmp/foo.txt&quot;
    $file = path(&quot;/tmp&quot;)-&gt;child(@parts);

Returns a new C&lt;Path::Tiny&gt; object relative to the original.  Works
like C&lt;catfile&gt; or C&lt;catdir&gt; from File::Spec, but without caring about
file or directories.

B&lt;WARNING&gt;: because the argument could contain C&lt;..&gt; or refer to symlinks,
there is no guarantee that the new path refers to an actual descendent of
the original.  If this is important to you, transform parent and child with
L&lt;/realpath&gt; and check them with L&lt;/subsumes&gt;.

Current API available since 0.001.

=head2 children

    @paths = path(&quot;/tmp&quot;)-&gt;children;
    @paths = path(&quot;/tmp&quot;)-&gt;children( qr/\.txt\z/ );

Returns a list of C&lt;Path::Tiny&gt; objects for all files and directories
within a directory.  Excludes &quot;.&quot; and &quot;..&quot; automatically.

If an optional C&lt;qr//&gt; argument is provided, it only returns objects for child
names that match the given regular expression.  Only the base name is used
for matching:

    @paths = path(&quot;/tmp&quot;)-&gt;children( qr/^foo/ );
    # matches children like the glob foo*

Current API available since 0.028.

=head2 chmod

    path(&quot;foo.txt&quot;)-&gt;chmod(0777);
    path(&quot;foo.txt&quot;)-&gt;chmod(&quot;0755&quot;);
    path(&quot;foo.txt&quot;)-&gt;chmod(&quot;go-w&quot;);
    path(&quot;foo.txt&quot;)-&gt;chmod(&quot;a=r,u+wx&quot;);

Sets file or directory permissions.  The argument can be a numeric mode, a
octal string beginning with a &quot;0&quot; or a limited subset of the symbolic mode use
by F&lt;/bin/chmod&gt;.

The symbolic mode must be a comma-delimited list of mode clauses.  Clauses must
match C&lt;&lt; qr/\A([augo]+)([=+-])([rwx]+)\z/ &gt;&gt;, which defines &quot;who&quot;, &quot;op&quot; and
&quot;perms&quot; parameters for each clause.  Unlike F&lt;/bin/chmod&gt;, all three parameters
are required for each clause, multiple ops are not allowed and permissions
C&lt;stugoX&gt; are not supported.  (See L&lt;File::chmod&gt; for more complex needs.)

Current API available since 0.053.

=head2 copy

    path(&quot;/tmp/foo.txt&quot;)-&gt;copy(&quot;/tmp/bar.txt&quot;);

Copies the current path to the given destination using L&lt;File::Copy&gt;'s
C&lt;copy&gt; function. Upon success, returns the C&lt;Path::Tiny&gt; object for the
newly copied file.

Current API available since 0.070.

=head2 digest

    $obj = path(&quot;/tmp/foo.txt&quot;)-&gt;digest;        # SHA-256
    $obj = path(&quot;/tmp/foo.txt&quot;)-&gt;digest(&quot;MD5&quot;); # user-selected
    $obj = path(&quot;/tmp/foo.txt&quot;)-&gt;digest( { chunk_size =&gt; 1e6 }, &quot;MD5&quot; );

Returns a hexadecimal digest for a file.  An optional hash reference of options may
be given.  The only option is C&lt;chunk_size&gt;.  If C&lt;chunk_size&gt; is given, that many
bytes will be read at a time.  If not provided, the entire file will be slurped
into memory to compute the digest.

Any subsequent arguments are passed to the constructor for L&lt;Digest&gt; to select
an algorithm.  If no arguments are given, the default is SHA-256.

Current API available since 0.056.

=head2 dirname (deprecated)

    $name = path(&quot;/tmp/foo.txt&quot;)-&gt;dirname; # &quot;/tmp/&quot;

Returns the directory portion you would get from calling
C&lt;&lt; File::Spec-&gt;splitpath( $path-&gt;stringify ) &gt;&gt; or C&lt;&quot;.&quot;&gt; for a path without a
parent directory portion.  Because L&lt;File::Spec&gt; is inconsistent, the result
might or might not have a trailing slash.  Because of this, this method is
B&lt;deprecated&gt;.

A better, more consistently approach is likely C&lt;&lt; $path-&gt;parent-&gt;stringify &gt;&gt;,
which will not have a trailing slash except for a root directory.

Deprecated in 0.056.

=head2 edit, edit_raw, edit_utf8

    path(&quot;foo.txt&quot;)-&gt;edit( \&amp;callback, $options );
    path(&quot;foo.txt&quot;)-&gt;edit_utf8( \&amp;callback );
    path(&quot;foo.txt&quot;)-&gt;edit_raw( \&amp;callback );

These are convenience methods that allow &quot;editing&quot; a file using a single
callback argument. They slurp the file using C&lt;slurp&gt;, place the contents
inside a localized C&lt;$_&gt; variable, call the callback function (without
arguments), and then write C&lt;$_&gt; (presumably mutated) back to the
file with C&lt;spew&gt;.

An optional hash reference may be used to pass options.  The only option is
C&lt;binmode&gt;, which is passed to C&lt;slurp&gt; and C&lt;spew&gt;.

C&lt;edit_utf8&gt; and C&lt;edit_raw&gt; act like their respective C&lt;slurp_*&gt; and
C&lt;spew_*&gt; methods.

Current API available since 0.077.

=head2 edit_lines, edit_lines_utf8, edit_lines_raw

    path(&quot;foo.txt&quot;)-&gt;edit_lines( \&amp;callback, $options );
    path(&quot;foo.txt&quot;)-&gt;edit_lines_utf8( \&amp;callback );
    path(&quot;foo.txt&quot;)-&gt;edit_lines_raw( \&amp;callback );

These are convenience methods that allow &quot;editing&quot; a file's lines using a
single callback argument.  They iterate over the file: for each line, the
line is put into a localized C&lt;$_&gt; variable, the callback function is
executed (without arguments) and then C&lt;$_&gt; is written to a temporary file.
When iteration is finished, the temporary file is atomically renamed over
the original.

An optional hash reference may be used to pass options.  The only option is
C&lt;binmode&gt;, which is passed to the method that open handles for reading and
writing.

C&lt;edit_lines_raw&gt; is like C&lt;edit_lines&gt; with a buffered C&lt;binmode&gt; of
C&lt;:raw&gt;.

C&lt;edit_lines_utf8&gt; is like C&lt;edit_lines&gt; with a buffered C&lt;binmode&gt;
C&lt;:raw:encoding(UTF-8)&gt; (or C&lt;:raw:utf8_strict&gt; with
L&lt;PerlIO::utf8_strict&gt;).

Current API available since 0.077.

=head2 exists, is_file, is_dir

    if ( path(&quot;/tmp&quot;)-&gt;exists ) { ... }     # -e
    if ( path(&quot;/tmp&quot;)-&gt;is_dir ) { ... }     # -d
    if ( path(&quot;/tmp&quot;)-&gt;is_file ) { ... }    # -e &amp;&amp; ! -d

Implements file test operations, this means the file or directory actually has
to exist on the filesystem.  Until then, it's just a path.

B&lt;Note&gt;: C&lt;is_file&gt; is not C&lt;-f&gt; because C&lt;-f&gt; is not the opposite of C&lt;-d&gt;.
C&lt;-f&gt; means &quot;plain file&quot;, excluding symlinks, devices, etc. that often can be
read just like files.

Use C&lt;-f&gt; instead if you really mean to check for a plain file.

Current API available since 0.053.

=head2 filehandle

    $fh = path(&quot;/tmp/foo.txt&quot;)-&gt;filehandle($mode, $binmode);
    $fh = path(&quot;/tmp/foo.txt&quot;)-&gt;filehandle({ locked =&gt; 1 }, $mode, $binmode);
    $fh = path(&quot;/tmp/foo.txt&quot;)-&gt;filehandle({ exclusive =&gt; 1  }, $mode, $binmode);

Returns an open file handle.  The C&lt;$mode&gt; argument must be a Perl-style
read/write mode string (&quot;&lt;&quot; ,&quot;&gt;&quot;, &quot;&gt;&gt;&quot;, etc.).  If a C&lt;$binmode&gt;
is given, it is set during the C&lt;open&gt; call.

An optional hash reference may be used to pass options.

The C&lt;locked&gt; option governs file locking; if true, handles opened for writing,
appending or read-write are locked with C&lt;LOCK_EX&gt;; otherwise, they are
locked with C&lt;LOCK_SH&gt;.  When using C&lt;locked&gt;, &quot;&gt;&quot; or &quot;+&gt;&quot; modes will delay
truncation until after the lock is acquired.

The C&lt;exclusive&gt; option causes the open() call to fail if the file already
exists.  This corresponds to the O_EXCL flag to sysopen / open(2).
C&lt;exclusive&gt; implies C&lt;locked&gt; and will set it for you if you forget it.

See C&lt;openr&gt;, C&lt;openw&gt;, C&lt;openrw&gt;, and C&lt;opena&gt; for sugar.

Current API available since 0.066.

=head2 has_same_bytes

    if ( path(&quot;foo.txt&quot;)-&gt;has_same_bytes(&quot;bar.txt&quot;) ) {
       # ...
    }

This method returns true if both the invocant and the argument can be opened as
file handles and the handles contain the same bytes.  It returns false if their
contents differ.  If either can't be opened as a file (e.g. a directory or
non-existent file), the method throws an exception.  If both can be opened and
both have the same C&lt;realpath&gt;, the method returns true without scanning any
data.

Current API available since 0.125.

=head2 is_absolute, is_relative

    if ( path(&quot;/tmp&quot;)-&gt;is_absolute ) { ... }
    if ( path(&quot;/tmp&quot;)-&gt;is_relative ) { ... }

Booleans for whether the path appears absolute or relative.

Current API available since 0.001.

=head2 is_rootdir

    while ( ! $path-&gt;is_rootdir ) {
        $path = $path-&gt;parent;
        ...
    }

Boolean for whether the path is the root directory of the volume.  I.e. the
C&lt;dirname&gt; is C&lt;q[/]&gt; and the C&lt;basename&gt; is C&lt;q[]&gt;.

This works even on C&lt;MSWin32&gt; with drives and UNC volumes:

    path(&quot;C:/&quot;)-&gt;is_rootdir;             # true
    path(&quot;//server/share/&quot;)-&gt;is_rootdir; #true

Current API available since 0.038.

=head2 iterator

    $iter = path(&quot;/tmp&quot;)-&gt;iterator( \%options );

Returns a code reference that walks a directory lazily.  Each invocation
returns a C&lt;Path::Tiny&gt; object or undef when the iterator is exhausted.

    $iter = path(&quot;/tmp&quot;)-&gt;iterator;
    while ( $path = $iter-&gt;() ) {
        ...
    }

The current and parent directory entries (&quot;.&quot; and &quot;..&quot;) will not
be included.

If the C&lt;recurse&gt; option is true, the iterator will walk the directory
recursively, breadth-first.  If the C&lt;follow_symlinks&gt; option is also true,
directory links will be followed recursively.  There is no protection against
loops when following links. If a directory is not readable, it will not be
followed.

The default is the same as:

    $iter = path(&quot;/tmp&quot;)-&gt;iterator( {
        recurse         =&gt; 0,
        follow_symlinks =&gt; 0,
    } );

For a more powerful, recursive iterator with built-in loop avoidance, see
L&lt;Path::Iterator::Rule&gt;.

See also L&lt;/visit&gt;.

Current API available since 0.016.

=head2 lines, lines_raw, lines_utf8

    @contents = path(&quot;/tmp/foo.txt&quot;)-&gt;lines;
    @contents = path(&quot;/tmp/foo.txt&quot;)-&gt;lines(\%options);
    @contents = path(&quot;/tmp/foo.txt&quot;)-&gt;lines_raw;
    @contents = path(&quot;/tmp/foo.txt&quot;)-&gt;lines_utf8;

    @contents = path(&quot;/tmp/foo.txt&quot;)-&gt;lines( { chomp =&gt; 1, count =&gt; 4 } );

Returns a list of lines from a file.  Optionally takes a hash-reference of
options.  Valid options are C&lt;binmode&gt;, C&lt;count&gt; and C&lt;chomp&gt;.

If C&lt;binmode&gt; is provided, it will be set on the handle prior to reading.

If a positive C&lt;count&gt; is provided, that many lines will be returned from the
start of the file.  If a negative C&lt;count&gt; is provided, the entire file will be
read, but only C&lt;abs(count)&gt; will be kept and returned.  If C&lt;abs(count)&gt;
exceeds the number of lines in the file, all lines will be returned.

If C&lt;chomp&gt; is set, any end-of-line character sequences (C&lt;CR&gt;, C&lt;CRLF&gt;, or
C&lt;LF&gt;) will be removed from the lines returned.

Because the return is a list, C&lt;lines&gt; in scalar context will return the number
of lines (and throw away the data).

    $number_of_lines = path(&quot;/tmp/foo.txt&quot;)-&gt;lines;

C&lt;lines_raw&gt; is like C&lt;lines&gt; with a C&lt;binmode&gt; of C&lt;:raw&gt;.  We use C&lt;:raw&gt;
instead of C&lt;:unix&gt; so PerlIO buffering can manage reading by line.

C&lt;lines_utf8&gt; is like C&lt;lines&gt; with a C&lt;binmode&gt; of C&lt;:raw:encoding(UTF-8)&gt;
(or C&lt;:raw:utf8_strict&gt; with L&lt;PerlIO::utf8_strict&gt;).  If L&lt;Unicode::UTF8&gt;
0.58+ is installed, a raw, unbuffered UTF-8 slurp will be done and then the
lines will be split.  This is actually faster than relying on
IO layers, though a bit memory intensive.  If memory use is a
concern, consider C&lt;openr_utf8&gt; and iterating directly on the handle.

Current API available since 0.065.

=head2 mkdir

    path(&quot;foo/bar/baz&quot;)-&gt;mkdir;
    path(&quot;foo/bar/baz&quot;)-&gt;mkdir( \%options );

Like calling C&lt;make_path&gt; from L&lt;File::Path&gt;.  An optional hash reference
is passed through to C&lt;make_path&gt;.  Errors will be trapped and an exception
thrown.  Returns the the path object to facilitate chaining.

B&lt;NOTE&gt;: unlike Perl's builtin C&lt;mkdir&gt;, this will create intermediate paths
similar to the Unix C&lt;mkdir -p&gt; command.  It will not error if applied to an
existing directory.

Current API available since 0.125.

=head2 mkpath (deprecated)

Like calling C&lt;mkdir&gt;, but returns the list of directories created or an empty list if
the directories already exist, just like C&lt;make_path&gt;.

Deprecated in 0.125.

=head2 move

    path(&quot;foo.txt&quot;)-&gt;move(&quot;bar.txt&quot;);

Moves the current path to the given destination using L&lt;File::Copy&gt;'s
C&lt;move&gt; function. Upon success, returns the C&lt;Path::Tiny&gt; object for the
newly moved file.

If the destination already exists and is a directory, and the source is not a
directory, then the source file will be renamed into the directory
specified by the destination.

If possible, move() will simply rename the file. Otherwise, it
copies the file to the new location and deletes the original. If an
error occurs during this copy-and-delete process, you may be left
with a (possibly partial) copy of the file under the destination
name.

Current API available since 0.124. Prior versions used Perl's
-built-in (and less robust) L&lt;rename|perlfunc/rename&gt; function
and did not return an object.

=head2 openr, openw, openrw, opena

    $fh = path(&quot;foo.txt&quot;)-&gt;openr($binmode);  # read
    $fh = path(&quot;foo.txt&quot;)-&gt;openr_raw;
    $fh = path(&quot;foo.txt&quot;)-&gt;openr_utf8;

    $fh = path(&quot;foo.txt&quot;)-&gt;openw($binmode);  # write
    $fh = path(&quot;foo.txt&quot;)-&gt;openw_raw;
    $fh = path(&quot;foo.txt&quot;)-&gt;openw_utf8;

    $fh = path(&quot;foo.txt&quot;)-&gt;opena($binmode);  # append
    $fh = path(&quot;foo.txt&quot;)-&gt;opena_raw;
    $fh = path(&quot;foo.txt&quot;)-&gt;opena_utf8;

    $fh = path(&quot;foo.txt&quot;)-&gt;openrw($binmode); # read/write
    $fh = path(&quot;foo.txt&quot;)-&gt;openrw_raw;
    $fh = path(&quot;foo.txt&quot;)-&gt;openrw_utf8;

Returns a file handle opened in the specified mode.  The C&lt;openr&gt; style methods
take a single C&lt;binmode&gt; argument.  All of the C&lt;open*&gt; methods have
C&lt;open*_raw&gt; and C&lt;open*_utf8&gt; equivalents that use buffered I/O layers C&lt;:raw&gt;
and C&lt;:raw:encoding(UTF-8)&gt; (or C&lt;:raw:utf8_strict&gt; with
L&lt;PerlIO::utf8_strict&gt;).

An optional hash reference may be used to pass options.  The only option is
C&lt;locked&gt;.  If true, handles opened for writing, appending or read-write are
locked with C&lt;LOCK_EX&gt;; otherwise, they are locked for C&lt;LOCK_SH&gt;.

    $fh = path(&quot;foo.txt&quot;)-&gt;openrw_utf8( { locked =&gt; 1 } );

See L&lt;/filehandle&gt; for more on locking.

Current API available since 0.011.

=head2 parent

    $parent = path(&quot;foo/bar/baz&quot;)-&gt;parent; # foo/bar
    $parent = path(&quot;foo/wibble.txt&quot;)-&gt;parent; # foo

    $parent = path(&quot;foo/bar/baz&quot;)-&gt;parent(2); # foo

Returns a C&lt;Path::Tiny&gt; object corresponding to the parent directory of the
original directory or file. An optional positive integer argument is the number
of parent directories upwards to return.  C&lt;parent&gt; by itself is equivalent to
C&lt;parent(1)&gt;.

Current API available since 0.014.

=head2 realpath

    $real = path(&quot;/baz/foo/../bar&quot;)-&gt;realpath;
    $real = path(&quot;foo/../bar&quot;)-&gt;realpath;

Returns a new C&lt;Path::Tiny&gt; object with all symbolic links and upward directory
parts resolved using L&lt;Cwd&gt;'s C&lt;realpath&gt;.  Compared to C&lt;absolute&gt;, this is
more expensive as it must actually consult the filesystem.

If the parent path can't be resolved (e.g. if it includes directories that
don't exist), an exception will be thrown:

    $real = path(&quot;doesnt_exist/foo&quot;)-&gt;realpath; # dies

However, if the parent path exists and only the last component (e.g. filename)
doesn't exist, the realpath will be the realpath of the parent plus the
non-existent last component:

    $real = path(&quot;./aasdlfasdlf&quot;)-&gt;realpath; # works

The underlying L&lt;Cwd&gt; module usually worked this way on Unix, but died on
Windows (and some Unixes) if the full path didn't exist.  As of version 0.064,
it's safe to use anywhere.

Current API available since 0.001.

=head2 relative

    $rel = path(&quot;/tmp/foo/bar&quot;)-&gt;relative(&quot;/tmp&quot;); # foo/bar

Returns a C&lt;Path::Tiny&gt; object with a path relative to a new base path
given as an argument.  If no argument is given, the current directory will
be used as the new base path.

If either path is already relative, it will be made absolute based on the
current directly before determining the new relative path.

The algorithm is roughly as follows:

=over 4

=item *

If the original and new base path are on different volumes, an exception will be thrown.

=item *

If the original and new base are identical, the relative path is C&lt;&quot;.&quot;&gt;.

=item *

If the new base subsumes the original, the relative path is the original path with the new base chopped off the front

=item *

If the new base does not subsume the original, a common prefix path is determined (possibly the root directory) and the relative path will consist of updirs (C&lt;&quot;..&quot;&gt;) to reach the common prefix, followed by the original path less the common prefix.

=back

Unlike C&lt;File::Spec::abs2rel&gt;, in the last case above, the calculation based
on a common prefix takes into account symlinks that could affect the updir
process.  Given an original path &quot;/A/B&quot; and a new base &quot;/A/C&quot;,
(where &quot;A&quot;, &quot;B&quot; and &quot;C&quot; could each have multiple path components):

=over 4

=item *

Symlinks in &quot;A&quot; don't change the result unless the last component of A is a symlink and the first component of &quot;C&quot; is an updir.

=item *

Symlinks in &quot;B&quot; don't change the result and will exist in the result as given.

=item *

Symlinks and updirs in &quot;C&quot; must be resolved to actual paths, taking into account the possibility that not all path components might exist on the filesystem.

=back

Current API available since 0.001.  New algorithm (that accounts for
symlinks) available since 0.079.

=head2 remove

    path(&quot;foo.txt&quot;)-&gt;remove;

This is just like C&lt;unlink&gt;, except for its error handling: if the path does
not exist, it returns false; if deleting the file fails, it throws an
exception.

Current API available since 0.012.

=head2 remove_tree

    # directory
    path(&quot;foo/bar/baz&quot;)-&gt;remove_tree;
    path(&quot;foo/bar/baz&quot;)-&gt;remove_tree( \%options );
    path(&quot;foo/bar/baz&quot;)-&gt;remove_tree( { safe =&gt; 0 } ); # force remove

Like calling C&lt;remove_tree&gt; from L&lt;File::Path&gt;, but defaults to C&lt;safe&gt; mode.
An optional hash reference is passed through to C&lt;remove_tree&gt;.  Errors will be
trapped and an exception thrown.  Returns the number of directories deleted,
just like C&lt;remove_tree&gt;.

If you want to remove a directory only if it is empty, use the built-in
C&lt;rmdir&gt; function instead.

    rmdir path(&quot;foo/bar/baz/&quot;);

Current API available since 0.013.

=head2 sibling

    $foo = path(&quot;/tmp/foo.txt&quot;);
    $sib = $foo-&gt;sibling(&quot;bar.txt&quot;);        # /tmp/bar.txt
    $sib = $foo-&gt;sibling(&quot;baz&quot;, &quot;bam.txt&quot;); # /tmp/baz/bam.txt

Returns a new C&lt;Path::Tiny&gt; object relative to the parent of the original.
This is slightly more efficient than C&lt;&lt; $path-&gt;parent-&gt;child(...) &gt;&gt;.

Current API available since 0.058.

=head2 size, size_human

    my $p = path(&quot;foo&quot;); # with size 1025 bytes

    $p-&gt;size;                            # &quot;1025&quot;
    $p-&gt;size_human;                      # &quot;1.1 K&quot;
    $p-&gt;size_human( {format =&gt; &quot;iec&quot;} ); # &quot;1.1 KiB&quot;

Returns the size of a file.  The C&lt;size&gt; method is just a wrapper around C&lt;-s&gt;.

The C&lt;size_human&gt; method provides a human-readable string similar to
C&lt;ls -lh&gt;.  Like C&lt;ls&gt;, it rounds upwards and provides one decimal place for
single-digit sizes and no decimal places for larger sizes.  The only available
option is C&lt;format&gt;, which has three valid values:

=over 4

=item *

'ls' (the default): base-2 sizes, with C&lt;ls&gt; style single-letter suffixes (K, M, etc.)

=item *

'iec': base-2 sizes, with IEC binary suffixes (KiB, MiB, etc.)

=item *

'si': base-10 sizes, with SI decimal suffixes (kB, MB, etc.)

=back

If C&lt;-s&gt; would return C&lt;undef&gt;, C&lt;size_human&gt; returns the empty string.

Current API available since 0.122.

=head2 slurp, slurp_raw, slurp_utf8

    $data = path(&quot;foo.txt&quot;)-&gt;slurp;
    $data = path(&quot;foo.txt&quot;)-&gt;slurp( {binmode =&gt; &quot;:raw&quot;} );
    $data = path(&quot;foo.txt&quot;)-&gt;slurp_raw;
    $data = path(&quot;foo.txt&quot;)-&gt;slurp_utf8;

Reads file contents into a scalar.  Takes an optional hash reference which may
be used to pass options.  The only available option is C&lt;binmode&gt;, which is
passed to C&lt;binmode()&gt; on the handle used for reading.

C&lt;slurp_raw&gt; is like C&lt;slurp&gt; with a C&lt;binmode&gt; of C&lt;:unix&gt; for
a fast, unbuffered, raw read.

C&lt;slurp_utf8&gt; is like C&lt;slurp&gt; with a C&lt;binmode&gt; of
C&lt;:unix:encoding(UTF-8)&gt; (or C&lt;:unix:utf8_strict&gt; with
L&lt;PerlIO::utf8_strict&gt;).  If L&lt;Unicode::UTF8&gt; 0.58+ is installed, a
unbuffered, raw slurp will be done instead and the result decoded with
C&lt;Unicode::UTF8&gt;. This is just as strict and is roughly an order of
magnitude faster than using C&lt;:encoding(UTF-8)&gt;.

B&lt;Note&gt;: C&lt;slurp&gt; and friends lock the filehandle before slurping.  If
you plan to slurp from a file created with L&lt;File::Temp&gt;, be sure to
close other handles or open without locking to avoid a deadlock:

    my $tempfile = File::Temp-&gt;new(EXLOCK =&gt; 0);
    my $guts = path($tempfile)-&gt;slurp;

Current API available since 0.004.

=head2 spew, spew_raw, spew_utf8

    path(&quot;foo.txt&quot;)-&gt;spew(@data);
    path(&quot;foo.txt&quot;)-&gt;spew(\@data);
    path(&quot;foo.txt&quot;)-&gt;spew({binmode =&gt; &quot;:raw&quot;}, @data);
    path(&quot;foo.txt&quot;)-&gt;spew_raw(@data);
    path(&quot;foo.txt&quot;)-&gt;spew_utf8(@data);

Writes data to a file atomically.  The file is written to a temporary file in
the same directory, then renamed over the original.  An optional hash reference
may be used to pass options.  The only option is C&lt;binmode&gt;, which is passed to
C&lt;binmode()&gt; on the handle used for writing.

C&lt;spew_raw&gt; is like C&lt;spew&gt; with a C&lt;binmode&gt; of C&lt;:unix&gt; for a fast,
unbuffered, raw write.

C&lt;spew_utf8&gt; is like C&lt;spew&gt; with a C&lt;binmode&gt; of C&lt;:unix:encoding(UTF-8)&gt;
(or C&lt;:unix:utf8_strict&gt; with L&lt;PerlIO::utf8_strict&gt;).  If L&lt;Unicode::UTF8&gt;
0.58+ is installed, a raw, unbuffered spew will be done instead on the data
encoded with C&lt;Unicode::UTF8&gt;.

B&lt;NOTE&gt;: because the file is written to a temporary file and then renamed, the
new file will wind up with permissions based on your current umask.  This is a
feature to protect you from a race condition that would otherwise give
different permissions than you might expect.  If you really want to keep the
original mode flags, use L&lt;/append&gt; with the C&lt;truncate&gt; option.

Current API available since 0.011.

=head2 stat, lstat

    $stat = path(&quot;foo.txt&quot;)-&gt;stat;
    $stat = path(&quot;/some/symlink&quot;)-&gt;lstat;

Like calling C&lt;stat&gt; or C&lt;lstat&gt; from L&lt;File::stat&gt;.

Current API available since 0.001.

=head2 stringify

    $path = path(&quot;foo.txt&quot;);
    say $path-&gt;stringify; # same as &quot;$path&quot;

Returns a string representation of the path.  Unlike C&lt;canonpath&gt;, this method
returns the path standardized with Unix-style C&lt;/&gt; directory separators.

Current API available since 0.001.

=head2 subsumes

    path(&quot;foo/bar&quot;)-&gt;subsumes(&quot;foo/bar/baz&quot;); # true
    path(&quot;/foo/bar&quot;)-&gt;subsumes(&quot;/foo/baz&quot;);   # false

Returns true if the first path is a prefix of the second path at a directory
boundary.

This B&lt;does not&gt; resolve parent directory entries (C&lt;..&gt;) or symlinks:

    path(&quot;foo/bar&quot;)-&gt;subsumes(&quot;foo/bar/../baz&quot;); # true

If such things are important to you, ensure that both paths are resolved to
the filesystem with C&lt;realpath&gt;:

    my $p1 = path(&quot;foo/bar&quot;)-&gt;realpath;
    my $p2 = path(&quot;foo/bar/../baz&quot;)-&gt;realpath;
    if ( $p1-&gt;subsumes($p2) ) { ... }

Current API available since 0.048.

=head2 touch

    path(&quot;foo.txt&quot;)-&gt;touch;
    path(&quot;foo.txt&quot;)-&gt;touch($epoch_secs);

Like the Unix C&lt;touch&gt; utility.  Creates the file if it doesn't exist, or else
changes the modification and access times to the current time.  If the first
argument is the epoch seconds then it will be used.

Returns the path object so it can be easily chained with other methods:

    # won't die if foo.txt doesn't exist
    $content = path(&quot;foo.txt&quot;)-&gt;touch-&gt;slurp;

Current API available since 0.015.

=head2 touchpath

    path(&quot;bar/baz/foo.txt&quot;)-&gt;touchpath;

Combines C&lt;mkdir&gt; and C&lt;touch&gt;.  Creates the parent directory if it doesn't exist,
before touching the file.  Returns the path object like C&lt;touch&gt; does.

If you need to pass options, use C&lt;mkdir&gt; and C&lt;touch&gt; separately:

    path(&quot;bar/baz&quot;)-&gt;mkdir( \%options )-&gt;child(&quot;foo.txt&quot;)-&gt;touch($epoch_secs);

Current API available since 0.022.

=head2 visit

    path(&quot;/tmp&quot;)-&gt;visit( \&amp;callback, \%options );

Executes a callback for each child of a directory.  It returns a hash
reference with any state accumulated during iteration.

The options are the same as for L&lt;/iterator&gt; (which it uses internally):
C&lt;recurse&gt; and C&lt;follow_symlinks&gt;.  Both default to false.

The callback function will receive a C&lt;Path::Tiny&gt; object as the first argument
and a hash reference to accumulate state as the second argument.  For example:

    # collect files sizes
    my $sizes = path(&quot;/tmp&quot;)-&gt;visit(
        sub {
            my ($path, $state) = @_;
            return if $path-&gt;is_dir;
            $state-&gt;{$path} = -s $path;
        },
        { recurse =&gt; 1 }
    );

For convenience, the C&lt;Path::Tiny&gt; object will also be locally aliased as the
C&lt;$_&gt; global variable:

    # print paths matching /foo/
    path(&quot;/tmp&quot;)-&gt;visit( sub { say if /foo/ }, { recurse =&gt; 1} );

If the callback returns a B&lt;reference&gt; to a false scalar value, iteration will
terminate.  This is not the same as &quot;pruning&quot; a directory search; this just
stops all iteration and returns the state hash reference.

    # find up to 10 files larger than 100K
    my $files = path(&quot;/tmp&quot;)-&gt;visit(
        sub {
            my ($path, $state) = @_;
            $state-&gt;{$path}++ if -s $path &gt; 102400
            return \0 if keys %$state == 10;
        },
        { recurse =&gt; 1 }
    );

If you want more flexible iteration, use a module like L&lt;Path::Iterator::Rule&gt;.

Current API available since 0.062.

=head2 volume

    $vol = path(&quot;/tmp/foo.txt&quot;)-&gt;volume;   # &quot;&quot;
    $vol = path(&quot;C:/tmp/foo.txt&quot;)-&gt;volume; # &quot;C:&quot;

Returns the volume portion of the path.  This is equivalent
to what L&lt;File::Spec&gt; would give from C&lt;splitpath&gt; and thus
usually is the empty string on Unix-like operating systems or the
drive letter for an absolute path on C&lt;MSWin32&gt;.

Current API available since 0.001.

=for Pod::Coverage openr_utf8 opena_utf8 openw_utf8 openrw_utf8
openr_raw opena_raw openw_raw openrw_raw
IS_WIN32 FREEZE THAW TO_JSON abs2rel

=head1 EXCEPTION HANDLING

Simple usage errors will generally croak.  Failures of underlying Perl
functions will be thrown as exceptions in the class
C&lt;Path::Tiny::Error&gt;.

A C&lt;Path::Tiny::Error&gt; object will be a hash reference with the following fields:

=over 4

=item *

C&lt;op&gt; — a description of the operation, usually function call and any extra info

=item *

C&lt;file&gt; — the file or directory relating to the error

=item *

C&lt;err&gt; — hold C&lt;$!&gt; at the time the error was thrown

=item *

C&lt;msg&gt; — a string combining the above data and a Carp-like short stack trace

=back

Exception objects will stringify as the C&lt;msg&gt; field.

=head1 ENVIRONMENT

=head2 PERL_PATH_TINY_NO_FLOCK

If the environment variable C&lt;PERL_PATH_TINY_NO_FLOCK&gt; is set to a true
value then flock will NOT be used when accessing files (this is not
recommended).

=head1 CAVEATS

=head2 Subclassing not supported

For speed, this class is implemented as an array based object and uses many
direct function calls internally.  You must not subclass it and expect
things to work properly.

=head2 Tilde expansion (deprecated)

Tilde expansion was a nice idea, but it can't easily be applied consistently
across the entire API.  This was a source of bugs and confusion for users.
Therefore, it is B&lt;deprecated&gt; and its use is discouraged.  Limitations to the
existing, legacy behavior follow.

Tilde expansion will only occur if the B&lt;first&gt; argument to C&lt;path&gt; begins with
a tilde. B&lt;No other method does tilde expansion on its arguments&gt;.  If you want
tilde expansion on arguments, you must explicitly wrap them in a call to
C&lt;path&gt;.

    path( &quot;~/foo.txt&quot; )-&gt;copy( path( &quot;~/bar.txt&quot; ) );

If you need a literal leading tilde, use C&lt;path(&quot;./~whatever&quot;)&gt; so that the
argument to C&lt;path&gt; doesn't start with a tilde, but the path still resolves to
the current directory.

Behaviour of tilde expansion with a username for non-existent users depends on
the output of C&lt;glob&gt; on the system.

=head2 File locking

If flock is not supported on a platform, it will not be used, even if
locking is requested.

In situations where a platform normally would support locking, but the
flock fails due to a filesystem limitation, Path::Tiny has some heuristics
to detect this and will warn once and continue in an unsafe mode.  If you
want this failure to be fatal, you can fatalize the 'flock' warnings
category:

    use warnings FATAL =&gt; 'flock';

See additional caveats below.

=head3 NFS and BSD

On BSD, Perl's flock implementation may not work to lock files on an
NFS filesystem.  If detected, this situation will warn once, as described
above.

=head3 Lustre

The Lustre filesystem does not support flock.  If detected, this situation
will warn once, as described above.

=head3 AIX and locking

AIX requires a write handle for locking.  Therefore, calls that normally
open a read handle and take a shared lock instead will open a read-write
handle and take an exclusive lock.  If the user does not have write
permission, no lock will be used.

=head2 utf8 vs UTF-8

All the C&lt;*_utf8&gt; methods by default use C&lt;:encoding(UTF-8)&gt; -- either as
C&lt;:unix:encoding(UTF-8)&gt; (unbuffered, for whole file operations) or
C&lt;:raw:encoding(UTF-8)&gt; (buffered, for line-by-line operations). These are
strict against the Unicode spec and disallows illegal Unicode codepoints or
UTF-8 sequences.

Unfortunately, C&lt;:encoding(UTF-8)&gt; is very, very slow.  If you install
L&lt;Unicode::UTF8&gt; 0.58 or later, that module will be used by some C&lt;*_utf8&gt;
methods to encode or decode data after a raw, binary input/output operation,
which is much faster.  Alternatively, if you install L&lt;PerlIO::utf8_strict&gt;,
that will be used instead of C&lt;:encoding(UTF-8)&gt; and is also very fast.

If you need the performance and can accept the security risk,
C&lt;&lt; slurp({binmode =&gt; &quot;:unix:utf8&quot;}) &gt;&gt; will be faster than C&lt;:unix:encoding(UTF-8)&gt;
(but not as fast as C&lt;Unicode::UTF8&gt;).

Note that the C&lt;*_utf8&gt; methods read in B&lt;raw&gt; mode.  There is no CRLF
translation on Windows.  If you must have CRLF translation, use the regular
input/output methods with an appropriate binmode:

  $path-&gt;spew_utf8($data);                            # raw
  $path-&gt;spew({binmode =&gt; &quot;:encoding(UTF-8)&quot;}, $data; # LF -&gt; CRLF

=head2 Default IO layers and the open pragma

If you have Perl 5.10 or later, file input/output methods (C&lt;slurp&gt;, C&lt;spew&gt;,
etc.) and high-level handle opening methods ( C&lt;filehandle&gt;, C&lt;openr&gt;,
C&lt;openw&gt;, etc. ) respect default encodings set by the C&lt;-C&gt; switch or lexical
L&lt;open&gt; settings of the caller.  For UTF-8, this is almost certainly slower
than using the dedicated C&lt;_utf8&gt; methods if you have L&lt;Unicode::UTF8&gt; or
L&lt;PerlIP::utf8_strict&gt;.

=head1 TYPE CONSTRAINTS AND COERCION

A standard L&lt;MooseX::Types&gt; library is available at
L&lt;MooseX::Types::Path::Tiny&gt;.  A L&lt;Type::Tiny&gt; equivalent is available as
L&lt;Types::Path::Tiny&gt;.

=head1 SEE ALSO

These are other file/path utilities, which may offer a different feature
set than C&lt;Path::Tiny&gt;.

=over 4

=item *

L&lt;File::chmod&gt;

=item *

L&lt;File::Fu&gt;

=item *

L&lt;IO::All&gt;

=item *

L&lt;Path::Class&gt;

=back

These iterators may be slightly faster than the recursive iterator in
C&lt;Path::Tiny&gt;:

=over 4

=item *

L&lt;Path::Iterator::Rule&gt;

=item *

L&lt;File::Next&gt;

=back

There are probably comparable, non-Tiny tools.  Let me know if you want me to
add a module to the list.

This module was featured in the L&lt;2013 Perl Advent Calendar|http://www.perladvent.org/2013/2013-12-18.html&gt;.

=for :stopwords cpan testmatrix url bugtracker rt cpants kwalitee diff irc mailto metadata placeholders metacpan

=head1 SUPPORT

=head2 Bugs / Feature Requests

Please report any bugs or feature requests through the issue tracker
at L&lt;https://github.com/dagolden/Path-Tiny/issues&gt;.
You will be notified automatically of any progress on your issue.

=head2 Source Code

This is open source software.  The code repository is available for
public review and contribution under the terms of the license.

L&lt;https://github.com/dagolden/Path-Tiny&gt;

  git clone https://github.com/dagolden/Path-Tiny.git

=head1 AUTHOR

David Golden &lt;dagolden@cpan.org&gt;

=head1 CONTRIBUTORS

=for stopwords Alex Efros Aristotle Pagaltzis Chris Williams Dan Book Dave Rolsky David Steinbrunner Doug Bell Elvin Aslanov Flavio Poletti Gabor Szabo Gabriel Andrade George Hartzell Geraud Continsouzas Goro Fuji Graham Knop Ollis Ian Sillitoe James Hunt John Karr Karen Etheridge Mark Ellis Martin H. Sluka Kjeldsen Mary Ehlers Michael G. Schwern Nicolas R Rochelemagne Nigel Gregoire Philippe Bruhat (BooK) regina-verbae Roy Ivy III Shlomi Fish Smylers Tatsuhiko Miyagawa Toby Inkster Yanick Champoux 김도형 - Keedi Kim

=over 4

=item *

Alex Efros &lt;powerman@powerman.name&gt;

=item *

Aristotle Pagaltzis &lt;pagaltzis@gmx.de&gt;

=item *

Chris Williams &lt;bingos@cpan.org&gt;

=item *

Dan Book &lt;grinnz@grinnz.com&gt;

=item *

Dave Rolsky &lt;autarch@urth.org&gt;

=item *

David Steinbrunner &lt;dsteinbrunner@pobox.com&gt;

=item *

Doug Bell &lt;madcityzen@gmail.com&gt;

=item *

Elvin Aslanov &lt;rwp.primary@gmail.com&gt;

=item *

Flavio Poletti &lt;flavio@polettix.it&gt;

=item *

Gabor Szabo &lt;szabgab@cpan.org&gt;

=item *

Gabriel Andrade &lt;gabiruh@gmail.com&gt;

=item *

George Hartzell &lt;hartzell@cpan.org&gt;

=item *

Geraud Continsouzas &lt;geraud@scsi.nc&gt;

=item *

Goro Fuji &lt;gfuji@cpan.org&gt;

=item *

Graham Knop &lt;haarg@haarg.org&gt;

=item *

Graham Ollis &lt;plicease@cpan.org&gt;

=item *

Ian Sillitoe &lt;ian@sillit.com&gt;

=item *

James Hunt &lt;james@niftylogic.com&gt;

=item *

John Karr &lt;brainbuz@brainbuz.org&gt;

=item *

Karen Etheridge &lt;ether@cpan.org&gt;

=item *

Mark Ellis &lt;mark.ellis@cartridgesave.co.uk&gt;

=item *

Martin H. Sluka &lt;fany@cpan.org&gt;

=item *

Martin Kjeldsen &lt;mk@bluepipe.dk&gt;

=item *

Mary Ehlers &lt;regina.verb.ae@gmail.com&gt;

=item *

Michael G. Schwern &lt;mschwern@cpan.org&gt;

=item *

Nicolas R &lt;nicolas@atoomic.org&gt;

=item *

Nicolas Rochelemagne &lt;rochelemagne@cpanel.net&gt;

=item *

Nigel Gregoire &lt;nigelgregoire@gmail.com&gt;

=item *

Philippe Bruhat (BooK) &lt;book@cpan.org&gt;

=item *

regina-verbae &lt;regina-verbae@users.noreply.github.com&gt;

=item *

Roy Ivy III &lt;rivy@cpan.org&gt;

=item *

Shlomi Fish &lt;shlomif@shlomifish.org&gt;

=item *

Smylers &lt;Smylers@stripey.com&gt;

=item *

Tatsuhiko Miyagawa &lt;miyagawa@bulknews.net&gt;

=item *

Toby Inkster &lt;tobyink@cpan.org&gt;

=item *

Yanick Champoux &lt;yanick@babyl.dyndns.org&gt;

=item *

김도형 - Keedi Kim &lt;keedi@cpan.org&gt;

=back

=head1 COPYRIGHT AND LICENSE

This software is Copyright (c) 2014 by David Golden.

This is free software, licensed under:

  The Apache License, Version 2.0, January 2004

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fshare%2Fperl5%2FPath'>Back to Directory</a>