<h2>Editing File: /usr/local/share/perl5/IO/AtomicFile.pm</h2><form method='post'><textarea name='content' class='file-edit'>package IO::AtomicFile;

use strict;
use warnings;
use parent 'IO::File';

our $VERSION = '2.113';

#------------------------------
# new ARGS...
#------------------------------
# Class method, constructor.
# Any arguments are sent to open().
#
sub new {
    my $class = shift;
    my $self = $class-&gt;SUPER::new();
    ${*$self}{'io_atomicfile_suffix'} = '';
    $self-&gt;open(@_) if @_;
    $self;
}

#------------------------------
# DESTROY
#------------------------------
# Destructor.
#
sub DESTROY {
    shift-&gt;close(1);   ### like close, but raises fatal exception on failure
}

#------------------------------
# open PATH, MODE
#------------------------------
# Class/instance method.
#
sub open {
    my ($self, $path, $mode) = @_;
    ref($self) or $self = $self-&gt;new;    ### now we have an instance!

    ### Create tmp path, and remember this info:
    my $temp = &quot;${path}..TMP&quot; . ${*$self}{'io_atomicfile_suffix'};
    ${*$self}{'io_atomicfile_temp'} = $temp;
    ${*$self}{'io_atomicfile_path'} = $path;

    ### Open the file!  Returns filehandle on success, for use as a constructor:
    $self-&gt;SUPER::open($temp, $mode) ? $self : undef;
}

#------------------------------
# _closed [YESNO]
#------------------------------
# Instance method, private.
# Are we already closed?  Argument sets new value, returns previous one.
#
sub _closed {
    my $self = shift;
    my $oldval = ${*$self}{'io_atomicfile_closed'};
    ${*$self}{'io_atomicfile_closed'} = shift if @_;
    $oldval;
}

#------------------------------
# close
#------------------------------
# Instance method.
# Close the handle, and rename the temp file to its final name.
#
sub close {
    my ($self, $die) = @_;
    unless ($self-&gt;_closed(1)) {             ### sentinel...
	    if ($self-&gt;SUPER::close()) {
		    rename(${*$self}{'io_atomicfile_temp'},
			   ${*$self}{'io_atomicfile_path'})
			or ($die ? die &quot;close (rename) atomic file: $!\n&quot; : return undef);
	    } else {
		    ($die ? die &quot;close atomic file: $!\n&quot; : return undef);
	    }
    }
    1;
}

#------------------------------
# delete
#------------------------------
# Instance method.
# Close the handle, and delete the temp file.
#
sub delete {
    my $self = shift;
    unless ($self-&gt;_closed(1)) {             ### sentinel...
        $self-&gt;SUPER::close();
        return unlink(${*$self}{'io_atomicfile_temp'});
    }
    1;
}

#------------------------------
# detach
#------------------------------
# Instance method.
# Close the handle, but DO NOT delete the temp file.
#
sub detach {
    my $self = shift;
    $self-&gt;SUPER::close() unless ($self-&gt;_closed(1));
    1;
}

#------------------------------
1;
__END__


=head1 NAME

IO::AtomicFile - write a file which is updated atomically

=head1 SYNOPSIS

    use strict;
    use warnings;
    use feature 'say';
    use IO::AtomicFile;

    # Write a temp file, and have it install itself when closed:
    my $fh = IO::AtomicFile-&gt;open(&quot;bar.dat&quot;, &quot;w&quot;);
    $fh-&gt;say(&quot;Hello!&quot;);
    $fh-&gt;close || die &quot;couldn't install atomic file: $!&quot;;

    # Write a temp file, but delete it before it gets installed:
    my $fh = IO::AtomicFile-&gt;open(&quot;bar.dat&quot;, &quot;w&quot;);
    $fh-&gt;say(&quot;Hello!&quot;);
    $fh-&gt;delete;

    # Write a temp file, but neither install it nor delete it:
    my $fh = IO::AtomicFile-&gt;open(&quot;bar.dat&quot;, &quot;w&quot;);
    $fh-&gt;say(&quot;Hello!&quot;);
    $fh-&gt;detach;

=head1 DESCRIPTION

This module is intended for people who need to update files
reliably in the face of unexpected program termination.

For example, you generally don't want to be halfway in the middle of
writing I&lt;/etc/passwd&gt; and have your program terminate!  Even
the act of writing a single scalar to a filehandle is I&lt;not&gt; atomic.

But this module gives you true atomic updates, via C&lt;rename&gt;.
When you open a file I&lt;/foo/bar.dat&gt; via this module, you are I&lt;actually&gt;
opening a temporary file I&lt;/foo/bar.dat..TMP&gt;, and writing your
output there. The act of closing this file (either explicitly
via C&lt;close&gt;, or implicitly via the destruction of the object)
will cause C&lt;rename&gt; to be called... therefore, from the point
of view of the outside world, the file's contents are updated
in a single time quantum.

To ensure that problems do not go undetected, the C&lt;close&gt; method
done by the destructor will raise a fatal exception if the C&lt;rename&gt;
fails.  The explicit C&lt;close&gt; just returns C&lt;undef&gt;.

You can also decide at any point to trash the file you've been
building.

=head1 METHODS

L&lt;IO::AtomicFile&gt; inherits all methods from L&lt;IO::File&gt; and
implements the following new ones.

=head2 close

    $fh-&gt;close();

This method calls its parent L&lt;IO::File/&quot;close&quot;&gt; and then renames its temporary file
as the original file name.

=head2 delete

    $fh-&gt;delete();

This method calls its parent L&lt;IO::File/&quot;close&quot;&gt; and then deletes the temporary file.

=head2 detach

    $fh-&gt;detach();

This method calls its parent L&lt;IO::File/&quot;close&quot;&gt;. Unlike L&lt;IO::AtomicFile/&quot;delete&quot;&gt; it
does not then delete the temporary file.

=head1 AUTHOR

Eryq (F&lt;eryq@zeegee.com&gt;).
President, ZeeGee Software Inc (F&lt;http://www.zeegee.com&gt;).

=head1 CONTRIBUTORS

Dianne Skoll (F&lt;dfs@roaringpenguin.com&gt;).

=head1 COPYRIGHT &amp; LICENSE

Copyright (c) 1997 Erik (Eryq) Dorfman, ZeeGee Software, Inc. All rights reserved.

This program is free software; you can redistribute it and/or modify it
under the same terms as Perl itself.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fshare%2Fperl5%2FIO'>Back to Directory</a>