<h2>Editing File: /usr/local/share/perl5/CPAN/Mirrors.pm</h2><form method='post'><textarea name='content' class='file-edit'># -*- Mode: cperl; coding: utf-8; cperl-indent-level: 4 -*-
# vim: ts=4 sts=4 sw=4:
=head1 NAME

CPAN::Mirrors - Get CPAN mirror information and select a fast one

=head1 SYNOPSIS

    use CPAN::Mirrors;

    my $mirrors = CPAN::Mirrors-&gt;new( $mirrored_by_file );

    my $seen = {};

    my $best_continent = $mirrors-&gt;find_best_continents( { seen =&gt; $seen } );
    my @mirrors        = $mirrors-&gt;get_mirrors_by_continents( $best_continent );

    my $callback = sub {
        my( $m ) = @_;
        printf &quot;%s = %s\n&quot;, $m-&gt;hostname, $m-&gt;rtt
        };
    $mirrors-&gt;get_mirrors_timings( \@mirrors, $seen, $callback, %args );

    @mirrors = sort { $a-&gt;rtt &lt;=&gt; $b-&gt;rtt } @mirrors;

    print &quot;Best mirrors are &quot;, map( { $_-&gt;rtt } @mirrors[0..3] ), &quot;\n&quot;;

=head1 DESCRIPTION

=over

=cut

package CPAN::Mirrors;
use strict;
use vars qw($VERSION $urllist $silent);
$VERSION = &quot;2.27&quot;;

use Carp;
use FileHandle;
use Fcntl &quot;:flock&quot;;
use Net::Ping ();
use CPAN::Version;

=item new( LOCAL_FILE_NAME )

Create a new CPAN::Mirrors object from LOCAL_FILE_NAME. This file
should look like that in http://www.cpan.org/MIRRORED.BY .

=cut

sub new {
    my ($class, $file) = @_;
    croak &quot;CPAN::Mirrors-&gt;new requires a filename&quot; unless defined $file;
    croak &quot;The file [$file] was not found&quot; unless -e $file;

    my $self = bless {
        mirrors      =&gt; [],
        geography    =&gt; {},
    }, $class;

    $self-&gt;parse_mirrored_by( $file );

    return $self;
}

sub parse_mirrored_by {
    my ($self, $file) = @_;
    my $handle = FileHandle-&gt;new;
    $handle-&gt;open($file)
        or croak &quot;Couldn't open $file: $!&quot;;
    flock $handle, LOCK_SH;
    $self-&gt;_parse($file,$handle);
    flock $handle, LOCK_UN;
    $handle-&gt;close;
}

=item continents()

Return a list of continents based on those defined in F&lt;MIRRORED.BY&gt;.

=cut

sub continents {
    my ($self) = @_;
    return sort keys %{$self-&gt;{geography} || {}};
}

=item countries( [CONTINENTS] )

Return a list of countries based on those defined in F&lt;MIRRORED.BY&gt;.
It only returns countries for the continents you specify (as defined
in C&lt;continents&gt;). If you don't specify any continents, it returns all
of the countries listed in F&lt;MIRRORED.BY&gt;.

=cut

sub countries {
    my ($self, @continents) = @_;
    @continents = $self-&gt;continents unless @continents;
    my @countries;
    for my $c (@continents) {
        push @countries, sort keys %{ $self-&gt;{geography}{$c} || {} };
    }
    return @countries;
}

=item mirrors( [COUNTRIES] )

Return a list of mirrors based on those defined in F&lt;MIRRORED.BY&gt;.
It only returns mirrors for the countries you specify (as defined
in C&lt;countries&gt;). If you don't specify any countries, it returns all
of the mirrors listed in F&lt;MIRRORED.BY&gt;.

=cut

sub mirrors {
    my ($self, @countries) = @_;
    return @{$self-&gt;{mirrors}} unless @countries;
    my %wanted = map { $_ =&gt; 1 } @countries;
    my @found;
    for my $m (@{$self-&gt;{mirrors}}) {
        push @found, $m if exists $wanted{$m-&gt;country};
    }
    return @found;
}

=item get_mirrors_by_countries( [COUNTRIES] )

A more sensible synonym for mirrors.

=cut

sub get_mirrors_by_countries { &amp;mirrors }

=item get_mirrors_by_continents( [CONTINENTS] )

Return a list of mirrors for all of continents you specify. If you don't
specify any continents, it returns all of the mirrors.

You can specify a single continent or an array reference of continents.

=cut

sub get_mirrors_by_continents {
    my ($self, $continents ) = @_;
    $continents = [ $continents ] unless ref $continents;

    eval {
        $self-&gt;mirrors( $self-&gt;get_countries_by_continents( @$continents ) );
        };
    }

=item get_countries_by_continents( [CONTINENTS] )

A more sensible synonym for countries.

=cut

sub get_countries_by_continents { &amp;countries }

=item default_mirror

Returns the default mirror, http://www.cpan.org/ . This mirror uses
dynamic DNS to give a close mirror.

=cut

sub default_mirror {
    CPAN::Mirrored::By-&gt;new({ http =&gt; 'http://www.cpan.org/'});
}

=item best_mirrors

C&lt;best_mirrors&gt; checks for the best mirrors based on the list of
continents you pass, or, without that, all continents, as defined
by C&lt;CPAN::Mirrored::By&gt;. It pings each mirror, up to the value of
C&lt;how_many&gt;. In list context, it returns up to C&lt;how_many&gt; mirrors.
In scalar context, it returns the single best mirror.

Arguments

    how_many      - the number of mirrors to return. Default: 1
    callback      - a callback for find_best_continents
    verbose       - true or false on all the whining and moaning. Default: false
    continents    - an array ref of the continents to check
    external_ping - if true, use external ping via Net::Ping::External. Default: false

If you don't specify the continents, C&lt;best_mirrors&gt; calls
C&lt;find_best_continents&gt; to get the list of continents to check.

If you don't have L&lt;Net::Ping&gt; v2.13 or later, needed for timings,
this returns the default mirror.

C&lt;external_ping&gt; should be set and then C&lt;Net::Ping::External&gt; needs
to be installed, if the local network has a transparent proxy.

=cut

sub best_mirrors {
    my ($self, %args) = @_;
    my $how_many      = $args{how_many} || 1;
    my $callback      = $args{callback};
    my $verbose       = defined $args{verbose} ? $args{verbose} : 0;
    my $continents    = $args{continents} || [];
       $continents    = [$continents] unless ref $continents;
    $args{external_ping} = 0 unless defined $args{external_ping};
    my $external_ping = $args{external_ping};

    # Old Net::Ping did not do timings at all
    my $min_version = '2.13';
    unless( CPAN::Version-&gt;vgt(Net::Ping-&gt;VERSION, $min_version) ) {
        carp sprintf &quot;Net::Ping version is %s (&lt; %s). Returning %s&quot;,
            Net::Ping-&gt;VERSION, $min_version, $self-&gt;default_mirror;
        return $self-&gt;default_mirror;
    }

    my $seen = {};

    if ( ! @$continents ) {
        print &quot;Searching for the best continent ...\n&quot; if $verbose;
        my @best_continents = $self-&gt;find_best_continents(
            seen          =&gt; $seen,
            verbose       =&gt; $verbose,
            callback      =&gt; $callback,
            external_ping =&gt; $external_ping,
            );

        # Only add enough continents to find enough mirrors
        my $count = 0;
        for my $continent ( @best_continents ) {
            push @$continents, $continent;
            $count += $self-&gt;mirrors( $self-&gt;countries($continent) );
            last if $count &gt;= $how_many;
        }
    }

    return $self-&gt;default_mirror unless @$continents;
    print &quot;Scanning &quot; . join(&quot;, &quot;, @$continents) . &quot; ...\n&quot; if $verbose;

    my $trial_mirrors = $self-&gt;get_n_random_mirrors_by_continents( 3 * $how_many, $continents-&gt;[0] );

    my $timings = $self-&gt;get_mirrors_timings(
        $trial_mirrors,
        $seen,
        $callback,
        %args,
    );
    return $self-&gt;default_mirror unless @$timings;

    $how_many = @$timings if $how_many &gt; @$timings;

    return wantarray ? @{$timings}[0 .. $how_many-1] : $timings-&gt;[0];
}

=item get_n_random_mirrors_by_continents( N, [CONTINENTS] )

Returns up to N random mirrors for the specified continents. Specify the
continents as an array reference.

=cut

sub get_n_random_mirrors_by_continents {
    my( $self, $n, $continents ) = @_;
    $n ||= 3;
    $continents = [ $continents ] unless ref $continents;

    if ( $n &lt;= 0 ) {
        return wantarray ? () : [];
    }

    my @long_list = $self-&gt;get_mirrors_by_continents( $continents );

    if ( $n eq '*' or $n &gt; @long_list ) {
        return wantarray ? @long_list : \@long_list;
    }

    @long_list = map  {$_-&gt;[0]}
                 sort {$a-&gt;[1] &lt;=&gt; $b-&gt;[1]}
                 map  {[$_, rand]} @long_list;

    splice @long_list, $n; # truncate

    \@long_list;
}

=item get_mirrors_timings( MIRROR_LIST, SEEN, CALLBACK, %ARGS );

Pings the listed mirrors and returns a list of mirrors sorted in
ascending ping times.

C&lt;MIRROR_LIST&gt; is an anonymous array of C&lt;CPAN::Mirrored::By&gt; objects to
ping.

The optional argument C&lt;SEEN&gt; is a hash reference used to track the
mirrors you've already pinged.

The optional argument C&lt;CALLBACK&gt; is a subroutine reference to call
after each ping. It gets the C&lt;CPAN::Mirrored::By&gt; object after each
ping.

=cut

sub get_mirrors_timings {
    my( $self, $mirror_list, $seen, $callback, %args ) = @_;

    $seen = {} unless defined $seen;
    croak &quot;The mirror list argument must be an array reference&quot;
        unless ref $mirror_list eq ref [];
    croak &quot;The seen argument must be a hash reference&quot;
        unless ref $seen eq ref {};
    croak &quot;callback must be a subroutine&quot;
        if( defined $callback and ref $callback ne ref sub {} );

    my $timings = [];
    for my $m ( @$mirror_list ) {
        $seen-&gt;{$m-&gt;hostname} = $m;
        next unless eval{ $m-&gt;http };

        if( $self-&gt;_try_a_ping( $seen, $m, ) ) {
            my $ping = $m-&gt;ping(%args);
            next unless defined $ping;
            # printf &quot;m %s ping %s\n&quot;, $m, $ping;
            push @$timings, $m;
            $callback-&gt;( $m ) if $callback;
        }
        else {
            push @$timings, $seen-&gt;{$m-&gt;hostname}
                if defined $seen-&gt;{$m-&gt;hostname}-&gt;rtt;
        }
    }

    my @best = sort {
           if( defined $a-&gt;rtt and defined $b-&gt;rtt )     {
            $a-&gt;rtt &lt;=&gt; $b-&gt;rtt
            }
        elsif( defined $a-&gt;rtt and ! defined $b-&gt;rtt )   {
            return -1;
            }
        elsif( ! defined $a-&gt;rtt and defined $b-&gt;rtt )   {
            return 1;
            }
        elsif( ! defined $a-&gt;rtt and ! defined $b-&gt;rtt ) {
            return 0;
            }

        } @$timings;

    return wantarray ? @best : \@best;
}

=item find_best_continents( HASH_REF );

C&lt;find_best_continents&gt; goes through each continent and pings C&lt;N&gt;
random mirrors on that continent. It then orders the continents by
ascending median ping time. In list context, it returns the ordered list
of continent. In scalar context, it returns the same list as an
anonymous array.

Arguments:

    n        - the number of hosts to ping for each continent. Default: 3
    seen     - a hashref of cached hostname ping times
    verbose  - true or false for noisy or quiet. Default: false
    callback - a subroutine to run after each ping.
    ping_cache_limit - how long, in seconds, to reuse previous ping times.
        Default: 1 day

The C&lt;seen&gt; hash has hostnames as keys and anonymous arrays as values.
The anonymous array is a triplet of a C&lt;CPAN::Mirrored::By&gt; object, a
ping time, and the epoch time for the measurement.

The callback subroutine gets the C&lt;CPAN::Mirrored::By&gt; object, the ping
time, and measurement time (the same things in the C&lt;seen&gt; hashref) as
arguments. C&lt;find_best_continents&gt; doesn't care what the callback does
and ignores the return value.

With a low value for C&lt;N&gt;, a single mirror might skew the results enough
to choose a worse continent. If you have that problem, try a larger
value.

=cut

sub find_best_continents {
    my ($self, %args) = @_;

    $args{n}     ||= 3;
    $args{verbose} = 0 unless defined $args{verbose};
    $args{seen}    = {} unless defined $args{seen};
    croak &quot;The seen argument must be a hash reference&quot;
        unless ref $args{seen} eq ref {};
    $args{ping_cache_limit} = 24 * 60 * 60
        unless defined $args{ping_cache_limit};
    croak &quot;callback must be a subroutine&quot;
        if( defined $args{callback} and ref $args{callback} ne ref sub {} );

    my %medians;
    CONT: for my $c ( $self-&gt;continents ) {
        my @mirrors = $self-&gt;mirrors( $self-&gt;countries($c) );
        printf &quot;Testing %s (%d mirrors)\n&quot;, $c, scalar @mirrors
            if $args{verbose};

        next CONT unless @mirrors;
        my $n = (@mirrors &lt; $args{n}) ? @mirrors : $args{n};

        my @tests;
        my $tries = 0;
        RANDOM: while ( @mirrors &amp;&amp; @tests &lt; $n &amp;&amp; $tries++ &lt; 15 ) {
            my $m = splice( @mirrors, int(rand(@mirrors)), 1 );
            if( $self-&gt;_try_a_ping(
                    $args{seen}, $m, $args{ping_cache_limit}
                )) {
                $self-&gt;get_mirrors_timings(
                    [ $m ],
                    $args{seen},
                    $args{callback},
                    %args,
                );
                next RANDOM unless defined $args{seen}{$m-&gt;hostname}-&gt;rtt;
            }
            printf &quot;(%s -&gt; %0.2f ms)&quot;,
                $m-&gt;hostname,
                join ' ', 1000 * $args{seen}{$m-&gt;hostname}-&gt;rtt
                    if $args{verbose};

            push @tests, $args{seen}{$m-&gt;hostname}-&gt;rtt;
        }

        my $median = $self-&gt;_get_median_ping_time( \@tests, $args{verbose} );
        $medians{$c} = $median if defined $median;
    }

    my @best_cont = sort { $medians{$a} &lt;=&gt; $medians{$b} } keys %medians;

    if ( $args{verbose} ) {
        print &quot;Median result by continent:\n&quot;;
        if ( @best_cont ) {
            for my $c ( @best_cont ) {
                printf( &quot;  %7.2f ms  %s\n&quot;, $medians{$c}*1000, $c );
            }
        } else {
            print &quot;  **** No results found ****\n&quot;
        }
    }

    return wantarray ? @best_cont : $best_cont[0];
}

# retry if
sub _try_a_ping {
    my ($self, $seen, $mirror, $ping_cache_limit ) = @_;

    ( ! exists $seen-&gt;{$mirror-&gt;hostname}
        or
    ! defined $seen-&gt;{$mirror-&gt;hostname}-&gt;rtt
      or
    ! defined $ping_cache_limit
      or
      time - $seen-&gt;{$mirror-&gt;hostname}-&gt;ping_time
        &gt; $ping_cache_limit
    )
}

sub _get_median_ping_time {
    my ($self, $tests, $verbose ) = @_;

    my @sorted = sort { $a &lt;=&gt; $b } @$tests;

    my $median = do {
           if ( @sorted == 0 ) { undef }
        elsif ( @sorted == 1 ) { $sorted[0] }
        elsif ( @sorted % 2 )  { $sorted[ int(@sorted / 2) ] }
        else {
            my $mid_high = int(@sorted/2);
            ($sorted[$mid_high-1] + $sorted[$mid_high])/2;
        }
    };

    if ($verbose){
        if ($median) {
            printf &quot; =&gt; median time: %.2f ms\n&quot;, $median * 1000
        } else {
            printf &quot; =&gt; **** no median time ****\n&quot;;
        }
    }

    return $median;
}

# Adapted from Parse::CPAN::MirroredBy by Adam Kennedy
sub _parse {
    my ($self, $file, $handle) = @_;
    my $output = $self-&gt;{mirrors};
    my $geo    = $self-&gt;{geography};

    local $/ = &quot;\012&quot;;
    my $line = 0;
    my $mirror = undef;
    while ( 1 ) {
        # Next line
        my $string = &lt;$handle&gt;;
        last if ! defined $string;
        $line = $line + 1;

        # Remove the useless lines
        chomp( $string );
        next if $string =~ /^\s*$/;
        next if $string =~ /^\s*#/;

        # Hostname or property?
        if ( $string =~ /^\s/ ) {
            # Property
            unless ( $string =~ /^\s+(\w+)\s+=\s+\&quot;(.*)\&quot;$/ ) {
                croak(&quot;Invalid property on line $line&quot;);
            }
            my ($prop, $value) = ($1,$2);
            $mirror ||= {};
            if ( $prop eq 'dst_location' ) {
                my (@location,$continent,$country);
                @location = (split /\s*,\s*/, $value)
                    and ($continent, $country) = @location[-1,-2];
                $continent =~ s/\s\(.*//;
                $continent =~ s/\W+$//; # if Jarkko doesn't know latitude/longitude
                $geo-&gt;{$continent}{$country} = 1 if $continent &amp;&amp; $country;
                $mirror-&gt;{continent} = $continent || &quot;unknown&quot;;
                $mirror-&gt;{country} = $country || &quot;unknown&quot;;
            }
            elsif ( $prop eq 'dst_http' ) {
                $mirror-&gt;{http} = $value;
            }
            elsif ( $prop eq 'dst_ftp' ) {
                $mirror-&gt;{ftp} = $value;
            }
            elsif ( $prop eq 'dst_rsync' ) {
                $mirror-&gt;{rsync} = $value;
            }
            else {
                $prop =~ s/^dst_//;
                $mirror-&gt;{$prop} = $value;
            }
        } else {
            # Hostname
            unless ( $string =~ /^([\w\.-]+)\:\s*$/ ) {
                croak(&quot;Invalid host name on line $line&quot;);
            }
            my $current = $mirror;
            $mirror     = { hostname =&gt; &quot;$1&quot; };
            if ( $current ) {
                push @$output, CPAN::Mirrored::By-&gt;new($current);
            }
        }
    }
    if ( $mirror ) {
        push @$output, CPAN::Mirrored::By-&gt;new($mirror);
    }

    return;
}

#--------------------------------------------------------------------------#

package CPAN::Mirrored::By;
use strict;
use Net::Ping   ();

sub new {
    my($self,$arg) = @_;
    $arg ||= {};
    bless $arg, $self;
}
sub hostname  { shift-&gt;{hostname}    }
sub continent { shift-&gt;{continent}   }
sub country   { shift-&gt;{country}     }
sub http      { shift-&gt;{http}  || '' }
sub ftp       { shift-&gt;{ftp}   || '' }
sub rsync     { shift-&gt;{rsync} || '' }
sub rtt       { shift-&gt;{rtt}         }
sub ping_time { shift-&gt;{ping_time}   }

sub url {
    my $self = shift;
    return $self-&gt;{http} || $self-&gt;{ftp};
}

sub ping {
    my($self, %args) = @_;

    my $external_ping = $args{external_ping};
    if ($external_ping) {
        eval { require Net::Ping::External }
            or die &quot;Net::Ping::External required to use external ping command&quot;;
    }
    my $ping = Net::Ping-&gt;new(
        $external_ping ? 'external' : $^O eq 'VMS' ? 'icmp' : 'tcp',
        1
    );
    my ($proto) = $self-&gt;url =~ m{^([^:]+)};
    my $port = $proto eq 'http' ? 80 : 21;
    return unless $port;

    if ( $ping-&gt;can('port_number') ) {
        $ping-&gt;port_number($port);
    }
    else {
        $ping-&gt;{'port_num'} = $port;
    }

    $ping-&gt;hires(1) if $ping-&gt;can('hires');
    my ($alive,$rtt) = eval { $ping-&gt;ping($self-&gt;hostname); };
    my $verbose = $args{verbose};
    if ($verbose &amp;&amp; !$alive) {
        printf &quot;(host %s not alive)&quot;, $self-&gt;hostname;
    }

    $self-&gt;{rtt} = $alive ? $rtt : undef;
    $self-&gt;{ping_time} = time;

    $self-&gt;rtt;
}


1;

=back

=head1 AUTHOR

Andreas Koenig C&lt;&lt; &lt;andk@cpan.org&gt; &gt;&gt;, David Golden C&lt;&lt; &lt;dagolden@cpan.org&gt; &gt;&gt;,
brian d foy C&lt;&lt; &lt;bdfoy@cpan.org&gt; &gt;&gt;

=head1 LICENSE

This program is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.

See L&lt;http://www.perl.com/perl/misc/Artistic.html&gt;

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fshare%2Fperl5%2FCPAN'>Back to Directory</a>