<h2>Editing File: /usr/local/share/perl5/CPAN/HTTP/Client.pm</h2><form method='post'><textarea name='content' class='file-edit'># -*- Mode: cperl; coding: utf-8; cperl-indent-level: 4 -*-
# vim: ts=4 sts=4 sw=4:
package CPAN::HTTP::Client;
use strict;
use vars qw(@ISA);
use CPAN::HTTP::Credentials;
use HTTP::Tiny 0.005;

$CPAN::HTTP::Client::VERSION = $CPAN::HTTP::Client::VERSION = &quot;1.9602&quot;;

# CPAN::HTTP::Client is adapted from parts of cpanm by Tatsuhiko Miyagawa
# and parts of LWP by Gisle Aas

sub new {
    my $class = shift;
    my %args = @_;
    for my $k ( keys %args ) {
        $args{$k} = '' unless defined $args{$k};
    }
    $args{no_proxy} = [split(&quot;,&quot;, $args{no_proxy}) ] if $args{no_proxy};
    return bless \%args, $class;
}

# This executes a request with redirection (up to 5) and returns the
# response structure generated by HTTP::Tiny
#
# If authentication fails, it will attempt to get new authentication
# information and repeat up to 5 times

sub mirror {
    my($self, $uri, $path) = @_;

    my $want_proxy = $self-&gt;_want_proxy($uri);
    my $http = HTTP::Tiny-&gt;new(
        verify_SSL =&gt; 1,
        $want_proxy ? (proxy =&gt; $self-&gt;{proxy}) : ()
    );

    my ($response, %headers);
    my $retries = 0;
    while ( $retries++ &lt; 5 ) {
        $response = $http-&gt;mirror( $uri, $path, {headers =&gt; \%headers} );
        if ( $response-&gt;{status} eq '401' ) {
            last unless $self-&gt;_get_auth_params( $response, 'non_proxy' );
        }
        elsif ( $response-&gt;{status} eq '407' ) {
            last unless $self-&gt;_get_auth_params( $response, 'proxy' );
        }
        else {
            last; # either success or failure
        }
        my %headers = (
            $self-&gt;_auth_headers( $uri, 'non_proxy' ),
            ( $want_proxy ? $self-&gt;_auth_headers($uri, 'proxy') : () ),
        );
    }

    return $response;
}

sub _want_proxy {
    my ($self, $uri) = @_;
    return unless $self-&gt;{proxy};
    my($host) = $uri =~ m|://([^/:]+)|;
    return ! grep { $host =~ /\Q$_\E$/ } @{ $self-&gt;{no_proxy} || [] };
}

# Generates the authentication headers for a given mode
# C&lt;mode&gt; is 'proxy' or 'non_proxy'
# C&lt;_${mode}_type&gt; is 'basic' or 'digest'
# C&lt;_${mode}_params&gt; will be the challenge parameters from the 401/407 headers
sub _auth_headers {
    my ($self, $uri, $mode) = @_;
    # Get names for our mode-specific attributes
    my ($type_key, $param_key) = map {&quot;_&quot; . $mode . $_} qw/_type _params/;

    # If _prepare_auth has not been called, we can't prepare headers
    return unless $self-&gt;{$type_key};

    # Get user credentials for mode
    my $cred_method = &quot;get_&quot; . ($mode ? &quot;proxy&quot; : &quot;non_proxy&quot;) .&quot;_credentials&quot;;
    my ($user, $pass) = CPAN::HTTP::Credentials-&gt;$cred_method;

    # Generate the header for the mode &amp; type
    my $header = $mode eq 'proxy' ? 'Proxy-Authorization' : 'Authorization';
    my $value_method = &quot;_&quot; . $self-&gt;{$type_key} . &quot;_auth&quot;;
    my $value = $self-&gt;$value_method($user, $pass, $self-&gt;{$param_key}, $uri);

    # If we didn't get a value, we didn't have the right modules available
    return $value ? ( $header, $value ) : ();
}

# Extract authentication parameters from headers, but clear any prior
# credentials if we failed (so we might prompt user for password again)
sub _get_auth_params {
    my ($self, $response, $mode) = @_;
    my $prefix = $mode eq 'proxy' ? 'Proxy' : 'WWW';
    my ($type_key, $param_key) = map {&quot;_&quot; . $mode . $_} qw/_type _params/;
    if ( ! $response-&gt;{success} ) { # auth failed
        my $method = &quot;clear_${mode}_credentials&quot;;
        CPAN::HTTP::Credentials-&gt;$method;
        delete $self-&gt;{$_} for $type_key, $param_key;
    }
    ($self-&gt;{$type_key}, $self-&gt;{$param_key}) =
        $self-&gt;_get_challenge( $response, &quot;${prefix}-Authenticate&quot;);
    return $self-&gt;{$type_key};
}

# Extract challenge type and parameters for a challenge list
sub _get_challenge {
    my ($self, $response, $auth_header) = @_;

    my $auth_list = $response-&gt;{headers}(lc $auth_header);
    return unless defined $auth_list;
    $auth_list = [$auth_list] unless ref $auth_list;

    for my $challenge (@$auth_list) {
        $challenge =~ tr/,/;/;  # &quot;,&quot; is used to separate auth-params!!
        ($challenge) = $self-&gt;split_header_words($challenge);
        my $scheme = shift(@$challenge);
        shift(@$challenge); # no value
        $challenge = { @$challenge };  # make rest into a hash

        unless ($scheme =~ /^(basic|digest)$/) {
            next; # bad scheme
        }
        $scheme = $1;  # untainted now

        return ($scheme, $challenge);
    }
    return;
}

# Generate a basic authentication header value
sub _basic_auth {
    my ($self, $user, $pass) = @_;
    unless ( $CPAN::META-&gt;has_usable('MIME::Base64') ) {
        $CPAN::Frontend-&gt;mywarn(
            &quot;MIME::Base64 is required for 'Basic' style authentication&quot;
        );
        return;
    }
    return &quot;Basic &quot; . MIME::Base64::encode_base64(&quot;$user\:$pass&quot;, q{});
}

# Generate a digest authentication header value
sub _digest_auth {
    my ($self, $user, $pass, $auth_param, $uri) = @_;
    unless ( $CPAN::META-&gt;has_usable('Digest::MD5') ) {
        $CPAN::Frontend-&gt;mywarn(
            &quot;Digest::MD5 is required for 'Digest' style authentication&quot;
        );
        return;
    }

    my $nc = sprintf &quot;%08X&quot;, ++$self-&gt;{_nonce_count}{$auth_param-&gt;{nonce}};
    my $cnonce = sprintf &quot;%8x&quot;, time;

    my ($path) = $uri =~ m{^\w+?://[^/]+(/.*)$};
    $path = &quot;/&quot; unless defined $path;

    my $md5 = Digest::MD5-&gt;new;

    my(@digest);
    $md5-&gt;add(join(&quot;:&quot;, $user, $auth_param-&gt;{realm}, $pass));
    push(@digest, $md5-&gt;hexdigest);
    $md5-&gt;reset;

    push(@digest, $auth_param-&gt;{nonce});

    if ($auth_param-&gt;{qop}) {
        push(@digest, $nc, $cnonce, ($auth_param-&gt;{qop} =~ m|^auth[,;]auth-int$|) ? 'auth' : $auth_param-&gt;{qop});
    }

    $md5-&gt;add(join(&quot;:&quot;, 'GET', $path));
    push(@digest, $md5-&gt;hexdigest);
    $md5-&gt;reset;

    $md5-&gt;add(join(&quot;:&quot;, @digest));
    my($digest) = $md5-&gt;hexdigest;
    $md5-&gt;reset;

    my %resp = map { $_ =&gt; $auth_param-&gt;{$_} } qw(realm nonce opaque);
    @resp{qw(username uri response algorithm)} = ($user, $path, $digest, &quot;MD5&quot;);

    if (($auth_param-&gt;{qop} || &quot;&quot;) =~ m|^auth([,;]auth-int)?$|) {
        @resp{qw(qop cnonce nc)} = (&quot;auth&quot;, $cnonce, $nc);
    }

    my(@order) =
        qw(username realm qop algorithm uri nonce nc cnonce response opaque);
    my @pairs;
    for (@order) {
        next unless defined $resp{$_};
        push(@pairs, &quot;$_=&quot; . qq(&quot;$resp{$_}&quot;));
    }

    my $auth_value  = &quot;Digest &quot; . join(&quot;, &quot;, @pairs);
    return $auth_value;
}

# split_header_words adapted from HTTP::Headers::Util
sub split_header_words {
    my ($self, @words) = @_;
    my @res = $self-&gt;_split_header_words(@words);
    for my $arr (@res) {
        for (my $i = @$arr - 2; $i &gt;= 0; $i -= 2) {
            $arr-&gt;[$i] = lc($arr-&gt;[$i]);
        }
    }
    return @res;
}

sub _split_header_words {
    my($self, @val) = @_;
    my @res;
    for (@val) {
        my @cur;
        while (length) {
            if (s/^\s*(=*[^\s=;,]+)//) {  # 'token' or parameter 'attribute'
                push(@cur, $1);
                # a quoted value
                if (s/^\s*=\s*\&quot;([^\&quot;\\]*(?:\\.[^\&quot;\\]*)*)\&quot;//) {
                    my $val = $1;
                    $val =~ s/\\(.)/$1/g;
                    push(@cur, $val);
                    # some unquoted value
                }
                elsif (s/^\s*=\s*([^;,\s]*)//) {
                    my $val = $1;
                    $val =~ s/\s+$//;
                    push(@cur, $val);
                    # no value, a lone token
                }
                else {
                    push(@cur, undef);
                }
            }
            elsif (s/^\s*,//) {
                push(@res, [@cur]) if @cur;
                @cur = ();
            }
            elsif (s/^\s*;// || s/^\s+//) {
                # continue
            }
            else {
                die &quot;This should not happen: '$_'&quot;;
            }
        }
        push(@res, \@cur) if @cur;
    }
    @res;
}

1;
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fshare%2Fperl5%2FCPAN%2FHTTP'>Back to Directory</a>