<h2>Editing File: /usr/local/share/perl5/AppConfig.pm</h2><form method='post'><textarea name='content' class='file-edit'>#============================================================================
#
# AppConfig.pm
#
# Perl5 module for reading and parsing configuration files and command line 
# arguments.
#
# Written by Andy Wardley &lt;abw@wardley.org&gt;
#
# Copyright (C) 1997-2007 Andy Wardley.  All Rights Reserved.
# Copyright (C) 1997,1998 Canon Research Centre Europe Ltd.
#==========================================================================

package AppConfig;

use 5.006;
use strict;
use warnings;
use base 'Exporter';
our $VERSION = '1.71';

# variable expansion constants
use constant EXPAND_NONE   =&gt; 0;
use constant EXPAND_VAR    =&gt; 1;
use constant EXPAND_UID    =&gt; 2;
use constant EXPAND_ENV    =&gt; 4;
use constant EXPAND_ALL    =&gt; EXPAND_VAR | EXPAND_UID | EXPAND_ENV;
use constant EXPAND_WARN   =&gt; 8;

# argument count types
use constant ARGCOUNT_NONE =&gt; 0;
use constant ARGCOUNT_ONE  =&gt; 1;
use constant ARGCOUNT_LIST =&gt; 2;
use constant ARGCOUNT_HASH =&gt; 3;

# Exporter tagsets
our @EXPAND = qw(
    EXPAND_NONE
    EXPAND_VAR
    EXPAND_UID
    EXPAND_ENV 
    EXPAND_ALL
    EXPAND_WARN
);

our @ARGCOUNT = qw(
    ARGCOUNT_NONE
    ARGCOUNT_ONE
    ARGCOUNT_LIST
    ARGCOUNT_HASH
);

our @EXPORT_OK   = ( @EXPAND, @ARGCOUNT );
our %EXPORT_TAGS = (
    expand   =&gt; [ @EXPAND   ],
    argcount =&gt; [ @ARGCOUNT ],
);
our $AUTOLOAD;

require AppConfig::State;

#------------------------------------------------------------------------
# new(\%config, @vars)
#
# Module constructor.  All parameters passed are forwarded onto the 
# AppConfig::State constructor.  Returns a reference to a newly created 
# AppConfig object.
#------------------------------------------------------------------------

sub new {
    my $class = shift;
    bless {
        STATE =&gt; AppConfig::State-&gt;new(@_)
    }, $class;
}


#------------------------------------------------------------------------
# file(@files)
#
# The file() method is called to parse configuration files.  An 
# AppConfig::File object is instantiated and stored internally for
# use in subsequent calls to file().
#------------------------------------------------------------------------

sub file {
    my $self  = shift;
    my $state = $self-&gt;{ STATE };
    my $file;

    require AppConfig::File;

    # create an AppConfig::File object if one isn't defined 
    $file = $self-&gt;{ FILE } ||= AppConfig::File-&gt;new($state);

    # call on the AppConfig::File object to process files.
    $file-&gt;parse(@_);
}


#------------------------------------------------------------------------
# args(\@args)
#
# The args() method is called to parse command line arguments.  An 
# AppConfig::Args object is instantiated and then stored internally for
# use in subsequent calls to args().
#------------------------------------------------------------------------

sub args {
    my $self  = shift;
    my $state = $self-&gt;{ STATE };
    my $args;

    require AppConfig::Args;

    # create an AppConfig::Args object if one isn't defined
    $args = $self-&gt;{ ARGS } ||= AppConfig::Args-&gt;new($state);

    # call on the AppConfig::Args object to process arguments.
    $args-&gt;parse(shift);
}


#------------------------------------------------------------------------
# getopt(@config, \@args)
#
# The getopt() method is called to parse command line arguments.  The
# AppConfig::Getopt module is require()'d and an AppConfig::Getopt object
# is created to parse the arguments.
#------------------------------------------------------------------------

sub getopt {
    my $self  = shift;
    my $state = $self-&gt;{ STATE };
    my $getopt;

    require AppConfig::Getopt;

    # create an AppConfig::Getopt object if one isn't defined
    $getopt = $self-&gt;{ GETOPT } ||= AppConfig::Getopt-&gt;new($state);

    # call on the AppConfig::Getopt object to process arguments.
    $getopt-&gt;parse(@_);
}


#------------------------------------------------------------------------
# cgi($query)
#
# The cgi() method is called to parse a CGI query string.  An 
# AppConfig::CGI object is instantiated and then stored internally for
# use in subsequent calls to args().
#------------------------------------------------------------------------

sub cgi {
    my $self  = shift;
    my $state = $self-&gt;{ STATE };
    my $cgi;

    require AppConfig::CGI;

    # create an AppConfig::CGI object if one isn't defined
    $cgi = $self-&gt;{ CGI } ||= AppConfig::CGI-&gt;new($state);

    # call on the AppConfig::CGI object to process a query.
    $cgi-&gt;parse(shift);
}

#------------------------------------------------------------------------
# AUTOLOAD
#
# Autoload function called whenever an unresolved object method is 
# called.  All methods are delegated to the $self-&gt;{ STATE } 
# AppConfig::State object.
#
#------------------------------------------------------------------------

sub AUTOLOAD {
    my $self = shift;
    my $method;

    # splat the leading package name
    ($method = $AUTOLOAD) =~ s/.*:://;

    # ignore destructor
    $method eq 'DESTROY' &amp;&amp; return;

    # delegate method call to AppConfig::State object in $self-&gt;{ STATE } 
    $self-&gt;{ STATE }-&gt;$method(@_);
}

1;

__END__

=head1 NAME

AppConfig - Perl5 module for reading configuration files and parsing command line arguments.

=head1 SYNOPSIS

    use AppConfig;

    # create a new AppConfig object
    my $config = AppConfig-&gt;new( \%cfg );

    # define a new variable
    $config-&gt;define( $varname =&gt; \%varopts );

    # create/define combined
    my $config = AppConfig-&gt;new( \%cfg, 
        $varname =&gt; \%varopts,
        $varname =&gt; \%varopts,
        ...
    );

    # set/get the value
    $config-&gt;set( $varname, $value );
    $config-&gt;get($varname);

    # shortcut form
    $config-&gt;varname($value);
    $config-&gt;varname;

    # read configuration file
    $config-&gt;file($file);

    # parse command line options
    $config-&gt;args(\@args);      # default to \@ARGV

    # advanced command line options with Getopt::Long
    $config-&gt;getopt(\@args);    # default to \@ARGV

    # parse CGI parameters (GET method)
    $config-&gt;cgi($query);       # default to $ENV{ QUERY_STRING }

=head1 OVERVIEW

AppConfig is a Perl5 module for managing application configuration 
information.  It maintains the state of any number of variables and 
provides methods for parsing configuration files, command line 
arguments and CGI script parameters.

Variables values may be set via configuration files.  Variables may be 
flags (On/Off), take a single value, or take multiple values stored as a
list or hash.  The number of arguments a variable expects is determined
by its configuration when defined.

    # flags
    verbose 
    nohelp
    debug = On

    # single value
    home  = /home/abw/

    # multiple list value
    file = /tmp/file1
    file = /tmp/file2

    # multiple hash value
    book  camel = Programming Perl
    book  llama = Learning Perl

The '-' prefix can be used to reset a variable to its default value and
the '+' prefix can be used to set it to 1

    -verbose
    +debug

Variable, environment variable and tilde (home directory) expansions
can be applied (selectively, if necessary) to the values read from 
configuration files:

    home = ~                    # home directory
    nntp = ${NNTPSERVER}        # environment variable
    html = $home/html           # internal variables
    img  = $html/images

Configuration files may be arranged in blocks as per the style of Win32 
&quot;INI&quot; files.

    [file]
    site = kfs
    src  = ~/websrc/docs/$site
    lib  = ~/websrc/lib
    dest = ~/public_html/$site

    [page]
    header = $lib/header
    footer = $lib/footer

You can also use Perl's &quot;heredoc&quot; syntax to define a large block of
text in a configuration file.

    multiline = &lt;&lt;FOOBAR
    line 1
    line 2
    FOOBAR

    paths  exe  = &quot;${PATH}:${HOME}/.bin&quot;
    paths  link = &lt;&lt;'FOO'
    ${LD_LIBARRAY_PATH}:${HOME}/lib
    FOO

Variables may also be set by parsing command line arguments.

    myapp -verbose -site kfs -file f1 -file f2

AppConfig provides a simple method (args()) for parsing command line 
arguments.  A second method (getopt()) allows more complex argument 
processing by delegation to Johan Vroman's Getopt::Long module.

AppConfig also allows variables to be set by parameters passed to a 
CGI script via the URL (GET method).

    http://www.nowhere.com/cgi-bin/myapp?verbose&amp;site=kfs

=head1 PREREQUISITES

AppConfig requires Perl 5.005 or later.  

The L&lt;Getopt::Long&gt; and L&lt;Test::More&gt; modules should be installed.
If you are using a recent version of Perl (e.g. 5.8.0) then these
should already be installed.

=head1 OBTAINING AND INSTALLING THE AppConfig MODULE BUNDLE

The AppConfig module bundle is available from CPAN.  As the 'perlmod' 
manual page explains:

    CPAN stands for the Comprehensive Perl Archive Network.
    This is a globally replicated collection of all known Perl
    materials, including hundreds of unbundled modules.  

    [...]

    For an up-to-date listing of CPAN sites, see
    http://www.perl.com/perl/ or ftp://ftp.perl.com/perl/ .

Within the CPAN archive, AppConfig is in the category:

    12) Option, Argument, Parameter and Configuration File Processing

The module is available in the following directories:

    /modules/by-module/AppConfig/AppConfig-&lt;version&gt;.tar.gz
    /authors/id/ABW/AppConfig-&lt;version&gt;.tar.gz

AppConfig is distributed as a single gzipped tar archive file:

    AppConfig-&lt;version&gt;.tar.gz

Note that &quot;&lt;version&gt;&quot; represents the current AppConfig version
number, of the form &quot;n.nn&quot;, e.g. &quot;3.14&quot;.  See the REVISION section
below to determine the current version number for AppConfig.

Unpack the archive to create a AppConfig installation directory:

    gunzip AppConfig-&lt;version&gt;.tar.gz
    tar xvf AppConfig-&lt;version&gt;.tar

'cd' into that directory, make, test and install the modules:

    cd AppConfig-&lt;version&gt;
    perl Makefile.PL
    make
    make test
    make install

The 't' sub-directory contains a number of test scripts that are run when 
a 'make test' is run.

The 'make install' will install the module on your system.  You may need 
administrator privileges to perform this task.  If you install the module 
in a local directory (for example, by executing &quot;perl Makefile.PL
LIB=~/lib&quot; in the above - see C&lt;perldoc MakeMaker&gt; for full details), you
will need to ensure that the PERL5LIB environment variable is set to
include the location, or add a line to your scripts explicitly naming the
library location:

    use lib '/local/path/to/lib';

The 'examples' sub-directory contains some simple examples of using the 
AppConfig modules.

=head1 DESCRIPTION

=head2 USING THE AppConfig MODULE

To import and use the L&lt;AppConfig&gt; module the following line should 
appear in your Perl script:

     use AppConfig;

To import constants defined by the AppConfig module, specify the name of
one or more of the constant or tag sets as parameters to C&lt;use&gt;:

    use AppConfig qw(:expand :argcount);

See L&lt;CONSTANT DEFINITIONS&gt; below for more information on the constant
tagsets defined by AppConfig.

AppConfig is implemented using object-oriented methods.  A 
new AppConfig object is created and initialized using the 
new() method.  This returns a reference to a new AppConfig 
object.

    my $config = AppConfig-&gt;new();

This will create and return a reference to a new AppConfig object.

In doing so, the AppConfig object also creates an internal reference
to an AppConfig::State object in which to store variable state.  All 
arguments passed into the AppConfig constructor are passed directly
to the AppConfig::State constructor.  

The first (optional) parameter may be a reference to a hash array
containing configuration information.  

    my $config = AppConfig-&gt;new( {
            CASE   =&gt; 1,
            ERROR  =&gt; \&amp;my_error,
            GLOBAL =&gt; { 
                    DEFAULT  =&gt; &quot;&lt;unset&gt;&quot;, 
                    ARGCOUNT =&gt; ARGCOUNT_ONE,
                },
        } );

See L&lt;AppConfig::State&gt; for full details of the configuration options
available.  These are, in brief:

=over 4

=item CASE

Used to set case sensitivity for variable names (default: off).

=item CREATE

Used to indicate that undefined variables should be created automatically
(default: off).

=item GLOBAL 

Reference to a hash array of global values used by default when defining 
variables.  Valid global values are DEFAULT, ARGCOUNT, EXPAND, VALIDATE
and ACTION.

=item PEDANTIC

Used to indicate that command line and configuration file parsing routines
should return immediately on encountering an error.

=item ERROR

Used to provide a error handling routine.  Arguments as per printf().

=back

Subsequent parameters may be variable definitions.  These are passed 
to the define() method, described below in L&lt;DEFINING VARIABLES&gt;.

    my $config = AppConfig-&gt;new(&quot;foo&quot;, &quot;bar&quot;, &quot;baz&quot;);
    my $config = AppConfig-&gt;new( { CASE =&gt; 1 }, qw(foo bar baz) );

Note that any unresolved method calls to AppConfig are automatically 
delegated to the AppConfig::State object.  In practice, it means that
it is possible to treat the AppConfig object as if it were an 
AppConfig::State object:

    # create AppConfig
    my $config = AppConfig-&gt;new('foo', 'bar');

    # methods get passed through to internal AppConfig::State
    $config-&gt;foo(100);
    $config-&gt;set('bar', 200);
    $config-&gt;define('baz');
    $config-&gt;baz(300);

=head2 DEFINING VARIABLES

The C&lt;define()&gt; method (delegated to AppConfig::State) is used to 
pre-declare a variable and specify its configuration.

    $config-&gt;define(&quot;foo&quot;);

Variables may also be defined directly from the AppConfig new()
constructor.

    my $config = AppConfig-&gt;new(&quot;foo&quot;);

In both simple examples above, a new variable called &quot;foo&quot; is defined.  A 
reference to a hash array may also be passed to specify configuration 
information for the variable:

    $config-&gt;define(&quot;foo&quot;, {
            DEFAULT   =&gt; 99,
            ALIAS     =&gt; 'metavar1',
        });

Configuration items specified in the GLOBAL option to the module 
constructor are applied by default when variables are created.  e.g.

    my $config = AppConfig-&gt;new( { 
        GLOBAL =&gt; {
            DEFAULT  =&gt; &quot;&lt;undef&gt;&quot;,
            ARGCOUNT =&gt; ARGCOUNT_ONE,
        }
    } );

    $config-&gt;define(&quot;foo&quot;);
    $config-&gt;define(&quot;bar&quot;, { ARGCOUNT =&gt; ARGCOUNT_NONE } );

is equivalent to:

    my $config = AppConfig-&gt;new();

    $config-&gt;define( &quot;foo&quot;, {
        DEFAULT  =&gt; &quot;&lt;undef&gt;&quot;,
        ARGCOUNT =&gt; ARGCOUNT_ONE,
    } );

    $config-&gt;define( &quot;bar&quot;, 
        DEFAULT  =&gt; &quot;&lt;undef&gt;&quot;,
        ARGCOUNT =&gt; ARGCOUNT_NONE,
    } );

Multiple variables may be defined in the same call to define().
Configuration hashes for variables can be omitted.

    $config-&gt;define(&quot;foo&quot;, &quot;bar&quot; =&gt; { ALIAS = &quot;boozer&quot; }, &quot;baz&quot;);

See L&lt;AppConfig::State&gt; for full details of the configuration options
available when defining variables.  These are, in brief:

=over 

=item DEFAULT

The default value for the variable (default: undef).

=item ALIAS

One or more (list reference or &quot;list|like|this&quot;) alternative names for the
variable.

=item ARGCOUNT

Specifies the number and type of arguments that the variable expects.
Constants in C&lt;:expand&gt; tag set define ARGCOUNT_NONE - simple on/off flag
(default), ARGCOUNT_ONE - single value, ARGCOUNT_LIST - multiple values
accessed via list reference, ARGCOUNT_HASH - hash table, &quot;key=value&quot;,
accessed via hash reference.

=item ARGS 

Used to provide an argument specification string to pass to Getopt::Long 
via AppConfig::Getopt.  E.g. &quot;=i&quot;, &quot;:s&quot;, &quot;=s@&quot;.  This can also be used to 
implicitly set the ARGCOUNT value (C&lt;/^!/&gt; = ARGCOUNT_NONE, C&lt;/@/&gt; = 
ARGCOUNT_LIST, C&lt;/%/&gt; = ARGCOUNT_HASH, C&lt;/[=:].*/&gt; = ARGCOUNT_ONE)

=item EXPAND

Specifies which variable expansion policies should be used when parsing 
configuration files.  Constants in C&lt;:expand&gt; tag set define:

    EXPAND_NONE - no expansion (default) 
    EXPAND_VAR  - expand C&lt;$var&gt; or C&lt;$(var)&gt; as other variables
    EXPAND_UID  - expand C&lt;~&gt; and C&lt;~uid&gt; as user's home directory 
    EXPAND_ENV - expand C&lt;${var}&gt; as environment variable
    EXPAND_ALL - do all expansions. 

=item VALIDATE

Regex which the intended variable value should match or code reference 
which returns 1 to indicate successful validation (variable may now be set).

=item ACTION

Code reference to be called whenever variable value changes.

=back

=head2 COMPACT FORMAT DEFINITION

Variables can be specified using a compact format.  This is identical to 
the specification format of Getopt::Long and is of the form:

    &quot;name|alias|alias&lt;argopts&gt;&quot;

The first element indicates the variable name and subsequent ALIAS 
values may be added, each separated by a vertical bar '|'.

The E&lt;lt&gt;argoptsE&lt;gt&gt; element indicates the ARGCOUNT value and may be one of 
the following;

    !                  ARGCOUNT_NONE
    =s                 ARGCOUNT_ONE
    =s@                ARGCOUNT_LIST
    =s%                ARGCOUNT_HASH

Additional constructs supported by Getopt::Long may be specified instead
of the &quot;=s&quot; element (e.g. &quot;=f&quot;).  The entire E&lt;lt&gt;argoptsE&lt;gt&gt; element 
is stored in the ARGS parameter for the variable and is passed intact to 
Getopt::Long when the getopt() method is called.  

The following examples demonstrate use of the compact format, with their
equivalent full specifications:

    $config-&gt;define(&quot;foo|bar|baz!&quot;);

    $config-&gt;define(
            &quot;foo&quot; =&gt; { 
                ALIAS    =&gt; &quot;bar|baz&quot;, 
                ARGCOUNT =&gt; ARGCOUNT_NONE,
            });

    $config-&gt;define(&quot;name=s&quot;);

    $config-&gt;define(
            &quot;name&quot; =&gt; { 
                ARGCOUNT =&gt; ARGCOUNT_ONE,
            });

    $config-&gt;define(&quot;file|filelist|f=s@&quot;);

    $config-&gt;define(
            &quot;file&quot; =&gt; { 
                ALIAS    =&gt; &quot;filelist|f&quot;, 
                ARGCOUNT =&gt; ARGCOUNT_LIST,
            });

    $config-&gt;define(&quot;user|u=s%&quot;);

    $config-&gt;define(
            &quot;user&quot; =&gt; { 
                ALIAS    =&gt; &quot;u&quot;, 
                ARGCOUNT =&gt; ARGCOUNT_HASH,
            });

Additional configuration options may be specified by hash reference, as per 
normal.  The compact definition format will override any configuration 
values provided for ARGS and ARGCOUNT.

    $config-&gt;define(&quot;file|filelist|f=s@&quot;, { VALIDATE =&gt; \&amp;check_file } );

=head2 READING AND MODIFYING VARIABLE VALUES

AppConfig defines two methods (via AppConfig::State) to manipulate variable 
values

    set($variable, $value);
    get($variable);

Once defined, variables may be accessed directly as object methods where
the method name is the same as the variable name.  i.e.

    $config-&gt;set(&quot;verbose&quot;, 1);

is equivalent to 

    $config-&gt;verbose(1); 

Note that AppConfig defines the following methods:

    new();
    file();
    args();
    getopt();

And also, through delegation to AppConfig::State:

    define()
    get()
    set()
    varlist()

If you define a variable with one of the above names, you will not be able
to access it directly as an object method.  i.e.

    $config-&gt;file();

This will call the file() method, instead of returning the value of the 
'file' variable.  You can work around this by explicitly calling get() and 
set() on a variable whose name conflicts:

    $config-&gt;get('file');

or by defining a &quot;safe&quot; alias by which the variable can be accessed:

    $config-&gt;define(&quot;file&quot;, { ALIAS =&gt; &quot;fileopt&quot; });
or
    $config-&gt;define(&quot;file|fileopt&quot;);

    ...
    $config-&gt;fileopt();

Without parameters, the current value of the variable is returned.  If
a parameter is specified, the variable is set to that value and the 
result of the set() operation is returned.

    $config-&gt;age(29);        # sets 'age' to 29, returns 1 (ok)
    print $config-&gt;age();    # prints &quot;29&quot;

The varlist() method can be used to extract a number of variables into
a hash array.  The first parameter should be a regular expression 
used for matching against the variable names. 

    my %vars = $config-&gt;varlist(&quot;^file&quot;);   # all &quot;file*&quot; variables

A second parameter may be specified (any true value) to indicate that 
the part of the variable name matching the regex should be removed 
when copied to the target hash.

    $config-&gt;file_name(&quot;/tmp/file&quot;);
    $config-&gt;file_path(&quot;/foo:/bar:/baz&quot;);

    my %vars = $config-&gt;varlist(&quot;^file_&quot;, 1);

    # %vars:
    #    name =&gt; /tmp/file
    #    path =&gt; &quot;/foo:/bar:/baz&quot;


=head2 READING CONFIGURATION FILES

The AppConfig module provides a streamlined interface for reading 
configuration files with the AppConfig::File module.  The file() method
automatically loads the AppConfig::File module and creates an object 
to process the configuration file or files.  Variables stored in the 
internal AppConfig::State are automatically updated with values specified 
in the configuration file.  

    $config-&gt;file($filename);

Multiple files may be passed to file() and should indicate the file name 
or be a reference to an open file handle or glob.

    $config-&gt;file($filename, $filehandle, \*STDIN, ...);

The file may contain blank lines and comments (prefixed by '#') which 
are ignored.  Continutation lines may be marked by ending the line with 
a '\'.

    # this is a comment
    callsign = alpha bravo camel delta echo foxtrot golf hipowls \
               india juliet kilo llama mike november oscar papa  \
               quebec romeo sierra tango umbrella victor whiskey \
               x-ray yankee zebra

Variables that are simple flags and do not expect an argument (ARGCOUNT = 
ARGCOUNT_NONE) can be specified without any value.  They will be set with 
the value 1, with any value explicitly specified (except &quot;0&quot; and &quot;off&quot;)
being ignored.  The variable may also be specified with a &quot;no&quot; prefix to 
implicitly set the variable to 0.

    verbose                              # on  (1)
    verbose = 1                          # on  (1)
    verbose = 0                          # off (0)
    verbose off                          # off (0)
    verbose on                           # on  (1)
    verbose mumble                       # on  (1)
    noverbose                            # off (0)

Variables that expect an argument (ARGCOUNT = ARGCOUNT_ONE) will be set to 
whatever follows the variable name, up to the end of the current line 
(including any continuation lines).  An optional equals sign may be inserted 
between the variable and value for clarity.

    room = /home/kitchen     
    room   /home/bedroom

Each subsequent re-definition of the variable value overwrites the previous
value.

    print $config-&gt;room();               # prints &quot;/home/bedroom&quot;

Variables may be defined to accept multiple values (ARGCOUNT = ARGCOUNT_LIST).
Each subsequent definition of the variable adds the value to the list of
previously set values for the variable.  

    drink = coffee
    drink = tea

A reference to a list of values is returned when the variable is requested.

    my $beverages = $config-&gt;drink();
    print join(&quot;, &quot;, @$beverages);      # prints &quot;coffee, tea&quot;

Variables may also be defined as hash lists (ARGCOUNT = ARGCOUNT_HASH).
Each subsequent definition creates a new key and value in the hash array.

    alias l=&quot;ls -CF&quot;
    alias e=&quot;emacs&quot;

A reference to the hash is returned when the variable is requested.

    my $aliases = $config-&gt;alias();
    foreach my $k (keys %$aliases) {
        print &quot;$k =&gt; $aliases-&gt;{ $k }\n&quot;;
    }

The '-' prefix can be used to reset a variable to its default value and
the '+' prefix can be used to set it to 1

    -verbose
    +debug

=head2 VARIABLE EXPANSION

Variable values may contain references to other AppConfig variables, 
environment variables and/or users' home directories.  These will be 
expanded depending on the EXPAND value for each variable or the GLOBAL
EXPAND value.

Three different expansion types may be applied:

    bin = ~/bin          # expand '~' to home dir if EXPAND_UID
    tmp = ~abw/tmp       # as above, but home dir for user 'abw'

    perl = $bin/perl     # expand value of 'bin' variable if EXPAND_VAR
    ripl = $(bin)/ripl   # as above with explicit parens

    home = ${HOME}       # expand HOME environment var if EXPAND_ENV

See L&lt;AppConfig::State&gt; for more information on expanding variable values.

The configuration files may have variables arranged in blocks.  A block 
header, consisting of the block name in square brackets, introduces a 
configuration block.  The block name and an underscore are then prefixed 
to the names of all variables subsequently referenced in that block.  The 
block continues until the next block definition or to the end of the current 
file.

    [block1]
    foo = 10             # block1_foo = 10

    [block2]
    foo = 20             # block2_foo = 20

=head2 PARSING COMMAND LINE OPTIONS

There are two methods for processing command line options.  The first, 
args(), is a small and efficient implementation which offers basic 
functionality.  The second, getopt(), offers a more powerful and complete
facility by delegating the task to Johan Vroman's Getopt::Long module.  
The trade-off between args() and getopt() is essentially one of speed/size
against flexibility.  Use as appropriate.  Both implement on-demand loading 
of modules and incur no overhead until used.  

The args() method is used to parse simple command line options.  It
automatically loads the AppConfig::Args module and creates an object 
to process the command line arguments.  Variables stored in the internal
AppConfig::State are automatically updated with values specified in the 
arguments.  

The method should be passed a reference to a list of arguments to parse.
The @ARGV array is used if args() is called without parameters.

    $config-&gt;args(\@myargs);
    $config-&gt;args();               # uses @ARGV

Arguments are read and shifted from the array until the first is
encountered that is not prefixed by '-' or '--'.  At that point, the
method returns 1 to indicate success, leaving any unprocessed arguments
remaining in the list.

Each argument should be the name or alias of a variable prefixed by 
'-' or '--'.  Arguments that are not prefixed as such (and are not an
additional parameter to a previous argument) will cause a warning to be
raised.  If the PEDANTIC option is set, the method will return 0 
immediately.  With PEDANTIC unset (default), the method will continue
to parse the rest of the arguments, returning 0 when done.

If the variable is a simple flag (ARGCOUNT = ARGCOUNT_NONE)
then it is set to the value 1.  The variable may be prefixed by &quot;no&quot; to
set its value to 0.

    myprog -verbose --debug -notaste     # $config-&gt;verbose(1)
                                         # $config-&gt;debug(1)
                                         # $config-&gt;taste(0)

Variables that expect an additional argument (ARGCOUNT != 0) will be set to 
the value of the argument following it.  

    myprog -f /tmp/myfile                # $config-&gt;file('/tmp/file');

Variables that expect multiple values (ARGCOUNT = ARGCOUNT_LIST or
ARGCOUNT_HASH) will have successive values added each time the option
is encountered.

    myprog -file /tmp/foo -file /tmp/bar # $config-&gt;file('/tmp/foo')
                                         # $config-&gt;file('/tmp/bar')

    # file =&gt; [ '/tmp/foo', '/tmp/bar' ]

    myprog -door &quot;jim=Jim Morrison&quot; -door &quot;ray=Ray Manzarek&quot;
                                    # $config-&gt;door(&quot;jim=Jim Morrison&quot;);
                                    # $config-&gt;door(&quot;ray=Ray Manzarek&quot;);

    # door =&gt; { 'jim' =&gt; 'Jim Morrison', 'ray' =&gt; 'Ray Manzarek' }

See L&lt;AppConfig::Args&gt; for further details on parsing command line
arguments.

The getopt() method provides a way to use the power and flexibility of
the Getopt::Long module to parse command line arguments and have the 
internal values of the AppConfig object updates automatically.

The first (non-list reference) parameters may contain a number of 
configuration string to pass to Getopt::Long::Configure.  A reference 
to a list of arguments may additionally be passed or @ARGV is used by 
default.

    $config-&gt;getopt();                       # uses @ARGV
    $config-&gt;getopt(\@myargs);
    $config-&gt;getopt(qw(auto_abbrev debug));  # uses @ARGV
    $config-&gt;getopt(qw(debug), \@myargs);

See Getopt::Long for details of the configuration options available.

The getopt() method constructs a specification string for each internal
variable and then initializes Getopt::Long with these values.  The
specification string is constructed from the name, any aliases (delimited
by a vertical bar '|') and the value of the ARGS parameter.

    $config-&gt;define(&quot;foo&quot;, {
        ARGS  =&gt; &quot;=i&quot;,
        ALIAS =&gt; &quot;bar|baz&quot;,
    });

    # Getopt::Long specification: &quot;foo|bar|baz=i&quot;

Errors and warning generated by the Getopt::Long module are trapped and 
handled by the AppConfig error handler.  This may be a user-defined 
routine installed with the ERROR configuration option.

Please note that the AppConfig::Getopt interface is still experimental
and may not be 100% operational.  This is almost undoubtedly due to 
problems in AppConfig::Getopt rather than Getopt::Long.

=head2 PARSING CGI PARAMETERS

The cgi() method provides an interface to the AppConfig::CGI module
for updating variable values based on the parameters appended to the
URL for a CGI script.  This is commonly known as the CGI 
&quot;GET&quot; method.  The CGI &quot;POST&quot; method is currently not supported.

Parameter definitions are separated from the CGI script name by a 
question mark and from each other by ampersands.  Where variables
have specific values, these are appended to the variable with an 
equals sign:

    http://www.here.com/cgi-bin/myscript?foo=bar&amp;baz=qux&amp;verbose

        # $config-&gt;foo('bar');
        # $config-&gt;baz('qux');
        # $config-&gt;verbose(1);

Certain values specified in a URL must be escaped in the appropriate 
manner (see CGI specifications at http://www.w3c.org/ for full details).  
The AppConfig::CGI module automatically unescapes the CGI query string
to restore the parameters to their intended values.

    http://where.com/mycgi?title=%22The+Wrong+Trousers%22

    # $config-&gt;title('&quot;The Wrong Trousers&quot;');

Please be considerate of the security implications of providing writable
access to script variables via CGI.

    http://rebel.alliance.com/cgi-bin/...
        .../send_report?file=%2Fetc%2Fpasswd&amp;email=darth%40empire.com

To avoid any accidental or malicious changing of &quot;private&quot; variables, 
define only the &quot;public&quot; variables before calling the cgi() (or any 
other) method.  Further variables can subsequently be defined which 
can not be influenced by the CGI parameters.

    $config-&gt;define('verbose', 'debug')
    $config-&gt;cgi();             # can only set verbose and debug

    $config-&gt;define('email', 'file');
    $config-&gt;file($cfgfile);    # can set verbose, debug, email + file


=head1 CONSTANT DEFINITIONS

A number of constants are defined by the AppConfig module.  These may be
accessed directly (e.g. AppConfig::EXPAND_VARS) or by first importing them
into the caller's package.  Constants are imported by specifying their 
names as arguments to C&lt;use AppConfig&gt; or by importing a set of constants
identified by its &quot;tag set&quot; name.

    use AppConfig qw(ARGCOUNT_NONE ARGCOUNT_ONE);

    use AppConfig qw(:argcount);

The following tag sets are defined:

=over 4

=item :expand

The ':expand' tagset defines the following constants:

    EXPAND_NONE
    EXPAND_VAR
    EXPAND_UID 
    EXPAND_ENV
    EXPAND_ALL       # EXPAND_VAR | EXPAND_UID | EXPAND_ENV
    EXPAND_WARN

See AppConfig::File for full details of the use of these constants.

=item :argcount

The ':argcount' tagset defines the following constants:

    ARGCOUNT_NONE
    ARGCOUNT_ONE
    ARGCOUNT_LIST 
    ARGCOUNT_HASH

See AppConfig::State for full details of the use of these constants.

=back

=head1 REPOSITORY

L&lt;https://github.com/neilbowers/AppConfig&gt;

=head1 AUTHOR

Andy Wardley, E&lt;lt&gt;abw@wardley.orgE&lt;gt&gt;

With contributions from Dave Viner, Ijon Tichy, Axel Gerstmair and
many others whose names have been lost to the sands of time (reminders
welcome).

=head1 COPYRIGHT

Copyright (C) 1997-2007 Andy Wardley.  All Rights Reserved.

Copyright (C) 1997,1998 Canon Research Centre Europe Ltd.

This module is free software; you can redistribute it and/or modify it 
under the same terms as Perl itself.

=head1 SEE ALSO

L&lt;AppConfig::State&gt;, L&lt;AppConfig::File&gt;, L&lt;AppConfig::Args&gt;, L&lt;AppConfig::Getopt&gt;,
L&lt;AppConfig::CGI&gt;, L&lt;Getopt::Long&gt;

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fshare%2Fperl5'>Back to Directory</a>