<h2>Editing File: /usr/local/share/perl5/Alien/Build/Plugin/Probe/CommandLine.pm</h2><form method='post'><textarea name='content' class='file-edit'>package Alien::Build::Plugin::Probe::CommandLine;

use strict;
use warnings;
use 5.008004;
use Alien::Build::Plugin;
use Carp ();
use Capture::Tiny qw( capture );
use File::Which ();
use Alien::Util qw( version_cmp );

# ABSTRACT: Probe for tools or commands already available
our $VERSION = '2.83'; # VERSION


has '+command' =&gt; sub { Carp::croak &quot;@{[ __PACKAGE__ ]} requires command property&quot; };


has 'args'       =&gt; [];


has 'secondary' =&gt; 0;


has 'match'     =&gt; undef;


has 'match_stderr' =&gt; undef;


has 'version'   =&gt; undef;


has 'version_stderr' =&gt; undef;


has 'atleast_version' =&gt; undef;


sub init
{
  my($self, $meta) = @_;

  my $check = sub {
    my($build) = @_;

    unless(File::Which::which($self-&gt;command))
    {
      die 'Command not found ' . $self-&gt;command;
    }

    if(defined $self-&gt;match || defined $self-&gt;match_stderr || defined $self-&gt;version || defined $self-&gt;version_stderr)
    {
      my($out,$err,$ret) = capture {
        system( $self-&gt;command, @{ $self-&gt;args } );
      };
      die 'Command did not return a true value' if $ret;
      die 'Command output did not match' if defined $self-&gt;match &amp;&amp; $out !~ $self-&gt;match;
      die 'Command standard error did not match' if defined $self-&gt;match_stderr &amp;&amp; $err !~ $self-&gt;match_stderr;
      if (defined $self-&gt;version or defined $self-&gt;version_stderr)
      {
        my $found_version = '0';
        if(defined $self-&gt;version)
        {
          if($out =~ $self-&gt;version)
          {
            $found_version = $1;
            $build-&gt;runtime_prop-&gt;{version} = $found_version;
          }
        }
        if(defined $self-&gt;version_stderr)
        {
          if($err =~ $self-&gt;version_stderr)
          {
            $found_version = $1;
            $build-&gt;hook_prop-&gt;{version} = $found_version;
            $build-&gt;runtime_prop-&gt;{version} = $found_version;
          }
        }
        if (my $atleast_version = $self-&gt;atleast_version)
        {
          if(version_cmp ($found_version, $self-&gt;atleast_version) &lt; 0)
          {
            #  reset the versions
            $build-&gt;runtime_prop-&gt;{version} = undef;
            $build-&gt;hook_prop-&gt;{version} = undef;
            die &quot;CommandLine probe found version $found_version, but at least $atleast_version is required.&quot;;
          }
        }
      }
    }

    $build-&gt;runtime_prop-&gt;{command} = $self-&gt;command;
    'system';
  };

  if($self-&gt;secondary)
  {
    $meta-&gt;around_hook(
      probe =&gt; sub {
        my $orig = shift;
        my $build = shift;
        my $type = $orig-&gt;($build, @_);
        return $type unless $type eq 'system';
        $check-&gt;($build);
      },
    );
  }
  else
  {
    $meta-&gt;register_hook(
      probe =&gt; $check,
    );
  }
}

1;

__END__

=pod

=encoding UTF-8

=head1 NAME

Alien::Build::Plugin::Probe::CommandLine - Probe for tools or commands already available

=head1 VERSION

version 2.83

=head1 SYNOPSIS

 use alienfile;
 plugin 'Probe::CommandLine' =&gt; (
   command =&gt; 'gzip',
   args    =&gt; [ '--version' ],
   match   =&gt; qr/gzip/,
   version =&gt; qr/gzip ([0-9\.]+)/,
 );

=head1 DESCRIPTION

This plugin probes for the existence of the given command line program.

=head1 PROPERTIES

=head2 command

The name of the command.

=head2 args

The arguments to pass to the command.

=head2 secondary

If you are using another probe plugin (such as L&lt;Alien::Build::Plugin::Probe::CBuilder&gt; or
L&lt;Alien::Build::Plugin::PkgConfig::Negotiate&gt;) to detect the existence of a library, but
also need a program to exist, then you should set secondary to a true value.  For example
when you need both:

 use alienfile;
 # requires both liblzma library and xz program
 plugin 'PkgConfig' =&gt; 'liblzma';
 plugin 'Probe::CommandLine' =&gt; (
   command   =&gt; 'xz',
   secondary =&gt; 1,
 );

When you don't:

 use alienfile;
 plugin 'Probe::CommandLine' =&gt; (
   command   =&gt; 'gzip',
   secondary =&gt; 0, # default
 );

=head2 match

Regular expression for which the program output should match.

=head2 match_stderr

Regular expression for which the program standard error should match.

=head2 version

Regular expression to parse out the version from the program output.
The regular expression should store the version number in C&lt;$1&gt;.

=head2 version_stderr

Regular expression to parse out the version from the program standard error.
The regular expression should store the version number in C&lt;$1&gt;.

=head2 atleast_version

The minimum required version as provided by the system.

=head1 SEE ALSO

L&lt;Alien::Build&gt;, L&lt;alienfile&gt;, L&lt;Alien::Build::MM&gt;, L&lt;Alien&gt;

=head1 AUTHOR

Author: Graham Ollis E&lt;lt&gt;plicease@cpan.orgE&lt;gt&gt;

Contributors:

Diab Jerius (DJERIUS)

Roy Storey (KIWIROY)

Ilya Pavlov

David Mertens (run4flat)

Mark Nunberg (mordy, mnunberg)

Christian Walde (Mithaldu)

Brian Wightman (MidLifeXis)

Zaki Mughal (zmughal)

mohawk (mohawk2, ETJ)

Vikas N Kumar (vikasnkumar)

Flavio Poletti (polettix)

Salvador Fandiño (salva)

Gianni Ceccarelli (dakkar)

Pavel Shaydo (zwon, trinitum)

Kang-min Liu (劉康民, gugod)

Nicholas Shipp (nshp)

Juan Julián Merelo Guervós (JJ)

Joel Berger (JBERGER)

Petr Písař (ppisar)

Lance Wicks (LANCEW)

Ahmad Fatoum (a3f, ATHREEF)

José Joaquín Atria (JJATRIA)

Duke Leto (LETO)

Shoichi Kaji (SKAJI)

Shawn Laffan (SLAFFAN)

Paul Evans (leonerd, PEVANS)

Håkon Hægland (hakonhagland, HAKONH)

nick nauwelaerts (INPHOBIA)

Florian Weimer

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2011-2022 by Graham Ollis.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fshare%2Fperl5%2FAlien%2FBuild%2FPlugin%2FProbe'>Back to Directory</a>