<h2>Editing File: /usr/local/share/perl5/Alien/Build/Plugin/Probe/CBuilder.pm</h2><form method='post'><textarea name='content' class='file-edit'>package Alien::Build::Plugin::Probe::CBuilder;

use strict;
use warnings;
use 5.008004;
use Alien::Build::Plugin;
use File::chdir;
use File::Temp ();
use Capture::Tiny qw( capture_merged capture );
use Alien::Util qw( version_cmp );

# ABSTRACT: Probe for system libraries by guessing with ExtUtils::CBuilder
our $VERSION = '2.83'; # VERSION


has options =&gt; sub { {} };


has cflags  =&gt; '';


has libs    =&gt; '';


has program =&gt; 'int main(int argc, char *argv[]) { return 0; }';


has version =&gt; undef;


has 'atleast_version' =&gt; undef;


has aliens =&gt; [];


has lang =&gt; 'C';

sub init
{
  my($self, $meta) = @_;

  $meta-&gt;add_requires('configure' =&gt; 'ExtUtils::CBuilder' =&gt; 0 );

  if(@{ $self-&gt;aliens })
  {
    die &quot;You can't specify both 'aliens' and either 'cflags' or 'libs' for the Probe::CBuilder plugin&quot; if $self-&gt;cflags || $self-&gt;libs;

    $meta-&gt;add_requires('configure' =&gt; $_ =&gt; 0 ) for @{ $self-&gt;aliens };
    $meta-&gt;add_requires('Alien::Build::Plugin::Probe::CBuilder' =&gt; '0.53');

    my $cflags = '';
    my $libs   = '';
    foreach my $alien (@{ $self-&gt;aliens })
    {
      my $pm = &quot;$alien.pm&quot;;
      $pm =~ s/::/\//g;
      require $pm;
      $cflags .= $alien-&gt;cflags . ' ';
      $libs   .= $alien-&gt;libs   . ' ';
    }
    $self-&gt;cflags($cflags);
    $self-&gt;libs($libs);
  }

  my @cpp;

  if($self-&gt;lang ne 'C')
  {
    $meta-&gt;add_requires('Alien::Build::Plugin::Probe::CBuilder' =&gt; '0.53');
    @cpp = ('C++' =&gt; 1) if $self-&gt;lang eq 'C++';
  }

  $meta-&gt;register_hook(
    probe =&gt; sub {
      my($build) = @_;

      $build-&gt;hook_prop-&gt;{probe_class} = __PACKAGE__;
      $build-&gt;hook_prop-&gt;{probe_instance_id} = $self-&gt;instance_id;

      local $CWD = File::Temp::tempdir( CLEANUP =&gt; 1, DIR =&gt; $CWD );

      open my $fh, '&gt;', 'mytest.c';
      print $fh $self-&gt;program;
      close $fh;

      $build-&gt;log(&quot;trying: cflags=@{[ $self-&gt;cflags ]} libs=@{[ $self-&gt;libs ]}&quot;);

      my $cb = ExtUtils::CBuilder-&gt;new(%{ $self-&gt;options });

      my($out1, $obj) = capture_merged { eval {
        $cb-&gt;compile(
          source               =&gt; 'mytest.c',
          extra_compiler_flags =&gt; $self-&gt;cflags,
          @cpp,
        );
      } };

      if(my $error = $@)
      {
        $build-&gt;log(&quot;compile failed: $error&quot;);
        $build-&gt;log(&quot;compile failed: $out1&quot;);
        die $error;
      }

      my($out2, $exe) = capture_merged { eval {
        $cb-&gt;link_executable(
          objects              =&gt; [$obj],
          extra_linker_flags   =&gt; $self-&gt;libs,
        );
      } };

      if(my $error = $@)
      {
        $build-&gt;log(&quot;link failed: $error&quot;);
        $build-&gt;log(&quot;link failed: $out2&quot;);
        die $error;
      }

      my($out, $err, $ret) = capture { system($^O eq 'MSWin32' ? $exe : &quot;./$exe&quot;) };
      die &quot;execute failed&quot; if $ret;

      my $cflags = $self-&gt;cflags;
      my $libs   = $self-&gt;libs;

      $cflags =~ s{\s*$}{ };
      $libs =~ s{\s*$}{ };

      $build-&gt;install_prop-&gt;{plugin_probe_cbuilder_gather}-&gt;{$self-&gt;instance_id} = {
        cflags  =&gt; $cflags,
        libs    =&gt; $libs,
      };

      if(defined $self-&gt;version)
      {
        my($version) = $out =~ $self-&gt;version;
        if (defined $self-&gt;atleast_version)
        {
          if(version_cmp ($version, $self-&gt;atleast_version) &lt; 0)
          {
            die &quot;CBuilder probe found version $version, but at least @{[ $self-&gt;atleast_version ]} is required.&quot;;
          }
        }
        $build-&gt;hook_prop-&gt;{version} = $version;
        $build-&gt;install_prop-&gt;{plugin_probe_cbuilder_gather}-&gt;{$self-&gt;instance_id}-&gt;{version} = $version;
      }

      'system';
    }
  );

  $meta-&gt;register_hook(
    gather_system =&gt; sub {
      my($build) = @_;

      return if $build-&gt;hook_prop-&gt;{name} eq 'gather_system'
      &amp;&amp;        ($build-&gt;install_prop-&gt;{system_probe_instance_id} || '') ne $self-&gt;instance_id;

      if(my $p = $build-&gt;install_prop-&gt;{plugin_probe_cbuilder_gather}-&gt;{$self-&gt;instance_id})
      {
        $build-&gt;runtime_prop-&gt;{$_} = $p-&gt;{$_} for keys %$p;
      }
    },
  );
}

1;

__END__

=pod

=encoding UTF-8

=head1 NAME

Alien::Build::Plugin::Probe::CBuilder - Probe for system libraries by guessing with ExtUtils::CBuilder

=head1 VERSION

version 2.83

=head1 SYNOPSIS

 use alienfile;
 plugin 'Probe::CBuilder' =&gt; (
   cflags =&gt; '-I/opt/libfoo/include',
   libs   =&gt; '-L/opt/libfoo/lib -lfoo',
 );

alternately:

 ues alienfile;
 plugin 'Probe::CBuilder' =&gt; (
   aliens =&gt; [ 'Alien::libfoo', 'Alien::libbar' ],
 );

=head1 DESCRIPTION

This plugin probes for compiler and linker flags using L&lt;ExtUtils::CBuilder&gt;.  This is a useful
alternative to L&lt;Alien::Build::Plugin::PkgConfig::Negotiate&gt; for packages that do not provide
a pkg-config C&lt;.pc&gt; file, or for when those C&lt;.pc&gt; files may not be available.  (For example,
on FreeBSD, C&lt;libarchive&gt; is a core part of the operating system, but doesn't include a C&lt;.pc&gt;
file which is usually provided when you install the C&lt;libarchive&gt; package on Linux).

=head1 PROPERTIES

=head2 options

Any extra options that you want to have passed into the constructor to L&lt;ExtUtils::CBuilder&gt;.

=head2 cflags

The compiler flags.

=head2 libs

The linker flags

=head2 program

The program to use in the test.

=head2 version

This is a regular expression to parse the version out of the output from the
test program.

=head2 atleast_version

The minimum required version as provided by the system.

=head2 aliens

List of aliens to query fro compiler and linker flags.

=head2 lang

The programming language to use.  One of either C&lt;C&gt; or C&lt;C++&gt;.

=head1 SEE ALSO

L&lt;Alien::Build&gt;, L&lt;alienfile&gt;, L&lt;Alien::Build::MM&gt;, L&lt;Alien&gt;

=head1 AUTHOR

Author: Graham Ollis E&lt;lt&gt;plicease@cpan.orgE&lt;gt&gt;

Contributors:

Diab Jerius (DJERIUS)

Roy Storey (KIWIROY)

Ilya Pavlov

David Mertens (run4flat)

Mark Nunberg (mordy, mnunberg)

Christian Walde (Mithaldu)

Brian Wightman (MidLifeXis)

Zaki Mughal (zmughal)

mohawk (mohawk2, ETJ)

Vikas N Kumar (vikasnkumar)

Flavio Poletti (polettix)

Salvador Fandiño (salva)

Gianni Ceccarelli (dakkar)

Pavel Shaydo (zwon, trinitum)

Kang-min Liu (劉康民, gugod)

Nicholas Shipp (nshp)

Juan Julián Merelo Guervós (JJ)

Joel Berger (JBERGER)

Petr Písař (ppisar)

Lance Wicks (LANCEW)

Ahmad Fatoum (a3f, ATHREEF)

José Joaquín Atria (JJATRIA)

Duke Leto (LETO)

Shoichi Kaji (SKAJI)

Shawn Laffan (SLAFFAN)

Paul Evans (leonerd, PEVANS)

Håkon Hægland (hakonhagland, HAKONH)

nick nauwelaerts (INPHOBIA)

Florian Weimer

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2011-2022 by Graham Ollis.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fshare%2Fperl5%2FAlien%2FBuild%2FPlugin%2FProbe'>Back to Directory</a>