<h2>Editing File: /usr/local/share/perl5/Alien/Build/Plugin/PkgConfig/PP.pm</h2><form method='post'><textarea name='content' class='file-edit'>package Alien::Build::Plugin::PkgConfig::PP;

use strict;
use warnings;
use 5.008004;
use Alien::Build::Plugin;
use Carp ();
use File::Which ();
use Env qw( @PKG_CONFIG_PATH );

# ABSTRACT: Probe system and determine library or tool properties using PkgConfig.pm
our $VERSION = '2.83'; # VERSION


has '+pkg_name' =&gt; sub {
  Carp::croak &quot;pkg_name is a required property&quot;;
};


has atleast_version =&gt; undef;


has exact_version =&gt; undef;


has max_version =&gt; undef;


has minimum_version =&gt; undef;


use constant _min_version =&gt; '0.14026';

# private for now, used by negotiator
has register_prereqs =&gt; 1;

sub available
{
  !!eval { require PkgConfig; PkgConfig-&gt;VERSION(_min_version) };
}

sub _cleanup
{
  my($value) = @_;
  $value =~ s{\s*$}{ };
  $value;
}

sub init
{
  my($self, $meta) = @_;

  unless(defined $meta-&gt;prop-&gt;{env}-&gt;{PKG_CONFIG})
  {
    # TODO: Better would be to to &quot;execute&quot; lib/PkgConfig.pm
    # as that should always be available, and will match the
    # exact version of PkgConfig.pm that we are using here.
    # there are a few corner cases to deal with before we
    # can do this.  What is here should handle most use cases.
    my $command_line =
      File::Which::which('ppkg-config')
      ? 'ppkg-config'
      : File::Which::which('pkg-config.pl')
        ? 'pkg-config.pl'
        : File::Which::which('pkg-config')
          ? 'pkg-config'
          : undef;
    $meta-&gt;prop-&gt;{env}-&gt;{PKG_CONFIG} = $command_line
      if defined $command_line;
  }

  if($self-&gt;register_prereqs)
  {
    $meta-&gt;add_requires('configure' =&gt; 'PkgConfig' =&gt; _min_version);
  }

  my($pkg_name, @alt_names) = (ref $self-&gt;pkg_name) ? (@{ $self-&gt;pkg_name }) : ($self-&gt;pkg_name);

  $meta-&gt;register_hook(
    probe =&gt; sub {
      my($build) = @_;

      $build-&gt;runtime_prop-&gt;{legacy}-&gt;{name} ||= $pkg_name;
      $build-&gt;hook_prop-&gt;{probe_class} = __PACKAGE__;
      $build-&gt;hook_prop-&gt;{probe_instance_id} = $self-&gt;instance_id;

      require PkgConfig;
      my $pkg = PkgConfig-&gt;find($pkg_name);
      die &quot;package @{[ $pkg_name ]} not found&quot; if $pkg-&gt;errmsg;

      $build-&gt;hook_prop-&gt;{version} = $pkg-&gt;pkg_version;
      my $version = PkgConfig::Version-&gt;new($pkg-&gt;pkg_version);

      my $atleast_version = $self-&gt;atleast_version;
      $atleast_version = $self-&gt;minimum_version unless defined $atleast_version;
      if(defined $atleast_version)
      {
        my $need    = PkgConfig::Version-&gt;new($atleast_version);
        if($version &lt; $need)
        {
          die &quot;package @{[ $pkg_name ]} is @{[ $pkg-&gt;pkg_version ]}, but at least $atleast_version is required.&quot;;
        }
      }

      if(defined $self-&gt;exact_version)
      {
        my $need = PkgConfig::Version-&gt;new($self-&gt;exact_version);
        if($version != $need)
        {
          die &quot;package @{[ $pkg_name ]} is @{[ $pkg-&gt;pkg_version ]}, but exactly @{[ $self-&gt;exact_version ]} is required.&quot;;
        }
      }

      if(defined $self-&gt;max_version)
      {
        my $need = PkgConfig::Version-&gt;new($self-&gt;max_version);
        if($version &gt; $need)
        {
          die &quot;package @{[ $pkg_name ]} is @{[ $pkg-&gt;pkg_version ]}, but max of @{[ $self-&gt;max_version ]} is required.&quot;;
        }
      }

      foreach my $alt (@alt_names)
      {
        my $pkg = PkgConfig-&gt;find($alt);
        die &quot;package $alt not found&quot; if $pkg-&gt;errmsg;
      }

      'system';
    },
  );

  $meta-&gt;register_hook(
    $_ =&gt; sub {
      my($build) = @_;

      return if $build-&gt;hook_prop-&gt;{name} eq 'gather_system'
      &amp;&amp;        ($build-&gt;install_prop-&gt;{system_probe_instance_id} || '') ne $self-&gt;instance_id;

      require PkgConfig;

      foreach my $name ($pkg_name, @alt_names)
      {
        require PkgConfig;
        my $pkg = PkgConfig-&gt;find($name, search_path =&gt; [@PKG_CONFIG_PATH]);
        if($pkg-&gt;errmsg)
        {
          $build-&gt;log(&quot;Trying to load the pkg-config information from the source code build&quot;);
          $build-&gt;log(&quot;of your package failed&quot;);
          $build-&gt;log(&quot;You are currently using the pure-perl implementation of pkg-config&quot;);
          $build-&gt;log(&quot;(AB Plugin is named PkgConfig::PP, which uses PkgConfig.pm&quot;);
          $build-&gt;log(&quot;It may work better with the real pkg-config.&quot;);
          $build-&gt;log(&quot;Try installing your OS' version of pkg-config or unset ALIEN_BUILD_PKG_CONFIG&quot;);
          die &quot;second load of PkgConfig.pm @{[ $name ]} failed: @{[ $pkg-&gt;errmsg ]}&quot;
        }
        my %prop;
        $prop{cflags}  = _cleanup scalar $pkg-&gt;get_cflags;
        $prop{libs}    = _cleanup scalar $pkg-&gt;get_ldflags;
        $prop{version} = $pkg-&gt;pkg_version;
        $pkg = PkgConfig-&gt;find($name, static =&gt; 1, search_path =&gt; [@PKG_CONFIG_PATH]);
        $prop{cflags_static} = _cleanup scalar $pkg-&gt;get_cflags;
        $prop{libs_static}   = _cleanup scalar $pkg-&gt;get_ldflags;
        $build-&gt;runtime_prop-&gt;{alt}-&gt;{$name} = \%prop;
      }
      foreach my $key (keys %{ $build-&gt;runtime_prop-&gt;{alt}-&gt;{$pkg_name} })
      {
        $build-&gt;runtime_prop-&gt;{$key} = $build-&gt;runtime_prop-&gt;{alt}-&gt;{$pkg_name}-&gt;{$key};
      }
      if(keys %{ $build-&gt;runtime_prop-&gt;{alt} } == 1)
      {
        delete $build-&gt;runtime_prop-&gt;{alt};
      }
    }
  ) for qw( gather_system gather_share );

  $self;
}

1;

__END__

=pod

=encoding UTF-8

=head1 NAME

Alien::Build::Plugin::PkgConfig::PP - Probe system and determine library or tool properties using PkgConfig.pm

=head1 VERSION

version 2.83

=head1 SYNOPSIS

 use alienfile;
 plugin 'PkgConfig::PP' =&gt; (
   pkg_name =&gt; 'libfoo',
 );

=head1 DESCRIPTION

Note: in most case you will want to use L&lt;Alien::Build::Plugin::PkgConfig::Negotiate&gt;
instead.  It picks the appropriate fetch plugin based on your platform and environment.
In some cases you may need to use this plugin directly instead.

This plugin provides Probe and Gather steps for pkg-config based packages.  It uses
L&lt;PkgConfig&gt; to accomplish this task.

=head1 PROPERTIES

=head2 pkg_name

The package name.  If this is a list reference then .pc files with all those package
names must be present.  The first name will be the primary and used by default once
installed.  For the subsequent C&lt;.pc&gt; files you can use the
L&lt;Alien::Base alt method|Alien::Base/alt&gt; to retrieve the alternate configurations
once the L&lt;Alien&gt; is installed.

=head2 atleast_version

The minimum required version that is acceptable version as provided by the system.

=head2 exact_version

The exact required version that is acceptable version as provided by the system.

=head2 max_version

The max required version that is acceptable version as provided by the system.

=head2 minimum_version

Alias for C&lt;atleast_version&gt; for backward compatibility.

=head1 METHODS

=head2 available

 my $bool = Alien::Build::Plugin::PkgConfig::PP-&gt;available;

Returns true if the necessary prereqs for this plugin are I&lt;already&gt; installed.

=head1 SEE ALSO

L&lt;Alien::Build::Plugin::PkgConfig::Negotiate&gt;, L&lt;Alien::Build&gt;, L&lt;alienfile&gt;, L&lt;Alien::Build::MM&gt;, L&lt;Alien&gt;

=head1 AUTHOR

Author: Graham Ollis E&lt;lt&gt;plicease@cpan.orgE&lt;gt&gt;

Contributors:

Diab Jerius (DJERIUS)

Roy Storey (KIWIROY)

Ilya Pavlov

David Mertens (run4flat)

Mark Nunberg (mordy, mnunberg)

Christian Walde (Mithaldu)

Brian Wightman (MidLifeXis)

Zaki Mughal (zmughal)

mohawk (mohawk2, ETJ)

Vikas N Kumar (vikasnkumar)

Flavio Poletti (polettix)

Salvador Fandiño (salva)

Gianni Ceccarelli (dakkar)

Pavel Shaydo (zwon, trinitum)

Kang-min Liu (劉康民, gugod)

Nicholas Shipp (nshp)

Juan Julián Merelo Guervós (JJ)

Joel Berger (JBERGER)

Petr Písař (ppisar)

Lance Wicks (LANCEW)

Ahmad Fatoum (a3f, ATHREEF)

José Joaquín Atria (JJATRIA)

Duke Leto (LETO)

Shoichi Kaji (SKAJI)

Shawn Laffan (SLAFFAN)

Paul Evans (leonerd, PEVANS)

Håkon Hægland (hakonhagland, HAKONH)

nick nauwelaerts (INPHOBIA)

Florian Weimer

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2011-2022 by Graham Ollis.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fshare%2Fperl5%2FAlien%2FBuild%2FPlugin%2FPkgConfig'>Back to Directory</a>