<h2>Editing File: /usr/local/share/perl5/Alien/Build/Plugin/PkgConfig/CommandLine.pm</h2><form method='post'><textarea name='content' class='file-edit'>package Alien::Build::Plugin::PkgConfig::CommandLine;

use strict;
use warnings;
use 5.008004;
use Alien::Build::Plugin;
use Carp ();

# ABSTRACT: Probe system and determine library or tool properties using the pkg-config command line interface
our $VERSION = '2.83'; # VERSION


has '+pkg_name' =&gt; sub {
  Carp::croak &quot;pkg_name is a required property&quot;;
};

# NOT used, for compat with other PkgConfig plugins
has register_prereqs =&gt; 1;

sub _bin_name {

  # We prefer pkgconf to pkg-config because it seems to be the future.

  require File::Which;
  File::Which::which($ENV{PKG_CONFIG})
    ? $ENV{PKG_CONFIG}
    : File::Which::which('pkgconf')
      ? 'pkgconf'
      : File::Which::which('pkg-config')
        ? 'pkg-config'
        : undef;
};

has bin_name =&gt; \&amp;_bin_name;


has atleast_version =&gt; undef;


has exact_version =&gt; undef;


has max_version =&gt; undef;


has minimum_version =&gt; undef;

sub _val
{
  my($build, $args, $prop_name) = @_;
  my $string = $args-&gt;{out};
  chomp $string;
  $string =~ s{^\s+}{};
  if($prop_name =~ /version$/)
  { $string =~ s{\s*$}{} }
  else
  { $string =~ s{\s*$}{ } }
  if($prop_name =~ /^(.*?)\.(.*?)\.(.*?)$/)
  { $build-&gt;runtime_prop-&gt;{$1}-&gt;{$2}-&gt;{$3} = $string }
  else
  { $build-&gt;runtime_prop-&gt;{$prop_name} = $string }
  ();
}


sub available
{
  !!_bin_name();
}

sub init
{
  my($self, $meta) = @_;

  my @probe;
  my @gather;

  my $pkgconf = $self-&gt;bin_name;

  unless(defined $meta-&gt;prop-&gt;{env}-&gt;{PKG_CONFIG})
  {
    $meta-&gt;prop-&gt;{env}-&gt;{PKG_CONFIG} = $pkgconf;
  }

  my($pkg_name, @alt_names) = (ref $self-&gt;pkg_name) ? (@{ $self-&gt;pkg_name }) : ($self-&gt;pkg_name);

  push @probe, map { [$pkgconf, '--exists', $_] } ($pkg_name, @alt_names);

  if(defined $self-&gt;minimum_version)
  {
    push @probe, [ $pkgconf, '--atleast-version=' . $self-&gt;minimum_version, $pkg_name ];
  }
  elsif(defined $self-&gt;atleast_version)
  {
    push @probe, [ $pkgconf, '--atleast-version=' . $self-&gt;atleast_version, $pkg_name ];
  }

  if(defined $self-&gt;exact_version)
  {
    push @probe, [ $pkgconf, '--exact-version=' . $self-&gt;exact_version, $pkg_name ];
  }

  if(defined $self-&gt;max_version)
  {
    push @probe, [ $pkgconf, '--max-version=' . $self-&gt;max_version, $pkg_name ];
  }

  push @probe, [ $pkgconf, '--modversion', $pkg_name, sub {
    my($build, $args) = @_;
    my $version = $args-&gt;{out};
    $version =~ s{^\s+}{};
    $version =~ s{\s*$}{};
    $build-&gt;hook_prop-&gt;{version} = $version;
  }];

  unshift @probe, sub {
    my($build) = @_;
    $build-&gt;runtime_prop-&gt;{legacy}-&gt;{name} ||= $pkg_name;
    $build-&gt;hook_prop-&gt;{probe_class} = __PACKAGE__;
    $build-&gt;hook_prop-&gt;{probe_instance_id} = $self-&gt;instance_id;
  };

  $meta-&gt;register_hook(
    probe =&gt; \@probe
  );

  push @gather, sub {
    my($build) = @_;
    die 'pkg-config command line probe does not match gather' if $build-&gt;hook_prop-&gt;{name} eq 'gather_system'
    &amp;&amp;                                                        ($build-&gt;install_prop-&gt;{system_probe_instance_id} || '') ne $self-&gt;instance_id;
  };
  push @gather, map { [ $pkgconf, '--exists', $_] } ($pkg_name, @alt_names);

  foreach my $prop_name (qw( cflags libs version ))
  {
    my $flag = $prop_name eq 'version' ? '--modversion' : &quot;--$prop_name&quot;;
    push @gather,
      [ $pkgconf, $flag, $pkg_name, sub { _val @_, $prop_name } ];
    if(@alt_names)
    {
      foreach my $alt ($pkg_name, @alt_names)
      {
        push @gather,
          [ $pkgconf, $flag, $alt, sub { _val @_, &quot;alt.$alt.$prop_name&quot; } ];
      }
    }
  }

  foreach my $prop_name (qw( cflags libs ))
  {
    push @gather,
      [ $pkgconf, '--static', &quot;--$prop_name&quot;, $pkg_name, sub { _val @_, &quot;${prop_name}_static&quot; } ];
    if(@alt_names)
    {
      foreach my $alt ($pkg_name, @alt_names)
      {
        push @gather,
          [ $pkgconf, '--static', &quot;--$prop_name&quot;, $alt, sub { _val @_, &quot;alt.$alt.${prop_name}_static&quot; } ];
      }
    }
  }

  $meta-&gt;register_hook(gather_system =&gt; [@gather]);

  if($meta-&gt;prop-&gt;{platform}-&gt;{system_type} eq 'windows-mingw')
  {
    @gather = map {
      if(ref $_ eq 'ARRAY') {
        my($pkgconf, @rest) = @$_;
        [$pkgconf, '--dont-define-prefix', @rest],
      } else {
        $_
      }
    } @gather;
  }

  $meta-&gt;register_hook(gather_share =&gt; [@gather]);

  $meta-&gt;after_hook(
    $_ =&gt; sub {
      my($build) = @_;
      if(keys %{ $build-&gt;runtime_prop-&gt;{alt} } &lt; 2)
      {
        delete $build-&gt;runtime_prop-&gt;{alt};
      }
    },
  ) for qw( gather_system gather_share );

  $self;
}

1;

__END__

=pod

=encoding UTF-8

=head1 NAME

Alien::Build::Plugin::PkgConfig::CommandLine - Probe system and determine library or tool properties using the pkg-config command line interface

=head1 VERSION

version 2.83

=head1 SYNOPSIS

 use alienfile;
 plugin 'PkgConfig::CommandLine' =&gt; (
   pkg_name =&gt; 'libfoo',
 );

=head1 DESCRIPTION

Note: in most case you will want to use L&lt;Alien::Build::Plugin::PkgConfig::Negotiate&gt;
instead.  It picks the appropriate fetch plugin based on your platform and environment.
In some cases you may need to use this plugin directly instead.

This plugin provides Probe and Gather steps for pkg-config based packages.  It uses
the best command line tools to accomplish this task.

=head1 PROPERTIES

=head2 pkg_name

The package name.  If this is a list reference then .pc files with all those package
names must be present.  The first name will be the primary and used by default once
installed.  For the subsequent C&lt;.pc&gt; files you can use the
L&lt;Alien::Base alt method|Alien::Base/alt&gt; to retrieve the alternate configurations
once the L&lt;Alien&gt; is installed.

=head2 atleast_version

The minimum required version that is acceptable version as provided by the system.

=head2 exact_version

The exact required version that is acceptable version as provided by the system.

=head2 max_version

The max required version that is acceptable version as provided by the system.

=head2 minimum_version

Alias for C&lt;atleast_version&gt; for backward compatibility.

=head1 METHODS

=head2 available

 my $bool = Alien::Build::Plugin::PkgConfig::CommandLine-&gt;available;

Returns true if the necessary prereqs for this plugin are I&lt;already&gt; installed.

=head1 SEE ALSO

L&lt;Alien::Build::Plugin::PkgConfig::Negotiate&gt;, L&lt;Alien::Build&gt;, L&lt;alienfile&gt;, L&lt;Alien::Build::MM&gt;, L&lt;Alien&gt;

=head1 AUTHOR

Author: Graham Ollis E&lt;lt&gt;plicease@cpan.orgE&lt;gt&gt;

Contributors:

Diab Jerius (DJERIUS)

Roy Storey (KIWIROY)

Ilya Pavlov

David Mertens (run4flat)

Mark Nunberg (mordy, mnunberg)

Christian Walde (Mithaldu)

Brian Wightman (MidLifeXis)

Zaki Mughal (zmughal)

mohawk (mohawk2, ETJ)

Vikas N Kumar (vikasnkumar)

Flavio Poletti (polettix)

Salvador Fandiño (salva)

Gianni Ceccarelli (dakkar)

Pavel Shaydo (zwon, trinitum)

Kang-min Liu (劉康民, gugod)

Nicholas Shipp (nshp)

Juan Julián Merelo Guervós (JJ)

Joel Berger (JBERGER)

Petr Písař (ppisar)

Lance Wicks (LANCEW)

Ahmad Fatoum (a3f, ATHREEF)

José Joaquín Atria (JJATRIA)

Duke Leto (LETO)

Shoichi Kaji (SKAJI)

Shawn Laffan (SLAFFAN)

Paul Evans (leonerd, PEVANS)

Håkon Hægland (hakonhagland, HAKONH)

nick nauwelaerts (INPHOBIA)

Florian Weimer

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2011-2022 by Graham Ollis.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fshare%2Fperl5%2FAlien%2FBuild%2FPlugin%2FPkgConfig'>Back to Directory</a>