<h2>Editing File: /usr/local/share/perl5/Alien/Build/Plugin/Fetch/NetFTP.pm</h2><form method='post'><textarea name='content' class='file-edit'>package Alien::Build::Plugin::Fetch::NetFTP;

use strict;
use warnings;
use 5.008004;
use Alien::Build::Plugin;
use Carp ();
use File::Temp ();
use Path::Tiny qw( path );

# ABSTRACT: Plugin for fetching files using Net::FTP
our $VERSION = '2.83'; # VERSION


has '+url' =&gt; '';


has ssl =&gt; 0;


has passive =&gt; 0;

sub init
{
  my($self, $meta) = @_;

  $meta-&gt;prop-&gt;{start_url} ||= $self-&gt;url;
  $self-&gt;url($meta-&gt;prop-&gt;{start_url});
  $self-&gt;url || Carp::croak('url is a required property');

  $meta-&gt;add_requires('share' =&gt; 'Net::FTP' =&gt; 0 );
  $meta-&gt;add_requires('share' =&gt; 'URI' =&gt; 0 );
  $meta-&gt;add_requires('share' =&gt; 'Alien::Build::Plugin::Fetch::NetFTP' =&gt; '0.61')
    if $self-&gt;passive;

  $meta-&gt;register_hook( fetch =&gt; sub {
    my($build, $url, %options) = @_;
    $url ||= $self-&gt;url;

    $build-&gt;log(&quot;plugin Fetch::NetFTP does not support http_headers option&quot;) if $options{http_headers};

    $url = URI-&gt;new($url);

    die &quot;Fetch::NetFTP does not support @{[ $url-&gt;scheme ]}&quot;
      unless $url-&gt;scheme eq 'ftp';

    $build-&gt;log(&quot;trying passive mode FTP first&quot;) if $self-&gt;passive;
    my $ftp = _ftp_connect($url, $self-&gt;passive);

    my $path = $url-&gt;path;

    unless($path =~ m!/$!)
    {
      my(@parts) = split /\//, $path;
      my $filename = pop @parts;
      my $dir      = join '/', @parts;

      my $path = eval {
        $ftp-&gt;cwd($dir) or die;
        my $tdir = File::Temp::tempdir( CLEANUP =&gt; 1);
        my $path = path(&quot;$tdir/$filename&quot;)-&gt;stringify;

        unless(eval { $ftp-&gt;get($filename, $path) }) # NAT problem? try to use passive mode
        {
          $ftp-&gt;quit;

          $build-&gt;log(&quot;switching to @{[ $self-&gt;passive ? 'active' : 'passive' ]} mode&quot;);
          $ftp = _ftp_connect($url, !$self-&gt;passive);

          $ftp-&gt;cwd($dir) or die;

          $ftp-&gt;get($filename, $path) or die;
        }

        $path;
      };

      if(defined $path)
      {
        return {
          type     =&gt; 'file',
          filename =&gt; $filename,
          path     =&gt; $path,
          protocol =&gt; 'ftp',
        };
      }

      $path .= &quot;/&quot;;
    }

    $ftp-&gt;quit;
    $ftp = _ftp_connect($url, $self-&gt;passive);
    $ftp-&gt;cwd($path) or die &quot;unable to fetch $url as either a directory or file&quot;;

    my $list = eval { $ftp-&gt;ls };
    unless(defined $list) # NAT problem? try to use passive mode
    {
      $ftp-&gt;quit;

      $build-&gt;log(&quot;switching to @{[ $self-&gt;passive ? 'active' : 'passive' ]} mode&quot;);
      $ftp = _ftp_connect($url, !$self-&gt;passive);

      $ftp-&gt;cwd($path) or die &quot;unable to fetch $url as either a directory or file&quot;;

      $list = $ftp-&gt;ls;

      die &quot;cannot list directory $path on $url&quot; unless defined $list;
    }

    die &quot;no files found at $url&quot; unless @$list;

    $path .= '/' unless $path =~ /\/$/;

    return {
      type     =&gt; 'list',
      protocol =&gt; 'ftp',
      list     =&gt; [
        map {
          my $filename = $_;
          my $furl = $url-&gt;clone;
          $furl-&gt;path($path . $filename);
          my %h = (
            filename =&gt; $filename,
            url      =&gt; $furl-&gt;as_string,
          );
          \%h;
        } sort @$list,
      ],
    };

  });

  $self;
}

sub _ftp_connect {
  my $url = shift;
  my $is_passive = shift || 0;

  my $ftp = Net::FTP-&gt;new(
    $url-&gt;host, Port =&gt;$url-&gt;port, Passive =&gt;$is_passive,
  ) or die &quot;error fetching $url: $@&quot;;

  $ftp-&gt;login($url-&gt;user, $url-&gt;password)
    or die &quot;error on login $url: @{[ $ftp-&gt;message ]}&quot;;

  $ftp-&gt;binary;

  $ftp;
}

1;

__END__

=pod

=encoding UTF-8

=head1 NAME

Alien::Build::Plugin::Fetch::NetFTP - Plugin for fetching files using Net::FTP

=head1 VERSION

version 2.83

=head1 SYNOPSIS

 use alienfile;
 share {
   start_url 'ftp://ftp.gnu.org/gnu/make';
   plugin 'Fetch::NetFTP';
 };

=head1 DESCRIPTION

Note: in most case you will want to use L&lt;Alien::Build::Plugin::Download::Negotiate&gt;
instead.  It picks the appropriate fetch plugin based on your platform and environment.
In some cases you may need to use this plugin directly instead.

This fetch plugin fetches files and directory listings via the C&lt;ftp&gt;, protocol using
L&lt;Net::FTP&gt;.

=head1 PROPERTIES

=head2 url

The initial URL to fetch.  This may be a directory or the final file.

=head2 ssl

This property is for compatibility with other fetch plugins, but is not used.

=head2 passive

If set to true, try passive mode FIRST.  By default it will try an active mode, then
passive mode.

=head1 SEE ALSO

L&lt;Alien::Build::Plugin::Download::Negotiate&gt;, L&lt;Alien::Build&gt;, L&lt;alienfile&gt;, L&lt;Alien::Build::MM&gt;, L&lt;Alien&gt;

=head1 AUTHOR

Author: Graham Ollis E&lt;lt&gt;plicease@cpan.orgE&lt;gt&gt;

Contributors:

Diab Jerius (DJERIUS)

Roy Storey (KIWIROY)

Ilya Pavlov

David Mertens (run4flat)

Mark Nunberg (mordy, mnunberg)

Christian Walde (Mithaldu)

Brian Wightman (MidLifeXis)

Zaki Mughal (zmughal)

mohawk (mohawk2, ETJ)

Vikas N Kumar (vikasnkumar)

Flavio Poletti (polettix)

Salvador Fandiño (salva)

Gianni Ceccarelli (dakkar)

Pavel Shaydo (zwon, trinitum)

Kang-min Liu (劉康民, gugod)

Nicholas Shipp (nshp)

Juan Julián Merelo Guervós (JJ)

Joel Berger (JBERGER)

Petr Písař (ppisar)

Lance Wicks (LANCEW)

Ahmad Fatoum (a3f, ATHREEF)

José Joaquín Atria (JJATRIA)

Duke Leto (LETO)

Shoichi Kaji (SKAJI)

Shawn Laffan (SLAFFAN)

Paul Evans (leonerd, PEVANS)

Håkon Hægland (hakonhagland, HAKONH)

nick nauwelaerts (INPHOBIA)

Florian Weimer

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2011-2022 by Graham Ollis.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fshare%2Fperl5%2FAlien%2FBuild%2FPlugin%2FFetch'>Back to Directory</a>