<h2>Editing File: /usr/local/share/perl5/Alien/Build/Plugin/Fetch/CurlCommand.pm</h2><form method='post'><textarea name='content' class='file-edit'>package Alien::Build::Plugin::Fetch::CurlCommand;

use strict;
use warnings;
use 5.008004;
use Alien::Build::Plugin;
use File::Which qw( which );
use Path::Tiny qw( path );
use Capture::Tiny qw( capture );
use File::Temp qw( tempdir );
use List::Util 1.33 qw( any pairmap );
use File::chdir;

# ABSTRACT: Plugin for fetching files using curl
our $VERSION = '2.83'; # VERSION


sub curl_command
{
  defined $ENV{CURL} ? scalar which($ENV{CURL}) : scalar which('curl');
}

has ssl =&gt; 0;
has _see_headers =&gt; 0;
has '+url' =&gt; '';

# when bootstrapping we have to specify this plugin as a prereq
# 1 is the default so that when this plugin is used directly
# you also get the prereq
has bootstrap_ssl =&gt; 1;


sub protocol_ok
{
  my($class, $protocol) = @_;
  my $curl = $class-&gt;curl_command;
  return 0 unless defined $curl;
  my($out, $err, $exit) = capture {
    system $curl, '--version';
  };

  {
    # make sure curl supports the -J option.
    # CentOS 6 for example is recent enough
    # that it does not.  gh#147, gh#148, gh#149
    local $CWD = tempdir( CLEANUP =&gt; 1 );
    my $file1 = path('foo/foo.txt');
    $file1-&gt;parent-&gt;mkpath;
    $file1-&gt;spew(&quot;hello world\n&quot;);
    my $url = 'file://' . $file1-&gt;absolute;
    my($out, $err, $exit) = capture {
      system $curl, '-O', '-J', $url;
    };
    my $file2 = $file1-&gt;parent-&gt;child($file1-&gt;basename);
    unlink &quot;$file1&quot;;
    unlink &quot;$file2&quot;;
    rmdir($file1-&gt;parent);
    return 0 if $exit;
  }

  foreach my $line (split /\n/, $out)
  {
    if($line =~ /^Protocols:\s*(.*)\s*$/)
    {
      my %proto = map { $_ =&gt; 1 } split /\s+/, $1;
      return $proto{$protocol} if $proto{$protocol};
    }
  }
  return 0;
}

sub init
{
  my($self, $meta) = @_;

  $meta-&gt;prop-&gt;{start_url} ||= $self-&gt;url;
  $self-&gt;url($meta-&gt;prop-&gt;{start_url});
  $self-&gt;url || Carp::croak('url is a required property');

  $meta-&gt;add_requires('configure', 'Alien::Build::Plugin::Fetch::CurlCommand' =&gt; '1.19')
    if $self-&gt;bootstrap_ssl;

  $meta-&gt;register_hook(
    fetch =&gt; sub {
      my($build, $url, %options) = @_;
      $url ||= $self-&gt;url;

      my($scheme) = $url =~ /^([a-z0-9]+):/i;

      if($scheme =~ /^https?$/)
      {
        local $CWD = tempdir( CLEANUP =&gt; 1 );

        my @writeout = (
          &quot;ab-filename     :%{filename_effective}&quot;,
          &quot;ab-content_type :%{content_type}&quot;,
          &quot;ab-url          :%{url_effective}&quot;,
        );

        $build-&gt;log(&quot;writeout: $_\\n&quot;) for @writeout;
        path('writeout')-&gt;spew(join(&quot;\\n&quot;, @writeout));

        my @headers;
        if(my $headers = $options{http_headers})
        {
          if(ref $headers eq 'ARRAY')
          {
            @headers = pairmap { -H =&gt; &quot;$a: $b&quot; } @$headers;
          }
          else
          {
            $build-&gt;log(&quot;Fetch for $url with http_headers that is not an array reference&quot;);
          }
        }

        my @command = (
          $self-&gt;curl_command,
          '-L', '-f', '-O', '-J',
          -w =&gt; '@writeout',
          @headers,
        );

        push @command, -D =&gt; 'head' if $self-&gt;_see_headers;

        push @command, $url;

        my($stdout, $stderr) = $self-&gt;_execute($build, @command);

        my %h = map { /^ab-(.*?)\s*:(.*)$/ ? ($1 =&gt; $2) : () } split /\n/, $stdout;

        if(-e 'head')
        {
          $build-&gt;log(&quot; ~ $_ =&gt; $h{$_}&quot;) for sort keys %h;
          $build-&gt;log(&quot; header: $_&quot;) for path('headers')-&gt;lines;
        }

        my($type) = split /;/, $h{content_type};

        if($type eq 'text/html')
        {
          return {
            type     =&gt; 'html',
            base     =&gt; $h{url},
            content  =&gt; scalar path($h{filename})-&gt;slurp,
            protocol =&gt; $scheme,
          };
        }
        else
        {
          return {
            type     =&gt; 'file',
            filename =&gt; $h{filename},
            path     =&gt; path($h{filename})-&gt;absolute-&gt;stringify,
            protocol =&gt; $scheme,
          };
        }
      }
#      elsif($scheme eq 'ftp')
#      {
#        if($url =~ m{/$})
#        {
#          my($stdout, $stderr) = $self-&gt;_execute($build, $self-&gt;curl_command, -l =&gt; $url);
#          chomp $stdout;
#          return {
#            type =&gt; 'list',
#            list =&gt; [
#              map { { filename =&gt; $_, url =&gt; &quot;$url$_&quot; } } sort split /\n/, $stdout,
#            ],
#          };
#        }
#
#        my $first_error;
#
#        {
#          local $CWD = tempdir( CLEANUP =&gt; 1 );
#
#          my($filename) = $url =~ m{/([^/]+)$};
#          $filename = 'unknown' if (! defined $filename) || ($filename eq '');
#          my($stdout, $stderr) = eval { $self-&gt;_execute($build, $self-&gt;curl_command, -o =&gt; $filename, $url) };
#          $first_error = $@;
#          if($first_error eq '')
#          {
#            return {
#              type     =&gt; 'file',
#              filename =&gt; $filename,
#              path     =&gt; path($filename)-&gt;absolute-&gt;stringify,
#            };
#          }
#        }
#
#        {
#          my($stdout, $stderr) = eval { $self-&gt;_execute($build, $self-&gt;curl_command, -l =&gt; &quot;$url/&quot;) };
#          if($@ eq '')
#          {
#            chomp $stdout;
#            return {
#              type =&gt; 'list',
#              list =&gt; [
#                map { { filename =&gt; $_, url =&gt; &quot;$url/$_&quot; } } sort split /\n/, $stdout,
#              ],
#            };
#          };
#        }
#
#        $first_error ||= 'unknown error';
#        die $first_error;
#
#      }
      else
      {
        die &quot;scheme $scheme is not supported by the Fetch::CurlCommand plugin&quot;;
      }

    },
  ) if $self-&gt;curl_command;

  $self;
}

sub _execute
{
  my($self, $build, @command) = @_;
  $build-&gt;log(&quot;+ @command&quot;);
  my($stdout, $stderr, $err) = capture {
    system @command;
    $?;
  };
  if($err)
  {
    chomp $stderr;
    $build-&gt;log($_) for split /\n/, $stderr;
    if($stderr =~ /Remote filename has no length/ &amp;&amp; !!(any { /^-O$/ } @command))
    {
      my @new_command = map {
        /^-O$/ ? ( -o =&gt; 'index.html' ) : /^-J$/ ? () : ($_)
      } @command;
      return $self-&gt;_execute($build, @new_command);
    }
    die &quot;error in curl fetch&quot;;
  }
  ($stdout, $stderr);
}

1;

__END__

=pod

=encoding UTF-8

=head1 NAME

Alien::Build::Plugin::Fetch::CurlCommand - Plugin for fetching files using curl

=head1 VERSION

version 2.83

=head1 SYNOPSIS

 use alienfile;
 
 share {
   start_url 'https://www.openssl.org/source/';
   plugin 'Fetch::CurlCommand';
 };

=head1 DESCRIPTION

This plugin provides a fetch based on the C&lt;curl&gt; command.  It works with other fetch
plugins (that is, the first one which succeeds will be used).  Most of the time the best plugin
to use will be L&lt;Alien::Build::Plugin::Download::Negotiate&gt;, but for some SSL bootstrapping
it may be desirable to try C&lt;curl&gt; first.

Protocols supported: C&lt;http&gt;, C&lt;https&gt;

C&lt;https&gt; support requires that curl was built with SSL support.

=head1 PROPERTIES

=head2 curl_command

The full path to the C&lt;curl&gt; command.  The default is usually correct.

=head2 ssl

Ignored by this plugin.  Provided for compatibility with some other fetch plugins.

=head1 METHODS

=head2 protocol_ok

 my $bool = $plugin-&gt;protocol_ok($protocol);
 my $bool = Alien::Build::Plugin::Fetch::CurlCommand-&gt;protocol_ok($protocol);

=head1 SEE ALSO

=over 4

=item L&lt;alienfile&gt;

=item L&lt;Alien::Build&gt;

=back

=head1 AUTHOR

Author: Graham Ollis E&lt;lt&gt;plicease@cpan.orgE&lt;gt&gt;

Contributors:

Diab Jerius (DJERIUS)

Roy Storey (KIWIROY)

Ilya Pavlov

David Mertens (run4flat)

Mark Nunberg (mordy, mnunberg)

Christian Walde (Mithaldu)

Brian Wightman (MidLifeXis)

Zaki Mughal (zmughal)

mohawk (mohawk2, ETJ)

Vikas N Kumar (vikasnkumar)

Flavio Poletti (polettix)

Salvador Fandiño (salva)

Gianni Ceccarelli (dakkar)

Pavel Shaydo (zwon, trinitum)

Kang-min Liu (劉康民, gugod)

Nicholas Shipp (nshp)

Juan Julián Merelo Guervós (JJ)

Joel Berger (JBERGER)

Petr Písař (ppisar)

Lance Wicks (LANCEW)

Ahmad Fatoum (a3f, ATHREEF)

José Joaquín Atria (JJATRIA)

Duke Leto (LETO)

Shoichi Kaji (SKAJI)

Shawn Laffan (SLAFFAN)

Paul Evans (leonerd, PEVANS)

Håkon Hægland (hakonhagland, HAKONH)

nick nauwelaerts (INPHOBIA)

Florian Weimer

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2011-2022 by Graham Ollis.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fshare%2Fperl5%2FAlien%2FBuild%2FPlugin%2FFetch'>Back to Directory</a>