<h2>Editing File: /usr/local/share/perl5/Alien/Build/Plugin/Extract/CommandLine.pm</h2><form method='post'><textarea name='content' class='file-edit'>package Alien::Build::Plugin::Extract::CommandLine;

use strict;
use warnings;
use 5.008004;
use Alien::Build::Plugin;
use Path::Tiny ();
use File::Which ();
use File::chdir;
use File::Temp qw( tempdir );
use Capture::Tiny qw( capture_merged );

# ABSTRACT: Plugin to extract an archive using command line tools
our $VERSION = '2.83'; # VERSION


has '+format' =&gt; 'tar';


sub gzip_cmd
{
  _which('gzip') ? 'gzip' : undef;
}


sub _which { scalar File::Which::which(@_) }

sub bzip2_cmd
{
  _which('bzip2') ? 'bzip2' : undef;
}


sub xz_cmd
{
  _which('xz') ? 'xz' : undef;
}


{
  my $bsd_tar;

  # Note: GNU tar can be iffy to very bad on windows, where absolute
  # paths get confused with remote tars.  We used to assume that 'tar.exe'
  # is borked on Windows, but recent versions of Windows 10 come bundled
  # with bsdtar (libarchive) named 'tar.exe', and we should definitely
  # prefer that to ptar.
  sub _windows_tar_is_bsdtar
  {
    return 1 if $^O ne 'MSWin32';
    return $bsd_tar if defined $bsd_tar;
    my($out) = capture_merged {
      system 'tar', '--version';
    };
    return $bsd_tar = $out =~ /bsdtar/ ? 1 : 0
  }
}

sub tar_cmd
{
  _which('bsdtar')
    ? 'bsdtar'
    # Slowlaris /usr/bin/tar doesn't seem to like pax global header
    # but seems to have gtar in the path by default, which is okay with it
    : $^O eq 'solaris' &amp;&amp; _which('gtar')
      ? 'gtar'
      # See note above for Windows logic.
      : _which('tar') &amp;&amp; _windows_tar_is_bsdtar()
        ? 'tar'
        : _which('ptar')
          ? 'ptar'
          : undef;
};


sub unzip_cmd
{
  if($^O eq 'MSWin32' &amp;&amp; _which('tar') &amp;&amp; _windows_tar_is_bsdtar())
  {
    (_which('tar'), 'xf');
  }
  else
  {
    _which('unzip') ? 'unzip' : undef;
  }
}

sub _run
{
  my(undef, $build, @cmd) = @_;
  $build-&gt;log(&quot;+ @cmd&quot;);
  system @cmd;
  die &quot;execute failed&quot; if $?;
}

sub _cp
{
  my(undef, $build, $from, $to) = @_;
  require File::Copy;
  $build-&gt;log(&quot;copy $from =&gt; $to&quot;);
  File::Copy::cp($from, $to) || die &quot;unable to copy: $!&quot;;
}

sub _mv
{
  my(undef, $build, $from, $to) = @_;
  $build-&gt;log(&quot;move $from =&gt; $to&quot;);
  rename($from, $to) || die &quot;unable to rename: $!&quot;;
}

sub _dcon
{
  my($self, $src) = @_;

  my $name;
  my $cmd;

  if($src =~ /\.(gz|tgz|Z|taz)$/)
  {
    $self-&gt;gzip_cmd(_which('gzip')) unless defined $self-&gt;gzip_cmd;
    if($src =~ /\.(gz|tgz)$/)
    {
      $cmd = $self-&gt;gzip_cmd unless $self-&gt;_tar_can('tar.gz');
    }
    elsif($src =~ /\.(Z|taz)$/)
    {
      $cmd = $self-&gt;gzip_cmd unless $self-&gt;_tar_can('tar.Z');
    }
  }
  elsif($src =~ /\.(bz2|tbz)$/)
  {
    $self-&gt;bzip2_cmd(_which('bzip2')) unless defined $self-&gt;bzip2_cmd;
    $cmd = $self-&gt;bzip2_cmd unless $self-&gt;_tar_can('tar.bz2');
  }
  elsif($src =~ /\.(xz|txz)$/)
  {
    $self-&gt;xz_cmd(_which('xz')) unless defined $self-&gt;xz_cmd;
    $cmd = $self-&gt;xz_cmd unless $self-&gt;_tar_can('tar.xz');
  }

  if($cmd &amp;&amp; $src =~ /\.(gz|bz2|xz|Z)$/)
  {
    $name = $src;
    $name =~ s/\.(gz|bz2|xz|Z)$//g;
  }
  elsif($cmd &amp;&amp; $src =~ /\.(tgz|tbz|txz|taz)$/)
  {
    $name = $src;
    $name =~ s/\.(tgz|tbz|txz|taz)$/.tar/;
  }

  ($name,$cmd);
}


sub handles
{
  my($class, $ext) = @_;

  my $self = ref $class
  ? $class
  : __PACKAGE__-&gt;new;

  $ext = 'tar.Z'   if $ext eq 'taz';
  $ext = 'tar.gz'  if $ext eq 'tgz';
  $ext = 'tar.bz2' if $ext eq 'tbz';
  $ext = 'tar.xz'  if $ext eq 'txz';

  return 1 if $ext eq 'tar.gz'  &amp;&amp; $self-&gt;_tar_can('tar.gz');
  return 1 if $ext eq 'tar.Z'   &amp;&amp; $self-&gt;_tar_can('tar.Z');
  return 1 if $ext eq 'tar.bz2' &amp;&amp; $self-&gt;_tar_can('tar.bz2');
  return 1 if $ext eq 'tar.xz'  &amp;&amp; $self-&gt;_tar_can('tar.xz');

  return 0 if $ext =~ s/\.(gz|Z)$// &amp;&amp; (!$self-&gt;gzip_cmd);
  return 0 if $ext =~ s/\.bz2$//    &amp;&amp; (!$self-&gt;bzip2_cmd);
  return 0 if $ext =~ s/\.xz$//     &amp;&amp; (!$self-&gt;xz_cmd);

  return 1 if $ext eq 'tar' &amp;&amp; $self-&gt;_tar_can('tar');
  return 1 if $ext eq 'zip' &amp;&amp; $self-&gt;_tar_can('zip');

  return 0;
}


sub available
{
  my(undef, $ext) = @_;

  # this is actually the same as handles
  __PACKAGE__-&gt;handles($ext);
}

sub init
{
  my($self, $meta) = @_;

  if($self-&gt;format eq 'tar.xz' &amp;&amp; !$self-&gt;handles('tar.xz'))
  {
    $meta-&gt;add_requires('share' =&gt; 'Alien::xz' =&gt; '0.06');
  }
  elsif($self-&gt;format eq 'tar.bz2' &amp;&amp; !$self-&gt;handles('tar.bz2'))
  {
    $meta-&gt;add_requires('share' =&gt; 'Alien::Libbz2' =&gt; '0.22');
  }
  elsif($self-&gt;format =~ /^tar\.(gz|Z)$/ &amp;&amp; !$self-&gt;handles($self-&gt;format))
  {
    $meta-&gt;add_requires('share' =&gt; 'Alien::gzip' =&gt; '0.03');
  }
  elsif($self-&gt;format eq 'zip' &amp;&amp; !$self-&gt;handles('zip'))
  {
    $meta-&gt;add_requires('share' =&gt; 'Alien::unzip' =&gt; '0');
  }

  $meta-&gt;register_hook(
    extract =&gt; sub {
      my($build, $src) = @_;

      my($dcon_name, $dcon_cmd) = _dcon($self, $src);

      if($dcon_name)
      {
        unless($dcon_cmd)
        {
          die &quot;unable to decompress $src&quot;;
        }
        # if we have already decompressed, then keep it.
        unless(-f $dcon_name)
        {
          # we don't use pipes, because that may not work on Windows.
          # keep the original archive, in case another extract
          # plugin needs it.  keep the decompressed archive
          # in case WE need it again.
          my $src_tmp = Path::Tiny::path($src)
            -&gt;parent
            -&gt;child('x'.Path::Tiny::path($src)-&gt;basename);
          my $dcon_tmp = Path::Tiny::path($dcon_name)
            -&gt;parent
            -&gt;child('x'.Path::Tiny::path($dcon_name)-&gt;basename);
          $self-&gt;_cp($build, $src, $src_tmp);
          $self-&gt;_run($build, $dcon_cmd, &quot;-d&quot;, $src_tmp);
          $self-&gt;_mv($build, $dcon_tmp, $dcon_name);
        }
        $src = $dcon_name;
      }

      if($src =~ /\.zip$/i)
      {
        $self-&gt;_run($build, $self-&gt;unzip_cmd, $src);
      }
      elsif($src =~ /\.tar/ || $src =~ /(\.tgz|\.tbz|\.txz|\.taz)$/i)
      {
        $self-&gt;_run($build, $self-&gt;tar_cmd, '-xf', $src);
      }
      else
      {
        die &quot;not sure of archive type from extension&quot;;
      }
    }
  );
}

my %tars;

sub _tar_can
{
  my($self, $ext) = @_;

  unless(%tars)
  {
    my $name = '';
    local $_; # to avoid dynamically scoped read-only $_ from upper scopes
    while(my $line = &lt;DATA&gt;)
    {
      if($line =~ /^\[ (.*) \]$/)
      {
        $name = $1;
      }
      else
      {
        $tars{$name} .= $line;
      }
    }

    foreach my $key (keys %tars)
    {
      $tars{$key} = unpack &quot;u&quot;, $tars{$key};
    }
  }

  my $name = &quot;xx.$ext&quot;;

  return 0 unless $tars{$name};

  local $CWD = tempdir( CLEANUP =&gt; 1 );

  my $cleanup = sub {
    my $save = $CWD;
    unlink $name;
    unlink 'xx.txt';
    $CWD = '..';
    rmdir $save;
  };

  Path::Tiny-&gt;new($name)-&gt;spew_raw($tars{$name});

  my @cmd = ($self-&gt;tar_cmd, 'xf', $name);
  if($ext eq 'zip')
  {
    @cmd = ($self-&gt;unzip_cmd, $name);
  }

  my(undef, $exit) = capture_merged {
    system(@cmd);
    $?;
  };

  if($exit)
  {
    $cleanup-&gt;();
    return 0;
  }

  my $content = eval { Path::Tiny-&gt;new('xx.txt')-&gt;slurp };
  $cleanup-&gt;();

  return defined $content &amp;&amp; $content eq &quot;xx\n&quot;;
}

1;

=pod

=encoding UTF-8

=head1 NAME

Alien::Build::Plugin::Extract::CommandLine - Plugin to extract an archive using command line tools

=head1 VERSION

version 2.83

=head1 SYNOPSIS

 use alienfile;
 plugin 'Extract::CommandLine' =&gt; (
   format =&gt; 'tar.gz',
 );

=head1 DESCRIPTION

Note: in most case you will want to use L&lt;Alien::Build::Plugin::Extract::Negotiate&gt;
instead.  It picks the appropriate Extract plugin based on your platform and environment.
In some cases you may need to use this plugin directly instead.

This plugin extracts from an archive in various formats using command line tools.

=head1 PROPERTIES

=head2 format

Gives a hint as to the expected format.

=head2 gzip_cmd

The C&lt;gzip&gt; command, if available.  C&lt;undef&gt; if not available.

=head2 bzip2_cmd

The C&lt;bzip2&gt; command, if available.  C&lt;undef&gt; if not available.

=head2 xz_cmd

The C&lt;xz&gt; command, if available.  C&lt;undef&gt; if not available.

=head2 tar_cmd

The C&lt;tar&gt; command, if available.  C&lt;undef&gt; if not available.

=head2 unzip_cmd

The C&lt;unzip&gt; command, if available.  C&lt;undef&gt; if not available.

=head1 METHODS

=head2 handles

 Alien::Build::Plugin::Extract::CommandLine-&gt;handles($ext);
 $plugin-&gt;handles($ext);

Returns true if the plugin is able to handle the archive of the
given format.

=head2 available

 Alien::Build::Plugin::Extract::CommandLine-&gt;available($ext);

Returns true if the plugin is available to extract without
installing anything new.

=head1 SEE ALSO

L&lt;Alien::Build::Plugin::Extract::Negotiate&gt;, L&lt;Alien::Build&gt;, L&lt;alienfile&gt;, L&lt;Alien::Build::MM&gt;, L&lt;Alien&gt;

=head1 AUTHOR

Author: Graham Ollis E&lt;lt&gt;plicease@cpan.orgE&lt;gt&gt;

Contributors:

Diab Jerius (DJERIUS)

Roy Storey (KIWIROY)

Ilya Pavlov

David Mertens (run4flat)

Mark Nunberg (mordy, mnunberg)

Christian Walde (Mithaldu)

Brian Wightman (MidLifeXis)

Zaki Mughal (zmughal)

mohawk (mohawk2, ETJ)

Vikas N Kumar (vikasnkumar)

Flavio Poletti (polettix)

Salvador Fandiño (salva)

Gianni Ceccarelli (dakkar)

Pavel Shaydo (zwon, trinitum)

Kang-min Liu (劉康民, gugod)

Nicholas Shipp (nshp)

Juan Julián Merelo Guervós (JJ)

Joel Berger (JBERGER)

Petr Písař (ppisar)

Lance Wicks (LANCEW)

Ahmad Fatoum (a3f, ATHREEF)

José Joaquín Atria (JJATRIA)

Duke Leto (LETO)

Shoichi Kaji (SKAJI)

Shawn Laffan (SLAFFAN)

Paul Evans (leonerd, PEVANS)

Håkon Hægland (hakonhagland, HAKONH)

nick nauwelaerts (INPHOBIA)

Florian Weimer

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2011-2022 by Graham Ollis.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut

__DATA__

[ xx.tar ]
M&gt;'@N='AT````````````````````````````````````````````````````
M````````````````````````````````````````````````````````````
M`````````````#`P,#8T-&quot;``,#`P-S8U(``P,#`P,C0@`#`P,#`P,#`P,#`S
M(#$S-#,U,#0S-#(R(#`Q,C&lt;P,P`@,```````````````````````````````
M````````````````````````````````````````````````````````````
M``````````````````````````````````````````!U&lt;W1A&lt;@`P,&amp;]L;&amp;ES
M9P``````````````````````````````````&lt;W1A9F8`````````````````
M```````````````````P,#`P,#`@`#`P,#`P,&quot;``````````````````````
M````````````````````````````````````````````````````````````
M````````````````````````````````````````````````````````````
M````````````````````````````````````````````````````````````
M``````````````````````!X&gt;`H`````````````````````````````````
M````````````````````````````````````````````````````````````
M````````````````````````````````````````````````````````````
M````````````````````````````````````````````````````````````
M````````````````````````````````````````````````````````````
M````````````````````````````````````````````````````````````
M````````````````````````````````````````````````````````````
M````````````````````````````````````````````````````````````
M````````````````````````````````````````````````````````````
M````````````````````````````````````````````````````````````
M````````````````````````````````````````````````````````````
M````````````````````````````````````````````````````````````
M````````````````````````````````````````````````````````````
M````````````````````````````````````````````````````````````
M````````````````````````````````````````````````````````````
M````````````````````````````````````````````````````````````
M````````````````````````````````````````````````````````````
M````````````````````````````````````````````````````````````
M````````````````````````````````````````````````````````````
M````````````````````````````````````````````````````````````
M````````````````````````````````````````````````````````````
M````````````````````````````````````````````````````````````
M````````````````````````````````````````````````````````````
M````````````````````````````````````````````````````````````
M````````````````````````````````````````````````````````````
M````````````````````````````````````````````````````````````
M````````````````````````````````````````````````````````````
M````````````````````````````````````````````````````````````
M````````````````````````````````````````````````````````````
M````````````````````````````````````````````````````````````
M````````````````````````````````````````````````````````````
M````````````````````````````````````````````````````````````
M````````````````````````````````````````````````````````````
M````````````````````````````````````````````````````````````
7````````````````````````````````


[ xx.tar.Z ]
M'YV0&gt;/&quot;XH(.'#H&quot;#&quot;!,J7,BPH&lt;.'$&quot;-*1`BCH@T:-$``J`CCAHT:&amp;CG&quot;D)%Q
MH\B3,T#$F$%C1@T8+6G(D`$&quot;1@P9-V#,`%!SHL^?0(,*!5!G#ITP&lt;DR^8&lt;,F
MS9PS0Q&lt;:#6/&amp;3-2%)V&amp;$/*GQJM&gt;O8,.*'1I0P=BS:-.J7&lt;NVK=NW&lt;./*G4NW
7KMV[&gt;//JW&lt;NWK]^_@`,+'DRXL.'#0P$`


[ xx.tar.bz2 ]
M0EIH.3%!629365(,+ID``$A[D-$0`8!``7^``!!AI)Y`!```&quot;&quot;``=!JGIBC3
M30&amp;CU`]($HHTTR:`&gt;D#0)SI*Z'R%H*J&quot;&amp;3@H]P@J&gt;U$F5BMHOC`$L-&quot;8C!(V
I&quot;`'?*WA:(9*4U)@4)+&quot;(V%.G]#W(_E6B'J8G]D`/Q=R13A0D%(,+ID``


[ xx.tar.gz ]
M'XL(&quot;!)'=%P``WAX+G1A&lt;@&quot;KJ-`KJ2AAH&quot;DP,#`P,S%1`-'F9J9@VL`(PH&lt;&quot;
M8P5#8Q-C4P,38Q,C(P4#0R-S`V,&amp;!0/:.@L&quot;2HM+$HN`3LG/R&lt;DL3L&gt;M#J@L
E+0V/.1&quot;/*,#I(0(J*K@&amp;V@FC8!2,@E$P&quot;@8````U:,3F``@`````


[ xx.tar.xz ]
M_3=Z6%H```3FUK1&amp;`@`A`18```!T+^6CX`?_`&amp;!=`#Q@M.AX.4O&amp;N38V648.
M[J6L\\&lt;_[3M*R;CASOTX?B.F\V:^)+G;\YY4&quot;!4MLF9`*\N40G=O+K,J0&quot;NF
M0VU7J%NN(A,R^DM8@/(_YGR5CAO+1CS_YNHE:,1!G%6L1\GT``&quot;[$^?&quot;O*&quot;!
9`P`!?(`0````:OY*7K'$9_L&quot;``````196@``


[ xx.zip ]
M4$L#!`H``````%5V64X:^I&quot;B`P````,````&amp;`!P`&gt;'@N='AT550)``,21W1&lt;
M$D=T7'5X&quot;P`!!/4!```$%````'AX&quot;E!+`0(&gt;`PH``````%5V64X:^I&quot;B`P``
M``,````&amp;`!@```````$```&quot;D@0````!X&gt;&quot;YT&gt;'155`4``Q)'=%QU&gt;`L``03U
&gt;`0``!!0```!02P4&amp;``````$``0!,````0P``````


</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fshare%2Fperl5%2FAlien%2FBuild%2FPlugin%2FExtract'>Back to Directory</a>