<h2>Editing File: /usr/local/share/perl5/Alien/Build/Plugin/Download/Negotiate.pm</h2><form method='post'><textarea name='content' class='file-edit'>package Alien::Build::Plugin::Download::Negotiate;

use strict;
use warnings;
use 5.008004;
use Alien::Build::Plugin;
use Alien::Build::Util qw( _has_ssl );
use Carp ();

# ABSTRACT: Download negotiation plugin
our $VERSION = '2.83'; # VERSION


has '+url' =&gt; undef;


has 'filter'  =&gt; undef;


has 'version' =&gt; undef;


has 'ssl'     =&gt; 0;


has 'passive' =&gt; 0;

has 'scheme'  =&gt; undef;


has 'bootstrap_ssl' =&gt; 0;


has 'prefer' =&gt; 1;


has 'decoder' =&gt; undef;


sub pick
{
  my($self) = @_;
  my($fetch, @decoders) = $self-&gt;_pick;
  if($self-&gt;decoder)
  {
    @decoders = ref $self-&gt;decoder ? @{ $self-&gt;decoder } : ($self-&gt;decoder);
  }
  ($fetch, @decoders);
}

sub _pick_decoder
{
  my($self) = @_;

  if(eval { require Mojo::DOM58; Mojo::DOM58-&gt;VERSION(1.00); 1 })
  { return &quot;Decode::Mojo&quot; }
  elsif(eval { require Mojo::DOM; require Mojolicious; Mojolicious-&gt;VERSION('7.00'); 1 })
  { return &quot;Decode::Mojo&quot; }
  elsif(eval { require HTML::LinkExtor; 1; })
  { return &quot;Decode::HTML&quot; }
  else
  { return &quot;Decode::Mojo&quot; }
}

sub _pick
{
  my($self) = @_;

  $self-&gt;scheme(
    $self-&gt;url !~ m!(ftps?|https?|file):!i
      ? 'file'
      : $self-&gt;url =~ m!^([a-z]+):!i
  ) unless defined $self-&gt;scheme;

  if($self-&gt;scheme eq 'https' || ($self-&gt;scheme eq 'http' &amp;&amp; $self-&gt;ssl))
  {
    if($self-&gt;bootstrap_ssl &amp;&amp; ! _has_ssl)
    {
      return (['Fetch::CurlCommand','Fetch::Wget'], __PACKAGE__-&gt;_pick_decoder);
    }
    elsif(_has_ssl)
    {
      return ('Fetch::HTTPTiny', __PACKAGE__-&gt;_pick_decoder);
    }
    #elsif(do { require Alien::Build::Plugin::Fetch::CurlCommand; Alien::Build::Plugin::Fetch::CurlCommand-&gt;protocol_ok('https') })
    #{
    #  return ('Fetch::CurlCommand', __PACKAGE__-&gt;_pick_decoder);
    #}
    else
    {
      return ('Fetch::HTTPTiny', __PACKAGE__-&gt;_pick_decoder);
    }
  }
  elsif($self-&gt;scheme eq 'http')
  {
    return ('Fetch::HTTPTiny', __PACKAGE__-&gt;_pick_decoder);
  }
  elsif($self-&gt;scheme eq 'ftp')
  {
    if($ENV{ftp_proxy} || $ENV{all_proxy})
    {
      return $self-&gt;scheme =~ /^ftps?/
        ? ('Fetch::LWP', 'Decode::DirListing', __PACKAGE__-&gt;_pick_decoder)
        : ('Fetch::LWP', __PACKAGE__-&gt;_pick_decoder);
    }
    else
    {
      return ('Fetch::NetFTP');
    }
  }
  elsif($self-&gt;scheme eq 'file')
  {
    return ('Fetch::Local');
  }
  else
  {
    die &quot;do not know how to handle scheme @{[ $self-&gt;scheme ]} for @{[ $self-&gt;url ]}&quot;;
  }
}

sub init
{
  my($self, $meta) = @_;

  unless(defined $self-&gt;url)
  {
    if(defined $meta-&gt;prop-&gt;{start_url})
    {
      $self-&gt;url($meta-&gt;prop-&gt;{start_url});
    }
    else
    {
      Carp::croak &quot;url is a required property unless you use the start_url directive&quot;;
    }
  }

  if($self-&gt;url =~ /^http.*github.com.*releases$/)
  {
    Alien::Build-&gt;log('!! WARNING !! WARNING !!');
    Alien::Build-&gt;log('!! WARNING !! It looks like this alien is using the regular download negotiator');
    Alien::Build-&gt;log('plugin on a GitHub release page.  This will typically not work due to changes');
    Alien::Build-&gt;log('in the way GitHub release page works now.  The Alien should instead be updated');
    Alien::Build-&gt;log('to use the Download::GitHub plugin, which uses the GitHub API to find available');
    Alien::Build-&gt;log('releases.  See: https://metacpan.org/pod/Alien::Build::Plugin::Download::GitHub');
    Alien::Build-&gt;log('!! WARNING !! WARNING !!');
  }

  $meta-&gt;add_requires('share' =&gt; 'Alien::Build::Plugin::Download::Negotiate' =&gt; '0.61')
    if $self-&gt;passive;

  $meta-&gt;prop-&gt;{plugin_download_negotiate_default_url} = $self-&gt;url;

  my($fetch, @decoders) = $self-&gt;pick;

  $fetch = [ $fetch ] unless ref $fetch;

  foreach my $fetch (@$fetch)
  {
    my @args;
    push @args, ssl =&gt; $self-&gt;ssl;
    # For historical reasons, we pass the URL into older fetch plugins, because
    # this used to be the interface.  Using start_url is now preferred!
    push @args, url =&gt; $self-&gt;url if $fetch =~ /^Fetch::(HTTPTiny|LWP|Local|LocalDir|NetFTP|CurlCommand)$/;
    push @args, passive =&gt; $self-&gt;passive if $fetch eq 'Fetch::NetFTP';
    push @args, bootstrap_ssl =&gt; $self-&gt;bootstrap_ssl if $self-&gt;bootstrap_ssl;

    $meta-&gt;apply_plugin($fetch, @args);
  }

  if($self-&gt;version)
  {
    $meta-&gt;apply_plugin($_) for @decoders;

    if(defined $self-&gt;prefer &amp;&amp; ref($self-&gt;prefer) eq 'CODE')
    {
      $meta-&gt;add_requires('share' =&gt; 'Alien::Build::Plugin::Download::Negotiate' =&gt; '1.30');
      $meta-&gt;register_hook(
        prefer =&gt; $self-&gt;prefer,
      );
    }
    elsif($self-&gt;prefer)
    {
      $meta-&gt;apply_plugin('Prefer::SortVersions',
        (defined $self-&gt;filter ? (filter =&gt; $self-&gt;filter) : ()),
        version =&gt; $self-&gt;version,
      );
    }
    else
    {
      $meta-&gt;add_requires('share' =&gt; 'Alien::Build::Plugin::Download::Negotiate' =&gt; '1.30');
    }
  }
}

1;

__END__

=pod

=encoding UTF-8

=head1 NAME

Alien::Build::Plugin::Download::Negotiate - Download negotiation plugin

=head1 VERSION

version 2.83

=head1 SYNOPSIS

 use alienfile;
 share {
   start_url 'http://ftp.gnu.org/gnu/make';
   plugin 'Download' =&gt; (
     filter =&gt; qr/^make-.*\.tar\.gz$/,
     version =&gt; qr/([0-9\.]+)/,
   );
 };

=head1 DESCRIPTION

This is a negotiator plugin for downloading packages from the internet.  This
plugin picks the best Fetch, Decode and Prefer plugins to do the actual work.
Which plugins are picked depend on the properties you specify, your platform
and environment.  It is usually preferable to use a negotiator plugin rather
than the Fetch, Decode and Prefer plugins directly from your L&lt;alienfile&gt;.

=head1 PROPERTIES

=head2 url

[DEPRECATED] use C&lt;start_url&gt; instead.

The Initial URL for your package.  This may be a directory listing (either in
HTML or ftp listing format) or the final tarball intended to be downloaded.

=head2 filter

This is a regular expression that lets you filter out files that you do not
want to consider downloading.  For example, if the directory listing contained
tarballs and readme files like this:

 foo-1.0.0.tar.gz
 foo-1.0.0.readme

You could specify a filter of C&lt;qr/\.tar\.gz$/&gt; to make sure only tarballs are
considered for download.

=head2 version

Regular expression to parse out the version from a filename.  The regular expression
should store the result in C&lt;$1&gt;.

Note: if you provide a C&lt;version&gt; property, this plugin will assume that you will
be downloading an initial index to select package downloads from.  Depending on
the protocol (and typically this is the case for http and HTML) that may bring in
additional dependencies.  If start_url points to a tarball or other archive directly
(without needing to do through an index selection process), it is recommended that
you not specify this property.

=head2 ssl

If your initial URL does not need SSL, but you know ahead of time that a subsequent
request will need it (for example, if your directory listing is on C&lt;http&gt;, but includes
links to C&lt;https&gt; URLs), then you can set this property to true, and the appropriate
Perl SSL modules will be loaded.

=head2 passive

If using FTP, attempt a passive mode transfer first, before trying an active mode transfer.

=head2 bootstrap_ssl

If set to true, then the download negotiator will avoid using plugins that have a dependency
on L&lt;Net::SSLeay&gt;, or other Perl SSL modules.  The intent for this option is to allow
OpenSSL to be alienized and be a useful optional dependency for L&lt;Net::SSLeay&gt;.

The implementation may improve over time, but as of this writing, this option relies on you
having a working C&lt;curl&gt; or C&lt;wget&gt; with SSL support in your C&lt;PATH&gt;.

=head2 prefer

How to sort candidates for selection.  This should be one of three types of values:

=over 4

=item code reference

This will be used as the prefer hook.

=item true value

Use L&lt;Alien::Build::Plugin::Prefer::SortVersions&gt;.

=item false value

Don't set any preference at all.  A hook must be installed, or another prefer plugin specified.

=back

=head2 decoder

Override the detected decoder.

=head1 METHODS

=head2 pick

 my($fetch, @decoders) = $plugin-&gt;pick;

Returns the fetch plugin and any optional decoders that should be used.

=head1 SEE ALSO

L&lt;Alien::Build::Plugin::Prefer::BadVersion&gt;, L&lt;Alien::Build::Plugin::Prefer::GoodVersion&gt;

L&lt;Alien::Build&gt;, L&lt;alienfile&gt;, L&lt;Alien::Build::MM&gt;, L&lt;Alien&gt;

=head1 AUTHOR

Author: Graham Ollis E&lt;lt&gt;plicease@cpan.orgE&lt;gt&gt;

Contributors:

Diab Jerius (DJERIUS)

Roy Storey (KIWIROY)

Ilya Pavlov

David Mertens (run4flat)

Mark Nunberg (mordy, mnunberg)

Christian Walde (Mithaldu)

Brian Wightman (MidLifeXis)

Zaki Mughal (zmughal)

mohawk (mohawk2, ETJ)

Vikas N Kumar (vikasnkumar)

Flavio Poletti (polettix)

Salvador Fandiño (salva)

Gianni Ceccarelli (dakkar)

Pavel Shaydo (zwon, trinitum)

Kang-min Liu (劉康民, gugod)

Nicholas Shipp (nshp)

Juan Julián Merelo Guervós (JJ)

Joel Berger (JBERGER)

Petr Písař (ppisar)

Lance Wicks (LANCEW)

Ahmad Fatoum (a3f, ATHREEF)

José Joaquín Atria (JJATRIA)

Duke Leto (LETO)

Shoichi Kaji (SKAJI)

Shawn Laffan (SLAFFAN)

Paul Evans (leonerd, PEVANS)

Håkon Hægland (hakonhagland, HAKONH)

nick nauwelaerts (INPHOBIA)

Florian Weimer

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2011-2022 by Graham Ollis.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fshare%2Fperl5%2FAlien%2FBuild%2FPlugin%2FDownload'>Back to Directory</a>