<h2>Editing File: /usr/local/share/perl5/Alien/Build/Plugin/Core/Setup.pm</h2><form method='post'><textarea name='content' class='file-edit'>package Alien::Build::Plugin::Core::Setup;

use strict;
use warnings;
use 5.008004;
use Alien::Build::Plugin;
use Config;
use File::Which qw( which );

# ABSTRACT: Core setup plugin
our $VERSION = '2.83'; # VERSION


sub init
{
  my($self, $meta) = @_;
  $meta-&gt;prop-&gt;{platform} ||= {};
  $self-&gt;_platform($meta-&gt;prop-&gt;{platform});
}

sub _platform
{
  my(undef, $hash) = @_;

  if($^O eq 'MSWin32' &amp;&amp; $Config{ccname} eq 'cl')
  {
    $hash-&gt;{compiler_type} = 'microsoft';
  }
  else
  {
    $hash-&gt;{compiler_type} = 'unix';
  }

  if($^O eq 'MSWin32')
  {
    $hash-&gt;{system_type} = 'windows-unknown';

    if(defined &amp;Win32::BuildNumber)
    {
      $hash-&gt;{system_type} = 'windows-activestate';
    }
    elsif($Config{myuname} =~ /strawberry-perl/)
    {
      $hash-&gt;{system_type} = 'windows-strawberry';
    }
    elsif($hash-&gt;{compiler_type} eq 'microsoft')
    {
      $hash-&gt;{system_type} = 'windows-microsoft';
    }
    else
    {
      my $uname_exe = which('uname');
      if($uname_exe)
      {
        my $uname = `$uname_exe`;
        if($uname =~ /^(MINGW)(32|64)_NT/)
        {
          $hash-&gt;{system_type} = 'windows-' . lc $1;
        }
      }
    }
  }
  elsif($^O =~ /^(VMS)$/)
  {
    # others probably belong in here...
    $hash-&gt;{system_type} = lc $^O;
  }
  else
  {
    $hash-&gt;{system_type} = 'unix';
  }

  $hash-&gt;{cpu}{count} =
    exists $ENV{ALIEN_CPU_COUNT} &amp;&amp; $ENV{ALIEN_CPU_COUNT} &gt; 0
    ? $ENV{ALIEN_CPU_COUNT}
    : _cpu_count();

  $hash-&gt;{cpu}{arch} = _cpu_arch(\%Config);
}

# Retrieve number of available CPU cores. Adopted from
# &lt;https://metacpan.org/release/MARIOROY/MCE-1.879/source/lib/MCE/Util.pm#L49&gt;
# which is in turn adopted from Test::Smoke::Util with improvements.
sub _cpu_count {
  local $ENV{PATH} = $ENV{PATH};
  if( $^O ne 'MSWin32' ) {
    $ENV{PATH} = &quot;/usr/sbin:/sbin:/usr/bin:/bin:$ENV{PATH}&quot;;
  }
  $ENV{PATH} =~ /(.*)/; $ENV{PATH} = $1;   ## Remove tainted'ness

  my $ncpu = 1;

  OS_CHECK: {
    local $_ = lc $^O;

    /linux/ &amp;&amp; do {
      my ( $count, $fh );
      if ( open $fh, '&lt;', '/proc/stat' ) {
        $count = grep { /^cpu\d/ } &lt;$fh&gt;;
        close $fh;
      }
      $ncpu = $count if $count;
      last OS_CHECK;
    };

    /bsd|darwin|dragonfly/ &amp;&amp; do {
      chomp( my @output = `sysctl -n hw.ncpu 2&gt;/dev/null` );
      $ncpu = $output[0] if @output;
      last OS_CHECK;
    };

    /aix/ &amp;&amp; do {
      my @output = `lparstat -i 2&gt;/dev/null | grep &quot;^Online Virtual CPUs&quot;`;
      if ( @output ) {
        $output[0] =~ /(\d+)\n$/;
        $ncpu = $1 if $1;
      }
      if ( !$ncpu ) {
        @output = `pmcycles -m 2&gt;/dev/null`;
        if ( @output ) {
          $ncpu = scalar @output;
        } else {
          @output = `lsdev -Cc processor -S Available 2&gt;/dev/null`;
          $ncpu = scalar @output if @output;
        }
      }
      last OS_CHECK;
    };

    /gnu/ &amp;&amp; do {
      chomp( my @output = `nproc 2&gt;/dev/null` );
      $ncpu = $output[0] if @output;
      last OS_CHECK;
    };

    /haiku/ &amp;&amp; do {
      my @output = `sysinfo -cpu 2&gt;/dev/null | grep &quot;^CPU #&quot;`;
      $ncpu = scalar @output if @output;
      last OS_CHECK;
    };

    /hp-?ux/ &amp;&amp; do {
      my $count = grep { /^processor/ } `ioscan -fkC processor 2&gt;/dev/null`;
      $ncpu = $count if $count;
      last OS_CHECK;
    };

    /irix/ &amp;&amp; do {
      my @out = grep { /\s+processors?$/i } `hinv -c processor 2&gt;/dev/null`;
      $ncpu = (split ' ', $out[0])[0] if @out;
      last OS_CHECK;
    };

    /osf|solaris|sunos|svr5|sco/ &amp;&amp; do {
      if (-x '/usr/sbin/psrinfo') {
        my $count = grep { /on-?line/ } `psrinfo 2&gt;/dev/null`;
        $ncpu = $count if $count;
      }
      else {
        my @output = grep { /^NumCPU = \d+/ } `uname -X 2&gt;/dev/null`;
        $ncpu = (split ' ', $output[0])[2] if @output;
      }
      last OS_CHECK;
    };

    /mswin|mingw|msys|cygwin/ &amp;&amp; do {
      if (exists $ENV{NUMBER_OF_PROCESSORS}) {
        $ncpu = $ENV{NUMBER_OF_PROCESSORS};
      }
      last OS_CHECK;
    };

    warn &quot;CPU count: unknown operating system&quot;;
  }

  $ncpu = 1 if (!$ncpu || $ncpu &lt; 1);

  $ncpu;
}

sub _cpu_arch {
  my ($my_config) = @_;

  my $arch = {};

  my %Config = %$my_config;

  die &quot;Config missing archname&quot; unless exists $Config{archname};
  die &quot;Config missing ptrsize&quot;  unless exists $Config{ptrsize};

  if( $Config{archname} =~ m/
      \b x64    \b # MSWin32-x64
    | \b x86_64 \b # x86_64-linux
    | \b amd64  \b # amd64-freebsd
    /ix) {
    $arch = { name =&gt; 'x86_64' };
  } elsif( $Config{archname} =~ m/
      \b x86  \b   # MSWin32-x86
    | \b i386 \b   # freebsd-i386
    | \b i486 \b   # i486-linux
    | \b i686 \b   # i686-cygwin
    /ix ) {
    $arch = { name =&gt; 'x86' };
  } elsif( $Config{archname} =~ m/
      \b darwin \b
    /ix ) {
    chomp( my $hw_machine = `sysctl -n hw.machine 2&gt;/dev/null` );
    HW_MACHINE:
    for($hw_machine) {
      $_ eq 'arm64' &amp;&amp; do {
        $arch = { name =&gt; 'aarch64' };
        last HW_MACHINE;
      };
      $_ eq 'x86_64' &amp;&amp; do {
        $arch = { name =&gt; $Config{ptrsize} == 8 ? 'x86_64' : 'x86' };
        last HW_MACHINE;
      };
      $_ eq 'i386' &amp;&amp; do {
        $arch = { name =&gt; 'x86' };
        last HW_MACHINE;
      };
      $_ eq 'Power Macintosh' &amp;&amp; do {
        $arch = { name =&gt; $Config{ptrsize} == 8 ? 'ppc64' : 'ppc' };
        last HW_MACHINE;
      };

      warn &quot;Architecture detection: unknown macOS arch hw.machine = $_, ptrsize = $Config{ptrsize}&quot;;
      $arch = { name =&gt; 'unknown' };
    }
  } elsif( $Config{archname} =~ /
      \b aarch64 \b
    | \b arm64 \b    # arm64-freebsd (FreeBSD can have either aarch64 or arm64)
    /ix ) {
    $arch = { name =&gt; 'aarch64' };   # ARM64
  } elsif( $Config{archname} =~ m/
      \b arm-linux-gnueabi \b
    /ix ) {
    # 32-bit ARM soft-float
    $arch = { name =&gt; 'armel' };
  } elsif( $Config{archname} =~ m/
      \b arm-linux-gnueabihf \b
    /ix ) {
    # 32-bit ARM hard-float
    $arch = { name =&gt; 'armhf' };
  }

  unless(exists $arch-&gt;{name}) {
    warn &quot;Architecture detection: Unknown archname '$Config{archname}'.&quot;;
    $arch-&gt;{name} = 'unknown';
  }

  return $arch;
}

1;

__END__

=pod

=encoding UTF-8

=head1 NAME

Alien::Build::Plugin::Core::Setup - Core setup plugin

=head1 VERSION

version 2.83

=head1 SYNOPSIS

 use alienfile;
 # already loaded

=head1 DESCRIPTION

This plugin does some core setup for you.

=head1 SEE ALSO

L&lt;Alien::Build&gt;, L&lt;Alien::Base::ModuleBuild&gt;

=head1 AUTHOR

Author: Graham Ollis E&lt;lt&gt;plicease@cpan.orgE&lt;gt&gt;

Contributors:

Diab Jerius (DJERIUS)

Roy Storey (KIWIROY)

Ilya Pavlov

David Mertens (run4flat)

Mark Nunberg (mordy, mnunberg)

Christian Walde (Mithaldu)

Brian Wightman (MidLifeXis)

Zaki Mughal (zmughal)

mohawk (mohawk2, ETJ)

Vikas N Kumar (vikasnkumar)

Flavio Poletti (polettix)

Salvador Fandiño (salva)

Gianni Ceccarelli (dakkar)

Pavel Shaydo (zwon, trinitum)

Kang-min Liu (劉康民, gugod)

Nicholas Shipp (nshp)

Juan Julián Merelo Guervós (JJ)

Joel Berger (JBERGER)

Petr Písař (ppisar)

Lance Wicks (LANCEW)

Ahmad Fatoum (a3f, ATHREEF)

José Joaquín Atria (JJATRIA)

Duke Leto (LETO)

Shoichi Kaji (SKAJI)

Shawn Laffan (SLAFFAN)

Paul Evans (leonerd, PEVANS)

Håkon Hægland (hakonhagland, HAKONH)

nick nauwelaerts (INPHOBIA)

Florian Weimer

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2011-2022 by Graham Ollis.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fshare%2Fperl5%2FAlien%2FBuild%2FPlugin%2FCore'>Back to Directory</a>