<h2>Editing File: /usr/local/share/perl5/Alien/Build/Plugin/Core/Download.pm</h2><form method='post'><textarea name='content' class='file-edit'>package Alien::Build::Plugin::Core::Download;

use strict;
use warnings;
use 5.008004;
use Alien::Build::Plugin;
use Path::Tiny ();
use Alien::Build::Util qw( _mirror );

# ABSTRACT: Core download plugin
our $VERSION = '2.83'; # VERSION


sub _hook
{
  my($build) = @_;

  my $res = $build-&gt;fetch;

  if($res-&gt;{type} =~ /^(?:html|dir_listing)$/)
  {
    my $type = $res-&gt;{type};
    $type =~ s/_/ /;
    $build-&gt;log(&quot;decoding $type&quot;);
    $res = $build-&gt;decode($res);
  }

  if($res-&gt;{type} eq 'list')
  {
    my $orig = $res;
    $res = $build-&gt;prefer($res);

    my @exclude;
    if($build-&gt;meta-&gt;prop-&gt;{start_url} =~ /^https:/)
    {
      @{ $res-&gt;{list} } = grep {
        $_-&gt;{url} =~ /https:/ ? 1 : do {
          push @exclude, $_-&gt;{url};
          0;
        }
      } @{ $res-&gt;{list} };
    }

    if(@{ $res-&gt;{list} } == 0)
    {
      my @excluded = map { $_-&gt;{url} } @{ $orig-&gt;{list} };
      if(@excluded)
      {
        if(@excluded &gt; 15)
        {
          splice @excluded , 14;
          push @excluded, '...';
        }
        $build-&gt;log(&quot;These files were excluded by the filter stage:&quot;);
        $build-&gt;log(&quot;excluded $_&quot;) for @excluded;
      }
      else
      {
        $build-&gt;log(&quot;No files found prior to the filter stage&quot;);
      }
      die &quot;no matching files in listing&quot;;
    }
    my $version = $res-&gt;{list}-&gt;[0]-&gt;{version};
    my($pick, @other) = map { $_-&gt;{url} } @{ $res-&gt;{list} };

    if(@other &gt; 8)
    {
      splice @other, 7;
      push @other, '...';
    }
    $build-&gt;log(&quot;candidate *$pick&quot;);
    $build-&gt;log(&quot;candidate  $_&quot;) for @other;

    if(@exclude)
    {
      if(@exclude &gt; 8)
      {
        splice @exclude, 7;
        push @exclude, '...';
      }
      $build-&gt;log(&quot;excluded insecure URLs:&quot;);
      $build-&gt;log($_) for @exclude;
    }

    $res = $build-&gt;fetch($pick);

    if($version)
    {
      $version =~ s/\.+$//;
      $build-&gt;log(&quot;setting version based on archive to $version&quot;);
      $build-&gt;runtime_prop-&gt;{version} = $version;
    }
  }

  if($res-&gt;{type} eq 'file')
  {
    my $alienfile = $res-&gt;{filename};
    $build-&gt;log(&quot;downloaded $alienfile&quot;);
    if($res-&gt;{content})
    {
      my $tmp = Alien::Build::TempDir-&gt;new($build, &quot;download&quot;);
      my $path = Path::Tiny-&gt;new(&quot;$tmp/$alienfile&quot;);
      $path-&gt;spew_raw($res-&gt;{content});
      $build-&gt;install_prop-&gt;{download} = $path-&gt;stringify;
      $build-&gt;install_prop-&gt;{complete}-&gt;{download} = 1;
      $build-&gt;install_prop-&gt;{download_detail}-&gt;{&quot;$path&quot;}-&gt;{protocol} = $res-&gt;{protocol} if defined $res-&gt;{protocol};
      return $build;
    }
    elsif($res-&gt;{path})
    {
      if(defined $res-&gt;{tmp} &amp;&amp; !$res-&gt;{tmp})
      {
        if(-e $res-&gt;{path})
        {
          $build-&gt;install_prop-&gt;{download} = $res-&gt;{path};
          $build-&gt;install_prop-&gt;{complete}-&gt;{download} = 1;
          $build-&gt;install_prop-&gt;{download_detail}-&gt;{$res-&gt;{path}}-&gt;{protocol} = $res-&gt;{protocol} if defined $res-&gt;{protocol};
        }
        else
        {
          die &quot;not a file or directory: @{[ $res-&gt;{path} ]}&quot;;
        }
      }
      else
      {
        my $from = Path::Tiny-&gt;new($res-&gt;{path});
        my $tmp = Alien::Build::TempDir-&gt;new($build, &quot;download&quot;);
        my $to   = Path::Tiny-&gt;new(&quot;$tmp/@{[ $from-&gt;basename ]}&quot;);
        if(-d $res-&gt;{path})
        {
          # Please note: _mirror and Alien::Build::Util are ONLY
          # allowed to be used by core plugins.  If you are writing
          # a non-core plugin it may be removed.  That is why it
          # is private.
          _mirror $from, $to;
        }
        else
        {
          require File::Copy;
          File::Copy::copy(
            &quot;$from&quot; =&gt; &quot;$to&quot;,
          ) || die &quot;copy $from =&gt; $to failed: $!&quot;;
        }
        $build-&gt;install_prop-&gt;{download} = $to-&gt;stringify;
        $build-&gt;install_prop-&gt;{complete}-&gt;{download} = 1;
        $build-&gt;install_prop-&gt;{download_detail}-&gt;{&quot;$to&quot;}-&gt;{protocol} = $res-&gt;{protocol} if defined $res-&gt;{protocol};
      }
      return $build;
    }
    die &quot;file without content or path&quot;;
  }
  die &quot;unknown fetch response type: @{[ $res-&gt;{type} ]}&quot;;
}

sub init
{
  my($self, $meta) = @_;

  $meta-&gt;default_hook(download =&gt; \&amp;_hook);
}

1;

__END__

=pod

=encoding UTF-8

=head1 NAME

Alien::Build::Plugin::Core::Download - Core download plugin

=head1 VERSION

version 2.83

=head1 SYNOPSIS

 use alienfile;
 # already loaded

=head1 DESCRIPTION

This plugin does some core download logic.

=head1 SEE ALSO

L&lt;Alien::Build&gt;, L&lt;Alien::Base::ModuleBuild&gt;

=head1 AUTHOR

Author: Graham Ollis E&lt;lt&gt;plicease@cpan.orgE&lt;gt&gt;

Contributors:

Diab Jerius (DJERIUS)

Roy Storey (KIWIROY)

Ilya Pavlov

David Mertens (run4flat)

Mark Nunberg (mordy, mnunberg)

Christian Walde (Mithaldu)

Brian Wightman (MidLifeXis)

Zaki Mughal (zmughal)

mohawk (mohawk2, ETJ)

Vikas N Kumar (vikasnkumar)

Flavio Poletti (polettix)

Salvador Fandiño (salva)

Gianni Ceccarelli (dakkar)

Pavel Shaydo (zwon, trinitum)

Kang-min Liu (劉康民, gugod)

Nicholas Shipp (nshp)

Juan Julián Merelo Guervós (JJ)

Joel Berger (JBERGER)

Petr Písař (ppisar)

Lance Wicks (LANCEW)

Ahmad Fatoum (a3f, ATHREEF)

José Joaquín Atria (JJATRIA)

Duke Leto (LETO)

Shoichi Kaji (SKAJI)

Shawn Laffan (SLAFFAN)

Paul Evans (leonerd, PEVANS)

Håkon Hægland (hakonhagland, HAKONH)

nick nauwelaerts (INPHOBIA)

Florian Weimer

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2011-2022 by Graham Ollis.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fshare%2Fperl5%2FAlien%2FBuild%2FPlugin%2FCore'>Back to Directory</a>