<h2>Editing File: /usr/local/share/perl5/Alien/Build/Plugin/Build/SearchDep.pm</h2><form method='post'><textarea name='content' class='file-edit'>package Alien::Build::Plugin::Build::SearchDep;

use strict;
use warnings;
use 5.008004;
use Alien::Build::Plugin;
use Text::ParseWords qw( shellwords );

# ABSTRACT: Add dependencies to library and header search path
our $VERSION = '2.83'; # VERSION


has aliens =&gt; {};


has public_I =&gt; 0;
has public_l =&gt; 0;

sub init
{
  my($self, $meta) = @_;

  $meta-&gt;add_requires('configure' =&gt; 'Alien::Build::Plugin::Build::SearchDep' =&gt; '0.35');
  $meta-&gt;add_requires('share'     =&gt; 'Env::ShellWords' =&gt; 0.01);

  if($self-&gt;public_I || $self-&gt;public_l)
  {
    $meta-&gt;add_requires('configure' =&gt; 'Alien::Build::Plugin::Build::SearchDep' =&gt; '0.53');
  }

  my @aliens;
  if(ref($self-&gt;aliens) eq 'HASH')
  {
    @aliens = keys %{ $self-&gt;aliens };
    $meta-&gt;add_requires('share' =&gt; $_ =&gt; $self-&gt;aliens-&gt;{$_}) for @aliens;
  }
  else
  {
    @aliens = ref $self-&gt;aliens ? @{ $self-&gt;aliens } : ($self-&gt;aliens);
    $meta-&gt;add_requires('share' =&gt; $_ =&gt; 0) for @aliens;
  }

  $meta-&gt;around_hook(
    build =&gt; sub {
      my($orig, $build) = @_;

      local $ENV{CFLAGS}   = $ENV{CFLAGS};
      local $ENV{CXXFLAGS} = $ENV{CXXFLAGS};
      local $ENV{LDFLAGS}  = $ENV{LDFLAGS};

      tie my @CFLAGS,   'Env::ShellWords', 'CFLAGS';
      tie my @CXXFLAGS, 'Env::ShellWords', 'CXXFLAGS';
      tie my @LDFLAGS,  'Env::ShellWords', 'LDFLAGS';

      my $cflags  = $build-&gt;install_prop-&gt;{plugin_build_searchdep_cflags}  = [];
      my $ldflags = $build-&gt;install_prop-&gt;{plugin_build_searchdep_ldflags} = [];
      my $libs    = $build-&gt;install_prop-&gt;{plugin_build_searchdep_libs}    = [];

      foreach my $other (@aliens)
      {
        my $other_cflags;
        my $other_libs;
        if($other-&gt;install_type('share'))
        {
          $other_cflags = $other-&gt;cflags_static;
          $other_libs   = $other-&gt;libs_static;
        }
        else
        {
          $other_cflags = $other-&gt;cflags;
          $other_libs   = $other-&gt;libs;
        }
        unshift @$cflags,  grep /^-I/, shellwords($other_cflags);
        unshift @$ldflags, grep /^-L/, shellwords($other_libs);
        unshift @$libs,    grep /^-l/, shellwords($other_libs);
      }

      unshift @CFLAGS, @$cflags;
      unshift @CXXFLAGS, @$cflags;
      unshift @LDFLAGS, @$ldflags;

      $orig-&gt;($build);

    },
  );

  $meta-&gt;after_hook(
    gather_share =&gt; sub {
      my($build) = @_;

      $build-&gt;runtime_prop-&gt;{libs}        = '' unless defined $build-&gt;runtime_prop-&gt;{libs};
      $build-&gt;runtime_prop-&gt;{libs_static} = '' unless defined $build-&gt;runtime_prop-&gt;{libs_static};

      if($self-&gt;public_l)
      {
        $build-&gt;runtime_prop-&gt;{$_} = join(' ', _space_escape(@{ $build-&gt;install_prop-&gt;{plugin_build_searchdep_libs} })) . ' ' . $build-&gt;runtime_prop-&gt;{$_}
          for qw( libs libs_static );
      }

      $build-&gt;runtime_prop-&gt;{$_} = join(' ', _space_escape(@{ $build-&gt;install_prop-&gt;{plugin_build_searchdep_ldflags} })) . ' ' . $build-&gt;runtime_prop-&gt;{$_}
        for qw( libs libs_static );

      if($self-&gt;public_I)
      {
        $build-&gt;runtime_prop-&gt;{cflags}        = '' unless defined $build-&gt;runtime_prop-&gt;{cflags};
        $build-&gt;runtime_prop-&gt;{cflags_static} = '' unless defined $build-&gt;runtime_prop-&gt;{cflags_static};
        $build-&gt;runtime_prop-&gt;{$_} = join(' ', _space_escape(@{ $build-&gt;install_prop-&gt;{plugin_build_searchdep_cflags} })) . ' ' . $build-&gt;runtime_prop-&gt;{$_}
          for qw( cflags cflags_static );
      }
    },
  );
}

sub _space_escape
{
  map {
    my $str = $_;
    $str =~ s{(\s)}{\\$1}g;
    $str;
  } @_;
}

1;

__END__

=pod

=encoding UTF-8

=head1 NAME

Alien::Build::Plugin::Build::SearchDep - Add dependencies to library and header search path

=head1 VERSION

version 2.83

=head1 SYNOPSIS

 use alienfile;
 plugin 'Build::SearchDep' =&gt; (
   aliens =&gt; [qw( Alien::Foo Alien::Bar )],
 );

=head1 DESCRIPTION

This plugin adds the other aliens as prerequisites, and adds their header and library
search path to C&lt;CFLAGS&gt; and C&lt;LDFLAGS&gt; environment variable, so that tools that use
them (like autoconf) can pick them up.

=head1 PROPERTIES

=head2 aliens

Either a list reference or hash reference of the other aliens.  If a hash reference
then the keys are the class names and the values are the versions of those classes.

=head2 public_I

Include the C&lt;-I&gt; flags when setting the runtime cflags property.

=head2 public_l

Include the C&lt;-l&gt; flags when setting the runtime libs property.

=head1 AUTHOR

Author: Graham Ollis E&lt;lt&gt;plicease@cpan.orgE&lt;gt&gt;

Contributors:

Diab Jerius (DJERIUS)

Roy Storey (KIWIROY)

Ilya Pavlov

David Mertens (run4flat)

Mark Nunberg (mordy, mnunberg)

Christian Walde (Mithaldu)

Brian Wightman (MidLifeXis)

Zaki Mughal (zmughal)

mohawk (mohawk2, ETJ)

Vikas N Kumar (vikasnkumar)

Flavio Poletti (polettix)

Salvador Fandiño (salva)

Gianni Ceccarelli (dakkar)

Pavel Shaydo (zwon, trinitum)

Kang-min Liu (劉康民, gugod)

Nicholas Shipp (nshp)

Juan Julián Merelo Guervós (JJ)

Joel Berger (JBERGER)

Petr Písař (ppisar)

Lance Wicks (LANCEW)

Ahmad Fatoum (a3f, ATHREEF)

José Joaquín Atria (JJATRIA)

Duke Leto (LETO)

Shoichi Kaji (SKAJI)

Shawn Laffan (SLAFFAN)

Paul Evans (leonerd, PEVANS)

Håkon Hægland (hakonhagland, HAKONH)

nick nauwelaerts (INPHOBIA)

Florian Weimer

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2011-2022 by Graham Ollis.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fshare%2Fperl5%2FAlien%2FBuild%2FPlugin%2FBuild'>Back to Directory</a>