<h2>Editing File: /usr/local/share/perl5/Alien/Build/Plugin/Build/CMake.pm</h2><form method='post'><textarea name='content' class='file-edit'>package Alien::Build::Plugin::Build::CMake;

use strict;
use warnings;
use 5.008004;
use Config;
use Alien::Build::Plugin;
use Capture::Tiny qw( capture );

# ABSTRACT: CMake plugin for Alien::Build
our $VERSION = '2.83'; # VERSION


sub cmake_generator
{
  if($^O eq 'MSWin32')
  {
    return 'MinGW Makefiles' if is_dmake();

    {
      my($out, $err) = capture { system $Config{make}, '/?' };
      return 'NMake Makefiles' if $out =~ /NMAKE/;
    }

    {
      my($out, $err) = capture { system $Config{make}, '--version' };
      return 'MinGW Makefiles' if $out =~ /GNU Make/;
    }

    die 'make not detected';
  }
  else
  {
    return 'Unix Makefiles';
  }
}

sub init
{
  my($self, $meta) = @_;

  $meta-&gt;prop-&gt;{destdir} = $^O eq 'MSWin32' ? 0 : 1;

  $meta-&gt;add_requires('configure' =&gt; 'Alien::Build::Plugin::Build::CMake' =&gt; '0.99');
  $meta-&gt;add_requires('share'     =&gt; 'Alien::cmake3' =&gt; '0.02');

  if(is_dmake())
  {
    # even on at least some older versions of strawberry that do not
    # use it, come with gmake in the PATH.  So to save us the effort
    # of having to install Alien::gmake lets just use that version
    # if we can find it!
    my $found_gnu_make = 0;

    foreach my $exe (qw( gmake make mingw32-make ))
    {
      my($out, $err) = capture { system $exe, '--version' };
      if($out =~ /GNU Make/)
      {
        $meta-&gt;interpolator-&gt;replace_helper('make' =&gt; sub { $exe });
        $found_gnu_make = 1;
        last;
      }
    }

    if(!$found_gnu_make)
    {
      $meta-&gt;add_requires('share' =&gt; 'Alien::gmake' =&gt; '0.20');
      $meta-&gt;interpolator-&gt;replace_helper('make' =&gt; sub { require Alien::gmake; Alien::gmake-&gt;exe });
    }
  }

  $meta-&gt;interpolator-&gt;replace_helper('cmake' =&gt; sub { require Alien::cmake3; Alien::cmake3-&gt;exe });
  $meta-&gt;interpolator-&gt;add_helper('cmake_generator' =&gt; \&amp;cmake_generator);

  my @args = (
    -G =&gt; '%{cmake_generator}',
    '-DCMAKE_POSITION_INDEPENDENT_CODE:BOOL=true',
    '-DCMAKE_INSTALL_PREFIX:PATH=%{.install.prefix}',
    '-DCMAKE_INSTALL_LIBDIR:PATH=lib',
    '-DCMAKE_MAKE_PROGRAM:PATH=%{make}',
  );

  $meta-&gt;prop-&gt;{plugin_build_cmake}-&gt;{args} = \@args;

  $meta-&gt;default_hook(
    build =&gt; [
      ['%{cmake}', @args, '%{.install.extract}' ],
      ['%{make}' ],
      ['%{make}', 'install' ],
    ],
  );

  # TODO: handle destdir on windows ??
}

my $is_dmake;

sub is_dmake
{
  unless(defined $is_dmake)
  {
    if($^O eq 'MSWin32')
    {
      my($out, $err) = capture { system $Config{make}, '-V' };
      $is_dmake = $out =~ /dmake/ ? 1 : 0;
    }
    else
    {
      $is_dmake = 0;
    }
  }

  $is_dmake;
}

1;

__END__

=pod

=encoding UTF-8

=head1 NAME

Alien::Build::Plugin::Build::CMake - CMake plugin for Alien::Build

=head1 VERSION

version 2.83

=head1 SYNOPSIS

 use alienfile;
 
 share {
   plugin 'Build::CMake';
   build [
     # this is the default build step, if you do not specify one.
     [ '%{cmake}',
         @{ meta-&gt;prop-&gt;{plugin_build_cmake}-&gt;{args} },
         # ... put extra cmake args here ...
         '%{.install.extract}'
     ],
     '%{make}',
     '%{make} install',
   ];
 };

=head1 DESCRIPTION

This plugin helps build alienized projects that use C&lt;cmake&gt;.
The intention is to make this a core L&lt;Alien::Build&gt; plugin if/when
it becomes stable enough.

This plugin provides a meta property C&lt;plugin_build_cmake.args&gt; which may change over time
but for the moment includes:

 -G %{cmake_generator}                          \
 -DCMAKE_POSITION_INDEPENDENT_CODE:BOOL=true    \
 -DCMAKE_INSTALL_PREFIX:PATH=%{.install.prefix} \
 -DCMAKE_INSTALL_LIBDIR:PATH=lib                \
 -DCMAKE_MAKE_PROGRAM:PATH=%{make}

This plugin supports out-of-source builds via the meta property C&lt;out_of_source&gt;.

=head1 METHODS

=head2 cmake_generator

Returns the C&lt;cmake&gt; generator according to your Perl's C&lt;make&gt;.

=head2 is_dmake

Returns true if your Perls C&lt;make&gt; appears to be C&lt;dmake&gt;.

=head1 HELPERS

=head2 cmake

This plugin replaces the default C&lt;cmake&gt; helper with the one that comes from L&lt;Alien::cmake3&gt;.

=head2 cmake_generator

This is the appropriate C&lt;cmake&gt; generator to use based on the make used by your Perl.  This is
frequently C&lt;Unix Makefiles&gt;.  One place where it may be different is if your Windows Perl uses
C&lt;nmake&gt;, which comes with Visual C++.

=head2 make

This plugin I&lt;may&gt; replace the default C&lt;make&gt; helper if the default C&lt;make&gt; is not supported by
C&lt;cmake&gt;.  This is most often an issue with older versions of Strawberry Perl which used C&lt;dmake&gt;.
On Perls that use C&lt;dmake&gt;, this plugin will search for GNU Make in the PATH, and if it can't be
found will fallback on using L&lt;Alien::gmake&gt;.

=head1 SEE ALSO

=over 4

=item L&lt;Alien::Build&gt;

=item L&lt;Alien::Build::Plugin::Build::Autoconf&gt;

=item L&lt;alienfile&gt;

=back

=head1 AUTHOR

Author: Graham Ollis E&lt;lt&gt;plicease@cpan.orgE&lt;gt&gt;

Contributors:

Diab Jerius (DJERIUS)

Roy Storey (KIWIROY)

Ilya Pavlov

David Mertens (run4flat)

Mark Nunberg (mordy, mnunberg)

Christian Walde (Mithaldu)

Brian Wightman (MidLifeXis)

Zaki Mughal (zmughal)

mohawk (mohawk2, ETJ)

Vikas N Kumar (vikasnkumar)

Flavio Poletti (polettix)

Salvador Fandiño (salva)

Gianni Ceccarelli (dakkar)

Pavel Shaydo (zwon, trinitum)

Kang-min Liu (劉康民, gugod)

Nicholas Shipp (nshp)

Juan Julián Merelo Guervós (JJ)

Joel Berger (JBERGER)

Petr Písař (ppisar)

Lance Wicks (LANCEW)

Ahmad Fatoum (a3f, ATHREEF)

José Joaquín Atria (JJATRIA)

Duke Leto (LETO)

Shoichi Kaji (SKAJI)

Shawn Laffan (SLAFFAN)

Paul Evans (leonerd, PEVANS)

Håkon Hægland (hakonhagland, HAKONH)

nick nauwelaerts (INPHOBIA)

Florian Weimer

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2011-2022 by Graham Ollis.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fshare%2Fperl5%2FAlien%2FBuild%2FPlugin%2FBuild'>Back to Directory</a>