<h2>Editing File: /usr/local/share/perl5/Alien/Build/Manual/AlienAuthor.pod</h2><form method='post'><textarea name='content' class='file-edit'># PODNAME: Alien::Build::Manual::AlienAuthor
# ABSTRACT: Alien author documentation
# VERSION

__END__

=pod

=encoding UTF-8

=head1 NAME

Alien::Build::Manual::AlienAuthor - Alien author documentation

=head1 VERSION

version 2.83

=head1 SYNOPSIS

 perldoc Alien::Build::Manual::AlienAuthor

=head1 DESCRIPTION

B&lt;Note&gt;: Please read the entire document before you get started in
writing your own L&lt;alienfile&gt;.  The section on dynamic vs. static
libraries will likely save you a lot of grief if you read it now!

This document is intended to teach L&lt;Alien&gt; authors how to build their
own L&lt;Alien&gt; distribution using L&lt;Alien::Build&gt; and L&lt;Alien::Base&gt;.
Such an L&lt;Alien&gt; distribution consists of three essential parts:

=over 4

=item An L&lt;alienfile&gt;

This is a recipe for how to 1) detect an already installed version of
the library or tool you are alienizing 2) download and build the library
or tool that you are alienizing and 3) gather the configuration settings
necessary for the use of that library or tool.

=item An installer C&lt;Makefile.PL&gt; or C&lt;Build.PL&gt; or a C&lt;dist.ini&gt; if you are using L&lt;Dist::Zilla&gt;

This is a thin layer between your L&lt;alienfile&gt; recipe, and the Perl
installer (either L&lt;ExtUtils::MakeMaker&gt; or L&lt;Module::Build&gt;.

=item A Perl class (.pm file) that inherits from L&lt;Alien::Base&gt;

For most L&lt;Alien&gt;s this does not need to be customized at all, since
L&lt;Alien::Base&gt; usually does what you need.

=back

For example if you were alienizing a library called libfoo, you might
have these files:

 Alien-Libfoo-1.00/Makefile.PL
 Alien-Libfoo-1.00/alienfile
 Alien-Libfoo-1.00/lib/Alien/Libfoo.pm

This document will focus mainly on instructing you how to construct an
L&lt;alienfile&gt;, but we will also briefly cover making a simple
C&lt;Makefile.PL&gt; or C&lt;dist.ini&gt; to go along with it.  We will also touch
on when you might want to extend your subclass to add non-standard
functionality.

=head2 Using commands

Most software libraries and tools will come with instructions for how to
install them in the form of commands that you are intended to type into
a shell manually.  The easiest way to automate those instructions is to
just put the commands in your L&lt;alienfile&gt;.  For example, lets suppose
that libfoo is built using autoconf and provides a C&lt;pkg-config&gt; C&lt;.pc&gt;
file.

We will also later discuss plugins.  For common build systems like
autoconf or CMake, it is usually better to use the appropriate plugin
because they will handle corner cases better than a simple set of
commands.  We're going to take a look at commands first because it's
easier to understand the different phases with commands.

(Aside, autoconf is a series of tools and macros used to configure
(usually) a C or C++ library or tool by generating any number of
Makefiles.  It is the C equivalent to L&lt;ExtUtils::MakeMaker&gt;, if you
will.  Basically, if your library or tool instructions start with
'./configure' it is most likely an autoconf based library or tool).

(Aside2, C&lt;pkg-config&gt; is a standard-ish way to provide the compiler and
linker flags needed for compiling and linking against the library.  If
your tool installs a C&lt;.pc&gt; file, usually in C&lt;$PREFIX/lib/pkgconfig&gt;
then, your tool uses C&lt;pkg-config&gt;).

Here is the L&lt;alienfile&gt; that you might have:

 use alienfile;
 
 probe [ 'pkg-config --exists libfoo' ];
 
 share {
 
   start_url 'http://www.libfoo.org/src/libfoo-1.00.tar.gz';
 
   download [ 'wget %{.meta.start_url}' ];
 
   extract [ 'tar zxf %{.install.download}' ];
 
   build [
     [ './configure --prefix=%{.install.prefix} --disable-shared' ],
     [ '%{make}' ],
     [ '%{make} install' ],
   ];
 
 };
 
 gather [
   [ 'pkg-config --modversion libfoo', \'%{.runtime.version}' ],
   [ 'pkg-config --cflags     libfoo', \'%{.runtime.cflags}'  ],
   [ 'pkg-config --libs       libfoo', \'%{.runtime.libs}'    ],
 ];

There is a lot going on here, so lets decode it a little bit.  An
L&lt;alienfile&gt; is just some Perl with some alien specific sugar.  The
first line

 use alienfile;

imports the sugar into the L&lt;alienfile&gt;.  It also is a flag for the
reader to see that this is an L&lt;alienfile&gt; and not some other kind of
Perl script.

The second line is the probe directive:

 probe [ 'pkg-config --exists libfoo' ];

is used to see if the library is already installed on the target system.
If C&lt;pkg-config&gt; is in the path, and if libfoo is installed, this should
exit with a success (0) and tell L&lt;Alien::Build&gt; to use the system
library.  If either C&lt;pkg-config&gt; in the PATH, or if libfoo is not
installed, then it will exist with non-success (!= 0) and tells
L&lt;Alien::Build&gt; to download and build from source.

You can provide as many probe directives as you want.  This is useful if
there are different ways to probe for the system.  L&lt;Alien::Build&gt; will
stop on the first successfully found system library found.  Say our
library libfoo comes with a C&lt;.pc&gt; file for use with C&lt;pkg-config&gt; and
also provides a C&lt;foo-config&gt; program to find the same values.  You
could then specify this in your L&lt;alienfile&gt;

 probe [ 'pkg-config --exists libfoo' ];
 probe [ 'foo-config --version' ];

Other directives can be specified multiple times if there are different
methods that can be tried for the various steps.

Sometimes it is easier to probe for a library from Perl rather than with
a command.  For that you can use a code reference.  For example, another
way to call C&lt;pkg-config&gt; would be from Perl:

 probe sub {
   my($build) = @_;  # $build is the Alien::Build instance.
   system 'pkg-config --exists libfoo';
   $? == 0 ? 'system' : 'share';
 };

The Perl code should return 'system' if the library is installed, and
'share' if not.  (Other directives should return a true value on
success, and a false value on failure).  You can also throw an exception with
C&lt;die&gt; to indicate a failure.

The next part of the L&lt;alienfile&gt; is the C&lt;share&gt; block, which is used
to group the directives which are used to download and install the
library or tool in the event that it is not already installed.

 share {
   start_url 'http://www.libfoo.org/src/libfoo-1.00.tar.gz';
   download [ 'wget %{.meta.start_url}' ];
   extract [ 'tar zxf %{.install.download}' ];
   build [
     [ './configure --prefix=%{.install.prefix} --disable-shared' ],
     [ '%{make}' ],
     [ '%{make} install' ],
   ];
 };

The start_url specifies where to find the package that you are alienizing.
It should be either a tarball (or zip file, or what have you) or an
HTML index.  The download directive as you might imagine specifies how
to download  the library or tool.  The extract directive specifies how
to extract the archive once it is downloaded.  In the extract step, you
can use the variable C&lt;%{.install.download}&gt; as a placeholder for the archive
that was downloaded in the download step.  This is also accessible if
you use a code reference from the L&lt;Alien::Build&gt; instance:

 share {
   ...
   requires 'Archive::Extract';
   extract sub {
     my($build) = @_;
     my $tarball = $build-&gt;install_prop-&gt;{download};
     my $ae = Archive::Extract-&gt;new( archive =&gt; $tarball );
     $ae-&gt;extract;
     1;
   }
   ...
 };

The build directive specifies how to build the library or tool once it
has been downloaded and extracted.  Note the special variable
C&lt;%{.install.prefix}&gt; is the location where the library should be
installed.  C&lt;%{make}&gt; is a helper which will be replaced by the
appropriate C&lt;make&gt;, which may be called something different on some
platforms (on Windows for example, it frequently may be called C&lt;nmake&gt;
or C&lt;dmake&gt;).

The final part of the L&lt;alienfile&gt; has a gather directive which
specifies how to get the details on how to compile and link against the
library.  For this, once again we use the C&lt;pkg-config&gt; command:

 gather [
   [ 'pkg-config --modversion libfoo', \'%{.runtime.version}' ],
   [ 'pkg-config --cflags     libfoo', \'%{.runtime.cflags}'  ],
   [ 'pkg-config --libs       libfoo', \'%{.runtime.libs}'    ],
 ];

The scalar reference as the final item in the command list tells
L&lt;Alien::Build&gt; that the output from the command should be stored in the
given variable.  The runtime variables are the ones that will be
available to C&lt;Alien::Libfoo&gt; once it is installed.  (Install
properties, which are the ones that we have seen up till now are thrown
away once the L&lt;Alien&gt; distribution is installed.

You can also provide a C&lt;sys&gt; block for directives that should be used
when a system install is detected.  Normally you only need to do this if
the gather step is different between share and system installs.  For
example, the above is equivalent to:

 build {
   ...
   gather [
     [ 'pkg-config --modversion libfoo', \'%{.runtime.version}' ],
     [ 'pkg-config --cflags     libfoo', \'%{.runtime.cflags}'  ],
     [ 'pkg-config --libs       libfoo', \'%{.runtime.libs}'    ],
   ];
 };
 
 sys {
   gather [
     [ 'pkg-config --modversion libfoo', \'%{.runtime.version}' ],
     [ 'pkg-config --cflags     libfoo', \'%{.runtime.cflags}'  ],
     [ 'pkg-config --libs       libfoo', \'%{.runtime.libs}'    ],
   ];
 };

(Aside3, the reason it is called C&lt;sys&gt; and not C&lt;system&gt; is so that it
does not conflict with the built in C&lt;system&gt; function)!

=head2 Using plugins

The first example is a good way of showing the full manual path that you
can choose, but there is a lot of repetition, if you are doing many
L&lt;Alien&gt;s that use autoconf and C&lt;pkg-config&gt; (which are quite common.
L&lt;alienfile&gt; allows you to use plugins.  See L&lt;Alien::Build::Plugin&gt; for
a list of some of the plugin categories.

For now, I will just show you how to write the L&lt;alienfile&gt; for libfoo
above using L&lt;Alien::Build::Plugin::Build::Autoconf&gt;,
L&lt;Alien::Build::Plugin::PkgConfig::Negotiate&gt;,
L&lt;Alien::Build::Plugin::Download::Negotiate&gt;, and
L&lt;Alien::Build::Plugin::Extract::Negotiate&gt;

 use alienfile;
 
 plugin 'PkgConfig' =&gt; (
   pkg_name =&gt; 'libfoo',
 );
 
 share {
   start_url 'http://www.libfoo.org/src';
   plugin 'Download' =&gt; (
     filter =&gt; qr/^libfoo-[0-9\.]+\.tar\.gz$/,
     version =&gt; qr/^libfoo-([0-9\.]+)\.tar\.gz$/,
   );
   plugin 'Extract' =&gt; 'tar.gz';
   plugin 'Build::Autoconf';
   build [
     '%{configure} --disable-shared',
     '%{make}',
     '%{make} install',
   ];
 };

The first plugin that we use is the C&lt;pkg-config&gt; negotiation plugin.  A
negotiation plugin is one which doesn't do the actual work but selects
the best one from a set of plugins depending on your platform and
environment.  (In the case of
L&lt;Alien::Build::Plugin::PkgConfig::Negotiate&gt;, it may choose to use
command line tools, a pure Perl implementation (L&lt;PkgConfig&gt;), or
libpkgconf, depending on what is available).  When using negotiation
plugins you may omit the C&lt;::Negotiate&gt; suffix.  So as you can see using
the plugin here is an advantage because it is more reliable than just
specifying a command which may not be installed!

Next we use the download negotiation plugin.  This is also better than
the version above, because again, C&lt;wget&gt; my not be installed on the
target system.  Also you can specify a URL which will be scanned for
links, and use the most recent version.

We use the Extract negotiation plugin to use either command line tools,
or Perl libraries to extract from the archive once it is downloaded.

Finally we use the Autoconf plugin
(L&lt;Alien::Build::Plugin::Build::Autoconf&gt;).  This is a lot more
sophisticated and reliable than in the previous example, for a number of
reasons.  This version will even work on Windows assuming the library or
tool you are alienizing supports that platform!

Strictly speaking the build directive is not necessary, because the
autoconf plugin provides a default which is reasonable.  The only reason
that you would want to include it is if you need to provide additional
flags to the configure step.

 share {
   ...
   build [
     '%{configure} --enable-bar --enable-baz --disable-shared',
     '%{make}',
     '%{make} install',
   ];
 };

=head2 Multiple .pc files

Some packages come with multiple libraries paired with multiple C&lt;.pc&gt;
files.  In this case you want to provide the
L&lt;Alien::Build::Plugin::PkgConfig::Negotiate&gt; with an array reference
of package names.

 plugin 'PkgConfig' =&gt; (
   pkg_name =&gt; [ 'foo', 'bar', 'baz' ],
 );

All packages must be found in order for the C&lt;system&gt; install to succeed.
Once installed the first C&lt;pkg_name&gt; will be used by default (in this
example C&lt;foo&gt;), and you can retrieve any other C&lt;pkg_name&gt; using
the L&lt;Alien::Base alt method|Alien::Base/alt&gt;.

=head2 A note about dynamic vs. static libraries

If you are using your L&lt;Alien&gt; to build an XS module, it is important
that you use static libraries if possible.  If you have a package that
refuses to build a static library, then you can use L&lt;Alien::Role::Dino&gt;.

Actually let me back up a minute.  For a C&lt;share&gt; install it is best
to use static libraries to build your XS extension.  This is because
if your L&lt;Alien&gt; is ever upgraded to a new version it can break your
existing XS modules.  For a C&lt;system&gt; install shared libraries are
usually best because you can often get security patches without having
to re-build anything in perl land.

If you looked closely at the &quot;Using commands&quot; and &quot;Using plugins&quot;
sections above, you may notice that we went out of our way where
possible to tell Autotools to build only static libraries using the
C&lt;--disable-shared&gt; command.  The Autoconf plugin also does this by
default.

Sometimes though you will have a package that builds both, or maybe
you I&lt;want&gt; both static and dynamic libraries to work with XS and FFI.
For that case, there is the L&lt;Alien::Build::Plugin::Gather::IsolateDynamic&gt;
plugin.

 use alienfile;
 ...
 plugin 'Gather::IsolateDynamic';

What it does, is that it moves the dynamic libraries (usually .so on
Unix and .DLL on Windows) to a place where they can be found by FFI,
and where they won't be used by the compiler for building XS.  It usually
doesn't do any harm to include this plugin, so if you are just starting
out you might want to add it anyway.  Arguably it should have been the
default behavior from the beginning.

If you have already published an Alien that does not isolate its
dynamic libraries, then you might get some fails from old upgraded
aliens because the share directory isn't cleaned up by default (this is
perhaps a design bug in the way that share directories work, but it
is a long standing characteristic).  One work around for this is to
use the C&lt;clean_install&gt; property on L&lt;Alien::Build::MM&gt;, which will
clean out the share directory on upgrade, and possibly save you a lot
of grief.

=head2 Verifying and debugging your alienfile

You could feed your alienfile directly into L&lt;Alien::Build&gt;, or
L&lt;Alien::Build::MM&gt;, but it is sometimes useful to test your alienfile
using the C&lt;af&gt; command (it does not come with L&lt;Alien::Build&gt;, you need
to install L&lt;App::af&gt;).  By default C&lt;af&gt; will use the C&lt;alienfile&gt; in
the current directory (just as C&lt;make&gt; uses the C&lt;Makefile&gt; in the
current directory; just like C&lt;make&gt; you can use the C&lt;-f&gt; option to
specify a different L&lt;alienfile&gt;).

You can test your L&lt;alienfile&gt; in dry run mode:

 % af install --dry-run
 Alien::Build::Plugin::Core::Legacy&gt; adding legacy hash to config
 Alien::Build::Plugin::Core::Gather&gt; mkdir -p /tmp/I2YXRyxb0r/_alien
 ---
 cflags: ''
 cflags_static: ''
 install_type: system
 legacy:
   finished_installing: 1
   install_type: system
   name: libfoo
   original_prefix: /tmp/7RtAusykNN
   version: 1.2.3
 libs: '-lfoo '
 libs_static: '-lfoo '
 prefix: /tmp/7RtAusykNN
 version: 1.2.3

You can use the C&lt;--type&gt; option to force a share install (download and
build from source):

 % af install --type=share --dry-run
 Alien::Build::Plugin::Core::Download&gt; decoding html
 Alien::Build::Plugin::Core::Download&gt; candidate *https://www.libfoo.org/download/libfoo-1.2.4.tar.gz
 Alien::Build::Plugin::Core::Download&gt; candidate  https://www.libfoo.org/download/libfoo-1.2.3.tar.gz
 Alien::Build::Plugin::Core::Download&gt; candidate  https://www.libfoo.org/download/libfoo-1.2.2.tar.gz
 Alien::Build::Plugin::Core::Download&gt; candidate  https://www.libfoo.org/download/libfoo-1.2.1.tar.gz
 Alien::Build::Plugin::Core::Download&gt; candidate  https://www.libfoo.org/download/libfoo-1.2.0.tar.gz
 Alien::Build::Plugin::Core::Download&gt; candidate  https://www.libfoo.org/download/libfoo-1.1.9.tar.gz
 Alien::Build::Plugin::Core::Download&gt; candidate  https://www.libfoo.org/download/libfoo-1.1.8.tar.gz
 Alien::Build::Plugin::Core::Download&gt; candidate  https://www.libfoo.org/download/libfoo-1.1.7.tar.gz
 Alien::Build::Plugin::Core::Download&gt; candidate  ...
 Alien::Build::Plugin::Core::Download&gt; setting version based on archive to 1.2.4
 Alien::Build::Plugin::Core::Download&gt; downloaded libfoo-1.2.4.tar.gz
 Alien::Build::CommandSequence&gt; + ./configure --prefix=/tmp/P22WEXj80r --with-pic --disable-shared
 ... snip ...
 Alien::Build::Plugin::Core::Gather&gt; mkdir -p /tmp/WsoLAQ889w/_alien
 ---
 cflags: ''
 cflags_static: ''
 install_type: share
 legacy:
   finished_installing: 1
   install_type: share
   original_prefix: /tmp/P22WEXj80r
   version: 1.2.4
 libs: '-L/tmp/P22WEXj80r/lib -lfoo '
 libs_static: '-L/tmp/P22WEXj80r/lib -lfoo '
 prefix: /tmp/P22WEXj80r
 version: 1.2.4

You can also use the C&lt;--before&gt; and C&lt;--after&gt; options to take a peek
at what the build environment looks like at different stages as well,
which can sometimes be useful:

 % af install --dry-run --type=share --before build bash
 Alien::Build::Plugin::Core::Download&gt; decoding html
 Alien::Build::Plugin::Core::Download&gt; candidate *https://www.libfoo.org/download/libfoo-1.2.4.tar.gz
 Alien::Build::Plugin::Core::Download&gt; candidate  https://www.libfoo.org/download/libfoo-1.2.3.tar.gz
 Alien::Build::Plugin::Core::Download&gt; candidate  https://www.libfoo.org/download/libfoo-1.2.2.tar.gz
 Alien::Build::Plugin::Core::Download&gt; candidate  https://www.libfoo.org/download/libfoo-1.2.1.tar.gz
 Alien::Build::Plugin::Core::Download&gt; candidate  https://www.libfoo.org/download/libfoo-1.2.0.tar.gz
 Alien::Build::Plugin::Core::Download&gt; candidate  https://www.libfoo.org/download/libfoo-1.1.9.tar.gz
 Alien::Build::Plugin::Core::Download&gt; candidate  https://www.libfoo.org/download/libfoo-1.1.8.tar.gz
 Alien::Build::Plugin::Core::Download&gt; candidate  https://www.libfoo.org/download/libfoo-1.1.7.tar.gz
 Alien::Build::Plugin::Core::Download&gt; candidate  ...
 Alien::Build::Plugin::Core::Download&gt; setting version based on archive to 1.2.4
 Alien::Build::Plugin::Core::Download&gt; downloaded libfoo-1.2.4.tar.gz
 App::af::install&gt;  [ before build ] + bash
 /tmp/fbVPu4LRTs/build_5AVn/libfoo-1.2.4$ ls
 CHANGES Makefile autoconf.ac lib
 /tmp/fbVPu4LRTs/build_5AVn/libfoo-1.2.4$

There are a lot of other useful things that you can do with the C&lt;af&gt;
command.  See L&lt;af&gt; for details.

=head2 Integrating with MakeMaker

Once you have a working L&lt;alienfile&gt; you can write your C&lt;Makefile.PL&gt;.

 use ExtUtils::MakeMaker;
 use Alien::Build::MM;
 
 my $abmm = Alien::Build::MM-&gt;new;
 
 WriteMakefile($abmm-&gt;mm_args(
   ABSTRACT           =&gt; 'Discover or download and install libfoo',
   DISTNAME           =&gt; 'Alien-Libfoo',
   NAME               =&gt; 'Alien::Libfoo',
   VERSION_FROM       =&gt; 'lib/Alien/Libfoo.pm',
   CONFIGURE_REQUIRES =&gt; {
     'Alien::Build::MM' =&gt; 0,
   },
   BUILD_REQUIRES =&gt; {
     'Alien::Build::MM' =&gt; 0,
   },
   PREREQ_PM =&gt; {
     'Alien::Base' =&gt; 0,
   },
   # If you are going to write the recommended
   # tests you will will want these:
   TEST_REQUIRES =&gt; {
     'Test::Alien' =&gt; 0,
     'Test2::V0'   =&gt; 0,
   },
 ));
 
 sub MY::postamble {
   $abmm-&gt;mm_postamble;
 }

The C&lt;lib/Alien/Libfoo.pm&gt; that goes along with it is very simple:

 package Alien::Libfoo;
 
 use strict;
 use warnings;
 use parent qw( Alien::Base );
 
 1;

You are done and can install it normally:

 % perl Makefile.PL
 % make
 % make test
 % make install

=head2 Integrating with Module::Build

Please don't!  Okay if you have to there is L&lt;Alien::Build::MB&gt;.

=head2 Non standard configuration

L&lt;Alien::Base&gt; support most of the things that your L&lt;Alien&gt; will need,
like compiler flags (cflags), linker flags (libs) and binary directory
(bin_dir).  Your library or tool may have other configuration items
which are not supported by default.  You can store the values in the
L&lt;alienfile&gt; into the runtime properties:

 gather [
   # standard:
   [ 'foo-config --version libfoo', \'%{.runtime.version}' ],
   [ 'foo-config --cflags  libfoo', \'%{.runtime.cflags}'  ],
   [ 'foo-config --libs    libfoo', \'%{.runtime.libs}'    ],
   # non-standard
   [ 'foo-config --bar-baz libfoo', \'%{.runtime.bar_baz}' ],
 ];

then you can expose them in your L&lt;Alien::Base&gt; subclass:

 package Alien::Libfoo;
 
 use strict;
 use warnings;
 use parent qw( Alien::Base );
 
 sub bar_baz {
   my($self) = @_;
   $self-&gt;runtime_prop-&gt;{bar_baz},
 };
 
 1;

=head2 Testing

(optional, but highly recommended)

You should write a test using L&lt;Test::Alien&gt; to make sure that your
alien will work with any XS modules that are going to use it:

 use Test2::V0;
 use Test::Alien;
 use Alien::Libfoo;
 
 alien_ok 'Alien::Libfoo';
 
 xs_ok do { local $/; &lt;DATA&gt; }, with_subtest {
   is Foo::something(), 1, 'Foo::something() returns 1';
 };
 
 done_testing;
 
 __DATA__
 #include &quot;EXTERN.h&quot;
 #include &quot;perl.h&quot;
 #include &quot;XSUB.h&quot;
 #include &lt;foo.h&gt;
 
 MODULE = Foo PACKAGE = Foo
 
 int something()

You can also use L&lt;Test::Alien&gt; to test tools instead of libraries:

 use Test2::V0;
 use Test::Alien;
 use Alien::Libfoo;
 
 alien_ok 'Alien::Libfoo';
 run_ok(['foo', '--version'])
   -&gt;exit_is(0);
 
 done_testing;

You can also write tests specifically for L&lt;FFI::Platypus&gt;, if your
alien is going to be used to write FFI bindings.  (the test below
is the FFI equivalent to the XS example above).

 use Test2::V0;
 use Test::Alien;
 use Alien::Libfoo;
 
 alien_ok 'Alien::Libfoo';
 ffi_ok { symbols =&gt; [ 'something' ] }, with_subtest {
   # $ffi is an instance of FFI::Platypus with the lib
   # set appropriately.
   my($ffi) = @_;
   my $something = $ffi-&gt;function( something =&gt; [] =&gt; 'int' );
   is $something-&gt;call(), 1, 'Foo::something() returns 1';
 };

If you do use C&lt;ffi_ok&gt; you want to make sure that your alien reliably
produces dynamic libraries.  If it isn't consistent (if for example
some platforms tend not to provide or build dynamic libraries), you can
check that C&lt;dynamic_libs&gt; doesn't return an empty list.

 ...
 alien_ok 'Alien::Libfoo';
 SKIP: {
   skip &quot;This test requires a dynamic library&quot;
     unless Alien::Libfoo-&gt;dynamic_libs;
   ffi_ok { symbols [ 'something' ] }, with_subtest {
     ...
   };
 }

More details on testing L&lt;Alien&gt; modules can be found in the
L&lt;Test::Alien&gt; documentation.

You can also run the tests that come with the package that you are alienizing,
by using a C&lt;test&gt; block in your L&lt;alienfile&gt;.  Keep in mind that some packages
use testing tools or have other prerequisites that will not be available on your
users machines when they attempt to install your alien.  So you do not want to
blindly add a test block without checking what the prereqs are.  For Autoconf
style packages you typically test a package using the C&lt;make check&gt; command:

 use alienfile;
 
 plugin 'PkgConfig' =&gt; 'libfoo';
 
 share {
   ... # standard build steps.
   test [ '%{make} check' ];
 };

=head2 Dist::Zilla

(optional, mildly recommended)

You can also use the L&lt;Alien::Build&gt; L&lt;Dist::Zilla&gt; plugin
L&lt;Dist::Zilla::Plugin::AlienBuild&gt;:

 name    = Alien-Libfoo
 author  = E. Xavier Ample &lt;example@cpan.org&gt;
 license = Perl_5
 copyright_holder = E. Xavier Ample &lt;example@cpan.org&gt;
 copyright_year   = 2017
 version = 0.01
 
 [@Basic]
 [AlienBuild]

The plugin takes care of a lot of details like making sure that the
correct minimum versions of L&lt;Alien::Build&gt; and L&lt;Alien::Base&gt; are used.
See the plugin documentation for additional details.

=head2 Using your Alien

Once you have installed you can use your Alien.  See
L&lt;Alien::Build::Manual::AlienUser&gt; for guidance on that.

=head1 SEE ALSO

=over 4

=item L&lt;Alien::Build::Manual&gt;

Other L&lt;Alien::Build&gt; manuals.

=back

=head1 AUTHOR

Author: Graham Ollis E&lt;lt&gt;plicease@cpan.orgE&lt;gt&gt;

Contributors:

Diab Jerius (DJERIUS)

Roy Storey (KIWIROY)

Ilya Pavlov

David Mertens (run4flat)

Mark Nunberg (mordy, mnunberg)

Christian Walde (Mithaldu)

Brian Wightman (MidLifeXis)

Zaki Mughal (zmughal)

mohawk (mohawk2, ETJ)

Vikas N Kumar (vikasnkumar)

Flavio Poletti (polettix)

Salvador Fandiño (salva)

Gianni Ceccarelli (dakkar)

Pavel Shaydo (zwon, trinitum)

Kang-min Liu (劉康民, gugod)

Nicholas Shipp (nshp)

Juan Julián Merelo Guervós (JJ)

Joel Berger (JBERGER)

Petr Písař (ppisar)

Lance Wicks (LANCEW)

Ahmad Fatoum (a3f, ATHREEF)

José Joaquín Atria (JJATRIA)

Duke Leto (LETO)

Shoichi Kaji (SKAJI)

Shawn Laffan (SLAFFAN)

Paul Evans (leonerd, PEVANS)

Håkon Hægland (hakonhagland, HAKONH)

nick nauwelaerts (INPHOBIA)

Florian Weimer

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2011-2022 by Graham Ollis.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fshare%2Fperl5%2FAlien%2FBuild%2FManual'>Back to Directory</a>