<h2>Editing File: /usr/local/share/perl5/Alien/Build/Interpolate.pm</h2><form method='post'><textarea name='content' class='file-edit'>package Alien::Build::Interpolate;

use strict;
use warnings;
use 5.008004;

# ABSTRACT: Advanced interpolation engine for Alien builds
our $VERSION = '2.83'; # VERSION


sub new
{
  my($class) = @_;
  my $self = bless {
    helper  =&gt; {},
    classes =&gt; {},
  }, $class;
  $self;
}


sub add_helper
{
  my $self = shift;
  my $name = shift;
  my $code = shift;

  if(defined $self-&gt;{helper}-&gt;{$name})
  {
    require Carp;
    Carp::croak(&quot;duplicate implementation for interpolated key $name&quot;);
  }

  my $require;

  if(ref $_[0] eq 'CODE')
  {
    $require = shift;
  }
  else
  {
    $require = [];
    while(@_)
    {
      my $module = shift;
      my $version = shift;
      $version ||= 0;
      push @$require, $module =&gt; $version;
    }
  }

  $self-&gt;{helper}-&gt;{$name} = Alien::Build::Helper-&gt;new(
    $name,
    $code,
    $require,
  );
}


sub replace_helper
{
  my $self = shift;
  my($name) = @_;
  delete $self-&gt;{helper}-&gt;{$name};
  $self-&gt;add_helper(@_);
}


sub has_helper
{
  my($self, $name) = @_;

  return unless defined $self-&gt;{helper}-&gt;{$name};

  my @require = $self-&gt;{helper}-&gt;{$name}-&gt;require;

  while(@require)
  {
    my $module  = shift @require;
    my $version = shift @require;

    {
      my $pm = &quot;$module.pm&quot;;
      $pm =~ s/::/\//g;
      require $pm;
      $module-&gt;VERSION($version) if $version;
    }

    unless($self-&gt;{classes}-&gt;{$module})
    {
      if($module-&gt;can('alien_helper'))
      {
        my $helpers = $module-&gt;alien_helper;
        foreach my $k (keys %$helpers)
        {
          $self-&gt;{helper}-&gt;{$k}-&gt;code($helpers-&gt;{$k});
        }
      }
      $self-&gt;{classes}-&gt;{$module} = 1;
    }
  }

  my $code = $self-&gt;{helper}-&gt;{$name}-&gt;code;

  return unless defined $code;

  if(ref($code) ne 'CODE')
  {
    my $perl = $code;
    package Alien::Build::Interpolate::Helper;
    $code = sub {
      ##  no critic
      my $value = eval $perl;
      ## use critic
      die $@ if $@;
      $value;
    };
  }

  $code;
}


sub execute_helper
{
  my($self, $name) = @_;

  my $code = $self-&gt;has_helper($name);
  die &quot;no helper defined for $name&quot; unless defined $code;

  $code-&gt;();
}


sub _get_prop
{
  my($name, $prop, $orig) = @_;

  $name =~ s/^\./alien./;

  if($name =~ /^(.*?)\.(.*)$/)
  {
    my($key,$rest) = ($1,$2);
    return _get_prop($rest, $prop-&gt;{$key}, $orig);
  }
  elsif(exists $prop-&gt;{$name})
  {
    return $prop-&gt;{$name};
  }
  else
  {
    require Carp;
    Carp::croak(&quot;No property $orig is defined&quot;);
  }
}

sub interpolate
{
  my($self, $string, $build) = @_;

  my $prop = defined $build &amp;&amp; eval { $build-&gt;isa('Alien::Build') }
  ? $build-&gt;_command_prop
  : {};

  $string =~ s{(?&lt;!\%)\%\{([a-zA-Z_][a-zA-Z_0-9]+)\}}{$self-&gt;execute_helper($1)}eg;
  $string =~ s{(?&lt;!\%)\%\{([a-zA-Z_\.][a-zA-Z_0-9\.]+)\}}{_get_prop($1,$prop,$1)}eg;
  $string =~ s/\%(?=\%)//g;
  $string;
}


sub requires
{
  my($self, $string) = @_;
  map {
    my $helper = $self-&gt;{helper}-&gt;{$_};
    $helper ? $helper-&gt;require : ();
  } $string =~ m{(?&lt;!\%)\%\{([a-zA-Z_][a-zA-Z_0-9]+)\}}g;
}


sub clone
{
  my($self) = @_;

  require Storable;

  my %helper;
  foreach my $name (keys %{ $self-&gt;{helper} })
  {
    $helper{$name} = $self-&gt;{helper}-&gt;{$name}-&gt;clone;
  }

  my $new = bless {
    helper =&gt; \%helper,
    classes =&gt; Storable::dclone($self-&gt;{classes}),
  }, ref $self;
}

package Alien::Build::Helper;

sub new
{
  my($class, $name, $code, $require) = @_;
  bless {
    name    =&gt; $name,
    code    =&gt; $code,
    require =&gt; $require,
  }, $class;
}

sub name { shift-&gt;{name} }

sub code
{
  my($self, $code) = @_;
  $self-&gt;{code} = $code if $code;
  $self-&gt;{code};
}

sub require
{
  my($self) = @_;
  if(ref $self-&gt;{require} eq 'CODE')
  {
    $self-&gt;{require} = [ $self-&gt;{require}-&gt;($self) ];
  }
  @{ $self-&gt;{require} };
}

sub clone
{
  my($self) = @_;
  my $class = ref $self;
  $class-&gt;new(
    $self-&gt;name,
    $self-&gt;code,
    [ $self-&gt;require ],
  );
}

1;

__END__

=pod

=encoding UTF-8

=head1 NAME

Alien::Build::Interpolate - Advanced interpolation engine for Alien builds

=head1 VERSION

version 2.83

=head1 CONSTRUCTOR

=head2 new

 my $intr = Alien::Build::Interpolate-&gt;new;

=head2 add_helper

 $intr-&gt;add_helper($name =&gt; $code);
 $intr-&gt;add_helper($name =&gt; $code, %requirements);

=head2 replace_helper

 $intr-&gt;replace_helper($name =&gt; $code);
 $intr-&gt;replace_helper($name =&gt; $code, %requirements);

=head2 has_helper

 my $coderef = $intr-&gt;has_helper($name);

Used to discover if a helper exists with the given name.
Returns the code reference.

=head2 execute_helper

 my $value = $intr-&gt;execute_helper($name);

This evaluates the given helper and returns the result.

=head2 interpolate

 my $string = $intr-&gt;interpolate($template, $build);
 my $string = $intr-&gt;interpolate($template);

This takes a template and fills in the appropriate values of any helpers used
in the template.

[version 2.58]

If you pass in an L&lt;Alien::Build&gt; instance as the second argument, you can use
properties as well as helpers in the template.  Example:

 my $patch = $intr-&gt;template(&quot;%{.install.patch}/foo-%{.runtime.version}.patch&quot;, $build);

=head2 requires

 my %requires = $intr-&gt;requires($template);

This returns a hash of modules required in order to execute the given template.
The keys are the module names and the values are the versions.  Version will be
set to C&lt;0&gt; if any version is sufficient.

=head2 clone

 my $intr2 = $intr-&gt;clone;

This creates a clone of the interpolator.

=head1 AUTHOR

Author: Graham Ollis E&lt;lt&gt;plicease@cpan.orgE&lt;gt&gt;

Contributors:

Diab Jerius (DJERIUS)

Roy Storey (KIWIROY)

Ilya Pavlov

David Mertens (run4flat)

Mark Nunberg (mordy, mnunberg)

Christian Walde (Mithaldu)

Brian Wightman (MidLifeXis)

Zaki Mughal (zmughal)

mohawk (mohawk2, ETJ)

Vikas N Kumar (vikasnkumar)

Flavio Poletti (polettix)

Salvador Fandiño (salva)

Gianni Ceccarelli (dakkar)

Pavel Shaydo (zwon, trinitum)

Kang-min Liu (劉康民, gugod)

Nicholas Shipp (nshp)

Juan Julián Merelo Guervós (JJ)

Joel Berger (JBERGER)

Petr Písař (ppisar)

Lance Wicks (LANCEW)

Ahmad Fatoum (a3f, ATHREEF)

José Joaquín Atria (JJATRIA)

Duke Leto (LETO)

Shoichi Kaji (SKAJI)

Shawn Laffan (SLAFFAN)

Paul Evans (leonerd, PEVANS)

Håkon Hægland (hakonhagland, HAKONH)

nick nauwelaerts (INPHOBIA)

Florian Weimer

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2011-2022 by Graham Ollis.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fshare%2Fperl5%2FAlien%2FBuild'>Back to Directory</a>