<h2>Editing File: /usr/local/share/perl5/Alien/Build/Interpolate/Default.pm</h2><form method='post'><textarea name='content' class='file-edit'>package Alien::Build::Interpolate::Default;

use strict;
use warnings;
use 5.008004;
use parent qw( Alien::Build::Interpolate );
use File::chdir;
use File::Which qw( which );
use Capture::Tiny qw( capture );

# ABSTRACT: Default interpolator for Alien::Build
our $VERSION = '2.83'; # VERSION

sub _config
{
  $Config::Config{$_[0]};
}


sub new
{
  my($class) = @_;
  my $self = $class-&gt;SUPER::new(@_);


  $self-&gt;add_helper( ar =&gt; sub { _config 'ar' }, 'Config' );


  $self-&gt;add_helper( bison =&gt; undef, sub {
    my $helper = shift;
    if(which 'bison')
    {
      $helper-&gt;code(sub { 'bison' });
      return  ();
    }
    else
    {
      return 'Alien::bison' =&gt; '0.17';
    }
  });


  $self-&gt;add_helper( bzip2 =&gt; undef, sub {
    my $helper = shift;
    if(which 'bzip2')
    {
      $helper-&gt;code( sub { 'bzip2' });
      return ();
    }
    else
    {
      return 'Alien::Libbz2' =&gt; '0.04';
    }
  });


  $self-&gt;add_helper( cc =&gt; sub { _config 'cc' }, 'Config' );


  $self-&gt;add_helper( cmake =&gt; sub { 'cmake' }, sub {
    if(which 'cmake')
    {
      return ();
    }
    else
    {
      return 'Alien::CMake' =&gt; '0.07';
    }
  });


  $self-&gt;add_helper( cp =&gt; sub { _config 'cp' }, 'Config' );


  $self-&gt;add_helper( devnull =&gt; sub { $^O eq 'MSWin32' ? 'NUL' : '/dev/null' });


  $self-&gt;add_helper( flex =&gt; undef, sub {
    my $helper = shift;
    if(which 'flex')
    {
      $helper-&gt;code(sub { 'flex' });
      return  ();
    }
    else
    {
      return 'Alien::flex' =&gt; '0.08';
    }
  });


  $self-&gt;add_helper( gmake =&gt; undef, 'Alien::gmake' =&gt; '0.11' );


  $self-&gt;add_helper( install =&gt; sub { 'install' });


  $self-&gt;add_helper( ld =&gt; sub { _config 'ld' }, 'Config' );


  $self-&gt;add_helper( m4 =&gt; undef, 'Alien::m4' =&gt; '0.08' );


  if($^O eq 'MSWin32')
  {
    # TL;DR: dmake is bad, and shouldn't be used to build anything but older
    # versions of Windows Perl that don't support gmake.
    my $perl_make = _config 'make';
    my $my_make;
    $self-&gt;add_helper( make =&gt; sub {
      return $my_make if defined $my_make;

      if( $perl_make ne 'dmake' &amp;&amp; which $perl_make )
      {
        # assume if it is called nmake or gmake that it really is what it
        # says it is.
        if( $perl_make eq 'nmake' || $perl_make eq 'gmake' )
        {
          return $my_make = $perl_make;
        }

        my $out = capture { system $perl_make, '--version' };
        if( $out =~ /GNU make/i || $out =~ /Microsoft \(R\) Program Maintenance/ )
        {
          return $my_make = $perl_make;
        }

      }

      # if we see something that looks like it might be gmake, use that.
      foreach my $try (qw( gmake mingw32-make ))
      {
        return $my_make = $try if which $try;
      }

      if( which 'make' )
      {
        my $out = capture { system 'make', '--version' };
        if( $out =~ /GNU make/i || $out =~ /Microsoft \(R\) Program Maintenance/ )
        {
          return $my_make = 'make';
        }
      }

      # if we see something that looks like it might be nmake, use that.
      foreach my $try (qw( nmake ))
      {
        return $my_make = $try if which $try;
      }

      $my_make = $perl_make;
    });
  }
  else
  {
    $self-&gt;add_helper( make =&gt; sub { _config 'make' }, 'Config' );
  }


  $self-&gt;add_helper( mkdir_deep =&gt; sub { $^O eq 'MSWin32' ? 'md' : 'mkdir -p'}, 'Alien::Build' =&gt; '1.04' );
  $self-&gt;add_helper( make_path  =&gt; sub { $^O eq 'MSWin32' ? 'md' : 'mkdir -p'}, 'Alien::Build' =&gt; '1.05' );


  $self-&gt;add_helper( nasm =&gt; undef, sub {
    my $helper = shift;
    if(which 'nasm')
    {
      $helper-&gt;code(sub { 'nasm' });
      return  ();
    }
    else
    {
      return 'Alien::nasm' =&gt; '0.11';
    }
  });


  $self-&gt;add_helper( patch =&gt; undef, sub {
    my $helper = shift;
    if(which 'patch')
    {
      if($^O eq 'MSWin32')
      {
        $helper-&gt;code(sub { 'patch --binary' });
      }
      else
      {
        $helper-&gt;code(sub { 'patch' });
      }
      return  ();
    }
    else
    {
      return 'Alien::patch' =&gt; '0.09';
    }
  });


  $self-&gt;add_helper( perl =&gt; sub {
      my $perl = Devel::FindPerl::find_perl_interpreter();
      $perl =~ s{\\}{/}g if $^O eq 'MSWin32';
      $perl;
  }, 'Devel::FindPerl' );


  $self-&gt;add_helper( pkgconf =&gt; undef, 'Alien::pkgconf' =&gt; 0.06 );


  $self-&gt;add_helper( cwd =&gt; sub {
    my $cwd = &quot;$CWD&quot;;
    $cwd =~ s{\\}{/}g if $^O eq 'MSWin32';
    $cwd;
  } );


  $self-&gt;add_helper( sh =&gt; sub { 'sh' }, 'Alien::MSYS' =&gt; '0.07' );


  $self-&gt;add_helper( rm =&gt; sub { _config 'rm' }, 'Config' );


  $self-&gt;add_helper( xz =&gt; undef, sub {
    my $helper = shift;
    if(which 'xz')
    {
      $helper-&gt;code(sub { 'xz' });
      return  ();
    }
    else
    {
      return 'Alien::xz' =&gt; '0.02';
    }
  });

  $self;
}

1;

__END__

=pod

=encoding UTF-8

=head1 NAME

Alien::Build::Interpolate::Default - Default interpolator for Alien::Build

=head1 VERSION

version 2.83

=head1 CONSTRUCTOR

=head2 new

 my $intr = Alien::Build::Interpolate::Default-&gt;new;

=head1 HELPERS

=head2 ar

 %{ar}

The ar command.

=head2 bison

 %{bison}

Requires: L&lt;Alien::bison&gt; 0.17 if not already in C&lt;PATH&gt;.

=head2 bzip2

 %{bzip2}

Requires: L&lt;Alien::Libbz2&gt; 0.04 if not already in C&lt;PATH&gt;.

=head2 cc

 %{cc}

The C Compiler used to build Perl

=head2 cmake

 %{cmake}

Requires: L&lt;Alien::CMake&gt; 0.07 if cmake is not already in C&lt;PATH&gt;.

Deprecated: Use the L&lt;Alien::Build::Plugin::Build::CMake&gt; plugin instead (which will replace
this helper with one that works with L&lt;Alien::cmake3&gt; that works better).

=head2 cp

 %{cp}

The copy command.

=head2 devnull

 %{devnull}

The null device, if available.  On Unix style operating systems this will be C&lt;/dev/null&gt; on Windows it is C&lt;NUL&gt;.

=head2 flex

 %{flex}

Requires: L&lt;Alien::flex&gt; 0.08 if not already in C&lt;PATH&gt;.

=head2 gmake

 %{gmake}

Requires: L&lt;Alien::gmake&gt; 0.11

Deprecated: use L&lt;Alien::Build::Plugin::Build::Make&gt; instead.

=head2 install

 %{install}

The Unix C&lt;install&gt; command.  Not normally available on Windows.

=head2 ld

 %{ld}

The linker used to build Perl

=head2 m4

 %{m4}

Requires: L&lt;Alien::m4&gt; 0.08

L&lt;Alien::m4&gt; should pull in a version of C&lt;m4&gt; that will work with Autotools.

=head2 make

 %{make}

Make.  On Unix this will be the same make used by Perl.  On Windows this will be
C&lt;gmake&gt; or C&lt;nmake&gt; if those are available, and only C&lt;dmake&gt; if the first two
are not available.

=head2 make_path

 %{make_path}

Make directory, including all parent directories as needed.  This is usually C&lt;mkdir -p&gt;
on Unix and simply C&lt;md&gt; on windows.

=head2 nasm

 %{nasm}

Requires: L&lt;Alien::nasm&gt; 0.11 if not already in the C&lt;PATH&gt;.

=head2 patch

 %{patch}

Requires: L&lt;Alien::patch&gt; 0.09 if not already in the C&lt;PATH&gt;.

On Windows this will normally render C&lt;patch --binary&gt;, which makes patch work like it does on Unix.

=head2 perl

 %{perl}

Requires: L&lt;Devel::FindPerl&gt;

=head2 pkgconf

 %{pkgconf}

Requires: L&lt;Alien::pkgconf&gt; 0.06.

=head2 cwd

 %{cwd}

=head2 sh

 %{sh}

Unix style command interpreter (/bin/sh).

Deprecated: use the L&lt;Alien::Build::Plugin::Build::MSYS&gt; plugin instead.

=head2 rm

 %{rm}

The remove command

=head2 xz

 %{xz}

Requires: L&lt;Alien::xz&gt; 0.02 if not already in the C&lt;PATH&gt;.

=head1 AUTHOR

Author: Graham Ollis E&lt;lt&gt;plicease@cpan.orgE&lt;gt&gt;

Contributors:

Diab Jerius (DJERIUS)

Roy Storey (KIWIROY)

Ilya Pavlov

David Mertens (run4flat)

Mark Nunberg (mordy, mnunberg)

Christian Walde (Mithaldu)

Brian Wightman (MidLifeXis)

Zaki Mughal (zmughal)

mohawk (mohawk2, ETJ)

Vikas N Kumar (vikasnkumar)

Flavio Poletti (polettix)

Salvador Fandiño (salva)

Gianni Ceccarelli (dakkar)

Pavel Shaydo (zwon, trinitum)

Kang-min Liu (劉康民, gugod)

Nicholas Shipp (nshp)

Juan Julián Merelo Guervós (JJ)

Joel Berger (JBERGER)

Petr Písař (ppisar)

Lance Wicks (LANCEW)

Ahmad Fatoum (a3f, ATHREEF)

José Joaquín Atria (JJATRIA)

Duke Leto (LETO)

Shoichi Kaji (SKAJI)

Shawn Laffan (SLAFFAN)

Paul Evans (leonerd, PEVANS)

Håkon Hægland (hakonhagland, HAKONH)

nick nauwelaerts (INPHOBIA)

Florian Weimer

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2011-2022 by Graham Ollis.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fshare%2Fperl5%2FAlien%2FBuild%2FInterpolate'>Back to Directory</a>