<h2>Editing File: /usr/local/share/perl5/Alien/Build/CommandSequence.pm</h2><form method='post'><textarea name='content' class='file-edit'>package Alien::Build::CommandSequence;

use strict;
use warnings;
use 5.008004;
use Text::ParseWords qw( shellwords );
use Capture::Tiny qw( capture );

# ABSTRACT: Alien::Build command sequence
our $VERSION = '2.83'; # VERSION


sub new
{
  my($class, @commands) = @_;
  my $self = bless {
    commands =&gt; \@commands,
  }, $class;
  $self;
}


sub apply_requirements
{
  my($self, $meta, $phase) = @_;
  my $intr = $meta-&gt;interpolator;
  foreach my $command (@{ $self-&gt;{commands} })
  {
    next if ref $command eq 'CODE';
    if(ref $command eq 'ARRAY')
    {
      foreach my $arg (@$command)
      {
        next if ref $arg eq 'CODE';
        $meta-&gt;add_requires($phase, $intr-&gt;requires($arg))
      }
    }
    else
    {
      $meta-&gt;add_requires($phase, $intr-&gt;requires($command));
    }
  }
  $self;
}

my %built_in = (

  cd =&gt; sub {
    my(undef, $dir) = @_;
    if(!defined $dir)
    {
      die &quot;undef passed to cd&quot;;
    }
    elsif(-d $dir)
    {
      chdir($dir) || die &quot;unable to cd $dir $!&quot;;
    }
    else
    {
      die &quot;unable to cd $dir, does not exist&quot;;
    }
  },

);

sub _run_list
{
  my($build, @cmd) = @_;
  $build-&gt;log(&quot;+ @cmd&quot;);
  return $built_in{$cmd[0]}-&gt;(@cmd) if $built_in{$cmd[0]};
  system @cmd;
  die &quot;external command failed&quot; if $?;
}

sub _run_string
{
  my($build, $cmd) = @_;
  $build-&gt;log(&quot;+ $cmd&quot;);

  {
    my $cmd = $cmd;
    $cmd =~ s{\\}{\\\\}g if $^O eq 'MSWin32';
    my @cmd = shellwords($cmd);
    return $built_in{$cmd[0]}-&gt;(@cmd) if $built_in{$cmd[0]};
  }

  system $cmd;
  die &quot;external command failed&quot; if $?;
}

sub _run_with_code
{
  my($build, @cmd) = @_;
  my $code = pop @cmd;
  $build-&gt;log(&quot;+ @cmd&quot;);
  my %args = ( command =&gt; \@cmd );

  if($built_in{$cmd[0]})
  {
    my $error;
    ($args{out}, $args{err}, $error) = capture {
      eval { $built_in{$cmd[0]}-&gt;(@cmd) };
      $@;
    };
    $args{exit} = $error eq '' ? 0 : 2;
    $args{builtin} = 1;
  }
  else
  {
    ($args{out}, $args{err}, $args{exit}) = capture {
      system @cmd; $?
    };
  }
  $build-&gt;log(&quot;[output consumed by Alien::Build recipe]&quot;);
  $code-&gt;($build, \%args);
}


sub _apply
{
  my($where, $prop, $value) = @_;
  if($where =~ /^(.*?)\.(.*?)$/)
  {
    _apply($2, $prop-&gt;{$1}, $value);
  }
  else
  {
    $prop-&gt;{$where} = $value;
  }
}

sub execute
{
  my($self, $build) = @_;
  my $intr = $build-&gt;meta-&gt;interpolator;

  foreach my $command (@{ $self-&gt;{commands} })
  {
    if(ref($command) eq 'CODE')
    {
      $command-&gt;($build);
    }
    elsif(ref($command) eq 'ARRAY')
    {
      my($command, @args) = @$command;
      my $code;
      $code = pop @args if $args[-1] &amp;&amp; ref($args[-1]) eq 'CODE';

      if($args[-1] &amp;&amp; ref($args[-1]) eq 'SCALAR')
      {
        my $dest = ${ pop @args };
        if($dest =~ /^\%\{((?:alien|)\.(?:install|runtime|hook)\.[a-z\.0-9_]+)\}$/)
        {
          $dest = $1;
          $dest =~ s/^\./alien./;
          $code = sub {
            my($build, $args) = @_;
            die &quot;external command failed&quot; if $args-&gt;{exit};
            my $out = $args-&gt;{out};
            chomp $out;
            _apply($dest, $build-&gt;_command_prop, $out);
          };
        }
        else
        {
          die &quot;illegal destination: $dest&quot;;
        }
      }

      ($command, @args) = map { $intr-&gt;interpolate($_, $build) } ($command, @args);

      if($code)
      {
        _run_with_code $build, $command, @args, $code;
      }
      else
      {
        _run_list $build, $command, @args;
      }
    }
    else
    {
      my $command = $intr-&gt;interpolate($command, $build);
      _run_string $build, $command;
    }
  }
}

1;

__END__

=pod

=encoding UTF-8

=head1 NAME

Alien::Build::CommandSequence - Alien::Build command sequence

=head1 VERSION

version 2.83

=head1 CONSTRUCTOR

=head2 new

 my $seq = Alien::Build::CommandSequence-&gt;new(@commands);

=head1 METHODS

=head2 apply_requirements

 $seq-&gt;apply_requirements($meta, $phase);

=head2 execute

 $seq-&gt;execute($build);

=head1 AUTHOR

Author: Graham Ollis E&lt;lt&gt;plicease@cpan.orgE&lt;gt&gt;

Contributors:

Diab Jerius (DJERIUS)

Roy Storey (KIWIROY)

Ilya Pavlov

David Mertens (run4flat)

Mark Nunberg (mordy, mnunberg)

Christian Walde (Mithaldu)

Brian Wightman (MidLifeXis)

Zaki Mughal (zmughal)

mohawk (mohawk2, ETJ)

Vikas N Kumar (vikasnkumar)

Flavio Poletti (polettix)

Salvador Fandiño (salva)

Gianni Ceccarelli (dakkar)

Pavel Shaydo (zwon, trinitum)

Kang-min Liu (劉康民, gugod)

Nicholas Shipp (nshp)

Juan Julián Merelo Guervós (JJ)

Joel Berger (JBERGER)

Petr Písař (ppisar)

Lance Wicks (LANCEW)

Ahmad Fatoum (a3f, ATHREEF)

José Joaquín Atria (JJATRIA)

Duke Leto (LETO)

Shoichi Kaji (SKAJI)

Shawn Laffan (SLAFFAN)

Paul Evans (leonerd, PEVANS)

Håkon Hægland (hakonhagland, HAKONH)

nick nauwelaerts (INPHOBIA)

Florian Weimer

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2011-2022 by Graham Ollis.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fshare%2Fperl5%2FAlien%2FBuild'>Back to Directory</a>