<h2>Editing File: /usr/local/share/perl5/Alien/Base.pm</h2><form method='post'><textarea name='content' class='file-edit'>package Alien::Base;

use strict;
use warnings;
use 5.008004;
use Carp;
use Path::Tiny ();
use Scalar::Util qw/blessed/;
use Capture::Tiny 0.17 qw/capture_stdout/;
use Text::ParseWords qw/shellwords/;
use Alien::Util;

# ABSTRACT: Base classes for Alien:: modules
our $VERSION = '2.83'; # VERSION


sub import {
  my $class = shift;

  return if $class eq __PACKAGE__;

  return if $class-&gt;runtime_prop;

  return if $class-&gt;install_type('system');

  require DynaLoader;

  # Sanity check in order to ensure that dist_dir can be found.
  # This will throw an exception otherwise.
  $class-&gt;dist_dir;

  # get a reference to %Alien::MyLibrary::AlienLoaded
  # which contains names of already loaded libraries
  # this logic may be replaced by investigating the DynaLoader arrays
  my $loaded = do {
    no strict 'refs';
    no warnings 'once';
    \%{ $class . &quot;::AlienLoaded&quot; };
  };

  my @libs = $class-&gt;split_flags( $class-&gt;libs );

  my @L = grep { s/^-L// } map { &quot;$_&quot; } @libs;  ## no critic (ControlStructures::ProhibitMutatingListFunctions)
  my @l = grep { /^-l/ } @libs;

  unshift @DynaLoader::dl_library_path, @L;

  my @libpaths;
  foreach my $l (@l) {
    next if $loaded-&gt;{$l};

    my $path = DynaLoader::dl_findfile( $l );
    unless ($path) {
      carp &quot;Could not resolve $l&quot;;
      next;
    }

    push @libpaths, $path;
    $loaded-&gt;{$l} = $path;
  }

  push @DynaLoader::dl_resolve_using, @libpaths;

  my @librefs = map { DynaLoader::dl_load_file( $_, 0x01 ) } grep !/\.(a|lib)$/, @libpaths;
  push @DynaLoader::dl_librefs, @librefs;

}


sub _dist_dir ($)
{
  my($dist_name) = @_;

  my @pm = split /-/, $dist_name;
  $pm[-1] .= &quot;.pm&quot;;

  foreach my $inc (@INC)
  {
    my $pm = Path::Tiny-&gt;new($inc, @pm);
    if(-f $pm)
    {
      my $share = Path::Tiny-&gt;new($inc, qw( auto share dist ), $dist_name );
      if(-d $share)
      {
        return $share-&gt;absolute-&gt;stringify;
      }
      last;
    }
  }
  Carp::croak(&quot;unable to find dist share directory for $dist_name&quot;);
}

sub dist_dir {
  my $class = shift;

  my $dist = blessed $class || $class;
  $dist =~ s/::/-/g;

  my $dist_dir =
    $class-&gt;config('finished_installing')
      ? _dist_dir $dist
      : $class-&gt;config('working_directory');

  croak &quot;Failed to find share dir for dist '$dist'&quot;
    unless defined $dist_dir &amp;&amp; -d $dist_dir;

  return $dist_dir;
}


sub new { return bless {}, $_[0] }

sub _flags
{
  my($class, $key) = @_;

  my $config = $class-&gt;runtime_prop;
  my $flags = $config-&gt;{$key};

  my $prefix = $config-&gt;{prefix};
  $prefix =~ s{\\}{/}g if $^O =~ /^(MSWin32|msys)$/;
  my $distdir = $config-&gt;{distdir};
  $distdir =~ s{\\}{/}g if $^O =~ /^(MSWin32|msys)$/;

  if(defined $flags &amp;&amp; $prefix ne $distdir)
  {
    $flags = join ' ', map {
      my $flag = $_;
      $flag =~ s/^(-I|-L|-LIBPATH:)?\Q$prefix\E/$1$distdir/;
      $flag =~ s/(\s)/\\$1/g;
      $flag;
    } $class-&gt;split_flags($flags);
  }

  $flags;
}


sub cflags {
  my $class = shift;
  return $class-&gt;runtime_prop ? $class-&gt;_flags('cflags') : $class-&gt;_pkgconfig_keyword('Cflags');
}


sub cflags_static {
  my $class = shift;
  return $class-&gt;runtime_prop ? $class-&gt;_flags('cflags_static') : $class-&gt;_pkgconfig_keyword('Cflags', 'static');
}


sub libs {
  my $class = shift;
  return $class-&gt;runtime_prop ? $class-&gt;_flags('libs') : $class-&gt;_pkgconfig_keyword('Libs');
}


sub libs_static {
  my $class = shift;
  return $class-&gt;runtime_prop ? $class-&gt;_flags('libs_static') : $class-&gt;_pkgconfig_keyword('Libs', 'static');
}


sub version {
  my $self = shift;
  return $self-&gt;runtime_prop
    ? $self-&gt;runtime_prop-&gt;{version}
    : do {
      my $version = $self-&gt;config('version');
      chomp $version;
      $version;
    };
}


sub atleast_version {
  my $self = shift;
  my ($wantver) = @_;

  defined(my $version = $self-&gt;version) or
    croak &quot;$self has no defined -&gt;version&quot;;

  return $self-&gt;version_cmp($version, $wantver) &gt;= 0;
}

sub exact_version {
  my $self = shift;
  my ($wantver) = @_;

  defined(my $version = $self-&gt;version) or
    croak &quot;$self has no defined -&gt;version&quot;;

  return $self-&gt;version_cmp($version, $wantver) == 0;
}

sub max_version {
  my $self = shift;
  my ($wantver) = @_;

  defined(my $version = $self-&gt;version) or
    croak &quot;$self has no defined -&gt;version&quot;;

  return $self-&gt;version_cmp($version, $wantver) &lt;= 0;
}


sub version_cmp {
  shift;
  goto &amp;Alien::Util::version_cmp;
}


sub install_type {
  my $self = shift;
  my $type = $self-&gt;config('install_type');
  return @_ ? $type eq $_[0] : $type;
}

sub _pkgconfig_keyword {
  my $self = shift;
  my $keyword = shift;
  my $static = shift;

  # use pkg-config if installed system-wide
  if ($self-&gt;install_type('system')) {
    my $name = $self-&gt;config('name');
    require Alien::Base::PkgConfig;
    my $command = Alien::Base::PkgConfig-&gt;pkg_config_command . &quot; @{[ $static ? '--static' : '' ]} --\L$keyword\E $name&quot;;

    $! = 0;
    chomp ( my $pcdata = capture_stdout { system( $command ) } );

    # if pkg-config fails for whatever reason, then we try to
    # fallback on alien_provides_*
    $pcdata = '' if $! || $?;

    $pcdata =~ s/\s*$//;

    if($self-&gt;config('system_provides')) {
      if(my $system_provides = $self-&gt;config('system_provides')-&gt;{$keyword}) {
        $pcdata = length $pcdata ? &quot;$pcdata $system_provides&quot; : $system_provides;
      }
    }

    return $pcdata;
  }

  # use parsed info from build .pc file
  my $dist_dir = $self-&gt;dist_dir;
  my @pc = $self-&gt;_pkgconfig(@_);
  my @strings =
    grep defined,
    map { $_-&gt;keyword($keyword,
      #{ pcfiledir =&gt; $dist_dir }
    ) }
    @pc;

  if(defined $self-&gt;config('original_prefix') &amp;&amp; $self-&gt;config('original_prefix') ne $self-&gt;dist_dir)
  {
    my $dist_dir = $self-&gt;dist_dir;
    $dist_dir =~ s{\\}{/}g if $^O eq 'MSWin32';
    my $old = quotemeta $self-&gt;config('original_prefix');
    @strings = map {
      my $flag = $_;
      $flag =~ s{^(-I|-L|-LIBPATH:)?($old)}{$1.$dist_dir}e;
      $flag =~ s/(\s)/\\$1/g;
      $flag;
    } map { $self-&gt;split_flags($_) } @strings;
  }

  return join( ' ', @strings );
}

sub _pkgconfig {
  my $self = shift;
  my %all = %{ $self-&gt;config('pkgconfig') };

  # merge in found pc files
  require File::Find;
  my $wanted = sub {
    return if ( -d or not /\.pc$/ );
    require Alien::Base::PkgConfig;
    my $pkg = Alien::Base::PkgConfig-&gt;new($_);
    $all{$pkg-&gt;{package}} = $pkg;
  };
  File::Find::find( $wanted, $self-&gt;dist_dir );

  croak &quot;No Alien::Base::PkgConfig objects are stored!&quot;
    unless keys %all;

  # Run through all pkgconfig objects and ensure that their modules are loaded:
  for my $pkg_obj (values %all) {
    my $perl_module_name = blessed $pkg_obj;
    my $pm = &quot;$perl_module_name.pm&quot;;
    $pm =~ s/::/\//g;
    eval { require $pm };
  }

  return @all{@_} if @_;

  my $manual = delete $all{_manual};

  if (keys %all) {
    return values %all;
  } else {
    return $manual;
  }
}


# helper method to call Alien::MyLib::ConfigData-&gt;config(@_)
sub config {
  my $class = shift;
  $class = blessed $class || $class;

  if(my $ab_config = $class-&gt;runtime_prop)
  {
    my $key = shift;
    return $ab_config-&gt;{legacy}-&gt;{$key};
  }

  my $config = $class . '::ConfigData';
  my $pm = &quot;$class/ConfigData.pm&quot;;
  $pm =~ s{::}{/}g;
  eval { require $pm };

  if($@)
  {
    warn &quot;Cannot find either a share directory or a ConfigData module for $class.\n&quot;;
    my $pm = &quot;$class.pm&quot;;
    $pm =~ s{::}{/}g;
    warn &quot;($class loaded from $INC{$pm})\n&quot; if $INC{$pm};
    warn &quot;Please see https://metacpan.org/pod/distribution/Alien-Build/lib/Alien/Build/Manual/FAQ.pod#Cannot-find-either-a-share-directory-or-a-ConfigData-module\n&quot;;
    die $@;
  }

  return $config-&gt;config(@_);
}

# helper method to split flags based on the OS
sub split_flags {
  my ($class, $line) = @_;
  if( $^O eq 'MSWin32' ) {
    $class-&gt;split_flags_windows($line);
  } else {
    # $os eq 'Unix'
    $class-&gt;split_flags_unix($line);
  }
}

sub split_flags_unix {
  my ($class, $line) = @_;
  shellwords($line);
}

sub split_flags_windows {
  # NOTE a better approach would be to write a function that understands cmd.exe metacharacters.
  my ($class, $line) = @_;

  # Double the backslashes so that when they are unescaped by shellwords(),
  # they become a single backslash. This should be fine on Windows since
  # backslashes are not used to escape metacharacters in cmd.exe.
  $line =~ s,\\,\\\\,g;
  shellwords($line);
}


sub dynamic_libs {
  my ($class) = @_;

  require FFI::CheckLib;

  my @find_lib_flags;

  if($class-&gt;install_type('system')) {

    if(my $prop = $class-&gt;runtime_prop)
    {
      if($prop-&gt;{ffi_checklib}-&gt;{system})
      {
        push @find_lib_flags, @{ $prop-&gt;{ffi_checklib}-&gt;{system} };
      }
      return FFI::CheckLib::find_lib( lib =&gt; $prop-&gt;{ffi_name}, @find_lib_flags )
        if defined $prop-&gt;{ffi_name};
    }

    my $name = $class-&gt;config('ffi_name');
    unless(defined $name)
    {
      $name = $class-&gt;config('name');
      $name = '' unless defined $name;
      # strip leading lib from things like libarchive or libffi
      $name =~ s/^lib//;
      # strip trailing version numbers
      $name =~ s/-[0-9\.]+$//;
    }

    my @libpath;
    if(defined $class-&gt;libs)
    {
      foreach my $flag ($class-&gt;split_flags($class-&gt;libs))
      {
        if($flag =~ /^-L(.*)$/)
        {
          push @libpath, $1;
        }
      }
    }

    return FFI::CheckLib::find_lib(lib =&gt; $name, libpath =&gt; \@libpath, @find_lib_flags );

  } else {

    my $dir = $class-&gt;dist_dir;
    my $dynamic = Path::Tiny-&gt;new($class-&gt;dist_dir, 'dynamic');

    if(my $prop = $class-&gt;runtime_prop)
    {
      if($prop-&gt;{ffi_checklib}-&gt;{share})
      {
        push @find_lib_flags, @{ $prop-&gt;{ffi_checklib}-&gt;{share_flags} };
      }
    }

    if(-d $dynamic)
    {
      return FFI::CheckLib::find_lib(
        lib        =&gt; '*',
        libpath    =&gt; &quot;$dynamic&quot;,
        systempath =&gt; [],
      );
    }

    return FFI::CheckLib::find_lib(
      lib        =&gt; '*',
      libpath    =&gt; $dir,
      systempath =&gt; [],
      recursive  =&gt; 1,
    );
  }
}


sub bin_dir {
  my ($class) = @_;
  if($class-&gt;install_type('system'))
  {
    my $prop = $class-&gt;runtime_prop;
    return () unless defined $prop;
    return () unless defined $prop-&gt;{system_bin_dir};
    return ref $prop-&gt;{system_bin_dir} ? @{ $prop-&gt;{system_bin_dir} } : ($prop-&gt;{system_bin_dir});
  }
  else
  {
    my $dir = Path::Tiny-&gt;new($class-&gt;dist_dir, 'bin');
    return -d $dir ? (&quot;$dir&quot;) : ();
  }
}


sub dynamic_dir {
  my ($class) = @_;
  if($class-&gt;install_type('system'))
  {
    return ();
  }
  else
  {
    my $dir = Path::Tiny-&gt;new($class-&gt;dist_dir, 'dynamic');
    return -d $dir ? (&quot;$dir&quot;) : ();
  }
}


sub alien_helper {
  {};
}


sub inline_auto_include {
  my ($class) = @_;
  $class-&gt;runtime_prop-&gt;{inline_auto_include} || $class-&gt;config('inline_auto_include') || []
}

sub Inline {
  my ($class, $language) = @_;
  return unless defined $language;
  return if $language !~ /^(C|CPP)$/;
  my $config = {
    # INC should arguably be for -I flags only, but
    # this improves compat with ExtUtils::Depends.
    # see gh#107, gh#108
    INC          =&gt; $class-&gt;cflags,
    LIBS         =&gt; $class-&gt;libs,
  };

  if (@{ $class-&gt;inline_auto_include } &gt; 0) {
    $config-&gt;{AUTO_INCLUDE} = join &quot;\n&quot;, map { &quot;#include \&quot;$_\&quot;&quot; } @{ $class-&gt;inline_auto_include };
  }

  $config;
}


{
  my %alien_build_config_cache;

  sub runtime_prop
  {
    my($class) = @_;

    if(ref($class))
    {
      # called as an instance method.
      my $self = $class;
      $class = ref $self;
      return $self-&gt;{_alt}-&gt;{runtime_prop} if defined $self-&gt;{_alt};
    }

    return $alien_build_config_cache{$class} if
      exists $alien_build_config_cache{$class};

    $alien_build_config_cache{$class} ||= do {
      my $dist = ref $class ? ref $class : $class;
      $dist =~ s/::/-/g;
      my $dist_dir = eval { _dist_dir $dist };
      return if $@;
      my $alien_json = Path::Tiny-&gt;new($dist_dir, '_alien', 'alien.json');
      return unless -r $alien_json;
      my $json = $alien_json-&gt;slurp;
      require JSON::PP;
      my $config = JSON::PP::decode_json($json);
      $config-&gt;{distdir} = $dist_dir;
      $config;
    };
  }
}


sub alt
{
  my($old, $name) = @_;
  my $new = ref $old ? (ref $old)-&gt;new : $old-&gt;new;

  my $orig;

  if(ref($old) &amp;&amp; defined $old-&gt;{_alt})
  { $orig = $old-&gt;{_alt}-&gt;{orig} }
  else
  { $orig = $old-&gt;runtime_prop }

  require Storable;
  my $runtime_prop = Storable::dclone($orig);

  if($runtime_prop-&gt;{alt}-&gt;{$name})
  {
    foreach my $key (keys %{ $runtime_prop-&gt;{alt}-&gt;{$name} })
    {
      $runtime_prop-&gt;{$key} = $runtime_prop-&gt;{alt}-&gt;{$name}-&gt;{$key};
    }
  }
  else
  {
    Carp::croak(&quot;no such alt: $name&quot;);
  }

  $new-&gt;{_alt} = {
    runtime_prop =&gt; $runtime_prop,
    orig         =&gt; $orig,
  };

  $new;
}


sub alt_names
{
  my($class) = @_;
  my $alts = $class-&gt;runtime_prop-&gt;{alt};
  defined $alts
    ? sort keys %$alts
    : ();
}


sub alt_exists
{
  my($class, $alt_name) = @_;
  my $alts = $class-&gt;runtime_prop-&gt;{alt};
  defined $alts
    ? exists $alts-&gt;{$alt_name} &amp;&amp; defined $alts-&gt;{$alt_name}
    : 0;
}

1;

=pod

=encoding UTF-8

=head1 NAME

Alien::Base - Base classes for Alien:: modules

=head1 VERSION

version 2.83

=head1 SYNOPSIS

 package Alien::MyLibrary;
 
 use strict;
 use warnings;
 
 use parent 'Alien::Base';
 
 1;

(for details on the C&lt;Makefile.PL&gt; or C&lt;Build.PL&gt; and L&lt;alienfile&gt;
that should be bundled with your L&lt;Alien::Base&gt; subclass, please see
L&lt;Alien::Build::Manual::AlienAuthor&gt;).

Then a C&lt;MyLibrary::XS&gt; can use C&lt;Alien::MyLibrary&gt; in its C&lt;Makefile.PL&gt;:

 use Alien::MyLibrary
 use ExtUtils::MakeMaker;
 use Alien::Base::Wrapper qw( Alien::MyLibrary !export );
 use Config;
 
 WriteMakefile(
   ...
   Alien::Base::Wrapper-&gt;mm_args,
   ...
 );

Or if you prefer L&lt;Module::Build&gt;, in its C&lt;Build.PL&gt;:

 use Alien::MyLibrary;
 use Module::Build 0.28; # need at least 0.28
 use Alien::Base::Wrapper qw( Alien::MyLibrary !export );
 
 my $builder = Module::Build-&gt;new(
   ...
   Alien::Base::Wrapper-&gt;mb_args,
   ...
 );
 
 $builder-&gt;create_build_script;

Or if you are using L&lt;ExtUtils::Depends&gt;:

 use ExtUtils::MakeMaker;
 use ExtUtils::Depends;
 my $eud = ExtUtils::Depends-&gt;new(qw( MyLibrary::XS Alien::MyLibrary ));
 WriteMakefile(
   ...
   $eud-&gt;get_makefile_vars
 );

If you are using L&lt;Alien::Base::ModuleBuild&gt; instead of the recommended L&lt;Alien::Build&gt;
and L&lt;alienfile&gt;, then in your C&lt;MyLibrary::XS&gt; module, you may need something like
this in your main C&lt;.pm&gt; file IF your library uses dynamic libraries:

 package MyLibrary::XS;
 
 use Alien::MyLibrary; # may only be needed if you are using Alien::Base::ModuleBuild
 
 ...

Or you can use it from an FFI module:

 package MyLibrary::FFI;
 
 use Alien::MyLibrary;
 use FFI::Platypus;
 use FFI::CheckLib 0.28 qw( find_lib_or_die );
 
 my $ffi = FFI::Platypus-&gt;new;
 $ffi-&gt;lib(find_lib_or_die lib =&gt; 'mylib', alien =&gt; ['Alien::MyLibrary']);
 
 $ffi-&gt;attach( 'my_library_function' =&gt; [] =&gt; 'void' );

You can even use it with L&lt;Inline&gt; (C and C++ languages are supported):

 package MyLibrary::Inline;
 
 use Alien::MyLibrary;
 # Inline 0.56 or better is required
 use Inline 0.56 with =&gt; 'Alien::MyLibrary';
 ...

=head1 DESCRIPTION

B&lt;NOTE&gt;: L&lt;Alien::Base::ModuleBuild&gt; is no longer bundled with L&lt;Alien::Base&gt; and has been spun off into a separate distribution.
L&lt;Alien::Base::ModuleBuild&gt; will be a prerequisite for L&lt;Alien::Base&gt; until October 1, 2017.  If you are using L&lt;Alien::Base::ModuleBuild&gt;
you need to make sure it is declared as a C&lt;configure_requires&gt; in your C&lt;Build.PL&gt;.  You may want to also consider using L&lt;Alien::Base&gt; and
L&lt;alienfile&gt; as a more modern alternative.

L&lt;Alien::Base&gt; comprises base classes to help in the construction of C&lt;Alien::&gt; modules. Modules in the L&lt;Alien&gt; namespace are used to locate and install (if necessary) external libraries needed by other Perl modules.

This is the documentation for the L&lt;Alien::Base&gt; module itself. If you
are starting out you probably want to do so from one of these documents:

=over 4

=item L&lt;Alien::Build::Manual::AlienUser&gt;

For users of an C&lt;Alien::libfoo&gt; that is implemented using L&lt;Alien::Base&gt;.
(The developer of C&lt;Alien::libfoo&gt; I&lt;should&gt; provide the documentation
necessary, but if not, this is the place to start).

=item L&lt;Alien::Build::Manual::AlienAuthor&gt;

If you are writing your own L&lt;Alien&gt; based on L&lt;Alien::Build&gt; and L&lt;Alien::Base&gt;.

=item L&lt;Alien::Build::Manual::FAQ&gt;

If you have a common question that has already been answered, like
&quot;How do I use L&lt;alienfile&gt; with some build system&quot;.

=item L&lt;Alien::Build::Manual::PluginAuthor&gt;

This is for the brave souls who want to write plugins that will work with
L&lt;Alien::Build&gt; + L&lt;alienfile&gt;.

=back

Before using an L&lt;Alien::Base&gt; based L&lt;Alien&gt; directly, please consider the following advice:

If you are wanting to use an L&lt;Alien::Base&gt; based L&lt;Alien&gt; with an XS module using L&lt;ExtUtils::MakeMaker&gt; or L&lt;Module::Build&gt;, it is highly
recommended that you use L&lt;Alien::Base::Wrapper&gt;, rather than using the L&lt;Alien&gt; directly, because it handles a number of sharp edges and avoids
pitfalls common when trying to use an L&lt;Alien&gt; directly with L&lt;ExtUtils::MakeMaker&gt;.

In the same vein, if you are wanting to use an L&lt;Alien::Base&gt; based L&lt;Alien&gt; with an XS module using L&lt;Dist::Zilla&gt; it is highly recommended
that you use L&lt;Dist::Zilla::Plugin::AlienBase::Wrapper&gt; for the same reasons.

As of version 0.28, L&lt;FFI::CheckLib&gt; has a good interface for working with L&lt;Alien::Base&gt; based L&lt;Alien&gt;s in fallback mode, which is
recommended.

You should typically only be using an L&lt;Alien::Base&gt; based L&lt;Alien&gt; directly, if you need to integrate it with some other system, or if it
is a tool based L&lt;Alien&gt; that you don't need to link.

The above synopsis and linked manual documents will lead you down the right path, but it is worth knowing before you read further in this
document.

=head1 METHODS

In the example snippets here, C&lt;Alien::MyLibrary&gt; represents any
subclass of L&lt;Alien::Base&gt;.

=head2 dist_dir

 my $dir = Alien::MyLibrary-&gt;dist_dir;

Returns the directory that contains the install root for
the packaged software, if it was built from install (i.e., if
C&lt;install_type&gt; is C&lt;share&gt;).

=head2 new

 my $alien = Alien::MyLibrary-&gt;new;

Creates an instance of an L&lt;Alien::Base&gt; object.  This is typically
unnecessary.

=head2 cflags

 my $cflags = Alien::MyLibrary-&gt;cflags;
 
 use Text::ParseWords qw( shellwords );
 my @cflags = shellwords( Alien::MyLibrary-&gt;cflags );

Returns the C compiler flags necessary to compile an XS
module using the alien software.  If you need this in list
form (for example if you are calling system with a list
argument) you can pass this value into C&lt;shellwords&gt; from
the Perl core L&lt;Text::ParseWords&gt; module.

=head2 cflags_static

 my $cflags = Alien::MyLibrary-&gt;cflags_static;

Same as C&lt;cflags&gt; above, but gets the static compiler flags,
if they are different.

=head2 libs

 my $libs = Alien::MyLibrary-&gt;libs;
 
 use Text::ParseWords qw( shellwords );
 my @cflags = shellwords( Alien::MyLibrary-&gt;libs );

Returns the library linker flags necessary to link an XS
module against the alien software.  If you need this in list
form (for example if you are calling system with a list
argument) you can pass this value into C&lt;shellwords&gt; from
the Perl core L&lt;Text::ParseWords&gt; module.

=head2 libs_static

 my $libs = Alien::MyLibrary-&gt;libs_static;

Same as C&lt;libs&gt; above, but gets the static linker flags,
if they are different.

=head2 version

 my $version = Alien::MyLibrary-&gt;version;

Returns the version of the alienized library or tool that was
determined at install time.

=head2 atleast_version

=head2 exact_version

=head2 max_version

 my $ok = Alien::MyLibrary-&gt;atleast_version($wanted_version);
 my $ok = Alien::MyLibrary-&gt;exact_version($wanted_version);
 my $ok = Alien::MyLibrary-&gt;max_version($wanted_version);

Returns true if the version of the alienized library or tool is at least,
exactly, or at most the version specified, respectively.

=head2 version_cmp

  $cmp = Alien::MyLibrary-&gt;version_cmp($x, $y)

Comparison method used by L&lt;/atleast_version&gt;, L&lt;/exact_version&gt; and
L&lt;/max_version&gt;. May be useful to implement custom comparisons, or for
subclasses to overload to get different version comparison semantics than the
default rules, for packages that have some other rules than the F&lt;pkg-config&gt;
behaviour.

Should return a number less than, equal to, or greater than zero; similar in
behaviour to the C&lt;&lt; &lt;=&gt; &gt;&gt; and C&lt;cmp&gt; operators.

=head2 install_type

 my $install_type = Alien::MyLibrary-&gt;install_type;
 my $bool = Alien::MyLibrary-&gt;install_type($install_type);

Returns the install type that was used when C&lt;Alien::MyLibrary&gt; was
installed.  If a type is provided (the second form in the synopsis)
returns true if the actual install type matches.  Types include:

=over 4

=item system

The library was provided by the operating system

=item share

The library was not available when C&lt;Alien::MyLibrary&gt; was installed, so
it was built from source code, either downloaded from the Internet
or bundled with C&lt;Alien::MyLibrary&gt;.

=back

=head2 config

 my $value = Alien::MyLibrary-&gt;config($key);

Returns the configuration data as determined during the install
of C&lt;Alien::MyLibrary&gt;.  For the appropriate config keys, see
L&lt;Alien::Base::ModuleBuild::API/&quot;CONFIG DATA&quot;&gt;.

This is not typically used by L&lt;Alien::Base&gt; and L&lt;alienfile&gt;,
but a compatible interface will be provided.

=head2 dynamic_libs

 my @dlls = Alien::MyLibrary-&gt;dynamic_libs;
 my($dll) = Alien::MyLibrary-&gt;dynamic_libs;

Returns a list of the dynamic library or shared object files for the
alien software.

=head2 bin_dir

 my(@dir) = Alien::MyLibrary-&gt;bin_dir

Returns a list of directories with executables in them.  For a C&lt;system&gt;
install this will be an empty list.  For a C&lt;share&gt; install this will be
a directory under C&lt;dist_dir&gt; named C&lt;bin&gt; if it exists.  You may wish
to override the default behavior if you have executables or scripts that
get installed into non-standard locations.

Example usage:

 use Env qw( @PATH );
 
 unshift @PATH, Alien::MyLibrary-&gt;bin_dir;

=head2 dynamic_dir

 my(@dir) = Alien::MyLibrary-&gt;dynamic_dir

Returns the dynamic dir for a dynamic build (if the main
build is static).  For a C&lt;share&gt; install this will be a
directory under C&lt;dist_dir&gt; named C&lt;dynamic&gt; if it exists.
System builds return an empty list.

Example usage:

 use Env qw( @PATH );
 
 unshift @PATH, Alien::MyLibrary-&gt;dynamic_dir;

=head2 alien_helper

 my $helpers = Alien::MyLibrary-&gt;alien_helper;

Returns a hash reference of helpers provided by the Alien module.
The keys are helper names and the values are code references.  The
code references will be executed at command time and the return value
will be interpolated into the command before execution.  The default
implementation returns an empty hash reference, and you are expected
to override the method to create your own helpers.

For use with commands specified in and L&lt;alienfile&gt; or in your C&lt;Build.Pl&gt;
when used with L&lt;Alien::Base::ModuleBuild&gt;.

Helpers allow users of your Alien module to use platform or environment
determined logic to compute command names or arguments in your installer
logic.  Helpers allow you to do this without making your Alien module a
requirement when a build from source code is not necessary.

As a concrete example, consider L&lt;Alien::gmake&gt;, which provides the
helper C&lt;gmake&gt;:

 package Alien::gmake;
 
 ...
 
 sub alien_helper {
   my($class) = @_;
   return {
     gmake =&gt; sub {
       # return the executable name for GNU make,
       # usually either make or gmake depending on
       # the platform and environment
       $class-&gt;exe;
     }
   },
 }

Now consider L&lt;Alien::nasm&gt;.  C&lt;nasm&gt; requires GNU Make to build from
source code, but if the system C&lt;nasm&gt; package is installed we don't
need it.  From the L&lt;alienfile&gt; of C&lt;Alien::nasm&gt;:

 use alienfile;
 
 plugin 'Probe::CommandLine' =&gt; (
   command =&gt; 'nasm',
   args    =&gt; ['-v'],
   match   =&gt; qr/NASM version/,
 );
 
 share {
   ...
   plugin 'Extract' =&gt; 'tar.gz';
   plugin 'Build::MSYS';
 
   build [
     'sh configure --prefix=%{alien.install.prefix}',
     '%{gmake}',
     '%{gmake} install',
   ];
 };
 
 ...

=head2 inline_auto_include

 my(@headers) = Alien::MyLibrary-&gt;inline_auto_include;

List of header files to automatically include in inline C and C++
code when using L&lt;Inline::C&gt; or L&lt;Inline::CPP&gt;.  This is provided
as a public interface primarily so that it can be overridden at run
time.  This can also be specified in your C&lt;Build.PL&gt; with
L&lt;Alien::Base::ModuleBuild&gt; using the C&lt;alien_inline_auto_include&gt;
property.

=head2 runtime_prop

 my $hashref = Alien::MyLibrary-&gt;runtime_prop;

Returns a hash reference of the runtime properties computed by L&lt;Alien::Build&gt; during its
install process.  If the L&lt;Alien::Base&gt; based L&lt;Alien&gt; was not built using L&lt;Alien::Build&gt;,
then this will return undef.

=head2 alt

 my $new_alien = Alien::MyLibrary-&gt;alt($alt_name);
 my $new_alien = $old_alien-&gt;alt($alt_name);

Returns an L&lt;Alien::Base&gt; instance with the alternate configuration.

Some packages come with multiple libraries, and multiple C&lt;.pc&gt; files to
use with them.  This method can be used with C&lt;pkg-config&gt; plugins to
access different configurations.  (It could also be used with non-pkg-config
based packages too, though there are not as of this writing any build
time plugins that take advantage of this feature).

From your L&lt;alienfile&gt;

 use alienfile;
 
 plugin 'PkgConfig' =&gt; (
   pkg_name =&gt; [ 'libfoo', 'libbar', ],
 );

Then in your base class works like normal:

 package Alien::MyLibrary;
 
 use parent qw( Alien::Base );
 
 1;

Then you can use it:

 use Alien::MyLibrary;
 
 my $cflags = Alien::MyLibrary-&gt;alt('foo1')-&gt;cflags;
 my $libs   = Alien::MyLibrary-&gt;alt('foo1')-&gt;libs;

=head2 alt_names

 my @alt_names = Alien::MyLibrary-&gt;alt_names

Returns the list of all available alternative configuration names.

=head2 alt_exists

 my $bool = Alien::MyLibrary-&gt;alt_exists($alt_name)

Returns true if the given alternative configuration exists.

=head1 SUPPORT AND CONTRIBUTING

First check the L&lt;Alien::Build::Manual::FAQ&gt; for questions that have already been answered.

IRC: #native on irc.perl.org

L&lt;(click for instant chatroom login)|http://chat.mibbit.com/#native@irc.perl.org&gt;

If you find a bug, please report it on the projects issue tracker on GitHub:

=over 4

=item L&lt;https://github.com/PerlAlien/Alien-Build/issues&gt;

=back

Development is discussed on the projects google groups.  This is also
a reasonable place to post a question if you don't want to open an issue
in GitHub.

=over 4

=item L&lt;https://groups.google.com/forum/#!forum/perl5-alien&gt;

=back

If you have implemented a new feature or fixed a bug, please open a pull
request.

=over 4

=item L&lt;https://github.com/PerlAlien/Alien-Build/pulls&gt;

=back

=head1 SEE ALSO

=over

=item *

L&lt;Alien::Build&gt;

=item *

L&lt;alienfile&gt;

=item *

L&lt;Alien&gt;

=item *

L&lt;Alien::Build::Manual::FAQ&gt;

=back

=head1 THANKS

C&lt;Alien::Base&gt; was originally written by Joel Berger, and that
code is still Copyright (C) 2012-2017 Joel Berger.  It has the
same license as the rest of the L&lt;Alien::Build&gt;.

Special thanks for the early development of C&lt;Alien::Base&gt; go to:

=over

=item Christian Walde (Mithaldu)

For productive conversations about component interoperability.

=item kmx

For writing Alien::Tidyp from which I drew many of my initial ideas.

=item David Mertens (run4flat)

For productive conversations about implementation.

=item Mark Nunberg (mordy, mnunberg)

For graciously teaching me about rpath and dynamic loading,

=back

=head1 AUTHOR

Author: Graham Ollis E&lt;lt&gt;plicease@cpan.orgE&lt;gt&gt;

Contributors:

Diab Jerius (DJERIUS)

Roy Storey (KIWIROY)

Ilya Pavlov

David Mertens (run4flat)

Mark Nunberg (mordy, mnunberg)

Christian Walde (Mithaldu)

Brian Wightman (MidLifeXis)

Zaki Mughal (zmughal)

mohawk (mohawk2, ETJ)

Vikas N Kumar (vikasnkumar)

Flavio Poletti (polettix)

Salvador Fandiño (salva)

Gianni Ceccarelli (dakkar)

Pavel Shaydo (zwon, trinitum)

Kang-min Liu (劉康民, gugod)

Nicholas Shipp (nshp)

Juan Julián Merelo Guervós (JJ)

Joel Berger (JBERGER)

Petr Písař (ppisar)

Lance Wicks (LANCEW)

Ahmad Fatoum (a3f, ATHREEF)

José Joaquín Atria (JJATRIA)

Duke Leto (LETO)

Shoichi Kaji (SKAJI)

Shawn Laffan (SLAFFAN)

Paul Evans (leonerd, PEVANS)

Håkon Hægland (hakonhagland, HAKONH)

nick nauwelaerts (INPHOBIA)

Florian Weimer

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2011-2022 by Graham Ollis.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut

__END__
__POD__

</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fshare%2Fperl5%2FAlien'>Back to Directory</a>