<h2>Editing File: /usr/local/lib64/perl5/Template/View.pm</h2><form method='post'><textarea name='content' class='file-edit'>#============================================================= -*-Perl-*-
#
# Template::View
#
# DESCRIPTION
#   A custom view of a template processing context.  Can be used to
#   implement custom &quot;skins&quot;.
#
# AUTHOR
#   Andy Wardley   &lt;abw@kfs.org&gt;
#
# COPYRIGHT
#   Copyright (C) 2000-2022 Andy Wardley.  All Rights Reserved.
#
#   This module is free software; you can redistribute it and/or
#   modify it under the same terms as Perl itself.
#
# TODO
#  * allowing print to have a hash ref as final args will cause problems
#    if you do this: [% view.print(hash1, hash2, hash3) %].  Current
#    work-around is to do [% view.print(hash1); view.print(hash2);
#    view.print(hash3) %] or [% view.print(hash1, hash2, hash3, { }) %]
#
#============================================================================

package Template::View;

use strict;
use warnings;
use base 'Template::Base';

our $VERSION  = '3.106';
our $DEBUG    = 0 unless defined $DEBUG;
our @BASEARGS = qw( context );
our $AUTOLOAD;
our $MAP = {
    HASH    =&gt; 'hash',
    ARRAY   =&gt; 'list',
    TEXT    =&gt; 'text',
    default =&gt; '',
};


#------------------------------------------------------------------------
# _init(\%config)
#
# Initialisation method called by the Template::Base class new()
# constructor.  $self-&gt;{ context } has already been set, by virtue of
# being named in @BASEARGS.  Remaining config arguments are presented
# as a hash reference.
#------------------------------------------------------------------------

sub _init {
    my ($self, $config) = @_;

    # move 'context' somewhere more private
    $self-&gt;{ _CONTEXT } = $self-&gt;{ context };
    delete $self-&gt;{ context };

    # generate table mapping object types to templates
    my $map = $config-&gt;{ map } || { };
    $map-&gt;{ default } //= $config-&gt;{ default };
    $self-&gt;{ map } = {
        %$MAP,
        %$map,
    };

    # local BLOCKs definition table
    $self-&gt;{ _BLOCKS } = $config-&gt;{ blocks } || { };

    # name of presentation method which printed objects might provide
    $self-&gt;{ method } = $config-&gt;{ method } // 'present';

    # view is sealed by default preventing variable update after
    # definition, however we don't actually seal a view until the
    # END of the view definition
    my $sealed = $config-&gt;{ sealed };
    $sealed //= 1;
    $self-&gt;{ sealed } = $sealed ? 1 : 0;

    # copy remaining config items from $config or set defaults
    foreach my $arg (qw( base prefix suffix notfound silent )) {
        $self-&gt;{ $arg } = $config-&gt;{ $arg } || '';
    }

    # check that any base specified is defined
    return $self-&gt;error('Invalid base specified for view')
        if exists $config-&gt;{ base } &amp;&amp; ! $self-&gt;{ base };

    # name of data item used by view()
    $self-&gt;{ item } = $config-&gt;{ item } || 'item';

    # map methods of form ${include_prefix}_foobar() to include('foobar')?
    $self-&gt;{ include_prefix } = $config-&gt;{ include_prefix } || 'include_';
    # what about mapping foobar() to include('foobar')?
    $self-&gt;{ include_naked }  = $config-&gt;{ include_naked } // 1;

    # map methods of form ${view_prefix}_foobar() to include('foobar')?
    $self-&gt;{ view_prefix } = $config-&gt;{ view_prefix } || 'view_';
    # what about mapping foobar() to view('foobar')?
    $self-&gt;{ view_naked  } = $config-&gt;{ view_naked  } || 0;

    # the view is initially unsealed, allowing directives in the initial
    # view template to create data items via the AUTOLOAD; once sealed via
    # call to seal(), the AUTOLOAD will not update any internal items.
    delete @$config{ qw(
        base method map default prefix suffix notfound item
        include_prefix include_naked silent sealed
        view_prefix view_naked blocks
    ) };
    $config = { %{ $self-&gt;{ base }-&gt;{ data } }, %$config }
        if $self-&gt;{ base };
    $self-&gt;{ data   } = $config;
    $self-&gt;{ SEALED } = 0;

    return $self;
}


#------------------------------------------------------------------------
# seal()
# unseal()
#
# Seal or unseal the view to allow/prevent new data items from being
# automatically created by the AUTOLOAD method.
#------------------------------------------------------------------------

sub seal {
    my $self = shift;
    $self-&gt;{ SEALED } = $self-&gt;{ sealed };
}

sub unseal {
    my $self = shift;
    $self-&gt;{ SEALED } = 0;
}


#------------------------------------------------------------------------
# clone(\%config)
#
# Cloning method which takes a copy of $self and then applies to it any
# modifications specified in the $config hash passed as an argument.
# Configuration items may also be specified as a list of &quot;name =&gt; $value&quot;
# arguments.  Returns a reference to the cloned Template::View object.
#
# NOTE: may need to copy BLOCKS???
#------------------------------------------------------------------------

sub clone {
    my $self   = shift;
    my $clone  = bless { %$self }, ref $self;
    my $config = ref $_[0] eq 'HASH' ? shift : { @_ };

    # merge maps
    $clone-&gt;{ map } = {
        %{ $self-&gt;{ map } },
        %{ $config-&gt;{ map } || { } },
    };

    # &quot;map =&gt; { default=&gt;'xxx' }&quot; can be specified as &quot;default =&gt; 'xxx'&quot;
    $clone-&gt;{ map }-&gt;{ default } = $config-&gt;{ default }
        if defined $config-&gt;{ default };

    # update any remaining config items
    my @args = qw(
        base prefix suffix notfound item method include_prefix
        include_naked view_prefix view_naked
    );
    foreach my $arg (@args) {
        $clone-&gt;{ $arg } = $config-&gt;{ $arg } if defined $config-&gt;{ $arg };
    }
    push(@args, qw( default map ));
    delete @$config{ @args };

    # anything left is data
    my $data = $clone-&gt;{ data } = { %{ $self-&gt;{ data } } };
    @$data{ keys %$config } = values %$config;

    return $clone;
}


#------------------------------------------------------------------------
# print(@items, ..., \%config)
#
# Prints @items in turn by mapping each to an appropriate template using
# the internal 'map' hash.  If an entry isn't found and the item is an
# object that implements the method named in the internal 'method' item,
# (default: 'present'), then the method will be called passing a reference
# to $self, against which the presenter method may make callbacks (e.g.
# to view_item()).  If the presenter method isn't implemented, then the
# 'default' map entry is consulted and used if defined.  The final argument
# may be a reference to a hash array providing local overrides to the internal
# defaults for various items (prefix, suffix, etc).  In the presence
# of this parameter, a clone of the current object is first made, applying
# any configuration updates, and control is then delegated to it.
#------------------------------------------------------------------------

sub print {
    my $self = shift;

    # if final config hash is specified then create a clone and delegate to it
    # NOTE: potential problem when called print(\%data_hash1, \%data_hash2);
    if ((scalar @_ &gt; 1) &amp;&amp; (ref $_[-1] eq 'HASH')) {
        my $cfg = pop @_;
        my $clone = $self-&gt;clone($cfg)
            || return;
        return $clone-&gt;print(@_)
            || $self-&gt;error($clone-&gt;error());
    }
    my ($item, $type, $template, $present);
    my $method = $self-&gt;{ method };
    my $map = $self-&gt;{ map };
    my $output = '';

    # print each argument
    foreach $item (@_) {
        my $newtype;

        if (! ($type = ref $item)) {
            # non-references are TEXT
            $type = 'TEXT';
            $template = $map-&gt;{ $type };
        }
        elsif (! defined ($template = $map-&gt;{ $type })) {
            # no specific map entry for object, maybe it implements a
            # 'present' (or other) method?
            if ( $method &amp;&amp; UNIVERSAL::can($item, $method) ) {
                $present = $item-&gt;$method($self);       ## call item method
                # undef returned indicates error, note that we expect
                # $item to have called error() on the view
                return unless defined $present;
                $output .= $present;
                next;                                   ## NEXT
            }
            elsif ( ref($item) eq 'HASH'
                    &amp;&amp; defined($newtype = $item-&gt;{$method})
                    &amp;&amp; defined($template = $map-&gt;{&quot;$method=&gt;$newtype&quot;})) {
            }
            elsif ( defined($newtype)
                    &amp;&amp; defined($template = $map-&gt;{&quot;$method=&gt;*&quot;}) ) {
                $template =~ s/\*/$newtype/;
            }
            elsif (! ($template = $map-&gt;{ default }) ) {
                # default not defined, so construct template name from type
                ($template = $type) =~ s/\W+/_/g;
            }
        }
#       else {
#           $self-&gt;DEBUG(&quot;defined map type for $type: $template\n&quot;);
#       }
        $self-&gt;DEBUG(&quot;printing view '&quot;, $template || '', &quot;', $item\n&quot;) if $DEBUG;
        $output .= $self-&gt;view($template, $item)
            if $template;
    }
    return $output;
}


#------------------------------------------------------------------------
# view($template, $item, \%vars)
#
# Wrapper around include() which expects a template name, $template,
# followed by a data item, $item, and optionally, a further hash array
# of template variables.  The $item is added as an entry to the $vars
# hash (which is created empty if not passed as an argument) under the
# name specified by the internal 'item' member, which is appropriately
# 'item' by default.  Thus an external object present() method can
# callback against this object method, simply passing a data item to
# be displayed.  The external object doesn't have to know what the
# view expects the item to be called in the $vars hash.
#------------------------------------------------------------------------

sub view {
    my ($self, $template, $item) = splice(@_, 0, 3);
    my $vars = ref $_[0] eq 'HASH' ? shift : { @_ };
    $vars-&gt;{ $self-&gt;{ item } } = $item if defined $item;
    $self-&gt;include($template, $vars);
}


#------------------------------------------------------------------------
# include($template, \%vars)
#
# INCLUDE a template, $template, mapped according to the current prefix,
# suffix, default, etc., where $vars is an optional hash reference
# containing template variable definitions.  If the template isn't found
# then the method will default to any 'notfound' template, if defined
# as an internal item.
#------------------------------------------------------------------------

sub include {
    my ($self, $template, $vars) = @_;
    my $context = $self-&gt;{ _CONTEXT };

    $template = $self-&gt;template($template);

    $vars = { } unless ref $vars eq 'HASH';
    $vars-&gt;{ view } ||= $self;

    $context-&gt;include( $template, $vars );

# DEBUGGING
#    my $out = $context-&gt;include( $template, $vars );
#    print STDERR &quot;VIEW return [$out]\n&quot;;
#    return $out;
}


#------------------------------------------------------------------------
# template($template)
#
# Returns a compiled template for the specified template name, according
# to the current configuration parameters.
#------------------------------------------------------------------------

sub template {
    my ($self, $name) = @_;
    my $context = $self-&gt;{ _CONTEXT };
    return $context-&gt;throw(
        Template::Constants::ERROR_VIEW,
        &quot;no view template specified&quot;
    ) unless $name;

    my $notfound = $self-&gt;{ notfound };
    my $base = $self-&gt;{ base };
    my ($template, $block, $error);

    return $block
        if ($block = $self-&gt;{ _BLOCKS }-&gt;{ $name });

    # try the named template
    $template = $self-&gt;template_name($name);
    $self-&gt;DEBUG(&quot;looking for $template\n&quot;) if $DEBUG;
    eval { $template = $context-&gt;template($template) };

    # try asking the base view if not found
    if (($error = $@) &amp;&amp; $base) {
        $self-&gt;DEBUG(&quot;asking base for $name\n&quot;) if $DEBUG;
        eval { $template = $base-&gt;template($name) };
    }

    # try the 'notfound' template (if defined) if that failed
    if (($error = $@) &amp;&amp; $notfound) {
        unless ($template = $self-&gt;{ _BLOCKS }-&gt;{ $notfound }) {
            $notfound = $self-&gt;template_name($notfound);
            $self-&gt;DEBUG(&quot;not found, looking for $notfound\n&quot;) if $DEBUG;
            eval { $template = $context-&gt;template($notfound) };

            return $context-&gt;throw(Template::Constants::ERROR_VIEW, $error)
                if $@;  # return first error
        }
    }
    elsif ($error) {
        $self-&gt;DEBUG(&quot;no 'notfound'\n&quot;)
            if $DEBUG;
        return $context-&gt;throw(Template::Constants::ERROR_VIEW, $error);
    }
    return $template;
}


#------------------------------------------------------------------------
# template_name($template)
#
# Returns the name of the specified template with any appropriate prefix
# and/or suffix added.
#------------------------------------------------------------------------

sub template_name {
    my ($self, $template) = @_;
    $template = $self-&gt;{ prefix } . $template . $self-&gt;{ suffix }
        if $template;

    $self-&gt;DEBUG(&quot;template name: $template\n&quot;) if $DEBUG;
    return $template;
}


#------------------------------------------------------------------------
# default($val)
#
# Special case accessor to retrieve/update 'default' as an alias for
# '$map-&gt;{ default }'.
#------------------------------------------------------------------------

sub default {
    my $self = shift;
    return @_
        ? ($self-&gt;{ map }-&gt;{ default } = shift)
        :  $self-&gt;{ map }-&gt;{ default };
}


#------------------------------------------------------------------------
# AUTOLOAD
#
# Returns/updates public internal data items (i.e. not prefixed '_' or
# '.') or presents a view if the method matches the view_prefix item,
# e.g. view_foo(...) =&gt; view('foo', ...).  Similarly, the
# include_prefix is used, if defined, to map include_foo(...) to
# include('foo', ...).  If that fails then the entire method name will
# be used as the name of a template to include iff the include_named
# parameter is set (default: 1).  Last attempt is to match the entire
# method name to a view() call, iff view_naked is set.  Otherwise, a
# 'view' exception is raised reporting the error &quot;no such view member:
# $method&quot;.
#------------------------------------------------------------------------

sub AUTOLOAD {
    my $self = shift;
    my $item = $AUTOLOAD;
    $item =~ s/.*:://;
    return if $item eq 'DESTROY';

    my $starts_with = substr($item,0,1);
    if ($starts_with eq '.' || $starts_with eq '_') {
        return $self-&gt;{ _CONTEXT }-&gt;throw(Template::Constants::ERROR_VIEW,
                            &quot;attempt to view private member: $item&quot;);
    }
    elsif (exists $self-&gt;{ $item }) {
        # update existing config item (e.g. 'prefix') if unsealed
        return $self-&gt;{ _CONTEXT }-&gt;throw(Template::Constants::ERROR_VIEW,
                            &quot;cannot update config item in sealed view: $item&quot;)
            if @_ &amp;&amp; $self-&gt;{ SEALED };
        $self-&gt;DEBUG(&quot;accessing item: $item\n&quot;) if $DEBUG;
        return @_ ? ($self-&gt;{ $item } = shift) : $self-&gt;{ $item };
    }
    elsif (exists $self-&gt;{ data }-&gt;{ $item }) {
        # get/update existing data item (must be unsealed to update)
        if (@_ &amp;&amp; $self-&gt;{ SEALED }) {
            return $self-&gt;{ _CONTEXT }-&gt;throw(
                Template::Constants::ERROR_VIEW,
                &quot;cannot update item in sealed view: $item&quot;
            ) unless $self-&gt;{ silent };
            # ignore args if silent
            @_ = ();
        }
        $self-&gt;DEBUG(@_
            ? &quot;updating data item: $item &lt;= $_[0]\n&quot;
            : &quot;returning data item: $item\n&quot;
        ) if $DEBUG;
        return @_
            ? ($self-&gt;{ data }-&gt;{ $item } = shift)
            :  $self-&gt;{ data }-&gt;{ $item };
    }
    elsif (@_ &amp;&amp; ! $self-&gt;{ SEALED }) {
        # set data item if unsealed
        $self-&gt;DEBUG(&quot;setting unsealed data: $item =&gt; @_\n&quot;) if $DEBUG;
        $self-&gt;{ data }-&gt;{ $item } = shift;
    }
    elsif ($item =~ s/^$self-&gt;{ view_prefix }//) {
        $self-&gt;DEBUG(&quot;returning view($item)\n&quot;) if $DEBUG;
        return $self-&gt;view($item, @_);
    }
    elsif ($item =~ s/^$self-&gt;{ include_prefix }//) {
        $self-&gt;DEBUG(&quot;returning include($item)\n&quot;) if $DEBUG;
        return $self-&gt;include($item, @_);
    }
    elsif ($self-&gt;{ include_naked }) {
        $self-&gt;DEBUG(&quot;returning naked include($item)\n&quot;) if $DEBUG;
        return $self-&gt;include($item, @_);
    }
    elsif ($self-&gt;{ view_naked }) {
        $self-&gt;DEBUG(&quot;returning naked view($item)\n&quot;) if $DEBUG;
        return $self-&gt;view($item, @_);
    }
    else {
        return $self-&gt;{ _CONTEXT }-&gt;throw(
            Template::Constants::ERROR_VIEW,
            &quot;no such view member: $item&quot;
        );
    }
}


1;


__END__

=head1 NAME

Template::View - customised view of a template processing context

=head1 SYNOPSIS

    # define a view
    [% VIEW view
            # some standard args
            prefix        =&gt; 'my_',
            suffix        =&gt; '.tt2',
            notfound      =&gt; 'no_such_file'
            ...

            # any other data
            title         =&gt; 'My View title'
            other_item    =&gt; 'Joe Random Data'
            ...
    %]
       # add new data definitions, via 'my' self reference
       [% my.author = &quot;$abw.name &lt;$abw.email&gt;&quot; %]
       [% my.copy   = &quot;&amp;copy; Copyright 2000 $my.author&quot; %]

       # define a local block
       [% BLOCK header %]
       This is the header block, title: [% title or my.title %]
       [% END %]

    [% END %]

    # access data items for view
    [% view.title %]
    [% view.other_item %]

    # access blocks directly ('include_naked' option, set by default)
    [% view.header %]
    [% view.header(title =&gt; 'New Title') %]

    # non-local templates have prefix/suffix attached
    [% view.footer %]           # =&gt; [% INCLUDE my_footer.tt2 %]

    # more verbose form of block access
    [% view.include( 'header', title =&gt; 'The Header Title' ) %]
    [% view.include_header( title =&gt; 'The Header Title' ) %]

    # very short form of above ('include_naked' option, set by default)
    [% view.header( title =&gt; 'The Header Title' ) %]

    # non-local templates have prefix/suffix attached
    [% view.footer %]           # =&gt; [% INCLUDE my_footer.tt2 %]

    # fallback on the 'notfound' template ('my_no_such_file.tt2')
    # if template not found
    [% view.include('missing') %]
    [% view.include_missing %]
    [% view.missing %]

    # print() includes a template relevant to argument type
    [% view.print(&quot;some text&quot;) %]     # type=TEXT, template='text'

    [% BLOCK my_text.tt2 %]           # 'text' with prefix/suffix
       Text: [% item %]
    [% END %]

    # now print() a hash ref, mapped to 'hash' template
    [% view.print(some_hash_ref) %]   # type=HASH, template='hash'

    [% BLOCK my_hash.tt2 %]           # 'hash' with prefix/suffix
       hash keys: [% item.keys.sort.join(', ')
    [% END %]

    # now print() a list ref, mapped to 'list' template
    [% view.print(my_list_ref) %]     # type=ARRAY, template='list'

    [% BLOCK my_list.tt2 %]           # 'list' with prefix/suffix
       list: [% item.join(', ') %]
    [% END %]

    # print() maps 'My::Object' to 'My_Object'
    [% view.print(myobj) %]

    [% BLOCK my_My_Object.tt2 %]
       [% item.this %], [% item.that %]
    [% END %]

    # update mapping table
    [% view.map.ARRAY = 'my_list_template' %]
    [% view.map.TEXT  = 'my_text_block'    %]


    # change prefix, suffix, item name, etc.
    [% view.prefix = 'your_' %]
    [% view.default = 'anyobj' %]
    ...

=head1 DESCRIPTION

TODO

=head1 METHODS

=head2 new($context, \%config)

Creates a new Template::View presenting a custom view of the specified
$context object.

A reference to a hash array of configuration options may be passed as the
second argument.

=over 4

=item prefix

Prefix added to all template names.

    [% USE view(prefix =&gt; 'my_') %]
    [% view.view('foo', a =&gt; 20) %]     # =&gt; my_foo

=item suffix

Suffix added to all template names.

    [% USE view(suffix =&gt; '.tt2') %]
    [% view.view('foo', a =&gt; 20) %]     # =&gt; foo.tt2

=item map

Hash array mapping reference types to template names.  The print()
method uses this to determine which template to use to present any
particular item.  The TEXT, HASH and ARRAY items default to 'test',
'hash' and 'list' appropriately.

    [% USE view(map =&gt; { ARRAY   =&gt; 'my_list',
                         HASH    =&gt; 'your_hash',
                         My::Foo =&gt; 'my_foo', } ) %]

    [% view.print(some_text) %]         # =&gt; text
    [% view.print(a_list) %]            # =&gt; my_list
    [% view.print(a_hash) %]            # =&gt; your_hash
    [% view.print(a_foo) %]             # =&gt; my_foo

    [% BLOCK text %]
       Text: [% item %]
    [% END %]

    [% BLOCK my_list %]
       list: [% item.join(', ') %]
    [% END %]

    [% BLOCK your_hash %]
       hash keys: [% item.keys.sort.join(', ')
    [% END %]

    [% BLOCK my_foo %]
       Foo: [% item.this %], [% item.that %]
    [% END %]

=item method

Name of a method which objects passed to print() may provide for presenting
themselves to the view.  If a specific map entry can't be found for an
object reference and it supports the method (default: 'present') then
the method will be called, passing the view as an argument.  The object
can then make callbacks against the view to present itself.

    package Foo;

    sub present {
        my ($self, $view) = @_;
        return &quot;a regular view of a Foo\n&quot;;
    }

    sub debug {
        my ($self, $view) = @_;
        return &quot;a debug view of a Foo\n&quot;;
    }

In a template:

    [% USE view %]
    [% view.print(my_foo_object) %]     # a regular view of a Foo

    [% USE view(method =&gt; 'debug') %]
    [% view.print(my_foo_object) %]     # a debug view of a Foo

=item default

Default template to use if no specific map entry is found for an item.

    [% USE view(default =&gt; 'my_object') %]

    [% view.print(objref) %]            # =&gt; my_object

If no map entry or default is provided then the view will attempt to
construct a template name from the object class, substituting any
sequence of non-word characters to single underscores, e.g.

    # 'fubar' is an object of class Foo::Bar
    [% view.print(fubar) %]             # =&gt; Foo_Bar

Any current prefix and suffix will be added to both the default template
name and any name constructed from the object class.

=item notfound

Fallback template to use if any other isn't found.

=item item

Name of the template variable to which the print() method assigns the current
item.  Defaults to 'item'.

    [% USE view %]
    [% BLOCK list %]
       [% item.join(', ') %]
    [% END %]
    [% view.print(a_list) %]

    [% USE view(item =&gt; 'thing') %]
    [% BLOCK list %]
       [% thing.join(', ') %]
    [% END %]
    [% view.print(a_list) %]

=item view_prefix

Prefix of methods which should be mapped to view() by AUTOLOAD.  Defaults
to 'view_'.

    [% USE view %]
    [% view.view_header() %]                    # =&gt; view('header')

    [% USE view(view_prefix =&gt; 'show_me_the_' %]
    [% view.show_me_the_header() %]             # =&gt; view('header')

=item view_naked

Flag to indicate if any attempt should be made to map method names to
template names where they don't match the view_prefix.  Defaults to 0.

    [% USE view(view_naked =&gt; 1) %]

    [% view.header() %]                 # =&gt; view('header')

=back

=head2 print( $obj1, $obj2, ... \%config)

TODO

=head2 view( $template, \%vars, \%config );

TODO

=head1 AUTHOR

Andy Wardley E&lt;lt&gt;abw@wardley.orgE&lt;gt&gt; L&lt;http://wardley.org/&gt;

=head1 COPYRIGHT

Copyright (C) 2000-2022 Andy Wardley.  All Rights Reserved.

This module is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.

=head1 SEE ALSO

L&lt;Template::Plugin&gt;

=cut


</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Flib64%2Fperl5%2FTemplate'>Back to Directory</a>