<h2>Editing File: /usr/local/lib64/perl5/Template/Plugin/Image.pm</h2><form method='post'><textarea name='content' class='file-edit'>#============================================================= -*-Perl-*-
#
# Template::Plugin::Image
#
# DESCRIPTION
#  Plugin for encapsulating information about an image.
#
# AUTHOR
#   Andy Wardley &lt;abw@wardley.org&gt;
#
# COPYRIGHT
#   This module is free software; you can redistribute it and/or
#   modify it under the same terms as Perl itself.
#
#============================================================================

package Template::Plugin::Image;

use strict;
use warnings;
use base 'Template::Plugin';
use Template::Exception;
use File::Spec;

our $VERSION = '3.106';
our $AUTOLOAD;

BEGIN {
    if (eval { require Image::Info; }) {
        *img_info = \&amp;Image::Info::image_info;
    }
    elsif (eval { require Image::Size; }) {
        *img_info = sub {
            my $file = shift;
            my @stuff = Image::Size::imgsize($file);
            return {
                &quot;width&quot;  =&gt; $stuff[0],
                &quot;height&quot; =&gt; $stuff[1],
                &quot;error&quot;  =&gt;
                    # imgsize returns either a three letter file type
                    # or an error message as third value
                    (defined($stuff[2]) &amp;&amp; length($stuff[2]) &gt; 3
                        ? $stuff[2]
                        : undef),
            };
        }
    }
    else {
        die(Template::Exception-&gt;new(&quot;image&quot;,
            &quot;Couldn't load Image::Info or Image::Size: $@&quot;));
    }

}

#------------------------------------------------------------------------
# new($context, $name, \%config)
#
# Create a new Image object.  Takes the pathname of the file as
# the argument following the context and an optional
# hash reference of configuration parameters.
#------------------------------------------------------------------------

sub new {
    my $config = ref($_[-1]) eq 'HASH' ? pop(@_) : { };
    my ($class, $context, $name) = @_;
    my ($root, $file, $type);

    # name can be a positional or named argument
    $name //= $config-&gt;{ name };

    return $class-&gt;throw('no image file specified')
        unless defined $name and length $name;

    # name can be specified as an absolute path or relative
    # to a root directory

    if ($root = $config-&gt;{ root }) {
        $file = File::Spec-&gt;catfile($root, $name);
    }
    else {
        $file = $config-&gt;{file} // $name;
    }

    # Make a note of whether we are using Image::Size or
    # Image::Info -- at least for the test suite
    $type = $INC{&quot;Image/Size.pm&quot;} ? &quot;Image::Size&quot; : &quot;Image::Info&quot;;

    # set a default (empty) alt attribute for tag()
    $config-&gt;{ alt } //= '';

    # do we want to check to see if file exists?
    bless {
        %$config,
        name =&gt; $name,
        file =&gt; $file,
        root =&gt; $root,
        type =&gt; $type,
    }, $class;
}

#------------------------------------------------------------------------
# init()
#
# Calls image_info on $self-&gt;{ file }
#------------------------------------------------------------------------

sub init {
    my $self = shift;
    return $self if $self-&gt;{ size };

    my $image = img_info($self-&gt;{ file });
    return $self-&gt;throw($image-&gt;{ error }) if defined $image-&gt;{ error };

    @$self{ keys %$image } = values %$image;
    $self-&gt;{ size } = [ $image-&gt;{ width }, $image-&gt;{ height } ];

    $self-&gt;{ modtime } = (stat $self-&gt;{ file })[9];

    return $self;
}

#------------------------------------------------------------------------
# attr()
#
# Return the width and height as HTML/XML attributes.
#------------------------------------------------------------------------

sub attr {
    my $self = shift;
    my $size = $self-&gt;size();
    return &quot;width=\&quot;$size-&gt;[0]\&quot; height=\&quot;$size-&gt;[1]\&quot;&quot;;
}


#------------------------------------------------------------------------
# modtime()
#
# Return last modification time as a time_t:
#
#   [% date.format(image.modtime, &quot;%Y/%m/%d&quot;) %]
#------------------------------------------------------------------------

sub modtime {
    my $self = shift;
    $self-&gt;init;
    return $self-&gt;{ modtime };
}


#------------------------------------------------------------------------
# tag(\%options)
#
# Return an XHTML img tag.
#------------------------------------------------------------------------

sub tag {
    my $self = shift;
    my $options = ref $_[0] eq 'HASH' ? shift : { @_ };

    my $tag = '&lt;img src=&quot;' . $self-&gt;name() . '&quot; ' . $self-&gt;attr();

    # XHTML spec says that the alt attribute is mandatory, so who
    # are we to argue?

    $options-&gt;{ alt } //= $self-&gt;{ alt };

    if (%$options) {
        for my $key (sort keys %$options) {
            my $escaped = escape( $options-&gt;{$key} );
            $tag .= qq[ $key=&quot;$escaped&quot;];
        }
    }

    $tag .= ' /&gt;';

    return $tag;
}

sub escape {
    my ($text) = @_;
    for ($text) {
        s/&amp;/&amp;amp;/g;
        s/&lt;/&amp;lt;/g;
        s/&gt;/&amp;gt;/g;
        s/&quot;/&amp;quot;/g;
    }
    $text;
}

sub throw {
    my ($self, $error) = @_;
    die (Template::Exception-&gt;new('Image', $error));
}

sub AUTOLOAD {
    my $self = shift;
   (my $a = $AUTOLOAD) =~ s/.*:://;

    $self-&gt;init;
    return $self-&gt;{ $a };
}

1;

__END__

=head1 NAME

Template::Plugin::Image - Plugin access to image sizes

=head1 SYNOPSIS

    [% USE Image(filename) %]
    [% Image.width %]
    [% Image.height %]
    [% Image.size.join(', ') %]
    [% Image.attr %]
    [% Image.tag %]

=head1 DESCRIPTION

This plugin provides an interface to the L&lt;Image::Info&gt; or L&lt;Image::Size&gt;
modules for determining the size of image files.

You can specify the plugin name as either 'C&lt;Image&gt;' or 'C&lt;image&gt;'.  The
plugin object created will then have the same name.  The file name of
the image should be specified as a positional or named argument.

    [% # all these are valid, take your pick %]
    [% USE Image('foo.gif') %]
    [% USE image('bar.gif') %]
    [% USE Image 'ping.gif' %]
    [% USE image(name='baz.gif') %]
    [% USE Image name='pong.gif' %]

A C&lt;root&gt; parameter can be used to specify the location of the image file:

    [% USE Image(root='/path/to/root', name='images/home.png') %]
    # image path: /path/to/root/images/home.png
    # img src: images/home.png

In cases where the image path and image url do not match up, specify the
file name directly:

    [% USE Image(file='/path/to/home.png', name='/images/home.png') %]

The C&lt;alt&gt; parameter can be used to specify an alternate name for the
image, for use in constructing an XHTML element (see the C&lt;tag()&gt; method
below).

    [% USE Image('home.png', alt=&quot;Home&quot;) %]

You can also provide an alternate name for an C&lt;Image&gt; plugin object.

    [% USE img1 = image 'foo.gif' %]
    [% USE img2 = image 'bar.gif' %]

The C&lt;name&gt; method returns the image file name.

    [% img1.name %]     # foo.gif

The C&lt;width&gt; and C&lt;height&gt; methods return the width and height of the
image, respectively.  The C&lt;size&gt; method returns a reference to a 2
element list containing the width and height.

    [% USE image 'foo.gif' %]
    width: [% image.width %]
    height: [% image.height %]
    size: [% image.size.join(', ') %]

The C&lt;modtime&gt; method returns the modification time of the file in question,
suitable for use with the L&lt;Date|Template::Plugin::Date&gt; plugin, for example:

    [% USE image 'foo.gif' %]
    [% USE date %]
    [% date.format(image.modtime, &quot;%B, %e %Y&quot;) %]

The C&lt;attr&gt; method returns the height and width as HTML/XML attributes.

    [% USE image 'foo.gif' %]
    [% image.attr %]

Typical output:

    width=&quot;60&quot; height=&quot;20&quot;

The C&lt;tag&gt; method returns a complete XHTML tag referencing the image.

    [% USE image 'foo.gif' %]
    [% image.tag %]

Typical output:

    &lt;img src=&quot;foo.gif&quot; width=&quot;60&quot; height=&quot;20&quot; alt=&quot;&quot; /&gt;

You can provide any additional attributes that should be added to the
XHTML tag.

    [% USE image 'foo.gif' %]
    [% image.tag(class=&quot;logo&quot; alt=&quot;Logo&quot;) %]

Typical output:

    &lt;img src=&quot;foo.gif&quot; width=&quot;60&quot; height=&quot;20&quot; alt=&quot;Logo&quot; class=&quot;logo&quot; /&gt;

Note that the C&lt;alt&gt; attribute is mandatory in a strict XHTML C&lt;img&gt;
element (even if it's empty) so it is always added even if you don't
explicitly provide a value for it.  You can do so as an argument to
the C&lt;tag&gt; method, as shown in the previous example, or as an argument

    [% USE image('foo.gif', alt='Logo') %]

=head1 CATCHING ERRORS

If the image file cannot be found then the above methods will throw an
C&lt;Image&gt; error.  You can enclose calls to these methods in a
C&lt;TRY...CATCH&gt; block to catch any potential errors.

    [% TRY;
         image.width;
       CATCH;
         error;      # print error
       END
    %]

=head1 USING Image::Info

At run time, the plugin tries to load L&lt;Image::Info&gt; in preference to
L&lt;Image::Size&gt;. If L&lt;Image::Info&gt; is found, then some additional methods are
available, in addition to C&lt;size&gt;, C&lt;width&gt;, C&lt;height&gt;, C&lt;attr&gt;, and C&lt;tag&gt;.
These additional methods are named after the elements that L&lt;Image::Info&gt;
retrieves from the image itself. The types of methods available depend on the
type of image (see L&lt;Image::Info&gt; for more details). These additional methods
will always include the following:

=head2 file_media_type

This is the MIME type that is appropriate for the given file format.
The corresponding value is a string like: &quot;C&lt;image/png&gt;&quot; or &quot;C&lt;image/jpeg&gt;&quot;.

=head2 file_ext

The is the suggested file name extension for a file of the given
file format.  The value is a 3 letter, lowercase string like
&quot;C&lt;png&gt;&quot;, &quot;C&lt;jpg&gt;&quot;.

=head2 color_type

The value is a short string describing what kind of values the pixels
encode.  The value can be one of the following:

    Gray
    GrayA
    RGB
    RGBA
    CMYK
    YCbCr
    CIELab

These names can also be prefixed by &quot;C&lt;Indexed-&gt;&quot; if the image is
composed of indexes into a palette.  Of these, only &quot;C&lt;Indexed-RGB&gt;&quot; is
likely to occur.

(It is similar to the TIFF field PhotometricInterpretation, but this
name was found to be too long, so we used the PNG inspired term
instead.)

=head2 resolution

The value of this field normally gives the physical size of the image
on screen or paper. When the unit specifier is missing then this field
denotes the squareness of pixels in the image.

The syntax of this field is:

   &lt;res&gt; &lt;unit&gt;
   &lt;xres&gt; &quot;/&quot; &lt;yres&gt; &lt;unit&gt;
   &lt;xres&gt; &quot;/&quot; &lt;yres&gt;

The C&lt;E&lt;lt&gt;resE&lt;gt&gt;&gt;, C&lt;E&lt;lt&gt;xresE&lt;gt&gt;&gt; and C&lt;E&lt;lt&gt;yresE&lt;gt&gt;&gt; fields are
numbers.  The C&lt;E&lt;lt&gt;unitE&lt;gt&gt;&gt; is a string like C&lt;dpi&gt;, C&lt;dpm&gt; or
C&lt;dpcm&gt; (denoting &quot;dots per inch/cm/meter).

=head2 SamplesPerPixel

This says how many channels there are in the image.  For some image
formats this number might be higher than the number implied from the
C&lt;color_type&gt;.

=head2 BitsPerSample

This says how many bits are used to encode each of samples.  The value
is a reference to an array containing numbers. The number of elements
in the array should be the same as C&lt;SamplesPerPixel&gt;.

=head2 Comment

Textual comments found in the file.  The value is a reference to an
array if there are multiple comments found.

=head2 Interlace

If the image is interlaced, then this returns the interlace type.

=head2 Compression

This returns the name of the compression algorithm is used.

=head2 Gamma

A number indicating the gamma curve of the image (e.g. 2.2)

=head1 AUTHOR

Andy Wardley E&lt;lt&gt;abw@wardley.orgE&lt;gt&gt; L&lt;http://wardley.org/&gt;

=head1 COPYRIGHT

Copyright (C) 1996-2022 Andy Wardley.  All Rights Reserved.

This module is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.

=head1 SEE ALSO

L&lt;Template::Plugin&gt;, L&lt;Image::Info&gt;

=cut

# Local Variables:
# mode: perl
# perl-indent-level: 4
# indent-tabs-mode: nil
# End:
#
# vim: expandtab shiftwidth=4:
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Flib64%2Fperl5%2FTemplate%2FPlugin'>Back to Directory</a>