<h2>Editing File: /usr/local/lib64/perl5/Template/Plugin/HTML.pm</h2><form method='post'><textarea name='content' class='file-edit'>#============================================================= -*-Perl-*-
#
# Template::Plugin::HTML
#
# DESCRIPTION
#   Template Toolkit plugin providing useful functionality for generating
#   HTML.
#
# AUTHOR
#   Andy Wardley   &lt;abw@wardley.org&gt;
#
# COPYRIGHT
#   Copyright (C) 1996-2022 Andy Wardley.  All Rights Reserved.
#
#   This module is free software; you can redistribute it and/or
#   modify it under the same terms as Perl itself.
#
#============================================================================

package Template::Plugin::HTML;

use strict;
use warnings;
use base 'Template::Plugin';

our $VERSION = '3.106';

sub new {
    my ($class, $context, @args) = @_;
    my $hash = ref $args[-1] eq 'HASH' ? pop @args : { };
    bless {
        _SORTED    =&gt; $hash-&gt;{ sorted     } || 0,
        attributes =&gt; $hash-&gt;{ attributes } || $hash-&gt;{ attrs } || { },
    }, $class;
}

sub element {
    my ($self, $name, $attr) = @_;
    ($name, $attr) = %$name if ref $name eq 'HASH';
    return '' unless defined $name and length $name;
    $attr = $self-&gt;attributes($attr);
    $attr = &quot; $attr&quot; if $attr;
    return &quot;&lt;$name$attr&gt;&quot;;
}

sub closed_element {
    my ($self, $name, $attr) = @_;
    ($name, $attr) = %$name if ref $name eq 'HASH';
    return '' unless defined $name and length $name;
    $attr = $self-&gt;attributes( $attr );
    $attr = &quot; $attr&quot; if $attr;
    return &quot;&lt;$name$attr /&gt;&quot;;
}

sub attributes {
    my ($self, $hash) = @_;
    $hash ||= $self-&gt;{ attributes };
    return '' unless ref $hash eq 'HASH';

    my @keys = keys %$hash;
    @keys = sort @keys if $self-&gt;{ _SORTED };

    join(' ', map {
        &quot;$_=\&quot;&quot; . $self-&gt;escape( $hash-&gt;{ $_ } ) . '&quot;';
    } @keys);
}

sub add_attributes {
    my ($self, $attr) = @_;
    return unless ref $attr eq 'HASH';

    my $cur = $self-&gt;{ attributes };

    for (keys %{$attr}) {
        $cur-&gt;{$_} = exists $cur-&gt;{$_}
            ? $cur-&gt;{$_} . &quot; $attr-&gt;{$_}&quot;
            : $attr-&gt;{$_};

    }

    return;
}

*add_attribute = \&amp;add_attributes;
*add           = \&amp;add_attributes;


sub replace_attributes {
    my ($self, $attr) = @_;
    return unless ref $attr eq 'HASH';

    my $cur = $self-&gt;{ attributes };

    for (keys %{$attr}) {
        $cur-&gt;{$_} = $attr-&gt;{$_};
    }

    return;
}

*replace_attribute = \&amp;replace_attributes;
*replace           = \&amp;replace_attributes;

sub clear_attributes {
    my $self = shift;
    $self-&gt;{ attributes } = { };
    return;
}


sub escape {
    my ($self, $text) = @_;
    for ($text) {
        s/&amp;/&amp;amp;/g;
        s/&lt;/&amp;lt;/g;
        s/&gt;/&amp;gt;/g;
        s/&quot;/&amp;quot;/g;
        s/'/&amp;#39;/g;
    }
    $text;
}

sub url {
    my ($self, $text) = @_;
    return undef unless defined $text;
    $text =~ s/([^a-zA-Z0-9_.-])/uc sprintf(&quot;%%%02x&quot;,ord($1))/eg;
    return $text;
}


1;

__END__

=head1 NAME

Template::Plugin::HTML - Plugin to create HTML elements

=head1 SYNOPSIS

    [% USE HTML %]

    [% HTML.escape(&quot;if (a &lt; b &amp;&amp; c &gt; d) ...&quot; %]

    [% HTML.element(table =&gt; { border =&gt; 1, cellpadding =&gt; 2 }) %]

    [% HTML.attributes(border =&gt; 1, cellpadding =&gt; 2) %]

=head1 DESCRIPTION

The C&lt;HTML&gt; plugin is a very basic plugin, implementing a few useful
methods for generating HTML.

=head1 METHODS

=head2 escape(text)

Returns the source text with any HTML reserved characters such as
C&lt;E&lt;lt&gt;&gt;, C&lt;E&lt;gt&gt;&gt;, etc., correctly escaped to their entity equivalents.

=head2 attributes(hash)

Returns the elements of the hash array passed by reference correctly
formatted (e.g. values quoted and correctly escaped) as attributes for
an HTML element.

=head2 add_attribute(attributes)

This provides a way to incrementally add attributes to the object.
The values passed in are stored in the object.  Calling
L&lt;element&gt; with just a tag or L&lt;attributes&gt; without an parameters
will used the saved attributes.

    USE tag = HTML;
    tag.add_attributes( { class =&gt; 'navbar' } );
    tag.add_attributes( { id =&gt; 'foo' } );
    tag.add_attributes( { class =&gt; 'active' } );

    tag.element( 'li' ); # &lt;li class=&quot;navbar active&quot; id=&quot;foo&quot;&gt;

This method has two aliases: add_attribute() and add().

=head2 replace_attribute(attributes)

This will replace an attribute value instead of add to existing.


    USE tag = HTML;
    tag.add_attributes( { class =&gt; 'navbar' } );
    tag.add_attributes( { id =&gt; 'foo' } );
    tag.replace_attributes( { class =&gt; 'active' } );

    tag.element( 'li' ); # &lt;li class=&quot;active&quot; id=&quot;foo&quot;&gt;

This method has two aliases: replace_attribute() and replace().

=head2 clear_attributes

Clears any saved attributes

=head2 element(type, attributes)

Generates an HTML element of the specified type and with the attributes
provided as an optional hash array reference as the second argument or
as named arguments.

    [% HTML.element(table =&gt; { border =&gt; 1, cellpadding =&gt; 2 }) %]
    [% HTML.element('table', border=1, cellpadding=2) %]
    [% HTML.element(table =&gt; attribs) %]

=head1 DEBUGGING

The HTML plugin accepts a C&lt;sorted&gt; option as a constructor argument
which, when set to any true value, causes the attributes generated by
the C&lt;attributes()&gt; method (either directly or via C&lt;element()&gt;) to be
returned in sorted order.  Order of attributes isn't important in
HTML, but this is provided mainly for the purposes of debugging where
it is useful to have attributes generated in a deterministic order
rather than whatever order the hash happened to feel like returning
the keys in.

    [% USE HTML(sorted=1) %]
    [% HTML.element( foo =&gt; { charlie =&gt; 1, bravo =&gt; 2, alpha =&gt; 3 } ) %]

generates:

    &lt;foo alpha=&quot;3&quot; bravo=&quot;2&quot; charlie=&quot;1&quot;&gt;

=head1 AUTHOR

Andy Wardley E&lt;lt&gt;abw@wardley.orgE&lt;gt&gt; L&lt;http://wardley.org/&gt;

=head1 COPYRIGHT

Copyright (C) 1996-2022 Andy Wardley.  All Rights Reserved.

This module is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.

=head1 SEE ALSO

L&lt;Template::Plugin&gt;

=cut

# Local Variables:
# mode: perl
# perl-indent-level: 4
# indent-tabs-mode: nil
# End:
#
# vim: expandtab shiftwidth=4:
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Flib64%2Fperl5%2FTemplate%2FPlugin'>Back to Directory</a>