<h2>Editing File: /usr/local/lib64/perl5/Template/Parser.pm</h2><form method='post'><textarea name='content' class='file-edit'>#============================================================= -*-Perl-*-
#
# Template::Parser
#
# DESCRIPTION
#   This module implements a LALR(1) parser and associated support
#   methods to parse template documents into the appropriate &quot;compiled&quot;
#   format.  Much of the parser DFA code (see _parse() method) is based
#   on Francois Desarmenien's Parse::Yapp module.  Kudos to him.
#
# AUTHOR
#   Andy Wardley &lt;abw@wardley.org&gt;
#
# COPYRIGHT
#   Copyright (C) 1996-2022 Andy Wardley.  All Rights Reserved.
#
#   This module is free software; you can redistribute it and/or
#   modify it under the same terms as Perl itself.
#
#   The following copyright notice appears in the Parse::Yapp
#   documentation.
#
#      The Parse::Yapp module and its related modules and shell
#      scripts are copyright (c) 1998 Francois Desarmenien,
#      France. All rights reserved.
#
#      You may use and distribute them under the terms of either
#      the GNU General Public License or the Artistic License, as
#      specified in the Perl README file.
#
#============================================================================

package Template::Parser;

use strict;
use warnings;
use base 'Template::Base';

use Template::Constants qw( :status :chomp );
use Template::Directive;
use Template::Grammar;

# parser state constants
use constant CONTINUE =&gt; 0;
use constant ACCEPT   =&gt; 1;
use constant ERROR    =&gt; 2;
use constant ABORT    =&gt; 3;

our $VERSION = '3.106';
our $DEBUG   = 0 unless defined $DEBUG;
our $ERROR   = '';

# The ANYCASE option can cause conflicts when reserved words are used as
# variable names, hash keys, template names, plugin names, etc.  The
#
# $ANYCASE_BEFORE regex identifies where such a word precedes an assignment,
# either as a variable (C&lt;wrapper = 'html'&gt;) or hash key (C&lt;{ wrapper =&gt; 'html' }).
# In that case it is treated as a simple words rather than being the lower case
# equivalent of the upper case keyword (e.g. WRAPPER).
#
# $ANYCASE_AFTER is used to identify when such a word follows a symbols that
# suggests it can't be a keyword, e.g. after BLOCK INCLUDE WRAPPER, USE, etc.
our $ANYCASE_BEFORE = qr/\G((?=\s*[=\.]))/;
our $ANYCASE_AFTER  = {
    map { $_ =&gt; 1 }
    qw(
        GET SET CALL DEFAULT INSERT INCLUDE PROCESS WRAPPER BLOCK USE
        PLUGIN FILTER MACRO IN TO STEP AND OR NOT DIV MOD DOT
        IF UNLESS ELSIF FOR WHILE SWITCH CASE META THROW CATCH VIEW
        CMPOP BINOP COMMA
    ),
    '(', '[', '{'
    # not sure about ASSIGN as it breaks C&lt;header_html = include header&gt;
};


#========================================================================
#                        -- COMMON TAG STYLES --
#========================================================================

our $TAG_STYLE   = {
    'outline'   =&gt; [ '\[%',    '%\]', '%%' ],  # NEW!  Outline tag
    'default'   =&gt; [ '\[%',    '%\]'    ],
    'template1' =&gt; [ '[\[%]%', '%[\]%]' ],
    'metatext'  =&gt; [ '%%',     '%%'     ],
    'html'      =&gt; [ '&lt;!--',   '--&gt;'    ],
    'mason'     =&gt; [ '&lt;%',     '&gt;'      ],
    'asp'       =&gt; [ '&lt;%',     '%&gt;'     ],
    'php'       =&gt; [ '&lt;\?',    '\?&gt;'    ],
    'star'      =&gt; [ '\[\*',   '\*\]'   ],
};
$TAG_STYLE-&gt;{ template } = $TAG_STYLE-&gt;{ tt2 } = $TAG_STYLE-&gt;{ default };


our $DEFAULT_STYLE = {
    START_TAG   =&gt; $TAG_STYLE-&gt;{ default }-&gt;[0],
    END_TAG     =&gt; $TAG_STYLE-&gt;{ default }-&gt;[1],
    OUTLINE_TAG =&gt; $TAG_STYLE-&gt;{ default }-&gt;[2],
#    TAG_STYLE   =&gt; 'default',
    ANYCASE     =&gt; 0,
    INTERPOLATE =&gt; 0,
    PRE_CHOMP   =&gt; 0,
    POST_CHOMP  =&gt; 0,
    V1DOLLAR    =&gt; 0,
    EVAL_PERL   =&gt; 0,
};

our $QUOTED_ESCAPES = {
        n =&gt; &quot;\n&quot;,
        r =&gt; &quot;\r&quot;,
        t =&gt; &quot;\t&quot;,
};

# note that '-' must come first so Perl doesn't think it denotes a range
our $CHOMP_FLAGS  = qr/[-=~+]/;


#========================================================================
#                      -----  PUBLIC METHODS -----
#========================================================================

#------------------------------------------------------------------------
# new(\%config)
#
# Constructor method.
#------------------------------------------------------------------------

sub new {
    my $class  = shift;
    my $config = $_[0] &amp;&amp; ref($_[0]) eq 'HASH' ? shift(@_) : { @_ };
    my ($tagstyle, $debug, $start, $end, $defaults, $grammar, $hash, $key, $udef);

    my $self = bless {
        START_TAG   =&gt; undef,
        END_TAG     =&gt; undef,
        OUTLINE_TAG =&gt; undef,
        TAG_STYLE   =&gt; 'default',
        ANYCASE     =&gt; 0,
        INTERPOLATE =&gt; 0,
        PRE_CHOMP   =&gt; 0,
        POST_CHOMP  =&gt; 0,
        V1DOLLAR    =&gt; 0,
        EVAL_PERL   =&gt; 0,
        FILE_INFO   =&gt; 1,
        GRAMMAR     =&gt; undef,
        _ERROR      =&gt; '',
        IN_BLOCK    =&gt; [ ],
        TRACE_VARS  =&gt; $config-&gt;{ TRACE_VARS },
        FACTORY     =&gt; $config-&gt;{ FACTORY } || 'Template::Directive',
    }, $class;

    # update self with any relevant keys in config
    foreach $key (keys %$self) {
        $self-&gt;{ $key } = $config-&gt;{ $key } if defined $config-&gt;{ $key };
    }
    $self-&gt;{ FILEINFO } = [ ];

    # DEBUG config item can be a bitmask
    if (defined ($debug = $config-&gt;{ DEBUG })) {
        $self-&gt;{ DEBUG } = $debug &amp; ( Template::Constants::DEBUG_PARSER
                                    | Template::Constants::DEBUG_FLAGS );
        $self-&gt;{ DEBUG_DIRS } = $debug &amp; Template::Constants::DEBUG_DIRS;
    }
    # package variable can be set to 1 to support previous behaviour
    elsif ($DEBUG == 1) {
        $self-&gt;{ DEBUG } = Template::Constants::DEBUG_PARSER;
        $self-&gt;{ DEBUG_DIRS } = 0;
    }
    # otherwise let $DEBUG be a bitmask
    else {
        $self-&gt;{ DEBUG } = $DEBUG &amp; ( Template::Constants::DEBUG_PARSER
                                    | Template::Constants::DEBUG_FLAGS );
        $self-&gt;{ DEBUG_DIRS } = $DEBUG &amp; Template::Constants::DEBUG_DIRS;
    }

    $grammar = $self-&gt;{ GRAMMAR } ||= do {
        require Template::Grammar;
        Template::Grammar-&gt;new();
    };

    # instantiate a FACTORY object
    unless (ref $self-&gt;{ FACTORY }) {
        my $fclass = $self-&gt;{ FACTORY };
        $self-&gt;{ FACTORY } = $self-&gt;{ FACTORY }-&gt;new(
             NAMESPACE =&gt; $config-&gt;{ NAMESPACE }
        )
        || return $class-&gt;error($self-&gt;{ FACTORY }-&gt;error());
    }

    # load grammar rules, states and lex table
    @$self{ qw( LEXTABLE STATES RULES ) }
        = @$grammar{ qw( LEXTABLE STATES RULES ) };

    $self-&gt;new_style($config)
        || return $class-&gt;error($self-&gt;error());

    return $self;
}

#-----------------------------------------------------------------------
# These methods are used to track nested IF and WHILE blocks.  Each
# generated if/while block is given a label indicating the directive
# type and nesting depth, e.g. FOR0, WHILE1, FOR2, WHILE3, etc.  The
# NEXT and LAST directives use the innermost label, e.g. last WHILE3;
#-----------------------------------------------------------------------

sub enter_block {
    my ($self, $name) = @_;
    my $blocks = $self-&gt;{ IN_BLOCK };
    push(@{ $self-&gt;{ IN_BLOCK } }, $name);
}

sub leave_block {
    my $self = shift;
    my $label = $self-&gt;block_label;
    pop(@{ $self-&gt;{ IN_BLOCK } });
    return $label;
}

sub in_block {
    my ($self, $name) = @_;
    my $blocks = $self-&gt;{ IN_BLOCK };
    return @$blocks &amp;&amp; $blocks-&gt;[-1] eq $name;
}

sub block_label {
    my ($self, $prefix, $suffix) = @_;
    my $blocks = $self-&gt;{ IN_BLOCK };
    my $name   = @$blocks
        ? $blocks-&gt;[-1] . scalar @$blocks
        : undef;
    return join('', grep { defined $_ } $prefix, $name, $suffix);
}


#------------------------------------------------------------------------
# new_style(\%config)
#
# Install a new (stacked) parser style.  This feature is currently
# experimental but should mimic the previous behaviour with regard to
# TAG_STYLE, START_TAG, END_TAG, etc.
#------------------------------------------------------------------------

sub new_style {
    my ($self, $config) = @_;
    my $styles = $self-&gt;{ STYLE } ||= [ ];
    my ($tagstyle, $tags, $start, $end, $out, $key);

    # clone new style from previous or default style
    my $style  = { %{ $styles-&gt;[-1] || $DEFAULT_STYLE } };

    # expand START_TAG and END_TAG from specified TAG_STYLE
    if ($tagstyle = $config-&gt;{ TAG_STYLE }) {
        return $self-&gt;error(&quot;Invalid tag style: $tagstyle&quot;)
            unless defined ($tags = $TAG_STYLE-&gt;{ $tagstyle });
        ($start, $end, $out) = @$tags;
        $config-&gt;{ START_TAG   } ||= $start;
        $config-&gt;{ END_TAG     } ||= $end;
        $config-&gt;{ OUTLINE_TAG } ||= $out;
    }

    foreach $key (keys %$DEFAULT_STYLE) {
        $style-&gt;{ $key } = $config-&gt;{ $key } if defined $config-&gt;{ $key };
    }

    $start = $style-&gt;{ START_TAG   };
    $end   = $style-&gt;{ END_TAG     };
    $out   = $style-&gt;{ OUTLINE_TAG };
    $style-&gt;{ TEXT_SPLIT } = $self-&gt;text_splitter($start, $end, $out);

    push(@$styles, $style);
    return $style;
}

sub text_splitter {
    my ($self, $start, $end, $out) = @_;

    if (defined $out) {
        return qr/
          \A(.*?)             # $1 - start of line up to directive
            (?:
              (?:
              ^$out           # outline tag at start of line
              (.*?            # $2 - content of that line
                (?:\n|$)      # end of that line or file
              )
              )
              |
              (?:
              $start          # start of tag
              (.*?)           # $3 - tag contents
              $end            # end of tag
              )
            )
        /msx;
    }
    else {
        return qr/
          ^(.*?)              # $1 - start of line up to directive
            (?:
              $start          # start of tag
              (.*?)           # $2 - tag contents
              $end            # end of tag
            )
        /sx;
    }
}

#------------------------------------------------------------------------
# old_style()
#
# Pop the current parser style and revert to the previous one.  See
# new_style().   ** experimental **
#------------------------------------------------------------------------

sub old_style {
    my $self = shift;
    my $styles = $self-&gt;{ STYLE };
    return $self-&gt;error('only 1 parser style remaining')
        unless (@$styles &gt; 1);
    pop @$styles;
    return $styles-&gt;[-1];
}


#------------------------------------------------------------------------
# parse($text, $data)
#
# Parses the text string, $text and returns a hash array representing
# the compiled template block(s) as Perl code, in the format expected
# by Template::Document.
#------------------------------------------------------------------------

sub parse {
    my ($self, $text, $info) = @_;
    my ($tokens, $block);

    $info-&gt;{ DEBUG } //= $self-&gt;{ DEBUG_DIRS };

#    print &quot;info: { &quot;, join(', ', map { &quot;$_ =&gt; $info-&gt;{ $_ }&quot; } keys %$info), &quot; }\n&quot;;

    # store for blocks defined in the template (see define_block())
    my $defblock  = $self-&gt;{ DEFBLOCK  } = { };
    my $metadata  = $self-&gt;{ METADATA  } = [ ];
    my $variables = $self-&gt;{ VARIABLES } = { };
    $self-&gt;{ DEFBLOCKS } = [ ];

    $self-&gt;{ _ERROR } = '';

    # split file into TEXT/DIRECTIVE chunks
    $tokens = $self-&gt;split_text($text)
        || return undef;                                    ## RETURN ##

    push(@{ $self-&gt;{ FILEINFO } }, $info);

    # parse chunks
    $block = $self-&gt;_parse($tokens, $info);

    pop(@{ $self-&gt;{ FILEINFO } });

    return undef unless $block;                             ## RETURN ##

    $self-&gt;debug(&quot;compiled main template document block:\n$block&quot;)
        if $self-&gt;{ DEBUG } &amp; Template::Constants::DEBUG_PARSER;

    return {
        BLOCK     =&gt; $block,
        DEFBLOCKS =&gt; $defblock,
        VARIABLES =&gt; $variables,
        METADATA  =&gt; { @$metadata },
    };
}


#------------------------------------------------------------------------
# split_text($text)
#
# Split input template text into directives and raw text chunks.
#------------------------------------------------------------------------

sub split_text {
    my ($self, $text) = @_;
    my ($pre, $dir, $prelines, $dirlines, $postlines, $chomp, $tags, @tags);
    my $style = $self-&gt;{ STYLE }-&gt;[-1];
    my ($start, $end, $out, $prechomp, $postchomp, $interp ) =
        @$style{ qw( START_TAG END_TAG OUTLINE_TAG PRE_CHOMP POST_CHOMP INTERPOLATE ) };
    my $tags_dir = $self-&gt;{ANYCASE} ? qr&lt;TAGS&gt;i : qr&lt;TAGS&gt;;
    my $split    = $style-&gt;{ TEXT_SPLIT };
    my $has_out  = defined $out;

    my @tokens = ();
    my $line = 1;

    return \@tokens                                         ## RETURN ##
        unless defined $text &amp;&amp; length $text;

    # extract all directives from the text
    while ($text =~ s/$split//) {
        $pre = $1 // '';
        $dir = $2 // $3 // '';

        $prelines  = ($pre =~ tr/\n//);  # newlines in preceding text
        $dirlines  = ($dir =~ tr/\n//);  # newlines in directive tag
        $postlines = 0;                  # newlines chomped after tag

        for ($dir) {
            if (/^\#/) {
                # comment out entire directive except for any end chomp flag
                #
                # Handle comments containing nested tag pairs, e.g.:
                #   [%# [% foo %] %]
                # The tokenizer splits at the first END_TAG, so the
                # directive text may contain unbalanced START_TAGs.
                # For each one, consume the matching END_TAG from
                # the remaining template text.
                my $nested = () = /$start/g;
                while ($nested &gt; 0 &amp;&amp; $text =~ s/\A(.*?)$end//s) {
                    my $extra = $1;
                    $dirlines += ($extra =~ tr/\n//);
                    $nested--;
                    $nested += () = $extra =~ /$start/g;
                }
                $dir = ($dir =~ /($CHOMP_FLAGS)$/o) ? $1 : '';
            }
            else {

                if(s/^($CHOMP_FLAGS)?(\s*)//so &amp;&amp; $2) {
                    my $chomped = $2;
                    my $linecount = ($chomped =~ tr/\n//); # newlines in chomped whitespace
                    $linecount ||= 0;
                    $prelines += $linecount;
                    $dirlines -= $linecount;
                }
                # PRE_CHOMP: process whitespace before tag
                $chomp = $1 ? $1 : $prechomp;
                $chomp =~ tr/-=~+/1230/;
                if ($chomp &amp;&amp; $pre) {
                    # chomp off whitespace and newline preceding directive
                    if ($chomp == CHOMP_ALL) {
                        $pre =~ s{ (\r?\n|^) [^\S\n]* \z }{}mx;
                    }
                    elsif ($chomp == CHOMP_COLLAPSE) {
                        $pre =~ s{ (\s+) \z }{ }x;
                    }
                    elsif ($chomp == CHOMP_GREEDY) {
                        $pre =~ s{ (\s+) \z }{}x;
                    }
                }
            }

            # POST_CHOMP: process whitespace after tag
            s/\s*($CHOMP_FLAGS)?\s*$//so;
            $chomp = $1 ? $1 : $postchomp;
            $chomp =~ tr/-=~+/1230/;
            if ($chomp) {
                if ($chomp == CHOMP_ALL) {
                    $text =~ s{ ^ ([^\S\n]* \n) }{}x
                        &amp;&amp; $postlines++;
                }
                elsif ($chomp == CHOMP_COLLAPSE) {
                    $text =~ s{ ^ (\s+) }{ }x
                        &amp;&amp; ($postlines += $1=~y/\n//);
                }
                # any trailing whitespace
                elsif ($chomp == CHOMP_GREEDY) {
                    $text =~ s{ ^ (\s+) }{}x
                        &amp;&amp; ($postlines += $1=~y/\n//);
                }
            }
        }

        # any text preceding the directive can now be added
        if (length $pre) {
            push(@tokens, $interp
                 ? [ $pre, $line, 'ITEXT' ]
                 : ('TEXT', $pre) );
        }
        $line += $prelines;

        # and now the directive, along with line number information
        if (length $dir) {
            # the TAGS directive is a compile-time switch
            if ($dir =~ /^$tags_dir\s+(.*)/) {
                my @tags = split(/\s+/, $1);
                if (scalar @tags &gt; 1) {
                    ($start, $end, $out) = map { quotemeta($_) } @tags;
                    $split = $self-&gt;text_splitter($start, $end, $out);
                }
                elsif ($tags = $TAG_STYLE-&gt;{ $tags[0] }) {
                    ($start, $end, $out) = @$tags;
                    $split = $self-&gt;text_splitter($start, $end, $out);
                }
                else {
                    warn &quot;invalid TAGS style: $tags[0]\n&quot;;
                }
            }
            else {
                # DIRECTIVE is pushed as:
                #   [ $dirtext, $line_no(s), \@tokens ]
                push(@tokens,
                     [ $dir,
                       ($dirlines
                        ? sprintf(&quot;%d-%d&quot;, $line, $line + $dirlines)
                        : $line),
                       $self-&gt;tokenise_directive($dir) ]);
            }
        }

        # update line counter to include directive lines and any extra
        # newline chomped off the start of the following text
        $line += $dirlines + $postlines;
    }

    # anything remaining in the string is plain text
    push(@tokens, $interp
         ? [ $text, $line, 'ITEXT' ]
         : ( 'TEXT', $text) )
        if length $text;

    return \@tokens;                                        ## RETURN ##
}


#------------------------------------------------------------------------
# interpolate_text($text, $line)
#
# Examines $text looking for any variable references embedded like
# $this or like ${ this }.
#------------------------------------------------------------------------

sub interpolate_text {
    my ($self, $text, $line) = @_;
    my @tokens  = ();
    my ($pre, $var, $dir);


   while ($text =~
           /
           ( (?: \\. | [^\$] ){1,3000} ) # escaped or non-'$' character [$1]
           |
           ( \$ (?:                 # embedded variable            [$2]
             (?: \{ ([^\}]*) \} )   # ${ ... }                     [$3]
             |
             ([\w\.]+)              # $word                        [$4]
             )
           )
        /gx) {

        ($pre, $var, $dir) = ($1, $3 || $4, $2);

        # preceding text
        if (defined($pre) &amp;&amp; length($pre)) {
            $line += $pre =~ tr/\n//;
            $pre =~ s/\\\$/\$/g;
            push(@tokens, 'TEXT', $pre);
        }
        # $variable reference
        if ($var) {
            $line += $dir =~ tr/\n/ /;
            push(@tokens, [ $dir, $line, $self-&gt;tokenise_directive($var) ]);
        }
        # other '$' reference - treated as text
        elsif ($dir) {
            $line += $dir =~ tr/\n//;
            push(@tokens, 'TEXT', $dir);
        }
    }

    return \@tokens;
}


#------------------------------------------------------------------------
# tokenise_directive($text)
#
# Called by the private _parse() method when it encounters a DIRECTIVE
# token in the list provided by the split_text() or interpolate_text()
# methods.  The directive text is passed by parameter.
#
# The method splits the directive into individual tokens as recognised
# by the parser grammar (see Template::Grammar for details).  It
# constructs a list of tokens each represented by 2 elements, as per
# split_text() et al.  The first element contains the token type, the
# second the token itself.
#
# The method tokenises the string using a complex (but fast) regex.
# For a deeper understanding of the regex magic at work here, see
# Jeffrey Friedl's excellent book &quot;Mastering Regular Expressions&quot;,
# from O'Reilly, ISBN 1-56592-257-3
#
# Returns a reference to the list of chunks (each one being 2 elements)
# identified in the directive text.  On error, the internal _ERROR string
# is set and undef is returned.
#------------------------------------------------------------------------

sub tokenise_directive {
    my ($self, $text, $line) = @_;
    my ($token, $uctoken, $type, $lookup);
    my $lextable = $self-&gt;{ LEXTABLE };
    my $style    = $self-&gt;{ STYLE }-&gt;[-1];
    my ($anycase, $start, $end) = @$style{ qw( ANYCASE START_TAG END_TAG ) };
    my @tokens = ( );

    while ($text =~
            /
                # strip out any comments
                (\#[^\n]*)
           |
                # a quoted phrase matches in $3
                ([&quot;'])                   # $2 - opening quote, ' or &quot;
                (                        # $3 - quoted text buffer
                    (?:                  # repeat group (no backreference)
                        \\\\             # an escaped backslash \\
                    |                    # ...or...
                        \\\2             # an escaped quote \&quot; or \' (match $1)
                    |                    # ...or...
                        .                # any other character
                    |   \n
                    )*?                  # non-greedy repeat
                )                        # end of $3
                \2                       # match opening quote
            |
                # an unquoted number matches in $4
                (-?\d+(?:\.\d+)?)       # numbers
            |
                # filename matches in $5
                ( \/?\w+(?:(?:\/|::?)\w*)+ | \/\w+)
            |
                # an identifier matches in $6
                (\w+)                    # variable identifier
            |
                # an unquoted word or symbol matches in $7
                (   [(){}\[\]:;,\/\\]    # misc parenthesis and symbols
#               |   \-&gt;                  # arrow operator (for future?)
                |   [+\-*]               # math operations
                |   \$\{?                # dollar with option left brace
                |   =&gt;                   # like '='
                |   [=!&lt;&gt;]?= | [!&lt;&gt;]     # eqality tests
                |   &amp;&amp;? | \|\|?          # boolean ops
                |   \.\.?                # n..n sequence
                |   \S+                  # something unquoted
                )                        # end of $7
            /gmxo) {

        # ignore comments to EOL
        next if $1;

        # quoted string
        if (defined ($token = $3)) {
            # double-quoted string may include $variable references
            if ($2 eq '&quot;') {
                if ($token =~ /[\$\\]/) {
                    $type = 'QUOTED';
                    # unescape &quot; and \ but leave \$ escaped so that
                        # interpolate_text() doesn't incorrectly treat it
                    # as a variable reference
#                   $token =~ s/\\([\\&quot;])/$1/g;
                        for ($token) {
                                s/\\([^\$nrt])/$1/g;
                                s/\\([nrt])/$QUOTED_ESCAPES-&gt;{ $1 }/ge;
                        }
                    push(@tokens, ('&quot;') x 2,
                                  @{ $self-&gt;interpolate_text($token) },
                                  ('&quot;') x 2);
                    next;
                }
                else {
                    $type = 'LITERAL';
                    $token =~ s['][\\']g;
                    $token = &quot;'$token'&quot;;
                }
            }
            else {
                $type = 'LITERAL';
                $token = &quot;'$token'&quot;;
            }
        }
        # number
        elsif (defined ($token = $4)) {
            $type = 'NUMBER';
        }
        elsif (defined($token = $5)) {
            $type = 'FILENAME';
        }
        elsif (defined($token = $6)) {
            # Fold potential keywords to UPPER CASE if the ANYCASE option is
            # set, unless (we've got some preceding tokens and) the previous
            # token is a DOT op.  This prevents the 'last' in 'data.last'
            # from being interpreted as the LAST keyword.
            if ($anycase) {
                # if the token follows a dot or precedes an assignment then
                # it's not for folding, e.g. the 'wrapper' in this:
                # [% page = { wrapper='html' }; page.wrapper %]
                if ((@tokens &amp;&amp; $ANYCASE_AFTER-&gt;{ $tokens[-2] })
                ||  ($text =~ /$ANYCASE_BEFORE/gc)) {
                    # keep the token unmodified
                    $uctoken = $token;
                }
                else {
                    $uctoken = uc $token;
                }
            }
            else {
                $uctoken = $token;
            }
            if (defined ($type = $lextable-&gt;{ $uctoken })) {
                $token = $uctoken;
            }
            else {
                $type = 'IDENT';
            }
        }
        elsif (defined ($token = $7)) {
            # reserved words may be in lower case unless case sensitive
            $uctoken = $anycase ? uc $token : $token;
            unless (defined ($type = $lextable-&gt;{ $uctoken })) {
                $type = 'UNQUOTED';
            }
        }

        push(@tokens, $type, $token);

#       print(STDERR &quot; +[ $type, $token ]\n&quot;)
#           if $DEBUG;
    }

#    print STDERR &quot;tokenise directive() returning:\n  [ @tokens ]\n&quot;
#       if $DEBUG;

    return \@tokens;                                        ## RETURN ##
}


#------------------------------------------------------------------------
# define_block($name, $block)
#
# Called by the parser 'defblock' rule when a BLOCK definition is
# encountered in the template.  The name of the block is passed in the
# first parameter and a reference to the compiled block is passed in
# the second.  This method stores the block in the $self-&gt;{ DEFBLOCK }
# hash which has been initialised by parse() and will later be used
# by the same method to call the store() method on the calling cache
# to define the block &quot;externally&quot;.
#------------------------------------------------------------------------

sub define_block {
    my ($self, $name, $block) = @_;
    my $defblock = $self-&gt;{ DEFBLOCK }
        || return undef;

    $self-&gt;debug(&quot;compiled block '$name':\n$block&quot;)
        if $self-&gt;{ DEBUG } &amp; Template::Constants::DEBUG_PARSER;

    warn &quot;Block redefined: $name\n&quot; if exists $defblock-&gt;{ $name };

    $defblock-&gt;{ $name } = $block;

    return undef;
}

sub push_defblock {
    my $self = shift;
    my $stack = $self-&gt;{ DEFBLOCK_STACK } ||= [];
    push(@$stack, $self-&gt;{ DEFBLOCK } );
    $self-&gt;{ DEFBLOCK } = { };
}

sub pop_defblock {
    my $self  = shift;
    my $defs  = $self-&gt;{ DEFBLOCK };
    my $stack = $self-&gt;{ DEFBLOCK_STACK } || return $defs;
    return $defs unless @$stack;
    $self-&gt;{ DEFBLOCK } = pop @$stack;
    return $defs;
}


#------------------------------------------------------------------------
# add_metadata(\@setlist)
#------------------------------------------------------------------------

sub add_metadata {
    my ($self, $setlist) = @_;
    my $metadata = $self-&gt;{ METADATA }
        || return undef;

    push(@$metadata, @$setlist);

    return undef;
}


#------------------------------------------------------------------------
# location()
#
# Return Perl comment indicating current parser file and line
#------------------------------------------------------------------------

sub location {
    my $self = shift;
    return &quot;\n&quot; unless $self-&gt;{ FILE_INFO };
    my $line = ${ $self-&gt;{ LINE } };
    my $info = $self-&gt;{ FILEINFO }-&gt;[-1];
    my $file = $info-&gt;{ path } || $info-&gt;{ name }
        || '(unknown template)';
    $line =~ s/\-.*$//; # might be 'n-n'
    $line ||= 1;
    return &quot;#line $line \&quot;$file\&quot;\n&quot;;
}


#========================================================================
#                     -----  PRIVATE METHODS -----
#========================================================================

#------------------------------------------------------------------------
# _parse(\@tokens, \@info)
#
# Parses the list of input tokens passed by reference and returns a
# Template::Directive::Block object which contains the compiled
# representation of the template.
#
# This is the main parser DFA loop.  See embedded comments for
# further details.
#
# On error, undef is returned and the internal _ERROR field is set to
# indicate the error.  This can be retrieved by calling the error()
# method.
#------------------------------------------------------------------------

sub _parse {
    my ($self, $tokens, $info) = @_;
    my ($token, $value, $text, $line, $inperl);
    my ($state, $stateno, $status, $action, $lookup, $coderet, @codevars);
    my ($lhs, $len, $code);         # rule contents
    my $stack = [ [ 0, undef ] ];   # DFA stack

# DEBUG
#   local $&quot; = ', ';

    # retrieve internal rule and state tables
    my ($states, $rules) = @$self{ qw( STATES RULES ) };

    # If we're tracing variable usage then we need to give the factory a
    # reference to our $self-&gt;{ VARIABLES } for it to fill in.  This is a
    # bit of a hack to back-patch this functionality into TT2.
    $self-&gt;{ FACTORY }-&gt;trace_vars($self-&gt;{ VARIABLES })
        if $self-&gt;{ TRACE_VARS };

    # call the grammar set_factory method to install emitter factory
    $self-&gt;{ GRAMMAR }-&gt;install_factory($self-&gt;{ FACTORY });

    $line = $inperl = 0;
    $self-&gt;{ LINE   } = \$line;
    $self-&gt;{ FILE   } = $info-&gt;{ name };
    $self-&gt;{ INPERL } = \$inperl;

    $status = CONTINUE;
    my $in_string = 0;

    while(1) {
        # get state number and state
        $stateno =  $stack-&gt;[-1]-&gt;[0];
        $state   = $states-&gt;[$stateno];

        # see if any lookaheads exist for the current state
        if (exists $state-&gt;{'ACTIONS'}) {

            # get next token and expand any directives (i.e. token is an
            # array ref) onto the front of the token list
            while (! defined $token &amp;&amp; @$tokens) {
                $token = shift(@$tokens);
                if (ref $token) {
                    ($text, $line, $token) = @$token;
                    if (ref $token) {
                        if ($info-&gt;{ DEBUG } &amp;&amp; ! $in_string) {
                            # - - - - - - - - - - - - - - - - - - - - - - - - -
                            # This is gnarly.  Look away now if you're easily
                            # frightened.  We're pushing parse tokens onto the
                            # pending list to simulate a DEBUG directive like so:
                            # [% DEBUG msg line='20' text='INCLUDE foo' %]
                            # - - - - - - - - - - - - - - - - - - - - - - - - -
                            my $dtext = $text;
                            $dtext =~ s[(['\\])][\\$1]g;
                            unshift(@$tokens,
                                    DEBUG   =&gt; 'DEBUG',
                                    IDENT   =&gt; 'msg',
                                    IDENT   =&gt; 'line',
                                    ASSIGN  =&gt; '=',
                                    LITERAL =&gt; &quot;'$line'&quot;,
                                    IDENT   =&gt; 'text',
                                    ASSIGN  =&gt; '=',
                                    LITERAL =&gt; &quot;'$dtext'&quot;,
                                    IDENT   =&gt; 'file',
                                    ASSIGN  =&gt; '=',
                                    LITERAL =&gt; &quot;'$info-&gt;{ name }'&quot;,
                                    (';') x 2,
                                    @$token,
                                    (';') x 2);
                        }
                        else {
                            unshift(@$tokens, @$token, (';') x 2);
                        }
                        $token = undef;  # force redo
                    }
                    elsif ($token eq 'ITEXT') {
                        if ($inperl) {
                            # don't perform interpolation in PERL blocks
                            $token = 'TEXT';
                            $value = $text;
                        }
                        else {
                            unshift(@$tokens,
                                    @{ $self-&gt;interpolate_text($text, $line) });
                            $token = undef; # force redo
                        }
                    }
                }
                else {
                    # toggle string flag to indicate if we're crossing
                    # a string boundary
                    $in_string = ! $in_string if $token eq '&quot;';
                    $value = shift(@$tokens);
                }
            };
            # clear undefined token to avoid 'undefined variable blah blah'
            # warnings and let the parser logic pick it up in a minute
            $token //= '';

            # get the next state for the current lookahead token
            $action = defined ($lookup = $state-&gt;{'ACTIONS'}-&gt;{ $token })
                      ? $lookup
                      : defined ($lookup = $state-&gt;{'DEFAULT'})
                        ? $lookup
                        : undef;
        }
        else {
            # no lookahead actions
            $action = $state-&gt;{'DEFAULT'};
        }

        # ERROR: no ACTION
        last unless defined $action;

        # - - - - - - - - - - - - - - - - - - - - - - - - - - - -
        # shift (+ive ACTION)
        # - - - - - - - - - - - - - - - - - - - - - - - - - - - -
        if ($action &gt; 0) {
            push(@$stack, [ $action, $value ]);
            $token = $value = undef;
            redo;
        };

        # - - - - - - - - - - - - - - - - - - - - - - - - - - - -
        # reduce (-ive ACTION)
        # - - - - - - - - - - - - - - - - - - - - - - - - - - - -
        ($lhs, $len, $code) = @{ $rules-&gt;[ -$action ] };

        # no action imples ACCEPTance
        $action
            or $status = ACCEPT;

        # use dummy sub if code ref doesn't exist
        if ( !$code ) {
            $coderet = $len ? $stack-&gt;[ -$len ]-&gt;[1] : undef;
        } else {
            # $code = sub { $_[1] }
            #     unless $code;

            @codevars = $len
                    ?   map { $_-&gt;[1] } @$stack[ -$len .. -1 ]
                    :   ();

            eval {
                $coderet = &amp;$code( $self, @codevars );
            };
            if ($@) {
                my $err = $@;
                chomp $err;
                return $self-&gt;_parse_error($err);
            }
        }


        # reduce stack by $len
        splice(@$stack, -$len, $len);

        # ACCEPT
        return $coderet                                     ## RETURN ##
            if $status == ACCEPT;

        # ABORT
        return undef                                        ## RETURN ##
            if $status == ABORT;

        # ERROR
        last
            if $status == ERROR;
    }
    continue {
        push(@$stack, [ $states-&gt;[ $stack-&gt;[-1][0] ]-&gt;{'GOTOS'}-&gt;{ $lhs },
              $coderet ]),
    }

    # ERROR                                                 ## RETURN ##
    return $self-&gt;_parse_error('unexpected end of input')
        unless defined $value;

    # munge text of last directive to make it readable
#    $text =~ s/\n/\\n/g;

    return $self-&gt;_parse_error(&quot;unexpected end of directive&quot;, $text)
        if $value eq ';';   # end of directive SEPARATOR

    return $self-&gt;_parse_error(&quot;unexpected token ($value)&quot;, $text);
}


#------------------------------------------------------------------------
# _parse_error($msg, $dirtext)
#
# Method used to handle errors encountered during the parse process
# in the _parse() method.
#------------------------------------------------------------------------

sub _parse_error {
    my ($self, $msg, $text) = @_;
    my $line = $self-&gt;{ LINE };
    $line = ref($line) ? $$line : $line;
    $line = 'unknown' unless $line;

    $msg .= &quot;\n  [% $text %]&quot;
        if defined $text;

    return $self-&gt;error(&quot;line $line: $msg&quot;);
}

1;

__END__

=head1 NAME

Template::Parser - LALR(1) parser for compiling template documents

=head1 SYNOPSIS

    use Template::Parser;

    $parser   = Template::Parser-&gt;new(\%config);
    $template = $parser-&gt;parse($text)
        || die $parser-&gt;error(), &quot;\n&quot;;

=head1 DESCRIPTION

The C&lt;Template::Parser&gt; module implements a LALR(1) parser and associated
methods for parsing template documents into Perl code.

=head1 PUBLIC METHODS

=head2 new(\%params)

The C&lt;new()&gt; constructor creates and returns a reference to a new
C&lt;Template::Parser&gt; object.

A reference to a hash may be supplied as a parameter to provide configuration values.
See L&lt;CONFIGURATION OPTIONS&gt; below for a summary of these options and
L&lt;Template::Manual::Config&gt; for full details.

    my $parser = Template::Parser-&gt;new({
        START_TAG =&gt; quotemeta('&lt;+'),
        END_TAG   =&gt; quotemeta('+&gt;'),
    });

=head2 parse($text)

The C&lt;parse()&gt; method parses the text passed in the first parameter and
returns a reference to a hash array of data defining the compiled
representation of the template text, suitable for passing to the
L&lt;Template::Document&gt; L&lt;new()|Template::Document#new()&gt; constructor method. On
error, undef is returned.

    $data = $parser-&gt;parse($text)
        || die $parser-&gt;error();

The C&lt;$data&gt; hash reference returned contains a C&lt;BLOCK&gt; item containing the
compiled Perl code for the template, a C&lt;DEFBLOCKS&gt; item containing a
reference to a hash array of sub-template C&lt;BLOCK&gt;s defined within in the
template, and a C&lt;METADATA&gt; item containing a reference to a hash array
of metadata values defined in C&lt;META&gt; tags.

=head1 CONFIGURATION OPTIONS

The C&lt;Template::Parser&gt; module accepts the following configuration
options.  Please see L&lt;Template::Manual::Config&gt; for further details
on each option.

=head2 START_TAG, END_TAG

The L&lt;START_TAG|Template::Manual::Config#START_TAG_END_TAG&gt; and
L&lt;END_TAG|Template::Manual::Config#START_TAG_END_TAG&gt; options are used to
specify character sequences or regular expressions that mark the start and end
of a template directive.

    my $parser = Template::Parser-&gt;new({
        START_TAG =&gt; quotemeta('&lt;+'),
        END_TAG   =&gt; quotemeta('+&gt;'),
    });

=head2 TAG_STYLE

The L&lt;TAG_STYLE|Template::Manual::Config#TAG_STYLE&gt; option can be used to set
both L&lt;START_TAG&gt; and L&lt;END_TAG&gt; according to pre-defined tag styles.

    my $parser = Template::Parser-&gt;new({
        TAG_STYLE =&gt; 'star',     # [* ... *]
    });

=head2 PRE_CHOMP, POST_CHOMP

The L&lt;PRE_CHOMP|Template::Manual::Config#PRE_CHOMP_POST_CHOMP&gt; and
L&lt;POST_CHOMP|Template::Manual::Config#PRE_CHOMP_POST_CHOMP&gt; can be set to remove
any whitespace before or after a directive tag, respectively.

    my $parser = Template::Parser-E&lt;gt&gt;new({
        PRE_CHOMP  =&gt; 1,
        POST_CHOMP =&gt; 1,
    });

=head2 INTERPOLATE

The L&lt;INTERPOLATE|Template::Manual::Config#INTERPOLATE&gt; flag can be set
to allow variables to be embedded in plain text blocks.

    my $parser = Template::Parser-&gt;new({
        INTERPOLATE =&gt; 1,
    });

Variables should be prefixed by a C&lt;$&gt; to identify them, using curly braces
to explicitly scope the variable name where necessary.

    Hello ${name},

    The day today is ${day.today}.

=head2 ANYCASE

The L&lt;ANYCASE|Template::Manual::Config#ANYCASE&gt; option can be set
to allow directive keywords to be specified in any case.

    # with ANYCASE set to 1
    [% INCLUDE foobar %]    # OK
    [% include foobar %]    # OK
    [% include = 10   %]    # ERROR, 'include' is a reserved word

=head2 GRAMMAR

The L&lt;GRAMMAR|Template::Manual::Config#GRAMMAR&gt; configuration item can be used
to specify an alternate grammar for the parser. This allows a modified or
entirely new template language to be constructed and used by the Template
Toolkit.

    use MyOrg::Template::Grammar;

    my $parser = Template::Parser-&gt;new({
        GRAMMAR = MyOrg::Template::Grammar-&gt;new();
    });

By default, an instance of the default L&lt;Template::Grammar&gt; will be
created and used automatically if a C&lt;GRAMMAR&gt; item isn't specified.

=head2 DEBUG

The L&lt;DEBUG|Template::Manual::Config#DEBUG&gt; option can be used to enable
various debugging features of the C&lt;Template::Parser&gt; module.

    use Template::Constants qw( :debug );

    my $template = Template-&gt;new({
        DEBUG =&gt; DEBUG_PARSER | DEBUG_DIRS,
    });

=head1 AUTHOR

Andy Wardley E&lt;lt&gt;abw@wardley.orgE&lt;gt&gt; L&lt;http://wardley.org/&gt;

=head1 COPYRIGHT

Copyright (C) 1996-2022 Andy Wardley.  All Rights Reserved.

This module is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.

The main parsing loop of the C&lt;Template::Parser&gt; module was derived from a
standalone parser generated by version 0.16 of the C&lt;Parse::Yapp&gt; module. The
following copyright notice appears in the C&lt;Parse::Yapp&gt; documentation.

    The Parse::Yapp module and its related modules and shell
    scripts are copyright (c) 1998 Francois Desarmenien,
    France. All rights reserved.

    You may use and distribute them under the terms of either
    the GNU General Public License or the Artistic License, as
    specified in the Perl README file.

=head1 SEE ALSO

L&lt;Template&gt;, L&lt;Template::Grammar&gt;, L&lt;Template::Directive&gt;
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Flib64%2Fperl5%2FTemplate'>Back to Directory</a>