<h2>Editing File: /usr/local/lib64/perl5/Template/Exception.pm</h2><form method='post'><textarea name='content' class='file-edit'>#============================================================= -*-Perl-*-
#
# Template::Exception
#
# DESCRIPTION
#   Module implementing a generic exception class used for error handling
#   in the Template Toolkit.
#
# AUTHOR
#   Andy Wardley   &lt;abw@wardley.org&gt;
#
# COPYRIGHT
#   Copyright (C) 1996-2022 Andy Wardley.  All Rights Reserved.
#
#   This module is free software; you can redistribute it and/or
#   modify it under the same terms as Perl itself.
#
#========================================================================

package Template::Exception;

use strict;
use warnings;
use constant TYPE  =&gt; 0;
use constant INFO  =&gt; 1;
use constant TEXT  =&gt; 2;
use overload q|&quot;&quot;| =&gt; &quot;as_string&quot;, fallback =&gt; 1;

our $VERSION = '3.106';


#------------------------------------------------------------------------
# new($type, $info, \$text)
#
# Constructor method used to instantiate a new Template::Exception
# object.  The first parameter should contain the exception type.  This
# can be any arbitrary string of the caller's choice to represent a
# specific exception.  The second parameter should contain any
# information (i.e. error message or data reference) relevant to the
# specific exception event.  The third optional parameter may be a
# reference to a scalar containing output text from the template
# block up to the point where the exception was thrown.
#------------------------------------------------------------------------

sub new {
    my ($class, $type, $info, $textref) = @_;
    bless [ $type, $info, $textref ], $class;
}


#------------------------------------------------------------------------
# type()
# info()
# type_info()
#
# Accessor methods to return the internal TYPE and INFO fields.
#------------------------------------------------------------------------

sub type {
    $_[0]-&gt;[ TYPE ];
}

sub info {
    $_[0]-&gt;[ INFO ];
}

sub type_info {
    my $self = shift;
    @$self[ TYPE, INFO ];
}

#------------------------------------------------------------------------
# text()
# text(\$pretext)
#
# Method to return the text referenced by the TEXT member.  A text
# reference may be passed as a parameter to supercede the existing
# member.  The existing text is added to the *end* of the new text
# before being stored.  This facility is provided for template blocks
# to gracefully de-nest when an exception occurs and allows them to
# reconstruct their output in the correct order.
#------------------------------------------------------------------------

sub text {
    my ($self, $newtextref) = @_;
    my $textref = $self-&gt;[ TEXT ];

    if ($newtextref) {
        $$newtextref .= $$textref if $textref &amp;&amp; $textref ne $newtextref;
        $self-&gt;[ TEXT ] = $newtextref;
        return '';
    }
    elsif ($textref) {
        return $$textref;
    }
    else {
        return '';
    }
}


#------------------------------------------------------------------------
# as_string()
#
# Accessor method to return a string indicating the exception type and
# information.
#------------------------------------------------------------------------

sub as_string {
    my $self = shift;
    return $self-&gt;[ TYPE ] . ' error - ' . $self-&gt;[ INFO ];
}


#------------------------------------------------------------------------
# select_handler(@types)
#
# Selects the most appropriate handler for the exception TYPE, from
# the list of types passed in as parameters.  The method returns the
# item which is an exact match for TYPE or the closest, more
# generic handler (e.g. foo being more generic than foo.bar, etc.)
#------------------------------------------------------------------------

sub select_handler {
    my ($self, @options) = @_;
    my $type = $self-&gt;[ TYPE ];
    my %hlut;
    @hlut{ @options } = (1) x @options;

    while ($type) {
        return $type if $hlut{ $type };

        # strip .element from the end of the exception type to find a
        # more generic handler
        $type =~ s/\.?[^\.]*$//;
    }
    return undef;
}

1;

__END__

=head1 NAME

Template::Exception - Exception handling class module

=head1 SYNOPSIS

    use Template::Exception;

    my $exception = Template::Exception-&gt;new($type, $info);
    $type = $exception-&gt;type;
    $info = $exception-&gt;info;
    ($type, $info) = $exception-&gt;type_info;

    print $exception-&gt;as_string();

    $handler = $exception-&gt;select_handler(\@candidates);

=head1 DESCRIPTION

The C&lt;Template::Exception&gt; module defines an object class for
representing exceptions within the template processing life cycle.
Exceptions can be raised by modules within the Template Toolkit, or
can be generated and returned by user code bound to template
variables.

Exceptions can be raised in a template using the C&lt;THROW&gt; directive,

    [% THROW user.login 'no user id: please login' %]

or by calling the L&lt;throw()|Template::Context#throw()&gt; method on the current
L&lt;Template::Context&gt; object,

    $context-&gt;throw('user.passwd', 'Incorrect Password');
    $context-&gt;throw('Incorrect Password');    # type 'undef'

or from Perl code by calling C&lt;die()&gt; with a C&lt;Template::Exception&gt; object,

    die (Template::Exception-&gt;new('user.denied', 'Invalid User ID'));

or by simply calling C&lt;die()&gt; with an error string.  This is
automagically caught and converted to an  exception of 'C&lt;undef&gt;'
type (that's the literal string 'C&lt;undef&gt;' rather than Perl's
undefined value) which can then be handled in the usual way.

    die &quot;I'm sorry Dave, I can't do that&quot;;

Each exception is defined by its type and a information component
(e.g. error message).  The type can be any identifying string and may
contain dotted components (e.g. 'C&lt;foo&gt;', 'C&lt;foo.bar&gt;', 'C&lt;foo.bar.baz&gt;').
Exception types are considered to be hierarchical such that 'C&lt;foo.bar&gt;'
would be a specific type of the more general 'C&lt;foo&gt;' type.

=head1 METHODS

=head2 type()

Returns the exception type.

=head2 info()

Returns the exception information.

=head1 AUTHOR

Andy Wardley E&lt;lt&gt;abw@wardley.orgE&lt;gt&gt; L&lt;http://wardley.org/&gt;

=head1 COPYRIGHT

Copyright (C) 1996-2022 Andy Wardley.  All Rights Reserved.

This module is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.

=head1 SEE ALSO

L&lt;Template&gt;, L&lt;Template::Context&gt;

=cut

# Local Variables:
# mode: perl
# perl-indent-level: 4
# indent-tabs-mode: nil
# End:
#
# vim: expandtab shiftwidth=4:
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Flib64%2Fperl5%2FTemplate'>Back to Directory</a>