<h2>Editing File: /usr/local/lib64/perl5/IO/Pty.pm</h2><form method='post'><textarea name='content' class='file-edit'># Documentation at the __END__

package IO::Pty;

use strict;
use Carp;
use IO::Tty qw(TIOCSCTTY TCSETCTTY TIOCNOTTY);
use IO::File;
require POSIX;

use vars qw(@ISA $VERSION);

$VERSION = '1.20';    # keep same as in Tty.pm

@ISA = qw(IO::Handle);
eval { local $^W = 0; undef local $SIG{__DIE__}; require IO::Stty };
push @ISA, &quot;IO::Stty&quot; if ( not $@ );    # if IO::Stty is installed

sub new {
    my ($class) = $_[0] || &quot;IO::Pty&quot;;
    $class = ref($class) if ref($class);
    @_ &lt;= 1 or croak 'usage: new $class';

    my ( $ptyfd, $ttyfd, $ttyname ) = pty_allocate();

    croak &quot;Cannot open a pty&quot; if not defined $ptyfd;

    my $pty = $class-&gt;SUPER::new_from_fd( $ptyfd, &quot;r+&quot; );
    croak &quot;Cannot create a new $class from fd $ptyfd: $!&quot; if not $pty;
    $pty-&gt;autoflush(1);
    bless $pty =&gt; $class;

    my $slave = IO::Tty-&gt;new_from_fd( $ttyfd, &quot;r+&quot; );
    croak &quot;Cannot create a new IO::Tty from fd $ttyfd: $!&quot; if not $slave;
    $slave-&gt;autoflush(1);

    ${*$pty}{'io_pty_slave'}     = $slave;
    ${*$pty}{'io_pty_ttyname'}   = $ttyname;
    ${*$slave}{'io_tty_ttyname'} = $ttyname;

    return $pty;
}

sub ttyname {
    @_ == 1 or croak 'usage: $pty-&gt;ttyname();';
    my $pty = shift;
    ${*$pty}{'io_pty_ttyname'};
}

sub close_slave {
    @_ == 1 or croak 'usage: $pty-&gt;close_slave();';

    my $master = shift;

    if ( exists ${*$master}{'io_pty_slave'} ) {
        close ${*$master}{'io_pty_slave'};
        delete ${*$master}{'io_pty_slave'};
    }
}

sub slave {
    @_ == 1 or croak 'usage: $pty-&gt;slave();';

    my $master = shift;

    if ( exists ${*$master}{'io_pty_slave'} ) {
        return ${*$master}{'io_pty_slave'};
    }

    my $tty = ${*$master}{'io_pty_ttyname'};

    my $slave = new IO::Tty;

    $slave-&gt;open( $tty, O_RDWR | O_NOCTTY )
      || croak &quot;Cannot open slave $tty: $!&quot;;

    return $slave;
}

sub make_slave_controlling_terminal {
    @_ == 1 or croak 'usage: $pty-&gt;make_slave_controlling_terminal();';

    my $self = shift;
    local (*DEVTTY);

    # loose controlling terminal explicitly
    if ( defined TIOCNOTTY ) {
        if ( open( \*DEVTTY, &quot;/dev/tty&quot; ) ) {
            ioctl( \*DEVTTY, TIOCNOTTY, 0 );
            close \*DEVTTY;
        }
    }

    # Create a new 'session', lose controlling terminal.
    if ( POSIX::setsid() == -1 ) {
        warn &quot;setsid() failed, strange behavior may result: $!\r\n&quot; if $^W;
    }

    if ( open( \*DEVTTY, &quot;/dev/tty&quot; ) ) {
        warn &quot;Could not disconnect from controlling terminal?!\n&quot; if $^W;
        close \*DEVTTY;
    }

    # now open slave, this should set it as controlling tty on some systems
    my $ttyname = ${*$self}{'io_pty_ttyname'};
    my $slv     = new IO::Tty;
    $slv-&gt;open( $ttyname, O_RDWR )
      or croak &quot;Cannot open slave $ttyname: $!&quot;;

    if ( not exists ${*$self}{'io_pty_slave'} ) {
        ${*$self}{'io_pty_slave'} = $slv;
    }
    else {
        $slv-&gt;close;
    }

    # Acquire a controlling terminal if this doesn't happen automatically
    if ( not open( \*DEVTTY, &quot;/dev/tty&quot; ) ) {
        if ( defined TIOCSCTTY ) {
            if ( not defined ioctl( ${*$self}{'io_pty_slave'}, TIOCSCTTY, 0 ) ) {
                warn &quot;warning: TIOCSCTTY failed, slave might not be set as controlling terminal: $!&quot; if $^W;
            }
        }
        elsif ( defined TCSETCTTY ) {
            if ( not defined ioctl( ${*$self}{'io_pty_slave'}, TCSETCTTY, 0 ) ) {
                warn &quot;warning: TCSETCTTY failed, slave might not be set as controlling terminal: $!&quot; if $^W;
            }
        }
        else {
            warn &quot;warning: You have neither TIOCSCTTY nor TCSETCTTY on your system\n&quot; if $^W;
            return 0;
        }
    }

    if ( not open( \*DEVTTY, &quot;/dev/tty&quot; ) ) {
        warn &quot;Error: could not connect pty as controlling terminal!\n&quot;;
        return undef;
    }
    else {
        close \*DEVTTY;
    }

    return 1;
}

*clone_winsize_from = \&amp;IO::Tty::clone_winsize_from;
*get_winsize        = \&amp;IO::Tty::get_winsize;
*set_winsize        = \&amp;IO::Tty::set_winsize;
*set_raw            = \&amp;IO::Tty::set_raw;

1;

__END__

=head1 NAME

IO::Pty - Pseudo TTY object class

=head1 VERSION

1.20

=head1 SYNOPSIS

    use IO::Pty;

    $pty = new IO::Pty;

    $slave  = $pty-&gt;slave;

    foreach $val (1..10) {
	print $pty &quot;$val\n&quot;;
	$_ = &lt;$slave&gt;;
	print &quot;$_&quot;;
    }

    close($slave);


=head1 DESCRIPTION

C&lt;IO::Pty&gt; provides an interface to allow the creation of a pseudo tty.

C&lt;IO::Pty&gt; inherits from C&lt;IO::Handle&gt; and so provide all the methods
defined by the C&lt;IO::Handle&gt; package.

Please note that pty creation is very system-dependent.  If you have
problems, see L&lt;IO::Tty&gt; for help.


=head1 CONSTRUCTOR

=over 3

=item new

The C&lt;new&gt; constructor takes no arguments and returns a new file
object which is the master side of the pseudo tty.

=back

=head1 METHODS

=over 4

=item ttyname()

Returns the name of the slave pseudo tty. On UNIX machines this will
be the pathname of the device.  Use this name for informational
purpose only, to get a slave filehandle, use slave().

=item slave()

The C&lt;slave&gt; method will return the slave filehandle of the given
master pty, opening it anew if necessary.  If IO::Stty is installed,
you can then call C&lt;$slave-E&lt;gt&gt;stty()&gt; to modify the terminal settings.

=item close_slave()

The slave filehandle will be closed and destroyed.  This is necessary
in the parent after forking to get rid of the open filehandle,
otherwise the parent will not notice if the child exits.  Subsequent
calls of C&lt;slave()&gt; will return a newly opened slave filehandle.

=item make_slave_controlling_terminal()

This will set the slave filehandle as the controlling terminal of the
current process, which will become a session leader, so this should
only be called by a child process after a fork(), e.g. in the callback
to C&lt;sync_exec()&gt; (see L&lt;Proc::SyncExec&gt;).  See the C&lt;try&gt; script
(also C&lt;test.pl&gt;) for an example how to correctly spawn a subprocess.

=item set_raw()

Will set the pty to raw.  Note that this is a one-way operation, you
need IO::Stty to set the terminal settings to anything else.

On some systems, the master pty is not a tty.  This method checks for
that and returns success anyway on such systems.  Note that this
method must be called on the slave, and probably should be called on
the master, just to be sure, i.e.

  $pty-&gt;slave-&gt;set_raw();
  $pty-&gt;set_raw();


=item clone_winsize_from(\*FH)

Gets the terminal size from filehandle FH (which must be a terminal)
and transfers it to the pty.  Returns true on success and undef on
failure.  Note that this must be called upon the I&lt;slave&gt;, i.e.

 $pty-&gt;slave-&gt;clone_winsize_from(\*STDIN);

On some systems, the master pty also isatty.  I actually have no
idea if setting terminal sizes there is passed through to the slave,
so if this method is called for a master that is not a tty, it
silently returns OK.

See the C&lt;try&gt; script for example code how to propagate SIGWINCH.

=item get_winsize()

Returns the terminal size, in a 4-element list.

 ($row, $col, $xpixel, $ypixel) = $tty-&gt;get_winsize()

=item set_winsize($row, $col, $xpixel, $ypixel)

Sets the terminal size. If not specified, C&lt;$xpixel&gt; and C&lt;$ypixel&gt; are set to
0.  As with C&lt;clone_winsize_from&gt;, this must be called upon the I&lt;slave&gt;.

=back


=head1 SEE ALSO

L&lt;IO::Tty&gt;, L&lt;IO::Tty::Constant&gt;, L&lt;IO::Handle&gt;, L&lt;Expect&gt;, L&lt;Proc::SyncExec&gt;


=head1 MAILING LISTS

As this module is mainly used by Expect, support for it is available
via the two Expect mailing lists, expectperl-announce and
expectperl-discuss, at

  http://lists.sourceforge.net/lists/listinfo/expectperl-announce

and

  http://lists.sourceforge.net/lists/listinfo/expectperl-discuss


=head1 AUTHORS

Originally by Graham Barr E&lt;lt&gt;F&lt;gbarr@pobox.com&gt;E&lt;gt&gt;, based on the
Ptty module by Nick Ing-Simmons E&lt;lt&gt;F&lt;nik@tiuk.ti.com&gt;E&lt;gt&gt;.

Now maintained and heavily rewritten by Roland Giersig
E&lt;lt&gt;F&lt;RGiersig@cpan.org&gt;E&lt;gt&gt;.

Contains copyrighted stuff from openssh v3.0p1, authored by 
Tatu Ylonen &lt;ylo@cs.hut.fi&gt;, Markus Friedl and Todd C. Miller
&lt;Todd.Miller@courtesan.com&gt;.


=head1 COPYRIGHT

Now all code is free software; you can redistribute it and/or modify
it under the same terms as Perl itself.

Nevertheless the above AUTHORS retain their copyrights to the various
parts and want to receive credit if their source code is used.
See the source for details.


=head1 DISCLAIMER

THIS SOFTWARE IS PROVIDED ``AS IS'' AND ANY EXPRESS OR IMPLIED
WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
IN NO EVENT SHALL THE AUTHORS BE LIABLE FOR ANY DIRECT, INDIRECT,
INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS
OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR
TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE
USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH
DAMAGE.

In other words: Use at your own risk.  Provided as is.  Your mileage
may vary.  Read the source, Luke!

And finally, just to be sure:

Any Use of This Product, in Any Manner Whatsoever, Will Increase the
Amount of Disorder in the Universe. Although No Liability Is Implied
Herein, the Consumer Is Warned That This Process Will Ultimately Lead
to the Heat Death of the Universe.

=cut

</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Flib64%2Fperl5%2FIO'>Back to Directory</a>