<h2>Editing File: /usr/local/cpanel/3rdparty/perl/542/lib/pod/perldbmfilter.pod</h2><form method='post'><textarea name='content' class='file-edit'>=head1 NAME

perldbmfilter - Perl DBM Filters

=head1 SYNOPSIS

    $db = tie %hash, 'DBM', ...

    $old_filter = $db-&gt;filter_store_key  ( sub { ... } );
    $old_filter = $db-&gt;filter_store_value( sub { ... } );
    $old_filter = $db-&gt;filter_fetch_key  ( sub { ... } );
    $old_filter = $db-&gt;filter_fetch_value( sub { ... } );

=head1 DESCRIPTION

The four C&lt;filter_*&gt; methods shown above are available in all the DBM
modules that ship with Perl, namely DB_File, GDBM_File, NDBM_File,
ODBM_File and SDBM_File.

Each of the methods works identically, and is used to install (or
uninstall) a single DBM Filter. The only difference between them is the
place that the filter is installed.

To summarise:

=over 5

=item B&lt;filter_store_key&gt;

If a filter has been installed with this method, it will be invoked
every time you write a key to a DBM database.

=item B&lt;filter_store_value&gt;

If a filter has been installed with this method, it will be invoked
every time you write a value to a DBM database.

=item B&lt;filter_fetch_key&gt;

If a filter has been installed with this method, it will be invoked
every time you read a key from a DBM database.

=item B&lt;filter_fetch_value&gt;

If a filter has been installed with this method, it will be invoked
every time you read a value from a DBM database.

=back

You can use any combination of the methods from none to all four.

All filter methods return the existing filter, if present, or C&lt;undef&gt;
if not.

To delete a filter pass C&lt;undef&gt; to it.

=head2 The Filter

When each filter is called by Perl, a local copy of C&lt;$_&gt; will contain
the key or value to be filtered. Filtering is achieved by modifying
the contents of C&lt;$_&gt;. The return code from the filter is ignored.

=head2 An Example: the NULL termination problem

DBM Filters are useful for a class of problems where you I&lt;always&gt;
want to make the same transformation to all keys, all values or both.

For example, consider the following scenario. You have a DBM database
that you need to share with a third-party C application. The C application
assumes that I&lt;all&gt; keys and values are NULL terminated. Unfortunately
when Perl writes to DBM databases it doesn't use NULL termination, so
your Perl application will have to manage NULL termination itself. When
you write to the database you will have to use something like this:

    $hash{&quot;$key\0&quot;} = &quot;$value\0&quot;;

Similarly the NULL needs to be taken into account when you are considering
the length of existing keys/values.

It would be much better if you could ignore the NULL terminations issue
in the main application code and have a mechanism that automatically
added the terminating NULL to all keys and values whenever you write to
the database and have them removed when you read from the database. As I'm
sure you have already guessed, this is a problem that DBM Filters can
fix very easily.

    use v5.36;
    use SDBM_File;
    use Fcntl;

    my %hash;
    my $filename = &quot;filt&quot;;
    unlink $filename;

    my $db = tie(%hash, 'SDBM_File', $filename, O_RDWR|O_CREAT, 0640)
      or die &quot;Cannot open $filename: $!\n&quot;;

    # Install DBM Filters
    $db-&gt;filter_fetch_key  ( sub { s/\0$//    } );
    $db-&gt;filter_store_key  ( sub { $_ .= &quot;\0&quot; } );
    $db-&gt;filter_fetch_value( 
        sub { no warnings 'uninitialized'; s/\0$// } );
    $db-&gt;filter_store_value( sub { $_ .= &quot;\0&quot; } );

    $hash{&quot;abc&quot;} = &quot;def&quot;;
    my $x = $hash{&quot;ABC&quot;};
    # ...
    undef $db;
    untie %hash;

The code above uses SDBM_File, but it will work with any of the DBM
modules.

Hopefully the contents of each of the filters should be
self-explanatory. Both &quot;fetch&quot; filters remove the terminating NULL,
and both &quot;store&quot; filters add a terminating NULL.


=head2 Another Example: Key is a C int

Here is another real-life example. By default, whenever Perl writes to
a DBM database it always writes the key and value as strings. So when
you use this:

    $hash{12345} = &quot;something&quot;;

the key 12345 will get stored in the DBM database as the 5 byte string
&quot;12345&quot;. If you actually want the key to be stored in the DBM database
as a C int, you will have to use C&lt;pack&gt; when writing, and C&lt;unpack&gt;
when reading.

Here is a DBM Filter that does it:

    use v5.36;
    use DB_File;
    my %hash;
    my $filename = &quot;filt&quot;;
    unlink $filename;


    my $db = tie %hash, 'DB_File', $filename, O_CREAT|O_RDWR, 0666,
        $DB_HASH or die &quot;Cannot open $filename: $!\n&quot;;

    $db-&gt;filter_fetch_key  ( sub { $_ = unpack(&quot;i&quot;, $_) } );
    $db-&gt;filter_store_key  ( sub { $_ = pack (&quot;i&quot;, $_) } );
    $hash{123} = &quot;def&quot;;
    # ...
    undef $db;
    untie %hash;

The code above uses DB_File, but again it will work with any of the
DBM modules.

This time only two filters have been used; we only need to manipulate
the contents of the key, so it wasn't necessary to install any value
filters.

=head1 SEE ALSO

L&lt;DB_File&gt;, L&lt;GDBM_File&gt;, L&lt;NDBM_File&gt;, L&lt;ODBM_File&gt; and L&lt;SDBM_File&gt;.

=head1 AUTHOR

Paul Marquess

</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fcpanel%2F3rdparty%2Fperl%2F542%2Flib%2Fpod'>Back to Directory</a>