<h2>Editing File: /usr/local/cpanel/3rdparty/perl/542/lib/bigint.pm</h2><form method='post'><textarea name='content' class='file-edit'>package bigint;

use strict;
use warnings;

use Carp qw&lt; carp croak &gt;;

our $VERSION = '0.67';

use Exporter;
our @ISA            = qw( Exporter );
our @EXPORT_OK      = qw( PI e bpi bexp hex oct );
our @EXPORT         = qw( inf NaN );

use overload;

my $obj_class = &quot;Math::BigInt&quot;;

##############################################################################

sub accuracy {
    my $self = shift;
    $obj_class -&gt; accuracy(@_);
}

sub precision {
    my $self = shift;
    $obj_class -&gt; precision(@_);
}

sub round_mode {
    my $self = shift;
    $obj_class -&gt; round_mode(@_);
}

sub div_scale {
    my $self = shift;
    $obj_class -&gt; div_scale(@_);
}

sub in_effect {
    my $level = shift || 0;
    my $hinthash = (caller($level))[10];
    $hinthash-&gt;{bigint};
}

sub _float_constant {
    my $str = shift;

    # We can't pass input directly to new() because of the way it handles the
    # combination of non-integers with no upgrading. Such cases are by
    # Math::BigInt returned as NaN, but we truncate to an integer.

    # See if we can convert the input string to a string using a normalized form
    # consisting of the significand as a signed integer, the character &quot;e&quot;, and
    # the exponent as a signed integer, e.g., &quot;+0e+0&quot;, &quot;+314e-2&quot;, and &quot;-1e+3&quot;.

    my $nstr;

    if (
        # See if it is an octal number. An octal number like '0377' is also
        # accepted by the functions parsing decimal and hexadecimal numbers, so
        # handle octal numbers before decimal and hexadecimal numbers.

        $str =~ /^0(?:[Oo]|_*[0-7])/ and
        $nstr = Math::BigInt -&gt; oct_str_to_dec_flt_str($str)

          or

        # See if it is decimal number.

        $nstr = Math::BigInt -&gt; dec_str_to_dec_flt_str($str)

          or

        # See if it is a hexadecimal number. Every hexadecimal number has a
        # prefix, but the functions parsing numbers don't require it, so check
        # to see if it actually is a hexadecimal number.

        $str =~ /^0[Xx]/ and
        $nstr = Math::BigInt -&gt; hex_str_to_dec_flt_str($str)

          or

        # See if it is a binary numbers. Every binary number has a prefix, but
        # the functions parsing numbers don't require it, so check to see if it
        # actually is a binary number.

        $str =~ /^0[Bb]/ and
        $nstr = Math::BigInt -&gt; bin_str_to_dec_flt_str($str))
    {
        my $pos      = index($nstr, 'e');
        my $expo_sgn = substr($nstr, $pos + 1, 1);
        my $sign     = substr($nstr, 0, 1);
        my $mant     = substr($nstr, 1, $pos - 1);
        my $mant_len = CORE::length($mant);
        my $expo     = substr($nstr, $pos + 2);

        if ($expo_sgn eq '-') {
            if ($mant_len &lt;= $expo) {
                return $obj_class -&gt; bzero();                   # underflow
            } else {
                $mant = substr $mant, 0, $mant_len - $expo;     # truncate
                return $obj_class -&gt; new($sign . $mant);
            }
        } else {
            $mant .= &quot;0&quot; x $expo;                               # pad with zeros
            return $obj_class -&gt; new($sign . $mant);
        }
    }

    # If we get here, there is a bug in the code above this point.

    warn &quot;Internal error: unable to handle literal constant '$str'.&quot;,
      &quot; This is a bug, so please report this to the module author.&quot;;
    return $obj_class -&gt; bnan();
}

#############################################################################
# the following two routines are for &quot;use bigint qw/hex oct/;&quot;:

use constant LEXICAL =&gt; $] &gt; 5.009004;

# Internal function with the same semantics as CORE::hex(). This function is
# not used directly, but rather by other front-end functions.

sub _hex_core {
    my $str = shift;

    # Strip off, clean, and parse as much as we can from the beginning.

    my $x;
    if ($str =~ s/ ^ ( 0? [xX] )? ( [0-9a-fA-F]* ( _ [0-9a-fA-F]+ )* ) //x) {
        my $chrs = $2;
        $chrs =~ tr/_//d;
        $chrs = '0' unless CORE::length $chrs;
        $x = $obj_class -&gt; from_hex($chrs);
    } else {
        $x = $obj_class -&gt; bzero();
    }

    # Warn about trailing garbage.

    if (CORE::length($str)) {
        require Carp;
        Carp::carp(sprintf(&quot;Illegal hexadecimal digit '%s' ignored&quot;,
                           substr($str, 0, 1)));
    }

    return $x;
}

# Internal function with the same semantics as CORE::oct(). This function is
# not used directly, but rather by other front-end functions.

sub _oct_core {
    my $str = shift;

    $str =~ s/^\s*//;

    # Hexadecimal input.

    return _hex_core($str) if $str =~ /^0?[xX]/;

    my $x;

    # Binary input.

    if ($str =~ /^0?[bB]/) {

        # Strip off, clean, and parse as much as we can from the beginning.

        if ($str =~ s/ ^ ( 0? [bB] )? ( [01]* ( _ [01]+ )* ) //x) {
            my $chrs = $2;
            $chrs =~ tr/_//d;
            $chrs = '0' unless CORE::length $chrs;
            $x = $obj_class -&gt; from_bin($chrs);
        }

        # Warn about trailing garbage.

        if (CORE::length($str)) {
            require Carp;
            Carp::carp(sprintf(&quot;Illegal binary digit '%s' ignored&quot;,
                               substr($str, 0, 1)));
        }

        return $x;
    }

    # Octal input. Strip off, clean, and parse as much as we can from the
    # beginning.

    if ($str =~ s/ ^ ( 0? [oO] )? ( [0-7]* ( _ [0-7]+ )* ) //x) {
        my $chrs = $2;
        $chrs =~ tr/_//d;
        $chrs = '0' unless CORE::length $chrs;
        $x = $obj_class -&gt; from_oct($chrs);
    }

    # Warn about trailing garbage. CORE::oct() only warns about 8 and 9, but it
    # is more helpful to warn about all invalid digits.

    if (CORE::length($str)) {
        require Carp;
        Carp::carp(sprintf(&quot;Illegal octal digit '%s' ignored&quot;,
                           substr($str, 0, 1)));
    }

    return $x;
}

{
    my $proto = LEXICAL ? '_' : ';$';
    eval '
sub hex(' . $proto . ') {' . &lt;&lt;'.';
    my $str = @_ ? $_[0] : $_;
    _hex_core($str);
}
.

    eval '
sub oct(' . $proto . ') {' . &lt;&lt;'.';
    my $str = @_ ? $_[0] : $_;
    _oct_core($str);
}
.
}

#############################################################################
# the following two routines are for Perl 5.9.4 or later and are lexical

my ($prev_oct, $prev_hex, $overridden);

if (LEXICAL) { eval &lt;&lt;'.' }
sub _hex(_) {
    my $hh = (caller 0)[10];
    return $$hh{bigint}   ? bigint::_hex_core($_[0])
         : $$hh{bigfloat} ? bigfloat::_hex_core($_[0])
         : $$hh{bigrat}   ? bigrat::_hex_core($_[0])
         : $prev_hex      ? &amp;$prev_hex($_[0])
         : CORE::hex($_[0]);
}

sub _oct(_) {
    my $hh = (caller 0)[10];
    return $$hh{bigint}   ? bigint::_oct_core($_[0])
         : $$hh{bigfloat} ? bigfloat::_oct_core($_[0])
         : $$hh{bigrat}   ? bigrat::_oct_core($_[0])
         : $prev_oct      ? &amp;$prev_oct($_[0])
         : CORE::oct($_[0]);
}
.

sub _override {
    return if $overridden;
    $prev_oct = *CORE::GLOBAL::oct{CODE};
    $prev_hex = *CORE::GLOBAL::hex{CODE};
    no warnings 'redefine';
    *CORE::GLOBAL::oct = \&amp;_oct;
    *CORE::GLOBAL::hex = \&amp;_hex;
    $overridden = 1;
}

sub unimport {
    delete $^H{bigint};         # no longer in effect
    overload::remove_constant('binary', '', 'float', '', 'integer');
}

sub import {
    my $class = shift;

    $^H{bigint} = 1;            # we are in effect
    delete $^H{bigfloat};
    delete $^H{bigrat};

    # for newer Perls always override hex() and oct() with a lexical version:
    if (LEXICAL) {
        _override();
    }

    my @import = ();
    my @a = ();                         # unrecognized arguments
    my $ver;                            # version? trace?

    while (@_) {
        my $param = shift;

        # Accuracy.

        if ($param =~ /^a(ccuracy)?$/) {
            push @import, 'accuracy', shift();
            next;
        }

        # Precision.

        if ($param =~ /^p(recision)?$/) {
            push @import, 'precision', shift();
            next;
        }

        # Rounding mode.

        if ($param eq 'round_mode') {
            push @import, 'round_mode', shift();
            next;
        }

        # Backend library.

        if ($param =~ /^(l|lib|try|only)$/) {
            push @import, $param eq 'l' ? 'lib' : $param;
            push @import, shift() if @_;
            next;
        }

        if ($param =~ /^(v|version)$/) {
            $ver = 1;
            next;
        }

        if ($param =~ /^(t|trace)$/) {
            $obj_class .= &quot;::Trace&quot;;
            eval &quot;require $obj_class&quot;;
            die $@ if $@;
            next;
        }

        if ($param =~ /^(PI|e|bexp|bpi|hex|oct)\z/) {
            push @a, $param;
            next;
        }

        croak(&quot;Unknown option '$param'&quot;);
    }

    eval &quot;require $obj_class&quot;;
    die $@ if $@;
    $obj_class -&gt; import(@import);

    if ($ver) {
        printf &quot;%-31s v%s\n&quot;, $class, $class -&gt; VERSION();
        printf &quot; lib =&gt; %-23s v%s\n&quot;,
          $obj_class -&gt; config(&quot;lib&quot;), $obj_class -&gt; config(&quot;lib_version&quot;);
        printf &quot;%-31s v%s\n&quot;, $obj_class, $obj_class -&gt; VERSION();
        exit;
    }

    $class -&gt; export_to_level(1, $class, @a);   # export inf, NaN, etc.

    overload::constant

        # This takes care each number written as decimal integer and within the
        # range of what perl can represent as an integer, e.g., &quot;314&quot;, but not
        # &quot;3141592653589793238462643383279502884197169399375105820974944592307&quot;.

        integer =&gt; sub {
            #printf &quot;Value '%s' handled by the 'integer' sub.\n&quot;, $_[0];
            my $str = shift;
            return $obj_class -&gt; new($str);
        },

        # This takes care of each number written with a decimal point and/or
        # using floating point notation, e.g., &quot;3.&quot;, &quot;3.0&quot;, &quot;3.14e+2&quot; (decimal),
        # &quot;0b1.101p+2&quot; (binary), &quot;03.14p+2&quot; and &quot;0o3.14p+2&quot; (octal), and
        # &quot;0x3.14p+2&quot; (hexadecimal).

        float =&gt; sub {
            #printf &quot;# Value '%s' handled by the 'float' sub.\n&quot;, $_[0];
            _float_constant(shift);
        },

        # Take care of each number written as an integer (no decimal point or
        # exponent) using binary, octal, or hexadecimal notation, e.g., &quot;0b101&quot;
        # (binary), &quot;0314&quot; and &quot;0o314&quot; (octal), and &quot;0x314&quot; (hexadecimal).

        binary =&gt; sub {
            #printf &quot;# Value '%s' handled by the 'binary' sub.\n&quot;, $_[0];
            my $str = shift;
            return $obj_class -&gt; new($str) if $str =~ /^0[XxBb]/;
            $obj_class -&gt; from_oct($str);
        };
}

sub inf () { $obj_class -&gt; binf(); }
sub NaN () { $obj_class -&gt; bnan(); }

sub PI  () { $obj_class -&gt; new(3); }
sub e   () { $obj_class -&gt; new(2); }

sub bpi ($) { $obj_class -&gt; new(3); }

sub bexp ($$) {
    my $x = $obj_class -&gt; new(shift);
    $x -&gt; bexp(@_);
}

1;

__END__

=pod

=head1 NAME

bigint - transparent big integer support for Perl

=head1 SYNOPSIS

    use bigint;

    $x = 2 + 4.5;                       # Math::BigInt 6
    print 2 ** 512;                     # Math::BigInt 134...096
    print inf + 42;                     # Math::BigInt inf
    print NaN * 7;                      # Math::BigInt NaN
    print hex(&quot;0x1234567890123490&quot;);    # Perl v5.10.0 or later

    {
        no bigint;
        print 2 ** 256;                 # a normal Perl scalar now
    }

    # for older Perls, import into current package:
    use bigint qw/hex oct/;
    print hex(&quot;0x1234567890123490&quot;);
    print oct(&quot;01234567890123490&quot;);

=head1 DESCRIPTION

All numeric literal in the given scope are converted to Math::BigInt objects.
Numeric literal that represent non-integers are truncated to an integer. All
results of expressions are also truncated to integer.

All operators (including basic math operations) except the range operator C&lt;..&gt;
are overloaded.

Unlike the L&lt;integer&gt; pragma, the C&lt;bigint&gt; pragma creates integers that are
only limited in their size by the available memory.

So, the following:

    use bigint;
    $x = 1234;

creates a Math::BigInt and stores a reference to in $x. This happens
transparently and behind your back, so to speak.

You can see this with the following:

    perl -Mbigint -le 'print ref(1234)'

Since numbers are actually objects, you can call all the usual methods from
Math::BigFloat on them. This even works to some extent on expressions:

    perl -Mbigint -le '$x = 1234; print $x-&gt;bdec()'
    perl -Mbigint -le 'print 1234-&gt;copy()-&gt;binc();'
    perl -Mbigint -le 'print 1234-&gt;copy()-&gt;binc-&gt;badd(6);'
    perl -Mbigint -le 'print +(1234)-&gt;copy()-&gt;binc()'

(Note that print doesn't do what you expect if the expression starts with
'(' hence the C&lt;+&gt;)

You can even chain the operations together as usual:

    perl -Mbigint -le 'print 1234-&gt;copy()-&gt;binc-&gt;badd(6);'
    1241

Please note the following does not work as expected (prints nothing), since
overloading of '..' is not yet possible in Perl (as of v5.8.0):

    perl -Mbigint -le 'for (1..2) { print ref($_); }'

=head2 use integer vs. use bigint

There are some difference between C&lt;use integer&gt; and C&lt;use bigint&gt;.

Whereas C&lt;use integer&gt; is limited to what can be handled as a Perl scalar, C&lt;use
bigint&gt; can handle arbitrarily large integers.

Also, C&lt;use integer&gt; does affect assignments to variables and the return value
of some functions. C&lt;use bigint&gt; truncates these results to integer:

    # perl -Minteger -wle 'print 3.2'
    3.2
    # perl -Minteger -wle 'print 3.2 + 0'
    3
    # perl -Mbigint -wle 'print 3.2'
    3
    # perl -Mbigint -wle 'print 3.2 + 0'
    3

    # perl -Mbigint -wle 'print exp(1) + 0'
    2
    # perl -Mbigint -wle 'print exp(1)'
    2
    # perl -Minteger -wle 'print exp(1)'
    2.71828182845905
    # perl -Minteger -wle 'print exp(1) + 0'
    2

In practice this seldom makes a difference for small integers as B&lt;parts and
results&gt; of expressions are truncated anyway, but this can, for instance, affect
the return value of subroutines:

    sub three_integer { use integer; return 3.2; }
    sub three_bigint { use bigint; return 3.2; }

    print three_integer(), &quot; &quot;, three_bigint(),&quot;\n&quot;;    # prints &quot;3.2 3&quot;

=head2 Options

C&lt;bigint&gt; recognizes some options that can be passed while loading it via
C&lt;use&gt;. The following options exist:

=over 4

=item a or accuracy

This sets the accuracy for all math operations. The argument must be greater
than or equal to zero. See Math::BigInt's bround() method for details.

    perl -Mbigint=a,2 -le 'print 12345+1'

Note that setting precision and accuracy at the same time is not possible.

=item p or precision

This sets the precision for all math operations. The argument can be any
integer. Negative values mean a fixed number of digits after the dot, and are
ignored since all operations happen in integer space. A positive value rounds to
this digit left from the dot. 0 means round to integer. See Math::BigInt's
bfround() method for details.

    perl -mbigint=p,5 -le 'print 123456789+123'

Note that setting precision and accuracy at the same time is not possible.

=item t or trace

This enables a trace mode and is primarily for debugging.

=item l, lib, try, or only

Load a different math lib, see L&lt;Math Library&gt;.

    perl -Mbigint=l,GMP -e 'print 2 ** 512'
    perl -Mbigint=lib,GMP -e 'print 2 ** 512'
    perl -Mbigint=try,GMP -e 'print 2 ** 512'
    perl -Mbigint=only,GMP -e 'print 2 ** 512'

=item hex

Override the built-in hex() method with a version that can handle big numbers.
This overrides it by exporting it to the current package. Under Perl v5.10.0 and
higher, this is not necessary, as hex() is lexically overridden in the current
scope whenever the C&lt;bigint&gt; pragma is active.

=item oct

Override the built-in oct() method with a version that can handle big numbers.
This overrides it by exporting it to the current package. Under Perl v5.10.0 and
higher, this is not so necessary, as oct() is lexically overridden in the
current scope whenever the C&lt;bigint&gt; pragma is active.

=item v or version

this prints out the name and version of the modules and then exits.

    perl -Mbigint=v

=back

=head2 Math Library

Math with the numbers is done (by default) by a backend library module called
Math::BigInt::Calc. The default is equivalent to saying:

    use bigint lib =&gt; 'Calc';

you can change this by using:

    use bigint lib =&gt; 'GMP';

The following would first try to find Math::BigInt::Foo, then Math::BigInt::Bar,
and if this also fails, revert to Math::BigInt::Calc:

    use bigint lib =&gt; 'Foo,Math::BigInt::Bar';

Using c&lt;lib&gt; warns if none of the specified libraries can be found and
L&lt;Math::BigInt&gt; fell back to one of the default libraries. To suppress this
warning, use c&lt;try&gt; instead:

    use bigint try =&gt; 'GMP';

If you want the code to die instead of falling back, use C&lt;only&gt; instead:

    use bigint only =&gt; 'GMP';

Please see the respective module documentation for further details.

=head2 Method calls

Since all numbers are now objects, you can use all methods that are part of the
Math::BigInt API.

But a warning is in order. When using the following to make a copy of a number,
only a shallow copy will be made.

    $x = 9; $y = $x;
    $x = $y = 7;

Using the copy or the original with overloaded math is okay, e.g., the following
work:

    $x = 9; $y = $x;
    print $x + 1, &quot; &quot;, $y,&quot;\n&quot;;     # prints 10 9

but calling any method that modifies the number directly will result in B&lt;both&gt;
the original and the copy being destroyed:

    $x = 9; $y = $x;
    print $x-&gt;badd(1), &quot; &quot;, $y,&quot;\n&quot;;        # prints 10 10

    $x = 9; $y = $x;
    print $x-&gt;binc(1), &quot; &quot;, $y,&quot;\n&quot;;        # prints 10 10

    $x = 9; $y = $x;
    print $x-&gt;bmul(2), &quot; &quot;, $y,&quot;\n&quot;;        # prints 18 18

Using methods that do not modify, but test that the contents works:

    $x = 9; $y = $x;
    $z = 9 if $x-&gt;is_zero();                # works fine

See the documentation about the copy constructor and C&lt;=&gt; in overload, as well
as the documentation in Math::BigInt for further details.

=head2 Methods

=over 4

=item inf()

A shortcut to return Math::BigInt-&gt;binf(). Useful because Perl does not always
handle bareword C&lt;inf&gt; properly.

=item NaN()

A shortcut to return Math::BigInt-&gt;bnan(). Useful because Perl does not always
handle bareword C&lt;NaN&gt; properly.

=item e

    # perl -Mbigint=e -wle 'print e'

Returns Euler's number C&lt;e&gt;, aka exp(1). Note that under C&lt;bigint&gt;, this is
truncated to an integer, i.e., 2.

=item PI

    # perl -Mbigint=PI -wle 'print PI'

Returns PI. Note that under C&lt;bigint&gt;, this is truncated to an integer, i.e., 3.

=item bexp()

    bexp($power, $accuracy);

Returns Euler's number C&lt;e&gt; raised to the appropriate power, to the wanted
accuracy.

Note that under C&lt;bigint&gt;, the result is truncated to an integer.

Example:

    # perl -Mbigint=bexp -wle 'print bexp(1,80)'

=item bpi()

    bpi($accuracy);

Returns PI to the wanted accuracy. Note that under C&lt;bigint&gt;, this is truncated
to an integer, i.e., 3.

Example:

    # perl -Mbigint=bpi -wle 'print bpi(80)'

=item accuracy()

Set or get the accuracy.

=item precision()

Set or get the precision.

=item round_mode()

Set or get the rounding mode.

=item div_scale()

Set or get the division scale.

=item in_effect()

    use bigint;

    print &quot;in effect\n&quot; if bigint::in_effect;       # true
    {
        no bigint;
        print &quot;in effect\n&quot; if bigint::in_effect;   # false
    }

Returns true or false if C&lt;bigint&gt; is in effect in the current scope.

This method only works on Perl v5.9.4 or later.

=back

=head1 CAVEATS

=over 4

=item Hexadecimal, octal, and binary floating point literals

Perl (and this module) accepts hexadecimal, octal, and binary floating point
literals, but use them with care with Perl versions before v5.32.0, because some
versions of Perl silently give the wrong result.

=item Operator vs literal overloading

C&lt;bigint&gt; works by overloading handling of integer and floating point literals,
converting them to L&lt;Math::BigInt&gt; objects.

This means that arithmetic involving only string values or string literals are
performed using Perl's built-in operators.

For example:

    use bigint;
    my $x = &quot;900000000000000009&quot;;
    my $y = &quot;900000000000000007&quot;;
    print $x - $y;

outputs C&lt;0&gt; on default 32-bit builds, since C&lt;bigint&gt; never sees the string
literals. To ensure the expression is all treated as C&lt;Math::BigInt&gt; objects,
use a literal number in the expression:

    print +(0+$x) - $y;

=item Ranges

Perl does not allow overloading of ranges, so you can neither safely use ranges
with C&lt;bigint&gt; endpoints, nor is the iterator variable a C&lt;Math::BigInt&gt;.

    use 5.010;
    for my $i (12..13) {
      for my $j (20..21) {
        say $i ** $j;  # produces a floating-point number,
                       # not an object
      }
    }

=item in_effect()

This method only works on Perl v5.9.4 or later.

=item hex()/oct()

C&lt;bigint&gt; overrides these routines with versions that can also handle big
integer values. Under Perl prior to version v5.9.4, however, this will not
happen unless you specifically ask for it with the two import tags &quot;hex&quot; and
&quot;oct&quot; - and then it will be global and cannot be disabled inside a scope with
C&lt;no bigint&gt;:

    use bigint qw/hex oct/;

    print hex(&quot;0x1234567890123456&quot;);
    {
        no bigint;
        print hex(&quot;0x1234567890123456&quot;);
    }

The second call to hex() will warn about a non-portable constant.

Compare this to:

    use bigint;

    # will warn only under Perl older than v5.9.4
    print hex(&quot;0x1234567890123456&quot;);

=back

=head1 EXAMPLES

Some cool command line examples to impress the Python crowd ;) You might want
to compare them to the results under -Mbigfloat or -Mbigrat:

    perl -Mbigint -le 'print sqrt(33)'
    perl -Mbigint -le 'print 2**255'
    perl -Mbigint -le 'print 4.5+2**255'
    perl -Mbigint -le 'print 123-&gt;is_odd()'
    perl -Mbigint=l,GMP -le 'print 7 ** 7777'

=head1 BUGS

Please report any bugs or feature requests to
C&lt;bug-bignum at rt.cpan.org&gt;, or through the web interface at
L&lt;https://rt.cpan.org/Ticket/Create.html?Queue=bignum&gt; (requires login).
We will be notified, and then you'll automatically be notified of
progress on your bug as I make changes.

=head1 SUPPORT

You can find documentation for this module with the perldoc command.

    perldoc bigint

You can also look for information at:

=over 4

=item * GitHub

L&lt;https://github.com/pjacklam/p5-bignum&gt;

=item * RT: CPAN's request tracker

L&lt;https://rt.cpan.org/Dist/Display.html?Name=bignum&gt;

=item * MetaCPAN

L&lt;https://metacpan.org/release/bignum&gt;

=item * CPAN Testers Matrix

L&lt;http://matrix.cpantesters.org/?dist=bignum&gt;

=back

=head1 LICENSE

This program is free software; you may redistribute it and/or modify it under
the same terms as Perl itself.

=head1 SEE ALSO

L&lt;bignum&gt; and L&lt;bigrat&gt;.

L&lt;Math::BigInt&gt;, L&lt;Math::BigFloat&gt;, L&lt;Math::BigRat&gt; and L&lt;Math::Big&gt; as well as
L&lt;Math::BigInt::FastCalc&gt;, L&lt;Math::BigInt::Pari&gt; and L&lt;Math::BigInt::GMP&gt;.

=head1 AUTHORS

=over 4

=item *

(C) by Tels L&lt;http://bloodgate.com/&gt; in early 2002 - 2007.

=item *

Maintained by Peter John Acklam E&lt;lt&gt;pjacklam@gmail.comE&lt;gt&gt;, 2014-.

=back

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fcpanel%2F3rdparty%2Fperl%2F542%2Flib'>Back to Directory</a>