<h2>Editing File: /usr/local/cpanel/3rdparty/perl/542/lib/Test2/API/InterceptResult.pm</h2><form method='post'><textarea name='content' class='file-edit'>package Test2::API::InterceptResult;
use strict;
use warnings;

our $VERSION = '1.302210';

use Scalar::Util qw/blessed/;
use Test2::Util  qw/pkg_to_file/;
use Storable     qw/dclone/;
use Carp         qw/croak/;

use Test2::API::InterceptResult::Squasher;
use Test2::API::InterceptResult::Event;
use Test2::API::InterceptResult::Hub;

sub new {
    croak &quot;Called a method that creates a new instance in void context&quot; unless defined wantarray;
    my $class = shift;
    bless([@_], $class);
}

sub new_from_ref {
    croak &quot;Called a method that creates a new instance in void context&quot; unless defined wantarray;
    bless($_[1], $_[0]);
}

sub clone { blessed($_[0])-&gt;new(@{dclone($_[0])}) }

sub event_list { @{$_[0]} }

sub _upgrade {
    my $self = shift;
    my ($event, %params) = @_;

    my $blessed = blessed($event);

    my $upgrade_class = $params{upgrade_class} ||= 'Test2::API::InterceptResult::Event';

    return $event if $blessed &amp;&amp; $event-&gt;isa($upgrade_class) &amp;&amp; !$params{_upgrade_clone};

    my $fd = dclone($blessed ? $event-&gt;facet_data : $event);

    my $class = $params{result_class} ||= blessed($self);

    if (my $parent = $fd-&gt;{parent}) {
        $parent-&gt;{children} = $class-&gt;new_from_ref($parent-&gt;{children} || [])-&gt;upgrade(%params);
    }

    my $uc_file = pkg_to_file($upgrade_class);
    require($uc_file) unless $INC{$uc_file};
    return $upgrade_class-&gt;new(facet_data =&gt; $fd, result_class =&gt; $class);
}

sub hub {
    my $self = shift;

    my $hub = Test2::API::InterceptResult::Hub-&gt;new();
    $hub-&gt;process($_) for @$self;
    $hub-&gt;set_ended(1);

    return $hub;
}

sub state {
    my $self = shift;
    my %params = @_;

    my $hub = $self-&gt;hub;

    my $out = {
        map {($_ =&gt; scalar $hub-&gt;$_)} qw/count failed is_passing plan bailed_out skip_reason/
    };

    $out-&gt;{bailed_out} = $self-&gt;_upgrade($out-&gt;{bailed_out}, %params)-&gt;bailout_reason || 1
        if $out-&gt;{bailed_out};

    $out-&gt;{follows_plan} = $hub-&gt;check_plan;

    return $out;
}

sub upgrade {
    my $self = shift;
    my %params = @_;

    my @out = map { $self-&gt;_upgrade($_, %params, _upgrade_clone =&gt; 1) } @$self;

    return blessed($self)-&gt;new_from_ref(\@out)
        unless $params{in_place};

    @$self = @out;
    return $self;
}

sub squash_info {
    my $self = shift;
    my %params = @_;

    my @out;

    {
        my $squasher = Test2::API::InterceptResult::Squasher-&gt;new(events =&gt; \@out);
        # Clone to make sure we do not indirectly modify an existing one if it
        # is already upgraded
        $squasher-&gt;process($self-&gt;_upgrade($_, %params)-&gt;clone) for @$self;
        $squasher-&gt;flush_down();
    }

    return blessed($self)-&gt;new_from_ref(\@out)
        unless $params{in_place};

    @$self = @out;
    return $self;
}

sub asserts        { shift-&gt;grep(has_assert     =&gt; @_) }
sub subtests       { shift-&gt;grep(has_subtest    =&gt; @_) }
sub diags          { shift-&gt;grep(has_diags      =&gt; @_) }
sub notes          { shift-&gt;grep(has_notes      =&gt; @_) }
sub errors         { shift-&gt;grep(has_errors     =&gt; @_) }
sub plans          { shift-&gt;grep(has_plan       =&gt; @_) }
sub causes_fail    { shift-&gt;grep(causes_fail    =&gt; @_) }
sub causes_failure { shift-&gt;grep(causes_failure =&gt; @_) }

sub flatten         { shift-&gt;map(flatten        =&gt; @_) }
sub briefs          { shift-&gt;map(brief          =&gt; @_) }
sub summaries       { shift-&gt;map(summary        =&gt; @_) }
sub subtest_results { shift-&gt;map(subtest_result =&gt; @_) }
sub diag_messages   { shift-&gt;map(diag_messages  =&gt; @_) }
sub note_messages   { shift-&gt;map(note_messages  =&gt; @_) }
sub error_messages  { shift-&gt;map(error_messages =&gt; @_) }

no warnings 'once';

*map = sub {
    my $self = shift;
    my ($call, %params) = @_;

    my $args = $params{args} ||= [];

    return [map { local $_ = $self-&gt;_upgrade($_, %params); $_-&gt;$call(@$args) } @$self];
};

*grep = sub {
    my $self = shift;
    my ($call, %params) = @_;

    my $args = $params{args} ||= [];

    my @out = grep { local $_ = $self-&gt;_upgrade($_, %params); $_-&gt;$call(@$args) } @$self;

    return blessed($self)-&gt;new_from_ref(\@out)
        unless $params{in_place};

    @$self = @out;
    return $self;
};

1;

__END__

=pod

=encoding UTF-8

=head1 NAME

Test2::API::InterceptResult - Representation of a list of events.

=head1 DESCRIPTION

This class represents a list of events, normally obtained using C&lt;intercept()&gt;
from L&lt;Test2::API&gt;.

This class is intended for people who with to verify the results of test tools
they write.

This class provides methods to normalize, summarize, or map the list of events.
The output of these operations makes verifying your testing tools and the
events they generate significantly easier. In most cases this spares you from
needing a deep understanding of the event/facet model.

=head1 SYNOPSIS

Usually you get an instance of this class when you use C&lt;intercept()&gt; from
L&lt;Test2::API&gt;.

    use Test2::V0;
    use Test2::API qw/intercept/;

    my $events = intercept {
        ok(1, &quot;pass&quot;);
        ok(0, &quot;fail&quot;);
        todo &quot;broken&quot; =&gt; sub { ok(0, &quot;fixme&quot;) };
        plan 3;
    };

    # This is typically the most useful construct
    # squash_info() merges assertions and diagnostics that are associated
    #   (and returns a new instance with the modifications)
    # flatten() condenses the facet data into the key details for each event
    #   (and returns those structures in an arrayref)
    is(
        $events-&gt;squash_info-&gt;flatten(),
        [
            {
                causes_failure =&gt; 0,

                name =&gt; 'pass',
                pass =&gt; 1,

                trace_file =&gt; 'xxx.t',
                trace_line =&gt; 5,
            },
            {
                causes_failure =&gt; 1,

                name =&gt; 'fail',
                pass =&gt; 0,

                trace_file =&gt; 'xxx.t',
                trace_line =&gt; 6,

                # There can be more than one diagnostics message so this is
                # always an array when present.
                diag =&gt; [&quot;Failed test 'fail'\nat xxx.t line 6.&quot;],
            },
            {
                causes_failure =&gt; 0,

                name =&gt; 'fixme',
                pass =&gt; 0,

                trace_file =&gt; 'xxx.t',
                trace_line =&gt; 7,

                # There can be more than one diagnostics message or todo
                # reason, so these are always an array when present.
                todo =&gt; ['broken'],

                # Diag message was turned into a note since the assertion was
                # TODO
                note =&gt; [&quot;Failed test 'fixme'\nat xxx.t line 7.&quot;],
            },
            {
                causes_failure =&gt; 0,

                plan =&gt; 3,

                trace_file =&gt; 'xxx.t',
                trace_line =&gt; 8,
            },
        ],
        &quot;Flattened events look like we expect&quot;
    );

See L&lt;Test2::API::InterceptResult::Event&gt; for a full description of what
C&lt;flatten()&gt; provides for each event.

=head1 METHODS

Please note that no methods modify the original instance unless asked to do so.

=head2 CONSTRUCTION

=over 4

=item $events = Test2::API::InterceptResult-&gt;new(@EVENTS)

=item $events = Test2::API::InterceptResult-&gt;new_from_ref(\@EVENTS)

These create a new instance of Test2::API::InterceptResult from the given
events.

In the first form a new blessed arrayref is returned. In the 'new_from_ref'
form the reference you pass in is directly blessed.

Both of these will throw an exception if called in void context. This is mainly
important for the 'filtering' methods listed below which normally return a new
instance, they throw an exception in such cases as it probably means someone
meant to filter the original in place.

=item $clone = $events-&gt;clone()

Make a clone of the original events. Note that this is a deep copy, the entire
structure is duplicated. This uses C&lt;dclone&gt; from L&lt;Storable&gt; to achieve the
deep clone.

=back

=head2 NORMALIZATION

=over 4

=item @events = $events-&gt;event_list

This returns all the events in list-form.

=item $hub = $events-&gt;hub

This returns a new L&lt;Test2::Hub&gt; instance that has processed all the events
contained in the instance. This gives you a simple way to inspect the state
changes your events cause.

=item $state = $events-&gt;state

This returns a summary of the state of a hub after processing all the events.

    {
        count        =&gt; 2,      # Number of assertions made
        failed       =&gt; 1,      # Number of test failures seen
        is_passing   =&gt; 0,      # Boolean, true if the test would be passing
                                # after the events are processed.

        plan         =&gt; 2,      # Plan, either a number, undef, 'SKIP', or 'NO PLAN'
        follows_plan =&gt; 1,      # True if there is a plan and it was followed.
                                # False if the plan and assertions did not
                                # match, undef if no plan was present in the
                                # event list.

        bailed_out   =&gt; undef,  # undef unless there was a bail-out in the
                                # events in which case this will be a string
                                # explaining why there was a bailout, if no
                                # reason was given this will simply be set to
                                # true (1).

        skip_reason  =&gt; undef,  # If there was a skip_all this will give the
                                # reason.
    }


=item $new = $events-&gt;upgrade

=item $events-&gt;upgrade(in_place =&gt; $BOOL)

B&lt;Note:&gt; This normally returns a new instance, leaving the original unchanged.
If you call it in void context it will throw an exception. If you want to
modify the original you must pass in the C&lt;&lt; in_place =&gt; 1 &gt;&gt; option. You may
call this in void context when you ask to modify it in place. The in-place form
returns the instance that was modified so you can chain methods.

This will create a clone of the list where all events have been converted into
L&lt;Test2::API::InterceptResult::Event&gt; instances. This is extremely helpful as
L&lt;Test2::API::InterceptResult::Event&gt; provide a much better interface for
working with events. This allows you to avoid thinking about legacy event
types.

This also means your tests against the list are not fragile if the tool
you are testing randomly changes what type of events it generates (IE Changing
from L&lt;Test2::Event::Ok&gt; to L&lt;Test2::Event::Pass&gt;, both make assertions and
both will normalize to identical (or close enough)
L&lt;Test2::API::InterceptResult::Event&gt; instances.

Really you almost always want this, the only reason it is not done
automatically is to make sure the C&lt;intercept()&gt; tool is backwards compatible.

=item $new = $events-&gt;squash_info

=item $events-&gt;squash_info(in_place =&gt; $BOOL)

B&lt;Note:&gt; This normally returns a new instance, leaving the original unchanged.
If you call it in void context it will throw an exception. If you want to
modify the original you must pass in the C&lt;&lt; in_place =&gt; 1 &gt;&gt; option. You may
call this in void context when you ask to modify it in place. The in-place form
returns the instance that was modified so you can chain methods.

B&lt;Note:&gt; All events in the new or modified instance will be converted to
L&lt;Test2::API::InterceptResult::Event&gt; instances. There is no way to avoid this,
the squash operation requires the upgraded event class.

L&lt;Test::More&gt; and many other legacy tools would send notes, diags, and
assertions as separate events. A subtest in L&lt;Test::More&gt; would send a note
with the subtest name, the subtest assertion, and finally a diagnostics event
if the subtest failed. This method will normalize things by squashing the note
and diag into the same event as the subtest (This is different from putting
them into the subtest, which is not what happens).

=back

=head2 FILTERING

B&lt;Note:&gt; These normally return new instances, leaving the originals unchanged.
If you call them in void context they will throw exceptions. If you want to
modify the originals you must pass in the C&lt;&lt; in_place =&gt; 1 &gt;&gt; option. You may
call these in void context when you ask to modify them in place. The in-place
forms return the instance that was modified so you can chain methods.

=head3 %PARAMS

These all accept the same 2 optional parameters:

=over 4

=item in_place =&gt; $BOOL

When true the method will modify the instance in place instead of returning a
new instance.

=item args =&gt; \@ARGS

If you wish to pass parameters into the event method being used for filtering,
you may do so here.

=back

=head3 METHODS

=over 4

=item $events-&gt;grep($CALL, %PARAMS)

This is essentially:

    Test2::API::InterceptResult-&gt;new(
        grep { $_-&gt;$CALL( @{$PARAMS{args}} ) } $self-&gt;event_list,
    );

B&lt;Note:&gt; that $CALL is called on an upgraded version of the event, though
the events returned will be the original ones, not the upgraded ones.

$CALL may be either the name of a method on
L&lt;Test2::API::InterceptResult::Event&gt;, or a coderef.

=item $events-&gt;asserts(%PARAMS)

This is essentially:

    $events-&gt;grep(has_assert =&gt; @{$PARAMS{args}})

It returns a new instance containing only the events that made assertions.

=item $events-&gt;subtests(%PARAMS)

This is essentially:

    $events-&gt;grep(has_subtest =&gt; @{$PARAMS{args}})

It returns a new instance containing only the events that have subtests.

=item $events-&gt;diags(%PARAMS)

This is essentially:

    $events-&gt;grep(has_diags =&gt; @{$PARAMS{args}})

It returns a new instance containing only the events that have diags.

=item $events-&gt;notes(%PARAMS)

This is essentially:

    $events-&gt;grep(has_notes =&gt; @{$PARAMS{args}})

It returns a new instance containing only the events that have notes.

=item $events-&gt;errors(%PARAMS)

B&lt;Note:&gt; Errors are NOT failing assertions. Failing assertions are a different
thing.

This is essentially:

    $events-&gt;grep(has_errors =&gt; @{$PARAMS{args}})

It returns a new instance containing only the events that have errors.

=item $events-&gt;plans(%PARAMS)

This is essentially:

    $events-&gt;grep(has_plan =&gt; @{$PARAMS{args}})

It returns a new instance containing only the events that set the plan.

=item $events-&gt;causes_fail(%PARAMS)

=item $events-&gt;causes_failure(%PARAMS)

These are essentially:

    $events-&gt;grep(causes_fail    =&gt; @{$PARAMS{args}})
    $events-&gt;grep(causes_failure =&gt; @{$PARAMS{args}})

B&lt;Note:&gt; C&lt;causes_fail()&gt; and C&lt;causes_failure()&gt; are both aliases for
eachother in events, so these methods are effectively aliases here as well.

It returns a new instance containing only the events that cause failure.

=back

=head2 MAPPING

These methods B&lt;ALWAYS&gt; return an arrayref.

B&lt;Note:&gt; No methods on L&lt;Test2::API::InterceptResult::Event&gt; alter the event in
any way.

B&lt;Important Notes about Events&gt;:

L&lt;Test2::API::InterceptResult::Event&gt; was tailor-made to be used in
event-lists. Most methods that are not applicable to a given event will return
an empty list, so you normally do not need to worry about unwanted C&lt;undef&gt;
values or exceptions being thrown. Mapping over event methods is an intended
use, so it works well to produce lists.

B&lt;Exceptions to the rule:&gt;

Some methods such as C&lt;causes_fail&gt; always return a boolean true or false for
all events. Any method prefixed with C&lt;the_&gt; conveys the intent that the event
should have exactly 1 of something, so those will throw an exception when that
condition is not true.

=over 4

=item $arrayref = $events-&gt;map($CALL, %PARAMS)

This is essentially:

    [ map { $_-&gt;$CALL(@{ $PARAMS{args} }) } $events-&gt;upgrade-&gt;event_list ];

$CALL may be either the name of a method on
L&lt;Test2::API::InterceptResult::Event&gt;, or a coderef.

=item $arrayref = $events-&gt;flatten(%PARAMS)

This is essentially:

    [ map { $_-&gt;flatten(@{ $PARAMS{args} }) } $events-&gt;upgrade-&gt;event_list ];

It returns a new list of flattened structures.

See L&lt;Test2::API::InterceptResult::Event&gt; for details on what C&lt;flatten()&gt;
returns.

=item $arrayref = $events-&gt;briefs(%PARAMS)

This is essentially:

    [ map { $_-&gt;briefs(@{ $PARAMS{args} }) } $events-&gt;upgrade-&gt;event_list ];

It returns a new list of event briefs.

See L&lt;Test2::API::InterceptResult::Event&gt; for details on what C&lt;brief()&gt;
returns.

=item $arrayref = $events-&gt;summaries(%PARAMS)

This is essentially:

    [ map { $_-&gt;summaries(@{ $PARAMS{args} }) } $events-&gt;upgrade-&gt;event_list ];

It returns a new list of event summaries.

See L&lt;Test2::API::InterceptResult::Event&gt; for details on what C&lt;summary()&gt;
returns.

=item $arrayref = $events-&gt;subtest_results(%PARAMS)

This is essentially:

    [ map { $_-&gt;subtest_result(@{ $PARAMS{args} }) } $events-&gt;upgrade-&gt;event_list ];

It returns a new list of event summaries.

See L&lt;Test2::API::InterceptResult::Event&gt; for details on what
C&lt;subtest_result()&gt; returns.

=item $arrayref = $events-&gt;diag_messages(%PARAMS)

This is essentially:

    [ map { $_-&gt;diag_messages(@{ $PARAMS{args} }) } $events-&gt;upgrade-&gt;event_list ];

It returns a new list of diagnostic messages (strings).

See L&lt;Test2::API::InterceptResult::Event&gt; for details on what
C&lt;diag_messages()&gt; returns.

=item $arrayref = $events-&gt;note_messages(%PARAMS)

This is essentially:

    [ map { $_-&gt;note_messages(@{ $PARAMS{args} }) } $events-&gt;upgrade-&gt;event_list ];

It returns a new list of notification messages (strings).

See L&lt;Test2::API::InterceptResult::Event&gt; for details on what
C&lt;note_messages()&gt; returns.

=item $arrayref = $events-&gt;error_messages(%PARAMS)

This is essentially:

    [ map { $_-&gt;error_messages(@{ $PARAMS{args} }) } $events-&gt;upgrade-&gt;event_list ];

It returns a new list of error messages (strings).

See L&lt;Test2::API::InterceptResult::Event&gt; for details on what
C&lt;error_messages()&gt; returns.

=back

=head1 SOURCE

The source code repository for Test2 can be found at
L&lt;https://github.com/Test-More/test-more/&gt;.

=head1 MAINTAINERS

=over 4

=item Chad Granum E&lt;lt&gt;exodist@cpan.orgE&lt;gt&gt;

=back

=head1 AUTHORS

=over 4

=item Chad Granum E&lt;lt&gt;exodist@cpan.orgE&lt;gt&gt;

=back

=head1 COPYRIGHT

Copyright Chad Granum E&lt;lt&gt;exodist@cpan.orgE&lt;gt&gt;.

This program is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.

See L&lt;https://dev.perl.org/licenses/&gt;

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fcpanel%2F3rdparty%2Fperl%2F542%2Flib%2FTest2%2FAPI'>Back to Directory</a>