<h2>Editing File: /usr/local/cpanel/3rdparty/perl/542/lib/Net/SMTP.pm</h2><form method='post'><textarea name='content' class='file-edit'># Net::SMTP.pm
#
# Copyright (C) 1995-2004 Graham Barr.  All rights reserved.
# Copyright (C) 2013-2016, 2020 Steve Hay.  All rights reserved.
# This module is free software; you can redistribute it and/or modify it under
# the same terms as Perl itself, i.e. under the terms of either the GNU General
# Public License or the Artistic License, as specified in the F&lt;LICENCE&gt; file.

package Net::SMTP;

use 5.008001;

use strict;
use warnings;

use Carp;
use IO::Socket;
use Net::Cmd;
use Net::Config;
use Socket;

our $VERSION = &quot;3.15&quot;;

# Code for detecting if we can use SSL
my $ssl_class = eval {
  require IO::Socket::SSL;
  # first version with default CA on most platforms
  no warnings 'numeric';
  IO::Socket::SSL-&gt;VERSION(2.007);
} &amp;&amp; 'IO::Socket::SSL';

my $nossl_warn = !$ssl_class &amp;&amp;
  'To use SSL please install IO::Socket::SSL with version&gt;=2.007';

# Code for detecting if we can use IPv6
my $family_key = 'Domain';
my $inet6_class = eval {
  require IO::Socket::IP;
  no warnings 'numeric';
  IO::Socket::IP-&gt;VERSION(0.25) || die;
  $family_key = 'Family';
} &amp;&amp; 'IO::Socket::IP' || eval {
  require IO::Socket::INET6;
  no warnings 'numeric';
  IO::Socket::INET6-&gt;VERSION(2.62);
} &amp;&amp; 'IO::Socket::INET6';

sub can_ssl   { $ssl_class };
sub can_inet6 { $inet6_class };

our @ISA = ('Net::Cmd', $inet6_class || 'IO::Socket::INET');

sub new {
  my $self = shift;
  my $type = ref($self) || $self;
  my ($host, %arg);
  if (@_ % 2) {
    $host = shift;
    %arg  = @_;
  }
  else {
    %arg  = @_;
    $host = delete $arg{Host};
  }

  if ($arg{SSL}) {
    # SSL from start
    die $nossl_warn if !$ssl_class;
    $arg{Port} ||= 465;
  }

  my $hosts = defined $host ? $host : $NetConfig{smtp_hosts};
  my $obj;

  $arg{Timeout} = 120 if ! defined $arg{Timeout};

  foreach my $h (@{ref($hosts) ? $hosts : [$hosts]}) {
    $obj = $type-&gt;SUPER::new(
      PeerAddr =&gt; ($host = $h),
      PeerPort =&gt; $arg{Port} || 'smtp(25)',
      LocalAddr =&gt; $arg{LocalAddr},
      LocalPort =&gt; $arg{LocalPort},
      $family_key =&gt; $arg{Domain} || $arg{Family},
      Proto     =&gt; 'tcp',
      Timeout   =&gt; $arg{Timeout}
      )
      and last;
  }

  return
    unless defined $obj;

  ${*$obj}{'net_smtp_arg'} = \%arg;
  ${*$obj}{'net_smtp_host'} = $host;

  if ($arg{SSL}) {
    Net::SMTP::_SSL-&gt;start_SSL($obj,%arg)
      or return;
  }

  $obj-&gt;autoflush(1);

  $obj-&gt;debug(exists $arg{Debug} ? $arg{Debug} : undef);

  unless ($obj-&gt;response() == CMD_OK) {
    my $err = ref($obj) . &quot;: &quot; . $obj-&gt;code . &quot; &quot; . $obj-&gt;message;
    $obj-&gt;close();
    $@ = $err;
    return;
  }

  ${*$obj}{'net_smtp_exact_addr'} = $arg{ExactAddresses};

  (${*$obj}{'net_smtp_banner'}) = $obj-&gt;message;
  (${*$obj}{'net_smtp_domain'}) = $obj-&gt;message =~ /\A\s*(\S+)/;

  if (!exists $arg{SendHello} || $arg{SendHello}) {
    unless ($obj-&gt;hello($arg{Hello} || &quot;&quot;)) {
      my $err = ref($obj) . &quot;: &quot; . $obj-&gt;code . &quot; &quot; . $obj-&gt;message;
      $obj-&gt;close();
      $@ = $err;
      return;
    }
  }

  $obj;
}


sub host {
  my $me = shift;
  ${*$me}{'net_smtp_host'};
}

##
## User interface methods
##


sub banner {
  my $me = shift;

  return ${*$me}{'net_smtp_banner'} || undef;
}


sub domain {
  my $me = shift;

  return ${*$me}{'net_smtp_domain'} || undef;
}


sub etrn {
  my $self = shift;
  defined($self-&gt;supports('ETRN', 500, [&quot;Command unknown: 'ETRN'&quot;]))
    &amp;&amp; $self-&gt;_ETRN(@_);
}


sub auth {
  my ($self, $username, $password) = @_;

  eval {
    require MIME::Base64;
    require Authen::SASL;
  } or $self-&gt;set_status(500, [&quot;Need MIME::Base64 and Authen::SASL todo auth&quot;]), return 0;

  my $mechanisms = $self-&gt;supports('AUTH', 500, [&quot;Command unknown: 'AUTH'&quot;]);
  return unless defined $mechanisms;

  my $sasl;

  if (ref($username) and UNIVERSAL::isa($username, 'Authen::SASL')) {
    $sasl = $username;
    my $requested_mechanisms = $sasl-&gt;mechanism();
    if (! defined($requested_mechanisms) || $requested_mechanisms eq '') {
      $sasl-&gt;mechanism($mechanisms);
    }
  }
  else {
    die &quot;auth(username, password)&quot; if not length $username;
    $sasl = Authen::SASL-&gt;new(
      mechanism =&gt; $mechanisms,
      callback  =&gt; {
        user     =&gt; $username,
        pass     =&gt; $password,
        authname =&gt; $username,
      },
      debug =&gt; $self-&gt;debug
    );
  }

  my $client;
  my $str;
  do {
    if ($client) {
      # $client mechanism failed, so we need to exclude this mechanism from list
      my $failed_mechanism = $client-&gt;mechanism;
      return unless defined $failed_mechanism;
      $self-&gt;debug_text(&quot;Auth mechanism failed: $failed_mechanism&quot;)
        if $self-&gt;debug;
      $mechanisms =~ s/\b\Q$failed_mechanism\E\b//;
      return unless $mechanisms =~ /\S/;
      $sasl-&gt;mechanism($mechanisms);
    }
    
    # We should probably allow the user to pass the host, but I don't
    # currently know and SASL mechanisms that are used by smtp that need it

    $client = $sasl-&gt;client_new('smtp', ${*$self}{'net_smtp_host'}, 0);
    $str    = $client-&gt;client_start;
  } while (!defined $str);

  # We don't support sasl mechanisms that encrypt the socket traffic.
  # todo that we would really need to change the ISA hierarchy
  # so we don't inherit from IO::Socket, but instead hold it in an attribute

  my @cmd = (&quot;AUTH&quot;, $client-&gt;mechanism);
  my $code;

  push @cmd, MIME::Base64::encode_base64($str, '')
    if defined $str and length $str;

  while (($code = $self-&gt;command(@cmd)-&gt;response()) == CMD_MORE) {
    my $str2 = MIME::Base64::decode_base64(($self-&gt;message)[0]);
    $self-&gt;debug_print(0, &quot;(decoded) &quot; . $str2 . &quot;\n&quot;) if $self-&gt;debug;

    $str = $client-&gt;client_step($str2);
    @cmd = (
      MIME::Base64::encode_base64($str, '')
    );

    $self-&gt;debug_print(1, &quot;(decoded) &quot; . $str . &quot;\n&quot;) if $self-&gt;debug;
  }

  $code == CMD_OK;
}


sub hello {
  my $me     = shift;
  my $domain = shift || &quot;localhost.localdomain&quot;;
  my $ok     = $me-&gt;_EHLO($domain);
  my @msg    = $me-&gt;message;

  if ($ok) {
    my $h = ${*$me}{'net_smtp_esmtp'} = {};
    foreach my $ln (@msg) {
      $h-&gt;{uc $1} = $2
        if $ln =~ /([-\w]+)\b[= \t]*([^\n]*)/;
    }
  }
  elsif ($me-&gt;status == CMD_ERROR) {
    @msg = $me-&gt;message
      if $ok = $me-&gt;_HELO($domain);
  }

  return unless $ok;
  ${*$me}{net_smtp_hello_domain} = $domain;

  $msg[0] =~ /\A\s*(\S+)/;
  return ($1 || &quot; &quot;);
}

sub starttls {
  my $self = shift;
  $ssl_class or die $nossl_warn;
  $self-&gt;_STARTTLS or return;
  Net::SMTP::_SSL-&gt;start_SSL($self,
    %{ ${*$self}{'net_smtp_arg'} }, # (ssl) args given in new
    @_   # more (ssl) args
  ) or return;

  # another hello after starttls to read new ESMTP capabilities
  return $self-&gt;hello(${*$self}{net_smtp_hello_domain});
}


sub supports {
  my $self = shift;
  my $cmd  = uc shift;
  return ${*$self}{'net_smtp_esmtp'}-&gt;{$cmd}
    if exists ${*$self}{'net_smtp_esmtp'}-&gt;{$cmd};
  $self-&gt;set_status(@_)
    if @_;
  return;
}


sub _addr {
  my $self = shift;
  my $addr = shift;
  $addr = &quot;&quot; unless defined $addr;

  if (${*$self}{'net_smtp_exact_addr'}) {
    return $1 if $addr =~ /^\s*(&lt;.*&gt;)\s*$/s;
  }
  else {
    return $1 if $addr =~ /(&lt;[^&gt;]*&gt;)/;
    $addr =~ s/^\s+|\s+$//sg;
  }

  &quot;&lt;$addr&gt;&quot;;
}


sub mail {
  my $me   = shift;
  my $addr = _addr($me, shift);
  my $opts = &quot;&quot;;

  if (@_) {
    my %opt = @_;
    my ($k, $v);

    if (exists ${*$me}{'net_smtp_esmtp'}) {
      my $esmtp = ${*$me}{'net_smtp_esmtp'};

      if (defined($v = delete $opt{Size})) {
        if (exists $esmtp-&gt;{SIZE}) {
          $opts .= sprintf &quot; SIZE=%d&quot;, $v + 0;
        }
        else {
          carp 'Net::SMTP::mail: SIZE option not supported by host';
        }
      }

      if (defined($v = delete $opt{Return})) {
        if (exists $esmtp-&gt;{DSN}) {
          $opts .= &quot; RET=&quot; . ((uc($v) eq &quot;FULL&quot;) ? &quot;FULL&quot; : &quot;HDRS&quot;);
        }
        else {
          carp 'Net::SMTP::mail: DSN option not supported by host';
        }
      }

      if (defined($v = delete $opt{Bits})) {
        if ($v eq &quot;8&quot;) {
          if (exists $esmtp-&gt;{'8BITMIME'}) {
            $opts .= &quot; BODY=8BITMIME&quot;;
          }
          else {
            carp 'Net::SMTP::mail: 8BITMIME option not supported by host';
          }
        }
        elsif ($v eq &quot;binary&quot;) {
          if (exists $esmtp-&gt;{'BINARYMIME'} &amp;&amp; exists $esmtp-&gt;{'CHUNKING'}) {
            $opts .= &quot; BODY=BINARYMIME&quot;;
            ${*$me}{'net_smtp_chunking'} = 1;
          }
          else {
            carp 'Net::SMTP::mail: BINARYMIME option not supported by host';
          }
        }
        elsif (exists $esmtp-&gt;{'8BITMIME'} or exists $esmtp-&gt;{'BINARYMIME'}) {
          $opts .= &quot; BODY=7BIT&quot;;
        }
        else {
          carp 'Net::SMTP::mail: 8BITMIME and BINARYMIME options not supported by host';
        }
      }

      if (defined($v = delete $opt{Transaction})) {
        if (exists $esmtp-&gt;{CHECKPOINT}) {
          $opts .= &quot; TRANSID=&quot; . _addr($me, $v);
        }
        else {
          carp 'Net::SMTP::mail: CHECKPOINT option not supported by host';
        }
      }

      if (defined($v = delete $opt{Envelope})) {
        if (exists $esmtp-&gt;{DSN}) {
          $v =~ s/([^\041-\176]|=|\+)/sprintf &quot;+%02X&quot;, ord($1)/sge;
          $opts .= &quot; ENVID=$v&quot;;
        }
        else {
          carp 'Net::SMTP::mail: DSN option not supported by host';
        }
      }

      if (defined($v = delete $opt{ENVID})) {

        # expected to be in a format as required by RFC 3461, xtext-encoded
        if (exists $esmtp-&gt;{DSN}) {
          $opts .= &quot; ENVID=$v&quot;;
        }
        else {
          carp 'Net::SMTP::mail: DSN option not supported by host';
        }
      }

      if (defined($v = delete $opt{AUTH})) {

        # expected to be in a format as required by RFC 2554,
        # rfc2821-quoted and xtext-encoded, or &lt;&gt;
        if (exists $esmtp-&gt;{AUTH}) {
          $v = '&lt;&gt;' if !defined($v) || $v eq '';
          $opts .= &quot; AUTH=$v&quot;;
        }
        else {
          carp 'Net::SMTP::mail: AUTH option not supported by host';
        }
      }

      if (defined($v = delete $opt{XVERP})) {
        if (exists $esmtp-&gt;{'XVERP'}) {
          $opts .= &quot; XVERP&quot;;
        }
        else {
          carp 'Net::SMTP::mail: XVERP option not supported by host';
        }
      }

      carp 'Net::SMTP::recipient: unknown option(s) ' . join(&quot; &quot;, keys %opt) . ' - ignored'
        if scalar keys %opt;
    }
    else {
      carp 'Net::SMTP::mail: ESMTP not supported by host - options discarded :-(';
    }
  }

  $me-&gt;_MAIL(&quot;FROM:&quot; . $addr . $opts);
}


sub send          { my $me = shift; $me-&gt;_SEND(&quot;FROM:&quot; . _addr($me, $_[0])) }
sub send_or_mail  { my $me = shift; $me-&gt;_SOML(&quot;FROM:&quot; . _addr($me, $_[0])) }
sub send_and_mail { my $me = shift; $me-&gt;_SAML(&quot;FROM:&quot; . _addr($me, $_[0])) }


sub reset {
  my $me = shift;

  $me-&gt;dataend()
    if (exists ${*$me}{'net_smtp_lastch'});

  $me-&gt;_RSET();
}


sub recipient {
  my $smtp     = shift;
  my $opts     = &quot;&quot;;
  my $skip_bad = 0;

  if (@_ &amp;&amp; ref($_[-1])) {
    my %opt = %{pop(@_)};
    my $v;

    $skip_bad = delete $opt{'SkipBad'};

    if (exists ${*$smtp}{'net_smtp_esmtp'}) {
      my $esmtp = ${*$smtp}{'net_smtp_esmtp'};

      if (defined($v = delete $opt{Notify})) {
        if (exists $esmtp-&gt;{DSN}) {
          $opts .= &quot; NOTIFY=&quot; . join(&quot;,&quot;, map { uc $_ } @$v);
        }
        else {
          carp 'Net::SMTP::recipient: DSN option not supported by host';
        }
      }

      if (defined($v = delete $opt{ORcpt})) {
        if (exists $esmtp-&gt;{DSN}) {
          $opts .= &quot; ORCPT=&quot; . $v;
        }
        else {
          carp 'Net::SMTP::recipient: DSN option not supported by host';
        }
      }

      carp 'Net::SMTP::recipient: unknown option(s) ' . join(&quot; &quot;, keys %opt) . ' - ignored'
        if scalar keys %opt;
    }
    elsif (%opt) {
      carp 'Net::SMTP::recipient: ESMTP not supported by host - options discarded :-(';
    }
  }

  my @ok;
  foreach my $addr (@_) {
    if ($smtp-&gt;_RCPT(&quot;TO:&quot; . _addr($smtp, $addr) . $opts)) {
      push(@ok, $addr) if $skip_bad;
    }
    elsif (!$skip_bad) {
      return 0;
    }
  }

  return $skip_bad ? @ok : 1;
}

BEGIN {
  *to  = \&amp;recipient;
  *cc  = \&amp;recipient;
  *bcc = \&amp;recipient;
}


sub data {
  my $me = shift;

  if (exists ${*$me}{'net_smtp_chunking'}) {
    carp 'Net::SMTP::data: CHUNKING extension in use, must call bdat instead';
  }
  else {
    my $ok = $me-&gt;_DATA() &amp;&amp; $me-&gt;datasend(@_);

    $ok &amp;&amp; @_
      ? $me-&gt;dataend
      : $ok;
  }
}


sub bdat {
  my $me = shift;

  if (exists ${*$me}{'net_smtp_chunking'}) {
    my $data = shift;

    $me-&gt;_BDAT(length $data)
      &amp;&amp; $me-&gt;rawdatasend($data)
      &amp;&amp; $me-&gt;response() == CMD_OK;
  }
  else {
    carp 'Net::SMTP::bdat: CHUNKING extension is not in use, call data instead';
  }
}


sub bdatlast {
  my $me = shift;

  if (exists ${*$me}{'net_smtp_chunking'}) {
    my $data = shift;

    $me-&gt;_BDAT(length $data, &quot;LAST&quot;)
      &amp;&amp; $me-&gt;rawdatasend($data)
      &amp;&amp; $me-&gt;response() == CMD_OK;
  }
  else {
    carp 'Net::SMTP::bdat: CHUNKING extension is not in use, call data instead';
  }
}


sub datafh {
  my $me = shift;
  return unless $me-&gt;_DATA();
  return $me-&gt;tied_fh;
}


sub expand {
  my $me = shift;

  $me-&gt;_EXPN(@_)
    ? ($me-&gt;message)
    : ();
}


sub verify { shift-&gt;_VRFY(@_) }


sub help {
  my $me = shift;

  $me-&gt;_HELP(@_)
    ? scalar $me-&gt;message
    : undef;
}


sub quit {
  my $me = shift;

  $me-&gt;_QUIT;
  $me-&gt;close;
}


sub DESTROY {

  # ignore
}

##
## RFC821 commands
##


sub _EHLO { shift-&gt;command(&quot;EHLO&quot;, @_)-&gt;response() == CMD_OK }
sub _HELO { shift-&gt;command(&quot;HELO&quot;, @_)-&gt;response() == CMD_OK }
sub _MAIL { shift-&gt;command(&quot;MAIL&quot;, @_)-&gt;response() == CMD_OK }
sub _RCPT { shift-&gt;command(&quot;RCPT&quot;, @_)-&gt;response() == CMD_OK }
sub _SEND { shift-&gt;command(&quot;SEND&quot;, @_)-&gt;response() == CMD_OK }
sub _SAML { shift-&gt;command(&quot;SAML&quot;, @_)-&gt;response() == CMD_OK }
sub _SOML { shift-&gt;command(&quot;SOML&quot;, @_)-&gt;response() == CMD_OK }
sub _VRFY { shift-&gt;command(&quot;VRFY&quot;, @_)-&gt;response() == CMD_OK }
sub _EXPN { shift-&gt;command(&quot;EXPN&quot;, @_)-&gt;response() == CMD_OK }
sub _HELP { shift-&gt;command(&quot;HELP&quot;, @_)-&gt;response() == CMD_OK }
sub _RSET { shift-&gt;command(&quot;RSET&quot;)-&gt;response() == CMD_OK }
sub _NOOP { shift-&gt;command(&quot;NOOP&quot;)-&gt;response() == CMD_OK }
sub _QUIT { shift-&gt;command(&quot;QUIT&quot;)-&gt;response() == CMD_OK }
sub _DATA { shift-&gt;command(&quot;DATA&quot;)-&gt;response() == CMD_MORE }
sub _BDAT { shift-&gt;command(&quot;BDAT&quot;, @_) }
sub _TURN { shift-&gt;unsupported(@_); }
sub _ETRN { shift-&gt;command(&quot;ETRN&quot;, @_)-&gt;response() == CMD_OK }
sub _AUTH { shift-&gt;command(&quot;AUTH&quot;, @_)-&gt;response() == CMD_OK }
sub _STARTTLS { shift-&gt;command(&quot;STARTTLS&quot;)-&gt;response() == CMD_OK }


{
  package Net::SMTP::_SSL;
  our @ISA = ( $ssl_class ? ($ssl_class):(), 'Net::SMTP' );
  sub starttls { die &quot;SMTP connection is already in SSL mode&quot; }
  sub start_SSL {
    my ($class,$smtp,%arg) = @_;
    delete @arg{ grep { !m{^SSL_} } keys %arg };
    ( $arg{SSL_verifycn_name} ||= $smtp-&gt;host )
        =~s{(?&lt;!:):[\w()]+$}{}; # strip port
    $arg{SSL_hostname} = $arg{SSL_verifycn_name}
        if ! defined $arg{SSL_hostname} &amp;&amp; $class-&gt;can_client_sni;
    $arg{SSL_verifycn_scheme} ||= 'smtp';
    my $ok = $class-&gt;SUPER::start_SSL($smtp,%arg);
    $@ = $ssl_class-&gt;errstr if !$ok;
    return $ok;
  }
}


1;

__END__

=head1 NAME

Net::SMTP - Simple Mail Transfer Protocol Client

=head1 SYNOPSIS

    use Net::SMTP;

    # Constructors
    $smtp = Net::SMTP-&gt;new('mailhost');
    $smtp = Net::SMTP-&gt;new('mailhost', Timeout =&gt; 60);

=head1 DESCRIPTION

This module implements a client interface to the SMTP and ESMTP
protocol, enabling a perl5 application to talk to SMTP servers. This
documentation assumes that you are familiar with the concepts of the
SMTP protocol described in RFC2821.
With L&lt;IO::Socket::SSL&gt; installed it also provides support for implicit and
explicit TLS encryption, i.e. SMTPS or SMTP+STARTTLS.

The Net::SMTP class is a subclass of Net::Cmd and (depending on avaibility) of
IO::Socket::IP, IO::Socket::INET6 or IO::Socket::INET.

=head2 Class Methods

=over 4

=item C&lt;new([$host][, %options])&gt;

This is the constructor for a new Net::SMTP object. C&lt;$host&gt; is the
name of the remote host to which an SMTP connection is required.

On failure C&lt;undef&gt; will be returned and C&lt;$@&gt; will contain the reason
for the failure.

C&lt;$host&gt; is optional. If C&lt;$host&gt; is not given then it may instead be
passed as the C&lt;Host&gt; option described below. If neither is given then
the C&lt;SMTP_Hosts&gt; specified in C&lt;Net::Config&gt; will be used.

C&lt;%options&gt; are passed in a hash like fashion, using key and value pairs.
Possible options are:

B&lt;Hello&gt; - SMTP requires that you identify yourself. This option
specifies a string to pass as your mail domain. If not given localhost.localdomain
will be used.

B&lt;SendHello&gt; - If false then the EHLO (or HELO) command that is normally sent
when constructing the object will not be sent. In that case the command will
have to be sent manually by calling C&lt;hello()&gt; instead.

B&lt;Host&gt; - SMTP host to connect to. It may be a single scalar (hostname[:port]),
as defined for the C&lt;PeerAddr&gt; option in L&lt;IO::Socket::INET&gt;, or a reference to
an array with hosts to try in turn. The L&lt;/host&gt; method will return the value
which was used to connect to the host.
Format - C&lt;PeerHost&gt; from L&lt;IO::Socket::INET&gt; new method.

B&lt;Port&gt; - port to connect to.
Default - 25 for plain SMTP and 465 for immediate SSL.

B&lt;SSL&gt; - If the connection should be done from start with SSL, contrary to later
upgrade with C&lt;starttls&gt;.
You can use SSL arguments as documented in L&lt;IO::Socket::SSL&gt;, but it will
usually use the right arguments already.

B&lt;LocalAddr&gt; and B&lt;LocalPort&gt; - These parameters are passed directly
to IO::Socket to allow binding the socket to a specific local address and port.

B&lt;Domain&gt; - This parameter is passed directly to IO::Socket and makes it
possible to enforce IPv4 connections even if L&lt;IO::Socket::IP&gt; is used as super
class. Alternatively B&lt;Family&gt; can be used.

B&lt;Timeout&gt; - Maximum time, in seconds, to wait for a response from the
SMTP server (default: 120)

B&lt;ExactAddresses&gt; - If true then all C&lt;$address&gt; arguments must be as
defined by C&lt;addr-spec&gt; in RFC2822. If not given, or false, then
Net::SMTP will attempt to extract the address from the value passed.

B&lt;Debug&gt; - Enable debugging information

Example:

    $smtp = Net::SMTP-&gt;new('mailhost',
                           Hello =&gt; 'my.mail.domain',
                           Timeout =&gt; 30,
                           Debug   =&gt; 1,
                          );

    # the same
    $smtp = Net::SMTP-&gt;new(
                           Host =&gt; 'mailhost',
                           Hello =&gt; 'my.mail.domain',
                           Timeout =&gt; 30,
                           Debug   =&gt; 1,
                          );

    # the same with direct SSL
    $smtp = Net::SMTP-&gt;new('mailhost',
                           Hello =&gt; 'my.mail.domain',
                           Timeout =&gt; 30,
                           Debug   =&gt; 1,
                           SSL     =&gt; 1,
                          );

    # Connect to the default server from Net::config
    $smtp = Net::SMTP-&gt;new(
                           Hello =&gt; 'my.mail.domain',
                           Timeout =&gt; 30,
                          );

=back

=head1 Object Methods

Unless otherwise stated all methods return either a I&lt;true&gt; or I&lt;false&gt;
value, with I&lt;true&gt; meaning that the operation was a success. When a method
states that it returns a value, failure will be returned as I&lt;undef&gt; or an
empty list.

C&lt;Net::SMTP&gt; inherits from C&lt;Net::Cmd&gt; so methods defined in C&lt;Net::Cmd&gt; may
be used to send commands to the remote SMTP server in addition to the methods
documented here.

=over 4

=item C&lt;banner()&gt;

Returns the banner message which the server replied with when the
initial connection was made.

=item C&lt;domain()&gt;

Returns the domain that the remote SMTP server identified itself as during
connection.

=item C&lt;hello($domain)&gt;

Tell the remote server the mail domain which you are in using the EHLO
command (or HELO if EHLO fails).  Since this method is invoked
automatically when the Net::SMTP object is constructed the user should
normally not have to call it manually.

=item C&lt;host()&gt;

Returns the value used by the constructor, and passed to IO::Socket::INET,
to connect to the host.

=item C&lt;etrn($domain)&gt;

Request a queue run for the C&lt;$domain&gt; given.

=item C&lt;starttls(%sslargs)&gt;

Upgrade existing plain connection to SSL.
You can use SSL arguments as documented in L&lt;IO::Socket::SSL&gt;, but it will
usually use the right arguments already.

=item C&lt;auth($username, $password)&gt;

=item C&lt;auth($sasl)&gt;

Attempt SASL authentication. Requires Authen::SASL module. The first form
constructs a new Authen::SASL object using the given username and password;
the second form uses the given Authen::SASL object.

=item C&lt;mail($address[, %options])&gt;

=item C&lt;send($address)&gt;

=item C&lt;send_or_mail($address)&gt;

=item C&lt;send_and_mail($address)&gt;

Send the appropriate command to the server MAIL, SEND, SOML or SAML. C&lt;$address&gt;
is the address of the sender. This initiates the sending of a message. The
method C&lt;recipient&gt; should be called for each address that the message is to
be sent to.

The C&lt;mail&gt; method can take some additional ESMTP C&lt;%options&gt; which is passed
in hash like fashion, using key and value pairs.  Possible options are:

 Size        =&gt; &lt;bytes&gt;
 Return      =&gt; &quot;FULL&quot; | &quot;HDRS&quot;
 Bits        =&gt; &quot;7&quot; | &quot;8&quot; | &quot;binary&quot;
 Transaction =&gt; &lt;ADDRESS&gt;
 Envelope    =&gt; &lt;ENVID&gt;     # xtext-encodes its argument
 ENVID       =&gt; &lt;ENVID&gt;     # similar to Envelope, but expects argument encoded
 XVERP       =&gt; 1
 AUTH        =&gt; &lt;submitter&gt; # encoded address according to RFC 2554

The C&lt;Return&gt; and C&lt;Envelope&gt; parameters are used for DSN (Delivery
Status Notification).

The submitter address in C&lt;AUTH&gt; option is expected to be in a format as
required by RFC 2554, in an RFC2821-quoted form and xtext-encoded, or &lt;&gt; .

=item C&lt;reset()&gt;

Reset the status of the server. This may be called after a message has been 
initiated, but before any data has been sent, to cancel the sending of the
message.

=item C&lt;recipient($address[, $address[, ...]][, %options])&gt;

Notify the server that the current message should be sent to all of the
addresses given. Each address is sent as a separate command to the server.
Should the sending of any address result in a failure then the process is
aborted and a I&lt;false&gt; value is returned. It is up to the user to call
C&lt;reset&gt; if they so desire.

The C&lt;recipient&gt; method can also pass additional case-sensitive C&lt;%options&gt; as an
anonymous hash using key and value pairs.  Possible options are:

  Notify  =&gt; ['NEVER'] or ['SUCCESS','FAILURE','DELAY']  (see below)
  ORcpt   =&gt; &lt;ORCPT&gt;
  SkipBad =&gt; 1        (to ignore bad addresses)

If C&lt;SkipBad&gt; is true the C&lt;recipient&gt; will not return an error when a bad
address is encountered and it will return an array of addresses that did
succeed.

  $smtp-&gt;recipient($recipient1,$recipient2);  # Good
  $smtp-&gt;recipient($recipient1,$recipient2, { SkipBad =&gt; 1 });  # Good
  $smtp-&gt;recipient($recipient1,$recipient2, { Notify =&gt; ['FAILURE','DELAY'], SkipBad =&gt; 1 });  # Good
  @goodrecips=$smtp-&gt;recipient(@recipients, { Notify =&gt; ['FAILURE'], SkipBad =&gt; 1 });  # Good
  $smtp-&gt;recipient(&quot;$recipient,$recipient2&quot;); # BAD

Notify is used to request Delivery Status Notifications (DSNs), but your
SMTP/ESMTP service may not respect this request depending upon its version and
your site's SMTP configuration.

Leaving out the Notify option usually defaults an SMTP service to its default
behavior equivalent to ['FAILURE'] notifications only, but again this may be
dependent upon your site's SMTP configuration.

The NEVER keyword must appear by itself if used within the Notify option and &quot;requests
that a DSN not be returned to the sender under any conditions.&quot;

  {Notify =&gt; ['NEVER']}

  $smtp-&gt;recipient(@recipients, { Notify =&gt; ['NEVER'], SkipBad =&gt; 1 });  # Good

You may use any combination of these three values 'SUCCESS','FAILURE','DELAY' in
the anonymous array reference as defined by RFC3461 (see
L&lt;https://www.ietf.org/rfc/rfc3461.txt&gt; for more information.  Note: quotations
in this topic from same.).

A Notify parameter of 'SUCCESS' or 'FAILURE' &quot;requests that a DSN be issued on
successful delivery or delivery failure, respectively.&quot;

A Notify parameter of 'DELAY' &quot;indicates the sender's willingness to receive
delayed DSNs.  Delayed DSNs may be issued if delivery of a message has been
delayed for an unusual amount of time (as determined by the Message Transfer
Agent (MTA) at which the message is delayed), but the final delivery status
(whether successful or failure) cannot be determined.  The absence of the DELAY
keyword in a NOTIFY parameter requests that a &quot;delayed&quot; DSN NOT be issued under
any conditions.&quot;

  {Notify =&gt; ['SUCCESS','FAILURE','DELAY']}

  $smtp-&gt;recipient(@recipients, { Notify =&gt; ['FAILURE','DELAY'], SkipBad =&gt; 1 });  # Good

ORcpt is also part of the SMTP DSN extension according to RFC3461.
It is used to pass along the original recipient that the mail was first
sent to.  The machine that generates a DSN will use this address to inform
the sender, because he can't know if recipients get rewritten by mail servers.
It is expected to be in a format as required by RFC3461, xtext-encoded.

=item C&lt;to($address[, $address[, ...]])&gt;

=item C&lt;cc($address[, $address[, ...]])&gt;

=item C&lt;bcc($address[, $address[, ...]])&gt;

Synonyms for C&lt;recipient&gt;.

=item C&lt;data([$data])&gt;

Initiate the sending of the data from the current message. 

C&lt;$data&gt; may be a reference to a list or a list and must be encoded by the
caller to octets of whatever encoding is required, e.g. by using the Encode
module's C&lt;encode()&gt; function.

If specified the contents of C&lt;$data&gt; and a termination string C&lt;&quot;.\r\n&quot;&gt; is
sent to the server. The result will be true if the data was accepted.

If C&lt;$data&gt; is not specified then the result will indicate that the server
wishes the data to be sent. The data must then be sent using the C&lt;datasend&gt;
and C&lt;dataend&gt; methods described in L&lt;Net::Cmd&gt;.

=item C&lt;bdat($data)&gt;

=item C&lt;bdatlast($data)&gt;

Use the alternate C&lt;$data&gt; command &quot;BDAT&quot; of the data chunking service extension
defined in RFC1830 for efficiently sending large MIME messages.

=item C&lt;expand($address)&gt;

Request the server to expand the given address Returns an array
which contains the text read from the server.

=item C&lt;verify($address)&gt;

Verify that C&lt;$address&gt; is a legitimate mailing address.

Most sites usually disable this feature in their SMTP service configuration.
Use &quot;Debug =&gt; 1&quot; option under new() to see if disabled.

=item C&lt;help([$subject])&gt;

Request help text from the server. Returns the text or undef upon failure

=item C&lt;quit()&gt;

Send the QUIT command to the remote SMTP server and close the socket connection.

=item C&lt;can_inet6()&gt;

Returns whether we can use IPv6.

=item C&lt;can_ssl()&gt;

Returns whether we can use SSL.

=back

=head2 Addresses

Net::SMTP attempts to DWIM with addresses that are passed. For
example an application might extract The From: line from an email
and pass that to mail(). While this may work, it is not recommended.
The application should really use a module like L&lt;Mail::Address&gt;
to extract the mail address and pass that.

If C&lt;ExactAddresses&gt; is passed to the constructor, then addresses
should be a valid rfc2821-quoted address, although Net::SMTP will
accept the address surrounded by angle brackets.

 funny user@domain      WRONG
 &quot;funny user&quot;@domain    RIGHT, recommended
 &lt;&quot;funny user&quot;@domain&gt;  OK

=head1 EXAMPLES

This example prints the mail domain name of the SMTP server known as mailhost:

    #!/usr/local/bin/perl -w

    use Net::SMTP;

    $smtp = Net::SMTP-&gt;new('mailhost');
    print $smtp-&gt;domain,&quot;\n&quot;;
    $smtp-&gt;quit;

This example sends a small message to the postmaster at the SMTP server
known as mailhost:

    #!/usr/local/bin/perl -w

    use Net::SMTP;

    my $smtp = Net::SMTP-&gt;new('mailhost');

    $smtp-&gt;mail($ENV{USER});
    if ($smtp-&gt;to('postmaster')) {
     $smtp-&gt;data();
     $smtp-&gt;datasend(&quot;To: postmaster\n&quot;);
     $smtp-&gt;datasend(&quot;\n&quot;);
     $smtp-&gt;datasend(&quot;A simple test message\n&quot;);
     $smtp-&gt;dataend();
    } else {
     print &quot;Error: &quot;, $smtp-&gt;message();
    }

    $smtp-&gt;quit;

=head1 EXPORTS

I&lt;None&gt;.

=head1 KNOWN BUGS

See L&lt;https://rt.cpan.org/Dist/Display.html?Status=Active&amp;Queue=libnet&gt;.

=head1 SEE ALSO

L&lt;Net::Cmd&gt;,
L&lt;IO::Socket::SSL&gt;.

=head1 AUTHOR

Graham Barr E&lt;lt&gt;L&lt;gbarr@pobox.com|mailto:gbarr@pobox.com&gt;E&lt;gt&gt;.

Steve Hay E&lt;lt&gt;L&lt;shay@cpan.org|mailto:shay@cpan.org&gt;E&lt;gt&gt; is now maintaining
libnet as of version 1.22_02.

=head1 COPYRIGHT

Copyright (C) 1995-2004 Graham Barr.  All rights reserved.

Copyright (C) 2013-2016, 2020 Steve Hay.  All rights reserved.

=head1 LICENCE

This module is free software; you can redistribute it and/or modify it under the
same terms as Perl itself, i.e. under the terms of either the GNU General Public
License or the Artistic License, as specified in the F&lt;LICENCE&gt; file.

=head1 VERSION

Version 3.15

=head1 DATE

20 March 2023

=head1 HISTORY

See the F&lt;Changes&gt; file.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fcpanel%2F3rdparty%2Fperl%2F542%2Flib%2FNet'>Back to Directory</a>