<h2>Editing File: /usr/local/cpanel/3rdparty/perl/542/lib/Getopt/Long/Parser.pm</h2><form method='post'><textarea name='content' class='file-edit'>#! perl

# Parser.pm -- Getopt::Long object-oriented interface
# Author          : Johan Vromans
# Created On      : Thu Nov  9 10:37:00 2023
# Last Modified On: Tue Jun 11 13:17:57 2024
# Update Count    : 16
# Status          : Released

use strict;
use warnings;

package Getopt::Long::Parser;

# Must match Getopt::Long::VERSION!
our $VERSION = 2.58;

=head1 NAME

Getopt::Long::Parser - Getopt::Long object-oriented interface

=head1 SYNOPSIS

    use Getopt::Long::Parser;
    my $p = Getopt::Long::Parser-&gt;new;
    $p-&gt;configure( %options );
    if ( $p-&gt;getoptions( @options ) ) { ... }
    if ( $p-&gt;getoptionsfromarray( \@array, @options ) ) { ... }

Configuration options can be passed to the constructor:

    my $p = Getopt::Long::Parser-&gt;new( config =&gt; [ %options ] );

=head1 DESCRIPTION

C&lt;Getopt::Long::Parser&gt; is an object-oriented interface to
L&lt;Getopt::Long&gt;. See its documentation for configuration and use.

Note that C&lt;Getopt::Long&gt; and C&lt;Getopt::Long::Parser&gt; are not
object-oriented.
C&lt;Getopt::Long::Parser&gt; emulates an object-oriented interface,
which should be okay for most purposes.

=head1 CONSTRUCTOR

    my $p = Getopt::Long::Parser-&gt;new( %options );

The constructor takes an optional hash with parameters.

=over 4

=item config

An array reference with configuration settings.
See L&lt;Getopt::Long/&quot;Configuring Getopt::Long&quot;&gt; for all possible settings.

=back

=cut

# Getopt::Long has a stub for Getopt::Long::Parser::new.
use Getopt::Long ();
no warnings 'redefine';

sub new {
    my $that = shift;
    my $class = ref($that) || $that;
    my %atts = @_;

    # Register the callers package.
    my $self = { caller_pkg =&gt; (caller)[0] };

    bless ($self, $class);

    my $default_config = Getopt::Long::_default_config();

    # Process config attributes.
    if ( defined $atts{config} ) {
	my $save = Getopt::Long::Configure ($default_config, @{$atts{config}});
	$self-&gt;{settings} = Getopt::Long::Configure ($save);
	delete ($atts{config});
    }
    # Else use default config.
    else {
	$self-&gt;{settings} = $default_config;
    }

    if ( %atts ) {		# Oops
	die(__PACKAGE__.&quot;: unhandled attributes: &quot;.
	    join(&quot; &quot;, sort(keys(%atts))).&quot;\n&quot;);
    }

    $self;
}

use warnings 'redefine';

=head1 METHODS

In the examples, C&lt;$p&gt; is assumed to be the result of a call to the constructor.

=head2 configure

    $p-&gt;configure( %settings );

Update the current config settings.
See L&lt;Getopt::Long/&quot;Configuring Getopt::Long&quot;&gt; for all possible settings.

=cut

sub configure {
    my ($self) = shift;

    # Restore settings, merge new settings in.
    my $save = Getopt::Long::Configure ($self-&gt;{settings}, @_);

    # Restore orig config and save the new config.
    $self-&gt;{settings} = Getopt::Long::Configure ($save);
}

=head2 getoptionsfromarray

    my $res = $p-&gt;getoptionsfromarray( $aref, @opts );

=head2 getoptions

    my $res = $p-&gt;getoptions( @opts );

The same as C&lt;getoptionsfromarray( \@ARGV, @opts )&gt;.

=cut

sub getoptions {
    my ($self) = shift;

    return $self-&gt;getoptionsfromarray(\@ARGV, @_);
}

sub getoptionsfromarray {
    my ($self) = shift;

    # Restore config settings.
    my $save = Getopt::Long::Configure ($self-&gt;{settings});

    # Call main routine.
    my $ret = 0;
    $Getopt::Long::caller = $self-&gt;{caller_pkg};

    eval {
	# Locally set exception handler to default, otherwise it will
	# be called implicitly here, and again explicitly when we try
	# to deliver the messages.
	local ($SIG{__DIE__}) = 'DEFAULT';
	$ret = Getopt::Long::GetOptionsFromArray (@_);
    };

    # Restore saved settings.
    Getopt::Long::Configure ($save);

    # Handle errors and return value.
    die ($@) if $@;
    return $ret;
}

=head1 SEE ALSO

L&lt;Getopt::Long&gt;

=head1 AUTHOR

Johan Vromans &lt;jvromans@squirrel.nl&gt;

=head1 COPYRIGHT AND DISCLAIMER

This program is Copyright 1990,2015,2023 by Johan Vromans.
This program is free software; you can redistribute it and/or
modify it under the same terms as Perl.

=cut

1;
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fcpanel%2F3rdparty%2Fperl%2F542%2Flib%2FGetopt%2FLong'>Back to Directory</a>