<h2>Editing File: /usr/local/cpanel/3rdparty/perl/542/lib/ExtUtils/Typemaps/OutputMap.pm</h2><form method='post'><textarea name='content' class='file-edit'>package ExtUtils::Typemaps::OutputMap;
use 5.006001;
use strict;
use warnings;
our $VERSION = '3.57';

=head1 NAME

ExtUtils::Typemaps::OutputMap - Entry in the OUTPUT section of a typemap

=head1 SYNOPSIS

  use ExtUtils::Typemaps;
  ...
  my $output = $typemap-&gt;get_output_map('T_NV');
  my $code = $output-&gt;code();
  $output-&gt;code(&quot;...&quot;);

=head1 DESCRIPTION

Refer to L&lt;ExtUtils::Typemaps&gt; for details.

=head1 METHODS

=cut

=head2 new

Requires C&lt;xstype&gt; and C&lt;code&gt; parameters.

=cut

sub new {
  my $prot = shift;
  my $class = ref($prot)||$prot;
  my %args = @_;

  if (!ref($prot)) {
    if (not defined $args{xstype} or not defined $args{code}) {
      die(&quot;Need xstype and code parameters&quot;);
    }
  }

  my $self = bless(
    (ref($prot) ? {%$prot} : {})
    =&gt; $class
  );

  $self-&gt;{xstype} = $args{xstype} if defined $args{xstype};
  $self-&gt;{code} = $args{code} if defined $args{code};
  $self-&gt;{code} =~ s/^(?=\S)/\t/mg;

  return $self;
}

=head2 code

Returns or sets the OUTPUT mapping code for this entry.

=cut

sub code {
  $_[0]-&gt;{code} = $_[1] if @_ &gt; 1;
  return $_[0]-&gt;{code};
}

=head2 xstype

Returns the name of the XS type of the OUTPUT map.

=cut

sub xstype {
  return $_[0]-&gt;{xstype};
}

=head2 cleaned_code

Returns a cleaned-up copy of the code to which certain transformations
have been applied to make it more ANSI compliant.

=cut

sub cleaned_code {
  my $self = shift;
  my $code = $self-&gt;code;

  # Move C pre-processor instructions to column 1 to be strictly ANSI
  # conformant. Some pre-processors are fussy about this.
  $code =~ s/^\s+#/#/mg;
  $code =~ s/\s*\z/\n/;

  return $code;
}

=head2 targetable_legacy

Do not use for new code.

This is the original version of the targetable() method, whose behaviour
has been frozen for backwards compatibility. It is used to determine
whether to emit an early C&lt;dXSTARG&gt;, which will be in scope for most of
the XSUB. More recent XSUB code generation emits a C&lt;dXSTARG&gt; in a tighter
scope if one has not already been emitted. Some XS code assumes that
C&lt;TARG&gt; has been declared, so continue to declare it under the same
conditions as before. The newer C&lt;targetable&gt; method may be true under
additional circumstances.

If the optimization can not be applied, this returns undef.  If it can be
applied, this method returns a hash reference containing the following
information:

  type:      Any of the characters i, u, n, p
  with_size: Bool indicating whether this is the sv_setpvn variant
  what:      The code that actually evaluates to the output scalar
  what_size: If &quot;with_size&quot;, this has the string length (as code,
             not constant, including leading comma)


=cut

sub targetable_legacy {
  my $self = shift;
  return $self-&gt;{targetable_legacy} if exists $self-&gt;{targetable_legacy};

  our $bal; # ()-balanced
  $bal = qr[
    (?:
      (?&gt;[^()]+)
      |
      \( (??{ $bal }) \)
    )*
  ]x;
  my $bal_no_comma = qr[
    (?:
      (?&gt;[^(),]+)
      |
      \( (??{ $bal }) \)
    )+
  ]x;

  # matches variations on (SV*)
  my $sv_cast = qr[
    (?:
      \( \s* SV \s* \* \s* \) \s*
    )?
  ]x;

  my $size = qr[ # Third arg (to setpvn)
    , \s* (??{ $bal })
  ]xo;

  my $code = $self-&gt;code;

  # We can still bootstrap compile 're', because in code re.pm is
  # available to miniperl, and does not attempt to load the XS code.
  use re 'eval';

  my ($type, $with_size, $arg, $sarg) =
    ($code =~
      m[^
        \s+
        sv_set([iunp])v(n)?    # Type, is_setpvn
        \s*
        \( \s*
          $sv_cast \$arg \s* , \s*
          ( $bal_no_comma )    # Set from
          ( $size )?           # Possible sizeof set-from
        \s* \) \s* ; \s* $
      ]xo
  );

  my $rv = undef;
  if ($type) {
    $rv = {
      type      =&gt; $type,
      with_size =&gt; $with_size,
      what      =&gt; $arg,
      what_size =&gt; $sarg,
    };
  }
  $self-&gt;{targetable_legacy} = $rv;
  return $rv;
}

=head2 targetable

Class method.

Return a boolean indicating whether the supplied code snippet is suitable
for using TARG as the destination SV rather than an new mortal.

In principle most things are, except expressions which would set the SV
to a ref value. That can cause the referred value to never be freed, as
targs aren't freed (at least for the lifetime of their CV). So in
practice, we restrict it to an approved list of sv_setfoo() forms, and
only where there is no extra code following the sv_setfoo() (so we have to
match the closing bracket, allowing for nested brackets etc within).

=cut

my %targetable_cache;

sub targetable {
  my ($class, $code) = @_;

  return $targetable_cache{$code} if exists $targetable_cache{$code};

  # Match a string with zero or more balanced/nested parentheses
  # within it, e.g.
  #
  #   &quot;aa,bb(cc,dd)ee(ff,gg(hh,ii)jj,kk)ll&quot;

  our $bal;
  $bal = qr[
    (?:
      (?&gt;[^()]+)
      |
      &quot; ([^&quot;] | \\&quot;)* &quot;
      |
      \( (??{ $bal }) \)
    )*
  ]x;

  # Like $bal, but doesn't allow commas at the *top* level; e.g.
  #
  #       &quot;aabb(cc,dd)ee(ff,gg(hh,ii)jj,kk)ll&quot;
  #
  # Something like &quot;aa,bb(cc,dd)&quot; will just match/consume the &quot;aa&quot;
  # part of the string.

  my $bal_no_comma = qr[
    (?:
      (?&gt;[^(),]+)
      |
      &quot; ([^&quot;] | \\&quot;)* &quot;
      |
      \( (??{ $bal }) \)
    )+
  ]x;

  # the SV whose value is to be set (typically arg 1)
  # Note that currently ParseXS will always call with $arg expanded
  # to 'RETVALSV', but also match other possibilities too for future
  # use.

  my $target = qr[
    (?:
      \( \s* SV \s* \* \s* \) \s*   # optional SV* cast
    )?
    (?:
        \$arg
    |
        RETVAL
    |
        RETVALSV
    |
        ST\(\d+\)
    )
    \s*
  ]x;

  # We can still bootstrap compile 're', because in code re.pm is
  # available to miniperl, and does not attempt to load the XS code.
  use re 'eval';

  my $match =
    ($code =~
      m[^
        \s*
        (?:
            # 1-arg functions
            sv_set_(?:undef|true|false)
            \s*
            \( \s*
              $target                # arg 1: SV to set
        |
            # 2-arg functions
            sv_set(?:iv|iv_mg|uv|uv_mg|nv|nv_mg|pv|pv_mg|_bool)
            \s*
            \( \s*
              $target                # arg 1: SV to set
              , \s*
              $bal_no_comma          # arg 2: value to use
        |
            # 3-arg functions
            sv_set(?:pvn|pvn_mg)
            \s*
            \( \s*
              $target                # arg 1: SV to set
              , \s*
              $bal_no_comma          # arg 2: value to use
              , \s*
              $bal_no_comma          # arg 3: length
        )
        \s* \)
        \s* ; \s*
        $
      ]xo
  );

  $targetable_cache{$code} = $match;
  return $match;
}

=head1 SEE ALSO

L&lt;ExtUtils::Typemaps&gt;

=head1 AUTHOR

Steffen Mueller C&lt;&lt;smueller@cpan.org&gt;&gt;

=head1 COPYRIGHT &amp; LICENSE

Copyright 2009, 2010, 2011, 2012 Steffen Mueller

This program is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.

=cut

1;

</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fcpanel%2F3rdparty%2Fperl%2F542%2Flib%2FExtUtils%2FTypemaps'>Back to Directory</a>