<h2>Editing File: /usr/local/cpanel/3rdparty/perl/542/lib/App/Cpan.pm</h2><form method='post'><textarea name='content' class='file-edit'>package App::Cpan;

use strict;
use warnings;
use vars qw($VERSION);

use if $] &lt; 5.008 =&gt; 'IO::Scalar';

$VERSION = '1.678';

=head1 NAME

App::Cpan - easily interact with CPAN from the command line

=head1 SYNOPSIS

	# with arguments and no switches, installs specified modules
	cpan module_name [ module_name ... ]

	# with switches, installs modules with extra behavior
	cpan [-cfFimtTw] module_name [ module_name ... ]

	# use local::lib
	cpan -I module_name [ module_name ... ]

	# one time mirror override for faster mirrors
	cpan -p ...

	# with just the dot, install from the distribution in the
	# current directory
	cpan .

	# without arguments, starts CPAN.pm shell
	cpan

	# without arguments, but some switches
	cpan [-ahpruvACDLOPX]

=head1 DESCRIPTION

This script provides a command interface (not a shell) to CPAN. At the
moment it uses CPAN.pm to do the work, but it is not a one-shot command
runner for CPAN.pm.

=head2 Options

=over 4

=item -a

Creates a CPAN.pm autobundle with CPAN::Shell-&gt;autobundle.

=item -A module [ module ... ]

Shows the primary maintainers for the specified modules.

=item -c module

Runs a `make clean` in the specified module's directories.

=item -C module [ module ... ]

Show the F&lt;Changes&gt; files for the specified modules

=item -D module [ module ... ]

Show the module details. This prints one line for each out-of-date module
(meaning, modules locally installed but have newer versions on CPAN).
Each line has three columns: module name, local version, and CPAN
version.

=item -f

Force the specified action, when it normally would have failed. Use this
to install a module even if its tests fail. When you use this option,
-i is not optional for installing a module when you need to force it:

	% cpan -f -i Module::Foo

=item -F

Turn off CPAN.pm's attempts to lock anything. You should be careful with
this since you might end up with multiple scripts trying to muck in the
same directory. This isn't so much of a concern if you're loading a special
config with C&lt;-j&gt;, and that config sets up its own work directories.

=item -g module [ module ... ]

Downloads to the current directory the latest distribution of the module.

=item -G module [ module ... ]

UNIMPLEMENTED

Download to the current directory the latest distribution of the
modules, unpack each distribution, and create a git repository for each
distribution.

If you want this feature, check out Yanick Champoux's C&lt;Git::CPAN::Patch&gt;
distribution.

=item -h

Print a help message and exit. When you specify C&lt;-h&gt;, it ignores all
of the other options and arguments.

=item -i module [ module ... ]

Install the specified modules. With no other switches, this switch
is implied.

=item -I

Load C&lt;local::lib&gt; (think like C&lt;-I&gt; for loading lib paths). Too bad
C&lt;-l&gt; was already taken.

=item -j Config.pm

Load the file that has the CPAN configuration data. This should have the
same format as the standard F&lt;CPAN/Config.pm&gt; file, which defines
C&lt;$CPAN::Config&gt; as an anonymous hash.

If the file does not exist, C&lt;cpan&gt; dies.

=item -J

Dump the configuration in the same format that CPAN.pm uses. This is useful
for checking the configuration as well as using the dump as a starting point
for a new, custom configuration.

=item -l

List all installed modules with their versions

=item -L author [ author ... ]

List the modules by the specified authors.

=item -m

Make the specified modules.

=item -M mirror1,mirror2,...

A comma-separated list of mirrors to use for just this run. The C&lt;-P&gt;
option can find them for you automatically.

=item -n

Do a dry run, but don't actually install anything. (unimplemented)

=item -O

Show the out-of-date modules.

=item -p

Ping the configured mirrors and print a report

=item -P

Find the best mirrors you could be using and use them for the current
session.

=item -r

Recompiles dynamically loaded modules with CPAN::Shell-&gt;recompile.

=item -s

Drop in the CPAN.pm shell. This command does this automatically if you don't
specify any arguments.

=item -t module [ module ... ]

Run a `make test` on the specified modules.

=item -T

Do not test modules. Simply install them.

=item -u

Upgrade all installed modules. Blindly doing this can really break things,
so keep a backup.

=item -v

Print the script version and CPAN.pm version then exit.

=item -V

Print detailed information about the cpan client.

=item -w

UNIMPLEMENTED

Turn on cpan warnings. This checks various things, like directory permissions,
and tells you about problems you might have.

=item -x module [ module ... ]

Find close matches to the named modules that you think you might have
mistyped. This requires the optional installation of Text::Levenshtein or
Text::Levenshtein::Damerau.

=item -X

Dump all the namespaces to standard output.

=back

=head2 Examples

	# print a help message
	cpan -h

	# print the version numbers
	cpan -v

	# create an autobundle
	cpan -a

	# recompile modules
	cpan -r

	# upgrade all installed modules
	cpan -u

	# install modules ( sole -i is optional )
	cpan -i Netscape::Booksmarks Business::ISBN

	# force install modules ( must use -i )
	cpan -fi CGI::Minimal URI

	# install modules but without testing them
	cpan -Ti CGI::Minimal URI

=head2 Environment variables

There are several components in CPAN.pm that use environment variables.
The build tools, L&lt;ExtUtils::MakeMaker&gt; and L&lt;Module::Build&gt; use some,
while others matter to the levels above them. Some of these are specified
by the Perl Toolchain Gang:

Lancaster Consensus: L&lt;https://github.com/Perl-Toolchain-Gang/toolchain-site/blob/master/lancaster-consensus.md&gt;

Oslo Consensus: L&lt;https://github.com/Perl-Toolchain-Gang/toolchain-site/blob/master/oslo-consensus.md&gt;

=over 4

=item NONINTERACTIVE_TESTING

Assume no one is paying attention and skips prompts for distributions
that do that correctly. C&lt;cpan(1)&gt; sets this to C&lt;1&gt; unless it already
has a value (even if that value is false).

=item PERL_MM_USE_DEFAULT

Use the default answer for a prompted questions. C&lt;cpan(1)&gt; sets this
to C&lt;1&gt; unless it already has a value (even if that value is false).

=item CPAN_OPTS

As with C&lt;PERL5OPT&gt;, a string of additional C&lt;cpan(1)&gt; options to
add to those you specify on the command line.

=item CPANSCRIPT_LOGLEVEL

The log level to use, with either the embedded, minimal logger or
L&lt;Log::Log4perl&gt; if it is installed. Possible values are the same as
the C&lt;Log::Log4perl&gt; levels: C&lt;TRACE&gt;, C&lt;DEBUG&gt;, C&lt;INFO&gt;, C&lt;WARN&gt;,
C&lt;ERROR&gt;, and C&lt;FATAL&gt;. The default is C&lt;INFO&gt;.

=item GIT_COMMAND

The path to the C&lt;git&gt; binary to use for the Git features. The default
is C&lt;/usr/local/bin/git&gt;.

=back

=head2 Methods

=over 4

=cut

use autouse Carp =&gt; qw(carp croak cluck);
use CPAN 1.80 (); # needs no test
use Config;
use autouse Cwd =&gt; qw(cwd);
use autouse 'Data::Dumper' =&gt; qw(Dumper);
use File::Spec::Functions qw(catfile file_name_is_absolute rel2abs);
use File::Basename;
use Getopt::Std;

# # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # #
# Internal constants
use constant TRUE  =&gt; 1;
use constant FALSE =&gt; 0;


# # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # #
# The return values
use constant HEY_IT_WORKED              =&gt;   0;
use constant I_DONT_KNOW_WHAT_HAPPENED  =&gt;   1; # 0b0000_0001
use constant ITS_NOT_MY_FAULT           =&gt;   2;
use constant THE_PROGRAMMERS_AN_IDIOT   =&gt;   4;
use constant A_MODULE_FAILED_TO_INSTALL =&gt;   8;


# # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # #
# set up the order of options that we layer over CPAN::Shell
BEGIN { # most of this should be in methods
use vars qw( @META_OPTIONS $Default %CPAN_METHODS @CPAN_OPTIONS  @option_order
	%Method_table %Method_table_index );

@META_OPTIONS = qw( h v V I g G M: C A D O l L a r p P j: J w x X );

$Default = 'default';

%CPAN_METHODS = ( # map switches to method names in CPAN::Shell
	$Default =&gt; 'install',
	'c'      =&gt; 'clean',
	'f'      =&gt; 'force',
	'i'      =&gt; 'install',
	'm'      =&gt; 'make',
	't'      =&gt; 'test',
	'u'      =&gt; 'upgrade',
	'T'      =&gt; 'notest',
	's'      =&gt; 'shell',
	);
@CPAN_OPTIONS = grep { $_ ne $Default } sort keys %CPAN_METHODS;

@option_order = ( @META_OPTIONS, @CPAN_OPTIONS );


# # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # #
# map switches to the subroutines in this script, along with other information.
# use this stuff instead of hard-coded indices and values
sub NO_ARGS   () { 0 }
sub ARGS      () { 1 }
sub GOOD_EXIT () { 0 }

%Method_table = (
# key =&gt; [ sub ref, takes args?, exit value, description ]

	# options that do their thing first, then exit
	h =&gt;  [ \&amp;_print_help,          NO_ARGS, GOOD_EXIT, 'Printing help'                ],
	v =&gt;  [ \&amp;_print_version,       NO_ARGS, GOOD_EXIT, 'Printing version'             ],
	V =&gt;  [ \&amp;_print_details,       NO_ARGS, GOOD_EXIT, 'Printing detailed version'    ],
	X =&gt;  [ \&amp;_list_all_namespaces, NO_ARGS, GOOD_EXIT, 'Listing all namespaces'       ],

	# options that affect other options
	j =&gt;  [ \&amp;_load_config,          ARGS, GOOD_EXIT, 'Use specified config file'    ],
	J =&gt;  [ \&amp;_dump_config,       NO_ARGS, GOOD_EXIT, 'Dump configuration to stdout' ],
	F =&gt;  [ \&amp;_lock_lobotomy,     NO_ARGS, GOOD_EXIT, 'Turn off CPAN.pm lock files'  ],
	I =&gt;  [ \&amp;_load_local_lib,    NO_ARGS, GOOD_EXIT, 'Loading local::lib'           ],
	M =&gt;  [ \&amp;_use_these_mirrors,    ARGS, GOOD_EXIT, 'Setting per session mirrors'  ],
	P =&gt;  [ \&amp;_find_good_mirrors, NO_ARGS, GOOD_EXIT, 'Finding good mirrors'         ],
	w =&gt;  [ \&amp;_turn_on_warnings,  NO_ARGS, GOOD_EXIT, 'Turning on warnings'          ],

	# options that do their one thing
	g =&gt;  [ \&amp;_download,             ARGS, GOOD_EXIT, 'Download the latest distro'        ],
	G =&gt;  [ \&amp;_gitify,               ARGS, GOOD_EXIT, 'Down and gitify the latest distro' ],

	C =&gt;  [ \&amp;_show_Changes,         ARGS, GOOD_EXIT, 'Showing Changes file'         ],
	A =&gt;  [ \&amp;_show_Author,          ARGS, GOOD_EXIT, 'Showing Author'               ],
	D =&gt;  [ \&amp;_show_Details,         ARGS, GOOD_EXIT, 'Showing Details'              ],
	O =&gt;  [ \&amp;_show_out_of_date,  NO_ARGS, GOOD_EXIT, 'Showing Out of date'          ],
	l =&gt;  [ \&amp;_list_all_mods,     NO_ARGS, GOOD_EXIT, 'Listing all modules'          ],

	L =&gt;  [ \&amp;_show_author_mods,     ARGS, GOOD_EXIT, 'Showing author mods'          ],
	a =&gt;  [ \&amp;_create_autobundle, NO_ARGS, GOOD_EXIT, 'Creating autobundle'          ],
	p =&gt;  [ \&amp;_ping_mirrors,      NO_ARGS, GOOD_EXIT, 'Pinging mirrors'              ],

	r =&gt;  [ \&amp;_recompile,         NO_ARGS, GOOD_EXIT, 'Recompiling'                  ],
	u =&gt;  [ \&amp;_upgrade,           NO_ARGS, GOOD_EXIT, 'Running `make test`'          ],
	's' =&gt; [ \&amp;_shell,            NO_ARGS, GOOD_EXIT, 'Drop into the CPAN.pm shell'  ],

	'x' =&gt; [ \&amp;_guess_namespace,     ARGS, GOOD_EXIT, 'Guessing namespaces'          ],
	c =&gt;  [ \&amp;_default,              ARGS, GOOD_EXIT, 'Running `make clean`'         ],
	f =&gt;  [ \&amp;_default,              ARGS, GOOD_EXIT, 'Installing with force'        ],
	i =&gt;  [ \&amp;_default,              ARGS, GOOD_EXIT, 'Running `make install`'       ],
	'm' =&gt; [ \&amp;_default,             ARGS, GOOD_EXIT, 'Running `make`'               ],
	t =&gt;  [ \&amp;_default,              ARGS, GOOD_EXIT, 'Running `make test`'          ],
	T =&gt;  [ \&amp;_default,              ARGS, GOOD_EXIT, 'Installing with notest'       ],
	);

%Method_table_index = (
	code        =&gt; 0,
	takes_args  =&gt; 1,
	exit_value  =&gt; 2,
	description =&gt; 3,
	);
}


# # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # #
# finally, do some argument processing

sub _stupid_interface_hack_for_non_rtfmers
	{
	no warnings 'uninitialized';
	shift @ARGV if( $ARGV[0] eq 'install' and @ARGV &gt; 1 )
	}

sub _process_options
	{
	my %options;

	push @ARGV, grep $_, split /\s+/, $ENV{CPAN_OPTS} || '';

	# if no arguments, just drop into the shell
	if( 0 == @ARGV ) { CPAN::shell(); exit 0 }
	elsif (Getopt::Std::getopts(
		  join( '', @option_order ), \%options ))
		{
		 \%options;
		}
	else { exit 1 }
}

sub _process_setup_options
	{
	my( $class, $options ) = @_;

	if( $options-&gt;{j} )
		{
		$Method_table{j}[ $Method_table_index{code} ]-&gt;( $options-&gt;{j} );
		delete $options-&gt;{j};
		}
	elsif ( ! $options-&gt;{h} ) { # h &quot;ignores all of the other options and arguments&quot;
		# this is what CPAN.pm would do otherwise
		local $CPAN::Be_Silent = 1;
		CPAN::HandleConfig-&gt;load(
			# be_silent  =&gt; 1, deprecated
			write_file =&gt; 0,
			);
		}

	$class-&gt;_turn_off_testing if $options-&gt;{T};

	foreach my $o ( qw(F I w P M) )
		{
		next unless exists $options-&gt;{$o};
		$Method_table{$o}[ $Method_table_index{code} ]-&gt;( $options-&gt;{$o} );
		delete $options-&gt;{$o};
		}

	if( $options-&gt;{o} )
		{
		my @pairs = map { [ split /=/, $_, 2 ] } split /,/, $options-&gt;{o};
		foreach my $pair ( @pairs )
			{
			my( $setting, $value ) = @$pair;
			$CPAN::Config-&gt;{$setting} = $value;
		#	$logger-&gt;debug( &quot;Setting [$setting] to [$value]&quot; );
			}
		delete $options-&gt;{o};
		}

	my $option_count = grep { $options-&gt;{$_} } @option_order;
	no warnings 'uninitialized';

	# don't count options that imply installation
	foreach my $opt ( qw(f T) ) { # don't count force or notest
		$option_count -= $options-&gt;{$opt};
		}

	# # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # #
	# if there are no options, set -i (this line fixes RT ticket 16915)
	$options-&gt;{i}++ unless $option_count;
	}

sub _setup_environment {
# should we override or set defaults? If this were a true interactive
# session, we'd be in the CPAN shell.

# https://github.com/Perl-Toolchain-Gang/toolchain-site/blob/master/lancaster-consensus.md
	$ENV{NONINTERACTIVE_TESTING} = 1 unless defined $ENV{NONINTERACTIVE_TESTING};
	$ENV{PERL_MM_USE_DEFAULT}    = 1 unless defined $ENV{PERL_MM_USE_DEFAULT};
	}

=item run( ARGS )

Just do it.

The C&lt;run&gt; method returns 0 on success and a positive number on
failure. See the section on EXIT CODES for details on the values.

=cut

my $logger;

sub run
	{
	my( $class, @args ) = @_;
	local @ARGV = @args;
	my $return_value = HEY_IT_WORKED; # assume that things will work

	$logger = $class-&gt;_init_logger;
	$logger-&gt;debug( &quot;Using logger from @{[ref $logger]}&quot; );

	$class-&gt;_hook_into_CPANpm_report;
	$logger-&gt;debug( &quot;Hooked into output&quot; );

	$class-&gt;_stupid_interface_hack_for_non_rtfmers;
	$logger-&gt;debug( &quot;Patched cargo culting&quot; );

	my $options = $class-&gt;_process_options;
	$logger-&gt;debug( &quot;Options are @{[Dumper($options)]}&quot; );

	$class-&gt;_process_setup_options( $options );

	$class-&gt;_setup_environment( $options );

	OPTION: foreach my $option ( @option_order )
		{
		next unless $options-&gt;{$option};

		my( $sub, $takes_args, $description ) =
			map { $Method_table{$option}[ $Method_table_index{$_} ] }
			qw( code takes_args description );

		unless( ref $sub eq ref sub {} )
			{
			$return_value = THE_PROGRAMMERS_AN_IDIOT;
			last OPTION;
			}

		$logger-&gt;info( &quot;[$option] $description -- ignoring other arguments&quot; )
			if( @ARGV &amp;&amp; ! $takes_args );

		$return_value = $sub-&gt;( \ @ARGV, $options );

		last;
		}

	return $return_value;
	}

my $LEVEL;
{
package
  Local::Null::Logger; # hide from PAUSE

my @LOGLEVELS = qw(TRACE DEBUG INFO WARN ERROR FATAL);
$LEVEL        = uc($ENV{CPANSCRIPT_LOGLEVEL} || 'INFO');
my %LL        = map { $LOGLEVELS[$_] =&gt; $_ } 0..$#LOGLEVELS;
unless (defined $LL{$LEVEL}){
	warn &quot;Unsupported loglevel '$LEVEL', setting to INFO&quot;;
	$LEVEL = 'INFO';
}
sub new { bless \ my $x, $_[0] }
sub AUTOLOAD {
	my $autoload = our $AUTOLOAD;
	$autoload =~ s/.*://;
	return if $LL{uc $autoload} &lt; $LL{$LEVEL};
	$CPAN::Frontend-&gt;mywarn(&quot;&gt;($autoload): $_\n&quot;)
		for split /[\r\n]+/, $_[1];
}
sub DESTROY { 1 }
}

# load a module without searching the default entry for the current
# directory
sub _safe_load_module {
	my $name = shift;

	local @INC = @INC;
	pop @INC if $INC[-1] eq '.';

	eval &quot;require $name; 1&quot;;
}

sub _init_logger
	{
	my $log4perl_loaded = _safe_load_module(&quot;Log::Log4perl&quot;);

	unless( $log4perl_loaded )
		{
		print STDOUT &quot;Loading internal logger. Log::Log4perl recommended for better logging\n&quot;;
		$logger = Local::Null::Logger-&gt;new;
		return $logger;
		}

	Log::Log4perl::init( \ &lt;&lt;&quot;HERE&quot; );
log4perl.rootLogger=$LEVEL, A1
log4perl.appender.A1=Log::Log4perl::Appender::Screen
log4perl.appender.A1.layout=PatternLayout
log4perl.appender.A1.layout.ConversionPattern=%m%n
HERE

	$logger = Log::Log4perl-&gt;get_logger( 'App::Cpan' );
	}

# # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # #
 # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # #
# # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # #

sub _default
	{
	my( $args, $options ) = @_;

	my $switch = '';

	# choose the option that we're going to use
	# we'll deal with 'f' (force) later, so skip it
	foreach my $option ( @CPAN_OPTIONS )
		{
		next if ( $option eq 'f' or $option eq 'T' );
		next unless $options-&gt;{$option};
		$switch = $option;
		last;
		}

	# 1. with no switches, but arguments, use the default switch (install)
	# 2. with no switches and no args, start the shell
	# 3. With a switch but no args, die! These switches need arguments.
	   if( not $switch and     @$args ) { $switch = $Default;  }
	elsif( not $switch and not @$args ) { return CPAN::shell() }
	elsif(     $switch and not @$args )
		{ die &quot;Nothing to $CPAN_METHODS{$switch}!\n&quot;; }

	# Get and check the method from CPAN::Shell
	my $method = $CPAN_METHODS{$switch};
	die &quot;CPAN.pm cannot $method!\n&quot; unless CPAN::Shell-&gt;can( $method );

	# call the CPAN::Shell method, with force or notest if specified
	my $action = do {
		   if( $options-&gt;{f} ) { sub { CPAN::Shell-&gt;force( $method, @_ )  } }
		elsif( $options-&gt;{T} ) { sub { CPAN::Shell-&gt;notest( $method, @_ ) } }
		else                   { sub { CPAN::Shell-&gt;$method( @_ )         } }
		};

	# How do I handle exit codes for multiple arguments?
	my @errors = ();

	$options-&gt;{x} or _disable_guessers();

	foreach my $arg ( @$args )
		{
		# check the argument and perhaps capture typos
		my $module = _expand_module( $arg ) or do {
			$logger-&gt;error( &quot;Skipping $arg because I couldn't find a matching namespace.&quot; );
			next;
			};

		_clear_cpanpm_output();
		$action-&gt;( $arg );

		my $error = _cpanpm_output_indicates_failure();
		push @errors, $error if $error;
		}

	return do {
		if( @errors ) { $errors[0] }
		else { HEY_IT_WORKED }
		};

	}

# # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # #

=for comment

CPAN.pm sends all the good stuff either to STDOUT, or to a temp
file if $CPAN::Be_Silent is set. I have to intercept that output
so I can find out what happened.

=cut

BEGIN {
my $scalar = '';

sub _hook_into_CPANpm_report
	{
	no warnings 'redefine';

	*CPAN::Shell::myprint = sub {
		my($self,$what) = @_;
		$scalar .= $what if defined $what;
		$self-&gt;print_ornamented($what,
			$CPAN::Config-&gt;{colorize_print}||'bold blue on_white',
			);
		};

	*CPAN::Shell::mywarn = sub {
		my($self,$what) = @_;
		$scalar .= $what if defined $what;
		$self-&gt;print_ornamented($what,
			$CPAN::Config-&gt;{colorize_warn}||'bold red on_white'
			);
		};

	}

sub _clear_cpanpm_output { $scalar = '' }

sub _get_cpanpm_output   { $scalar }

# These are lines I don't care about in CPAN.pm output. If I can
# filter out the informational noise, I have a better chance to
# catch the error signal
my @skip_lines = (
	qr/^\QWarning \(usually harmless\)/,
	qr/\bwill not store persistent state\b/,
	qr(//hint//),
	qr/^\s+reports\s+/,
	qr/^Try the command/,
	qr/^\s+$/,
	qr/^to find objects/,
	qr/^\s*Database was generated on/,
	qr/^Going to read/,
	qr|^\s+i\s+/|,    # the i /Foo::Whatever/ line when it doesn't know
	);

sub _get_cpanpm_last_line
	{
	my $fh;

	if( $] &lt; 5.008 ) {
		$fh = IO::Scalar-&gt;new( \ $scalar );
		}
	else {
		eval q{ open $fh, '&lt;', \\ $scalar; };
		}

	my @lines = &lt;$fh&gt;;

	# This is a bit ugly. Once we examine a line, we have to
	# examine the line before it and go through all of the same
	# regexes. I could do something fancy, but this works.
	REGEXES: {
	foreach my $regex ( @skip_lines )
		{
		if( $lines[-1] =~ m/$regex/ )
			{
			pop @lines;
			redo REGEXES; # we have to go through all of them for every line!
			}
		}
	}

	$logger-&gt;debug( &quot;Last interesting line of CPAN.pm output is:\n\t$lines[-1]&quot; );

	$lines[-1];
	}
}

BEGIN {
my $epic_fail_words = join '|',
	qw( Error stop(?:ping)? problems force not unsupported
		fail(?:ed)? Cannot\s+install );

sub _cpanpm_output_indicates_failure
	{
	my $last_line = _get_cpanpm_last_line();

	my $result = $last_line =~ /\b(?:$epic_fail_words)\b/i;
	return A_MODULE_FAILED_TO_INSTALL if $last_line =~ /\b(?:Cannot\s+install)\b/i;

	$result || ();
	}
}

sub _cpanpm_output_indicates_success
	{
	my $last_line = _get_cpanpm_last_line();

	my $result = $last_line =~ /\b(?:\s+-- OK|PASS)\b/;
	$result || ();
	}

sub _cpanpm_output_is_vague
	{
	return FALSE if
		_cpanpm_output_indicates_failure() ||
		_cpanpm_output_indicates_success();

	return TRUE;
	}

# # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # #
sub _turn_on_warnings {
	carp &quot;Warnings are implemented yet&quot;;
	return HEY_IT_WORKED;
	}

sub _turn_off_testing {
	$logger-&gt;debug( 'Trusting test report history' );
	$CPAN::Config-&gt;{trust_test_report_history} = 1;
	return HEY_IT_WORKED;
	}

# # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # # #
sub _print_help
	{
	$logger-&gt;info( &quot;Use perldoc to read the documentation&quot; );
	my $HAVE_PERLDOC = eval { require Pod::Perldoc; 1; };
	if ($HAVE_PERLDOC) {
		system qq{&quot;$^X&quot; -e &quot;require Pod::Perldoc; Pod::Perldoc-&gt;run()&quot; $0};
		exit;
	} else {
		warn &quot;Please install Pod::Perldoc, maybe try 'cpan -i Pod::Perldoc'\n&quot;;
		return HEY_IT_WORKED;
	}
	}

sub _print_version # -v
	{
	$logger-&gt;info(
		&quot;$0 script version $VERSION, CPAN.pm version &quot; . CPAN-&gt;VERSION );

	return HEY_IT_WORKED;
	}

sub _print_details # -V
	{
	_print_version();

	_check_install_dirs();

	$logger-&gt;info( '-' x 50 . &quot;\nChecking configured mirrors...&quot; );
	foreach my $mirror ( @{ $CPAN::Config-&gt;{urllist} } ) {
		_print_ping_report( $mirror );
		}

	$logger-&gt;info( '-' x 50 . &quot;\nChecking for faster mirrors...&quot; );

	{
	require CPAN::Mirrors;

	if ( $CPAN::Config-&gt;{connect_to_internet_ok} ) {
		$CPAN::Frontend-&gt;myprint(qq{Trying to fetch a mirror list from the Internet\n});
		eval { CPAN::FTP-&gt;localize('MIRRORED.BY',File::Spec-&gt;catfile($CPAN::Config-&gt;{keep_source_where},'MIRRORED.BY'),3,1) }
			or $CPAN::Frontend-&gt;mywarn(&lt;&lt;'HERE');
We failed to get a copy of the mirror list from the Internet.
You will need to provide CPAN mirror URLs yourself.
HERE
		$CPAN::Frontend-&gt;myprint(&quot;\n&quot;);
		}

	my $mirrors   = CPAN::Mirrors-&gt;new( _mirror_file() );
	my @continents = $mirrors-&gt;find_best_continents;

	my @mirrors   = $mirrors-&gt;get_mirrors_by_continents( $continents[0] );
	my @timings   = $mirrors-&gt;get_mirrors_timings( \@mirrors );

	foreach my $timing ( @timings ) {
		$logger-&gt;info( sprintf &quot;%s (%0.2f ms)&quot;,
			$timing-&gt;hostname, $timing-&gt;rtt );
		}
	}

	return HEY_IT_WORKED;
	}

sub _check_install_dirs
	{
	my $makepl_arg   = $CPAN::Config-&gt;{makepl_arg};
	my $mbuildpl_arg = $CPAN::Config-&gt;{mbuildpl_arg};

	my @custom_dirs;
	# PERL_MM_OPT
	push @custom_dirs,
		$makepl_arg   =~ m/INSTALL_BASE\s*=\s*(\S+)/g,
		$mbuildpl_arg =~ m/--install_base\s*=\s*(\S+)/g;

	if( @custom_dirs ) {
		foreach my $dir ( @custom_dirs ) {
			_print_inc_dir_report( $dir );
			}
		}

	# XXX: also need to check makepl_args, etc

	my @checks = (
		[ 'core',         [ grep $_, @Config{qw(installprivlib installarchlib)}      ] ],
		[ 'vendor',       [ grep $_, @Config{qw(installvendorlib installvendorarch)} ] ],
		[ 'site',         [ grep $_, @Config{qw(installsitelib installsitearch)}     ] ],
		[ 'PERL5LIB',     _split_paths( $ENV{PERL5LIB} ) ],
		[ 'PERLLIB',      _split_paths( $ENV{PERLLIB} )  ],
		);

	$logger-&gt;info( '-' x 50 . &quot;\nChecking install dirs...&quot; );
	foreach my $tuple ( @checks ) {
		my( $label ) = $tuple-&gt;[0];

		$logger-&gt;info( &quot;Checking $label&quot; );
		$logger-&gt;info( &quot;\tno directories for $label&quot; ) unless @{ $tuple-&gt;[1] };
		foreach my $dir ( @{ $tuple-&gt;[1] } ) {
			_print_inc_dir_report( $dir );
			}
		}

	}

sub _split_paths
	{
	[ map { _expand_filename( $_ ) } split /$Config{path_sep}/, $_[0] || '' ];
	}


=pod

Stolen from File::Path::Expand

=cut

sub _expand_filename
	{
	my( $path ) = @_;
	no warnings 'uninitialized';
	$logger-&gt;debug( &quot;Expanding path $path\n&quot; );
	$path =~ s{\A~([^/]+)?}{
		_home_of( $1 || $&gt; ) || &quot;~$1&quot;
		}e;
	return $path;
	}

sub _home_of
	{
	require User::pwent;
	my( $user ) = @_;
	my $ent = User::pwent::getpw($user) or return;
	return $ent-&gt;dir;
	}

sub _get_default_inc
	{
	require Config;

	[ @Config::Config{ _vars() }, '.' ];
	}

sub _vars {
	qw(
	installarchlib
	installprivlib
	installsitearch
	installsitelib
	);
	}

sub _ping_mirrors {
	my $urls   = $CPAN::Config-&gt;{urllist};
	require URI;

	foreach my $url ( @$urls ) {
		my( $obj ) = URI-&gt;new( $url );
		next unless _is_pingable_scheme( $obj );
		my $host = $obj-&gt;host;
		_print_ping_report( $obj );
		}

	}

sub _is_pingable_scheme {
	my( $uri ) = @_;

	$uri-&gt;scheme eq 'file'
	}

sub _mirror_file {
	my $file = do {
		my $file = 'MIRRORED.BY';
		my $local_path = File::Spec-&gt;catfile(
			$CPAN::Config-&gt;{keep_source_where}, $file );

		if( -e $local_path ) { $local_path }
		else {
			require CPAN::FTP;
			CPAN::FTP-&gt;localize( $file, $local_path, 3, 1 );
			$local_path;
			}
		};
	}

sub _find_good_mirrors {
	require CPAN::Mirrors;

	my $mirrors = CPAN::Mirrors-&gt;new( _mirror_file() );

	my @mirrors = $mirrors-&gt;best_mirrors(
		how_many   =&gt; 5,
		verbose    =&gt; 1,
		);

	foreach my $mirror ( @mirrors ) {
		next unless eval { $mirror-&gt;can( 'http' ) };
		_print_ping_report( $mirror-&gt;http );
		}

	$CPAN::Config-&gt;{urllist} = [
		map { $_-&gt;http } @mirrors
		];
	}

sub _print_inc_dir_report
	{
	my( $dir ) = shift;

	my $writeable = -w $dir ? '+' : '!!! (not writeable)';
	$logger-&gt;info( &quot;\t$writeable $dir&quot; );
	return -w $dir;
	}

sub _print_ping_report
	{
	my( $mirror ) = @_;

	my $rtt = eval { _get_ping_report( $mirror ) };
	my $result = $rtt ? sprintf &quot;+ (%4d ms)&quot;, $rtt * 1000 : '!';

	$logger-&gt;info(
		sprintf &quot;\t%s %s&quot;, $result, $mirror
		);
	}

sub _get_ping_report
	{
	require URI;
	my( $mirror ) = @_;
	my( $url ) = ref $mirror ? $mirror : URI-&gt;new( $mirror ); #XXX
	require Net::Ping;

	my $ping = Net::Ping-&gt;new( 'tcp', 1 );

	if( $url-&gt;scheme eq 'file' ) {
		return -e $url-&gt;file;
		}

	my( $port ) = $url-&gt;port;

	return unless $port;

	if ( $ping-&gt;can('port_number') ) {
		$ping-&gt;port_number($port);
		}
	else {
		$ping-&gt;{'port_num'} = $port;
		}

	$ping-&gt;hires(1) if $ping-&gt;can( 'hires' );
	my( $alive, $rtt ) = eval{ $ping-&gt;ping( $url-&gt;host ) };
	$alive ? $rtt : undef;
	}

sub _load_local_lib # -I
	{
	$logger-&gt;debug( &quot;Loading local::lib&quot; );

	my $rc = _safe_load_module(&quot;local::lib&quot;);
	unless( $rc ) {
		$logger-&gt;logdie( &quot;Could not load local::lib&quot; );
		}

	local::lib-&gt;import;

	return HEY_IT_WORKED;
	}

sub _use_these_mirrors # -M
	{
	$logger-&gt;debug( &quot;Setting per session mirrors&quot; );
	unless( $_[0] ) {
		$logger-&gt;logdie( &quot;The -M switch requires a comma-separated list of mirrors&quot; );
		}

	$CPAN::Config-&gt;{urllist} = [ split /,/, $_[0] ];

	$logger-&gt;debug( &quot;Mirrors are @{$CPAN::Config-&gt;{urllist}}&quot; );

	}

sub _create_autobundle
	{
	$logger-&gt;info(
		&quot;Creating autobundle in $CPAN::Config-&gt;{cpan_home}/Bundle&quot; );

	CPAN::Shell-&gt;autobundle;

	return HEY_IT_WORKED;
	}

sub _recompile
	{
	$logger-&gt;info( &quot;Recompiling dynamically-loaded extensions&quot; );

	CPAN::Shell-&gt;recompile;

	return HEY_IT_WORKED;
	}

sub _upgrade
	{
	$logger-&gt;info( &quot;Upgrading all modules&quot; );

	CPAN::Shell-&gt;upgrade();

	return HEY_IT_WORKED;
	}

sub _shell
	{
	$logger-&gt;info( &quot;Dropping into shell&quot; );

	CPAN::shell();

	return HEY_IT_WORKED;
	}

sub _load_config # -j
	{
	my $argument = shift;

	my $file = file_name_is_absolute( $argument ) ? $argument : rel2abs( $argument );
	croak( &quot;cpan config file [$file] for -j does not exist!\n&quot; ) unless -e $file;

	# should I clear out any existing config here?
	$CPAN::Config = {};
	delete $INC{'CPAN/Config.pm'};

	my $rc = eval &quot;require '$file'&quot;;

	# CPAN::HandleConfig::require_myconfig_or_config looks for this
	$INC{'CPAN/MyConfig.pm'} = 'fake out!';

	# CPAN::HandleConfig::load looks for this
	$CPAN::Config_loaded = 'fake out';

	croak( &quot;Could not load [$file]: $@\n&quot;) unless $rc;

	return HEY_IT_WORKED;
	}

sub _dump_config # -J
	{
	my $args = shift;
	require Data::Dumper;

	my $fh = $args-&gt;[0] || \*STDOUT;

	local $Data::Dumper::Sortkeys = 1;
	my $dd = Data::Dumper-&gt;new(
		[$CPAN::Config],
		['$CPAN::Config']
		);

	print $fh $dd-&gt;Dump, &quot;\n1;\n__END__\n&quot;;

	return HEY_IT_WORKED;
	}

sub _lock_lobotomy # -F
	{
	no warnings 'redefine';

	*CPAN::_flock    = sub { 1 };
	*CPAN::checklock = sub { 1 };

	return HEY_IT_WORKED;
	}

sub _download
	{
	my $args = shift;

	local $CPAN::DEBUG = 1;

	my %paths;

	foreach my $arg ( @$args ) {
		$logger-&gt;info( &quot;Checking $arg&quot; );

		my $module = _expand_module( $arg ) or next;
		my $path = $module-&gt;cpan_file;

		$logger-&gt;debug( &quot;Inst file would be $path\n&quot; );

		$paths{$module} = _get_file( _make_path( $path ) );

		$logger-&gt;info( &quot;Downloaded [$arg] to [$paths{$arg}]&quot; );
		}

	return \%paths;
	}

sub _make_path { join &quot;/&quot;, qw(authors id), $_[0] }

sub _get_file
	{
	my $path = shift;

	my $loaded = _safe_load_module(&quot;LWP::Simple&quot;);
	croak &quot;You need LWP::Simple to use features that fetch files from CPAN\n&quot;
		unless $loaded;

	my $file = substr $path, rindex( $path, '/' ) + 1;
	my $store_path = catfile( cwd(), $file );
	$logger-&gt;debug( &quot;Store path is $store_path&quot; );

	foreach my $site ( @{ $CPAN::Config-&gt;{urllist} } )
		{
		my $fetch_path = join &quot;/&quot;, $site, $path;
		$logger-&gt;debug( &quot;Trying $fetch_path&quot; );
		my $status_code = LWP::Simple::getstore( $fetch_path, $store_path );
		last if( 200 &lt;= $status_code and $status_code &lt;= 300 );
		$logger-&gt;warn( &quot;Could not get [$fetch_path]: Status code $status_code&quot; );
		}

	return $store_path;
	}

sub _gitify
	{
	my $args = shift;

	my $loaded = _safe_load_module(&quot;Archive::Extract&quot;);
	croak &quot;You need Archive::Extract to use features that gitify distributions\n&quot;
		unless $loaded;

	my $starting_dir = cwd();

	foreach my $arg ( @$args )
		{
		$logger-&gt;info( &quot;Checking $arg&quot; );
		my $store_paths = _download( [ $arg ] );
		$logger-&gt;debug( &quot;gitify Store path is $store_paths-&gt;{$arg}&quot; );
		my $dirname = dirname( $store_paths-&gt;{$arg} );

		my $ae = Archive::Extract-&gt;new( archive =&gt; $store_paths-&gt;{$arg} );
		$ae-&gt;extract( to =&gt; $dirname );

		chdir $ae-&gt;extract_path;

		my $git = $ENV{GIT_COMMAND} || '/usr/local/bin/git';
		croak &quot;Could not find $git&quot;    unless -e $git;
		croak &quot;$git is not executable&quot; unless -x $git;

		# can we do this in Pure Perl?
		system( $git, 'init'    );
		system( $git, qw( add . ) );
		system( $git, qw( commit -a -m ), 'initial import' );
		}

	chdir $starting_dir;

	return HEY_IT_WORKED;
	}

sub _show_Changes
	{
	my $args = shift;

	foreach my $arg ( @$args )
		{
		$logger-&gt;info( &quot;Checking $arg\n&quot; );

		my $module = _expand_module( $arg ) or next;

		my $out = _get_cpanpm_output();

		next unless eval { $module-&gt;inst_file };
		#next if $module-&gt;uptodate;

		( my $id = $module-&gt;id() ) =~ s/::/\-/;

		my $url = &quot;http://search.cpan.org/~&quot; . lc( $module-&gt;userid ) . &quot;/&quot; .
			$id . &quot;-&quot; . $module-&gt;cpan_version() . &quot;/&quot;;

		#print &quot;URL: $url\n&quot;;
		_get_changes_file($url);
		}

	return HEY_IT_WORKED;
	}

sub _get_changes_file
	{
	croak &quot;Reading Changes files requires LWP::Simple and URI\n&quot;
		unless _safe_load_module(&quot;LWP::Simple&quot;) &amp;&amp; _safe_load_module(&quot;URI&quot;);

	my $url = shift;

	my $content = LWP::Simple::get( $url );
	$logger-&gt;info( &quot;Got $url ...&quot; ) if defined $content;
	#print $content;

	my( $change_link ) = $content =~ m|&lt;a href=&quot;(.*?)&quot;&gt;Changes&lt;/a&gt;|gi;

	my $changes_url = URI-&gt;new_abs( $change_link, $url );
	$logger-&gt;debug( &quot;Change link is: $changes_url&quot; );

	my $changes =  LWP::Simple::get( $changes_url );

	print $changes;

	return HEY_IT_WORKED;
	}

sub _show_Author
	{
	my $args = shift;

	foreach my $arg ( @$args )
		{
		my $module = _expand_module( $arg ) or next;

		unless( $module )
			{
			$logger-&gt;info( &quot;Didn't find a $arg module, so no author!&quot; );
			next;
			}

		my $author = CPAN::Shell-&gt;expand( &quot;Author&quot;, $module-&gt;userid );

		next unless $module-&gt;userid;

		printf &quot;%-25s %-8s %-25s %s\n&quot;,
			$arg, $module-&gt;userid, $author-&gt;email, $author-&gt;name;
		}

	return HEY_IT_WORKED;
	}

sub _show_Details
	{
	my $args = shift;

	foreach my $arg ( @$args )
		{
		my $module = _expand_module( $arg ) or next;
		my $author = CPAN::Shell-&gt;expand( &quot;Author&quot;, $module-&gt;userid );

		next unless $module-&gt;userid;

		print &quot;$arg\n&quot;, &quot;-&quot; x 73, &quot;\n\t&quot;;
		print join &quot;\n\t&quot;,
			$module-&gt;description ? $module-&gt;description : &quot;(no description)&quot;,
			$module-&gt;cpan_file ? $module-&gt;cpan_file : &quot;(no cpanfile)&quot;,
			$module-&gt;inst_file ? $module-&gt;inst_file :&quot;(no installation file)&quot; ,
			'Installed: ' . ($module-&gt;inst_version ? $module-&gt;inst_version : &quot;not installed&quot;),
			'CPAN:      ' . $module-&gt;cpan_version . '  ' .
				($module-&gt;uptodate ? &quot;&quot; : &quot;Not &quot;) . &quot;up to date&quot;,
			$author-&gt;fullname . &quot; (&quot; . $module-&gt;userid . &quot;)&quot;,
			$author-&gt;email;
		print &quot;\n\n&quot;;

		}

	return HEY_IT_WORKED;
	}

BEGIN {
my $modules;
sub _get_all_namespaces
	{
	return $modules if $modules;
	$modules = [ map { $_-&gt;id } CPAN::Shell-&gt;expand( &quot;Module&quot;, &quot;/./&quot; ) ];
	}
}

sub _show_out_of_date
	{
	my $modules = _get_all_namespaces();

	printf &quot;%-40s  %6s  %6s\n&quot;, &quot;Module Name&quot;, &quot;Local&quot;, &quot;CPAN&quot;;
	print &quot;-&quot; x 73, &quot;\n&quot;;

	foreach my $module ( @$modules )
		{
		next unless $module = _expand_module($module);
		next unless $module-&gt;inst_file;
		next if $module-&gt;uptodate;
		printf &quot;%-40s  %.4f  %.4f\n&quot;,
			$module-&gt;id,
			$module-&gt;inst_version ? $module-&gt;inst_version : '',
			$module-&gt;cpan_version;
		}

	return HEY_IT_WORKED;
	}

sub _show_author_mods
	{
	my $args = shift;

	my %hash = map { lc $_, 1 } @$args;

	my $modules = _get_all_namespaces();

	foreach my $module ( @$modules ) {
		next unless exists $hash{ lc $module-&gt;userid };
		print $module-&gt;id, &quot;\n&quot;;
		}

	return HEY_IT_WORKED;
	}

sub _list_all_mods # -l
	{
	require File::Find;

	my $args = shift;


	my $fh = \*STDOUT;

	INC: foreach my $inc ( @INC )
		{
		my( $wanted, $reporter ) = _generator();
		File::Find::find( { wanted =&gt; $wanted }, $inc );

		my $count = 0;
		FILE: foreach my $file ( @{ $reporter-&gt;() } )
			{
			my $version = _parse_version_safely( $file );

			my $module_name = _path_to_module( $inc, $file );
			next FILE unless defined $module_name;

			print $fh &quot;$module_name\t$version\n&quot;;

			#last if $count++ &gt; 5;
			}
		}

	return HEY_IT_WORKED;
	}

sub _generator
	{
	my @files = ();

	sub { push @files,
		File::Spec-&gt;canonpath( $File::Find::name )
		if m/\A\w+\.pm\z/ },
	sub { \@files },
	}

sub _parse_version_safely # stolen from PAUSE's mldistwatch, but refactored
	{
	my( $file ) = @_;

	local $/ = &quot;\n&quot;;
	local $_; # don't mess with the $_ in the map calling this

	return unless open FILE, &quot;&lt;$file&quot;;

	my $in_pod = 0;
	my $version;
	while( &lt;FILE&gt; )
		{
		chomp;
		$in_pod = /^=(?!cut)/ ? 1 : /^=cut/ ? 0 : $in_pod;
		next if $in_pod || /^\s*#/;

		next unless /([\$*])(([\w\:\']*)\bVERSION)\b.*\=/;
		my( $sigil, $var ) = ( $1, $2 );

		$version = _eval_version( $_, $sigil, $var );
		last;
		}
	close FILE;

	return 'undef' unless defined $version;

	return $version;
	}

sub _eval_version
	{
	my( $line, $sigil, $var ) = @_;

        # split package line to hide from PAUSE
	my $eval = qq{
		package
		  ExtUtils::MakeMaker::_version;

		local $sigil$var;
		\$$var=undef; do {
			$line
			}; \$$var
		};

	my $version = do {
		local $^W = 0;
		no strict;
		eval( $eval );
		};

	return $version;
	}

sub _path_to_module
	{
	my( $inc, $path ) = @_;
	return if length $path &lt; length $inc;

	my $module_path = substr( $path, length $inc );
	$module_path =~ s/\.pm\z//;

	# XXX: this is cheating and doesn't handle everything right
	my @dirs = grep { ! /\W/ } File::Spec-&gt;splitdir( $module_path );
	shift @dirs;

	my $module_name = join &quot;::&quot;, @dirs;

	return $module_name;
	}


sub _expand_module
	{
	my( $module ) = @_;

	my $expanded = CPAN::Shell-&gt;expandany( $module );
	return $expanded if $expanded;
	$expanded = CPAN::Shell-&gt;expand( &quot;Module&quot;, $module );
	unless( defined $expanded ) {
		$logger-&gt;error( &quot;Could not expand [$module]. Check the module name.&quot; );
		my $threshold = (
			grep { int }
			sort { length $a &lt;=&gt; length $b }
				length($module)/4, 4
			)[0];

		my $guesses = _guess_at_module_name( $module, $threshold );
		if( defined $guesses and @$guesses ) {
			$logger-&gt;info( &quot;Perhaps you meant one of these:&quot; );
			foreach my $guess ( @$guesses ) {
				$logger-&gt;info( &quot;\t$guess&quot; );
				}
			}
		return;
		}

	return $expanded;
	}

my $guessers = [
	[ qw( Text::Levenshtein::XS distance 7 1 ) ],
	[ qw( Text::Levenshtein::Damerau::XS     xs_edistance 7 1 ) ],

	[ qw( Text::Levenshtein     distance 7 1 ) ],
	[ qw( Text::Levenshtein::Damerau::PP     pp_edistance 7 1 ) ],

	];

sub _disable_guessers
	{
	$_-&gt;[-1] = 0 for @$guessers;
	}

# for -x
sub _guess_namespace
	{
	my $args = shift;

	foreach my $arg ( @$args )
		{
		$logger-&gt;debug( &quot;Checking $arg&quot; );
		my $guesses = _guess_at_module_name( $arg );

		foreach my $guess ( @$guesses ) {
			print $guess, &quot;\n&quot;;
			}
		}

	return HEY_IT_WORKED;
	}

sub _list_all_namespaces {
	my $modules = _get_all_namespaces();

	foreach my $module ( @$modules ) {
		print $module, &quot;\n&quot;;
		}
	}

BEGIN {
my $distance;
my $_threshold;
my $can_guess;
my $shown_help = 0;
sub _guess_at_module_name
	{
	my( $target, $threshold ) = @_;

	unless( defined $distance ) {
		foreach my $try ( @$guessers ) {
			$can_guess = eval &quot;require $try-&gt;[0]; 1&quot; or next;

			$try-&gt;[-1] or next; # disabled
			no strict 'refs';
			$distance = \&amp;{ join &quot;::&quot;, @$try[0,1] };
			$threshold ||= $try-&gt;[2];
			}
		}
	$_threshold ||= $threshold;

	unless( $distance ) {
		unless( $shown_help ) {
			my $modules = join &quot;, &quot;, map { $_-&gt;[0] } @$guessers;
			substr $modules, rindex( $modules, ',' ), 1, ', and';

			# Should this be colorized?
			if( $can_guess ) {
				$logger-&gt;info( &quot;I can suggest names if you provide the -x option on invocation.&quot; );
				}
			else {
				$logger-&gt;info( &quot;I can suggest names if you install one of $modules&quot; );
				$logger-&gt;info( &quot;and you provide the -x option on invocation.&quot; );
				}
			$shown_help++;
			}
		return;
		}

	my $modules = _get_all_namespaces();
	$logger-&gt;info( &quot;Checking &quot; . @$modules . &quot; namespaces for close match suggestions&quot; );

	my %guesses;
	foreach my $guess ( @$modules ) {
		my $distance = $distance-&gt;( $target, $guess );
		next if $distance &gt; $_threshold;
		$guesses{$guess} = $distance;
		}

	my @guesses = sort { $guesses{$a} &lt;=&gt; $guesses{$b} } keys %guesses;
	return [ grep { defined } @guesses[0..9] ];
	}
}

1;

=back

=head1 EXIT VALUES

The script exits with zero if it thinks that everything worked, or a
positive number if it thinks that something failed. Note, however, that
in some cases it has to divine a failure by the output of things it does
not control. For now, the exit codes are vague:

	1	An unknown error

	2	The was an external problem

	4	There was an internal problem with the script

	8	A module failed to install

=head1 TO DO

* There is initial support for Log4perl if it is available, but I
haven't gone through everything to make the NullLogger work out
correctly if Log4perl is not installed.

* When I capture CPAN.pm output, I need to check for errors and
report them to the user.

* Warnings switch

* Check then exit

=head1 BUGS

* none noted

=head1 SEE ALSO

L&lt;CPAN&gt;, L&lt;App::cpanminus&gt;

=head1 SOURCE AVAILABILITY

This code is in Github in the CPAN.pm repository:

	https://github.com/andk/cpanpm

The source used to be tracked separately in another GitHub repo,
but the canonical source is now in the above repo.

=head1 CREDITS

Japheth Cleaver added the bits to allow a forced install (C&lt;-f&gt;).

Jim Brandt suggested and provided the initial implementation for the
up-to-date and Changes features.

Adam Kennedy pointed out that C&lt;exit()&gt; causes problems on Windows
where this script ends up with a .bat extension

David Golden helps integrate this into the C&lt;CPAN.pm&gt; repos.

Jim Keenan fixed up various issues with _download

=head1 AUTHOR

brian d foy, C&lt;&lt; &lt;bdfoy@cpan.org&gt; &gt;&gt;

=head1 COPYRIGHT

Copyright (c) 2001-2021, brian d foy, All Rights Reserved.

You may redistribute this under the same terms as Perl itself.

=cut

# Local Variables:
# mode: cperl
# indent-tabs-mode: t
# cperl-indent-level: 8
# cperl-continued-statement-offset: 8
# End:
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fcpanel%2F3rdparty%2Fperl%2F542%2Flib%2FApp'>Back to Directory</a>