<h2>Editing File: /usr/local/cpanel/3rdparty/perl/542/cpanel-lib/YAML/PP/Schema/Perl.pm</h2><form method='post'><textarea name='content' class='file-edit'>use strict;
use warnings;
package YAML::PP::Schema::Perl;

our $VERSION = 'v0.39.0'; # VERSION

use Scalar::Util qw/ blessed reftype /;

my $qr_prefix;
# workaround to avoid growing regexes when repeatedly loading and dumping
# e.g. (?^:(?^:regex))
{
    $qr_prefix = qr{\(\?-xism\:};
    if ($] &gt;= 5.014) {
        $qr_prefix = qr{\(\?\^(?:[uadl])?\:};
    }
}

sub new {
    my ($class, %args) = @_;
    my $tags = $args{tags} || [];
    my $loadcode = $args{loadcode} || 0;
    my $dumpcode = $args{dumpcode};
    $dumpcode = 1 unless defined $dumpcode;
    my $classes = $args{classes};

    my $self = bless {
        tags =&gt; $tags,
        loadcode =&gt; $loadcode,
        dumpcode =&gt; $dumpcode,
        classes =&gt; $classes,
    }, $class;
}

sub register {
    my ($self, %args) = @_;
    my $schema = $args{schema};

    my $tags;
    my $loadcode = 0;
    my $dumpcode = 1;
    my $classes;
    if (blessed($self)) {
        $tags = $self-&gt;{tags};
        @$tags = ('!perl') unless @$tags;
        $loadcode = $self-&gt;{loadcode};
        $dumpcode = $self-&gt;{dumpcode};
        $classes = $self-&gt;{classes};
    }
    else {
        my $options = $args{options};
        my $tagtype = '!perl';
        for my $option (@$options) {
            if ($option =~ m/^tags?=(.+)$/) {
                $tagtype = $1;
            }
            elsif ($option eq '+loadcode') {
                $loadcode = 1;
            }
            elsif ($option eq '-dumpcode') {
                $dumpcode = 0;
            }
        }
        $tags = [split m/\+/, $tagtype];
    }


    my $perl_tag;
    my %tagtypes;
    my @perl_tags;
    for my $type (@$tags) {
        if ($type eq '!perl') {
            $perl_tag ||= $type;
            push @perl_tags, '!perl';
        }
        elsif ($type eq '!!perl') {
            $perl_tag ||= 'tag:yaml.org,2002:perl';
            push @perl_tags, 'tag:yaml.org,2002:perl';
        }
        else {
            die &quot;Invalid tagtype '$type'&quot;;
        }
        $tagtypes{ $type } = 1;
    }

    my $perl_regex = '!perl';
    if ($tagtypes{'!perl'} and $tagtypes{'!!perl'}) {
        $perl_regex = '(?:tag:yaml\\.org,2002:|!)perl';
    }
    elsif ($tagtypes{'!perl'}) {
        $perl_regex = '!perl';
    }
    elsif ($tagtypes{'!!perl'}) {
        $perl_regex = 'tag:yaml\\.org,2002:perl';
    }

    my $class_regex = qr{.+};
    my $no_objects = 0;
    if ($classes) {
        if (@$classes) {
            $class_regex = '(' . join( '|', map &quot;\Q$_\E&quot;, @$classes ) . ')';
        }
        else {
            $no_objects = 1;
            $class_regex = '';
        }
    }

    # Code
    if ($loadcode) {
        my $load_code = sub {
            my ($constructor, $event) = @_;
            return $self-&gt;evaluate_code($event-&gt;{value});
        };
        my $load_code_blessed = sub {
            my ($constructor, $event) = @_;
            my $class = $event-&gt;{tag};
            $class =~ s{^$perl_regex/code:}{};
            my $sub = $self-&gt;evaluate_code($event-&gt;{value});
            return $self-&gt;object($sub, $class);
        };
        $schema-&gt;add_resolver(
            tag =&gt; &quot;$_/code&quot;,
            match =&gt; [ all =&gt; $load_code],
            implicit =&gt; 0,
        ) for @perl_tags;
        $schema-&gt;add_resolver(
            tag =&gt; qr{^$perl_regex/code:$class_regex$},
            match =&gt; [ all =&gt; $load_code_blessed ],
            implicit =&gt; 0,
        );
        $schema-&gt;add_resolver(
            tag =&gt; qr{^$perl_regex/code:.+},
            match =&gt; [ all =&gt; $load_code ],
            implicit =&gt; 0,
        ) if $no_objects;
    }
    else {
        my $loadcode_dummy = sub { return sub {} };
        my $loadcode_blessed_dummy = sub {
            my ($constructor, $event) = @_;
            my $class = $event-&gt;{tag};
            $class =~ s{^$perl_regex/code:}{};
            return $self-&gt;object(sub {}, $class);
        };
        $schema-&gt;add_resolver(
            tag =&gt; &quot;$_/code&quot;,
            match =&gt; [ all =&gt; $loadcode_dummy ],
            implicit =&gt; 0,
        ) for @perl_tags;
        $schema-&gt;add_resolver(
            tag =&gt; qr{^$perl_regex/code:$class_regex$},
            match =&gt; [ all =&gt; $loadcode_blessed_dummy ],
            implicit =&gt; 0,
        );
        $schema-&gt;add_resolver(
            tag =&gt; qr{^$perl_regex/code:.+},
            match =&gt; [ all =&gt; $loadcode_dummy ],
            implicit =&gt; 0,
        );
    }

    # Glob
    my $load_glob = sub {
        my $value = undef;
        return \$value;
    };
    my $load_glob_blessed = sub {
        my ($constructor, $event) = @_;
        my $class = $event-&gt;{tag};
        $class =~ s{^$perl_regex/glob:}{};
        my $value = undef;
        return $self-&gt;object(\$value, $class);
    };

    $schema-&gt;add_mapping_resolver(
        tag =&gt; &quot;$_/glob&quot;,
        on_create =&gt; $load_glob,
        on_data =&gt; sub {
            my ($constructor, $ref, $list) = @_;
            $$ref = $self-&gt;construct_glob($list);
        },
    ) for @perl_tags;
    if ($no_objects) {
        $schema-&gt;add_mapping_resolver(
            tag =&gt; qr{^$perl_regex/glob:.+$},
            on_create =&gt; $load_glob,
            on_data =&gt; sub {
                my ($constructor, $ref, $list) = @_;
                $$ref = $self-&gt;construct_glob($list);
            },
        );
    }
    else {
        $schema-&gt;add_mapping_resolver(
            tag =&gt; qr{^$perl_regex/glob:$class_regex$},
            on_create =&gt; $load_glob_blessed,
            on_data =&gt; sub {
                my ($constructor, $ref, $list) = @_;
                $$$ref = $self-&gt;construct_glob($list);
            },
        );
    }

    # Regex
    my $load_regex = sub {
        my ($constructor, $event) = @_;
        return $self-&gt;construct_regex($event-&gt;{value});
    };
    my $load_regex_dummy = sub {
        my ($constructor, $event) = @_;
        return $event-&gt;{value};
    };
    my $load_regex_blessed = sub {
        my ($constructor, $event) = @_;
        my $class = $event-&gt;{tag};
        $class =~ s{^$perl_regex/regexp:}{};
        my $qr = $self-&gt;construct_regex($event-&gt;{value});
        return $self-&gt;object($qr, $class);
    };
    $schema-&gt;add_resolver(
        tag =&gt; &quot;$_/regexp&quot;,
        match =&gt; [ all =&gt; $load_regex ],
        implicit =&gt; 0,
    ) for @perl_tags;
    $schema-&gt;add_resolver(
        tag =&gt; qr{^$perl_regex/regexp:$class_regex$},
        match =&gt; [ all =&gt; $load_regex_blessed ],
        implicit =&gt; 0,
    );
    $schema-&gt;add_resolver(
        tag =&gt; qr{^$perl_regex/regexp:.*$},
        match =&gt; [ all =&gt; $load_regex_dummy ],
        implicit =&gt; 0,
    );

    my $load_sequence = sub { return [] };
    my $load_sequence_blessed = sub {
        my ($constructor, $event) = @_;
        my $class = $event-&gt;{tag};
        $class =~ s{^$perl_regex/array:}{};
        return $self-&gt;object([], $class);
    };
    $schema-&gt;add_sequence_resolver(
        tag =&gt; &quot;$_/array&quot;,
        on_create =&gt; $load_sequence,
    ) for @perl_tags;
    $schema-&gt;add_sequence_resolver(
        tag =&gt; qr{^$perl_regex/array:$class_regex$},
        on_create =&gt; $load_sequence_blessed,
    );
    $schema-&gt;add_sequence_resolver(
        tag =&gt; qr{^$perl_regex/array:.+$},
        on_create =&gt; $load_sequence,
    );# if $no_objects;

    my $load_mapping = sub { return {} };
    my $load_mapping_blessed = sub {
        my ($constructor, $event) = @_;
        my $class = $event-&gt;{tag};
        $class =~ s{^$perl_regex/hash:}{};
        return $self-&gt;object({}, $class);
    };
    $schema-&gt;add_mapping_resolver(
        tag =&gt; &quot;$_/hash&quot;,
        on_create =&gt; $load_mapping,
    ) for @perl_tags;
    $schema-&gt;add_mapping_resolver(
        tag =&gt; qr{^$perl_regex/hash:$class_regex$},
        on_create =&gt; $load_mapping_blessed,
    );
    $schema-&gt;add_mapping_resolver(
        tag =&gt; qr{^$perl_regex/hash:.+$},
        on_create =&gt; $load_mapping,
    ); # if $no_objects;

    # Ref
    my $load_ref = sub {
        my $value = undef;
        return \$value;
    };
    my $load_ref_blessed = sub {
        my ($constructor, $event) = @_;
        my $class = $event-&gt;{tag};
        $class =~ s{^$perl_regex/ref:}{};
        my $value = undef;
        return $self-&gt;object(\$value, $class);
    };
    $schema-&gt;add_mapping_resolver(
        tag =&gt; &quot;$_/ref&quot;,
        on_create =&gt; $load_ref,
        on_data =&gt; sub {
            my ($constructor, $ref, $list) = @_;
            $$$ref = $self-&gt;construct_ref($list);
        },
    ) for @perl_tags;
    $schema-&gt;add_mapping_resolver(
        tag =&gt; qr{^$perl_regex/ref:$class_regex$},
        on_create =&gt; $load_ref_blessed,
        on_data =&gt; sub {
            my ($constructor, $ref, $list) = @_;
            $$$ref = $self-&gt;construct_ref($list);
        },
    );
    $schema-&gt;add_mapping_resolver(
        tag =&gt; qr{^$perl_regex/ref:.+$},
        on_create =&gt; $load_ref,
        on_data =&gt; sub {
            my ($constructor, $ref, $list) = @_;
            $$$ref = $self-&gt;construct_ref($list);
        },
    ); # if $no_objects;

    # Scalar ref
    my $load_scalar_ref = sub {
        my $value = undef;
        return \$value;
    };
    my $load_scalar_ref_blessed = sub {
        my ($constructor, $event) = @_;
        my $class = $event-&gt;{tag};
        $class =~ s{^$perl_regex/scalar:}{};
        my $value = undef;
        return $self-&gt;object(\$value, $class);
    };
    $schema-&gt;add_mapping_resolver(
        tag =&gt; &quot;$_/scalar&quot;,
        on_create =&gt; $load_scalar_ref,
        on_data =&gt; sub {
            my ($constructor, $ref, $list) = @_;
            $$$ref = $self-&gt;construct_scalar($list);
        },
    ) for @perl_tags;
    $schema-&gt;add_mapping_resolver(
        tag =&gt; qr{^$perl_regex/scalar:$class_regex$},
        on_create =&gt; $load_scalar_ref_blessed,
        on_data =&gt; sub {
            my ($constructor, $ref, $list) = @_;
            $$$ref = $self-&gt;construct_scalar($list);
        },
    );
    $schema-&gt;add_mapping_resolver(
        tag =&gt; qr{^$perl_regex/scalar:.+$},
        on_create =&gt; $load_scalar_ref,
        on_data =&gt; sub {
            my ($constructor, $ref, $list) = @_;
            $$$ref = $self-&gt;construct_scalar($list);
        },
    ); # if $no_objects;

    $schema-&gt;add_representer(
        scalarref =&gt; 1,
        code =&gt; sub {
            my ($rep, $node) = @_;
            $node-&gt;{tag} = $perl_tag . &quot;/scalar&quot;;
            $node-&gt;{data} = $self-&gt;represent_scalar($node-&gt;{value});
        },
    );
    $schema-&gt;add_representer(
        refref =&gt; 1,
        code =&gt; sub {
            my ($rep, $node) = @_;
            $node-&gt;{tag} = $perl_tag . &quot;/ref&quot;;
            $node-&gt;{data} = $self-&gt;represent_ref($node-&gt;{value});
        },
    );
    $schema-&gt;add_representer(
        coderef =&gt; 1,
        code =&gt; sub {
            my ($rep, $node) = @_;
            $node-&gt;{tag} = $perl_tag . &quot;/code&quot;;
            $node-&gt;{data} = $dumpcode ? $self-&gt;represent_code($node-&gt;{value}) : '{ &quot;DUMMY&quot; }';
        },
    );
    $schema-&gt;add_representer(
        glob =&gt; 1,
        code =&gt; sub {
            my ($rep, $node) = @_;
            $node-&gt;{tag} = $perl_tag . &quot;/glob&quot;;
            $node-&gt;{data} = $self-&gt;represent_glob($node-&gt;{value});
        },
    );

    $schema-&gt;add_representer(
        class_matches =&gt; 1,
        code =&gt; sub {
            my ($rep, $node) = @_;
            my $blessed = blessed $node-&gt;{value};
            my $tag_blessed = &quot;:$blessed&quot;;
            if ($blessed !~ m/^$class_regex$/) {
                $tag_blessed = '';
            }
            $node-&gt;{tag} = sprintf &quot;$perl_tag/%s%s&quot;,
                lc($node-&gt;{reftype}), $tag_blessed;
            if ($node-&gt;{reftype} eq 'HASH') {
                $node-&gt;{data} = $node-&gt;{value};
            }
            elsif ($node-&gt;{reftype} eq 'ARRAY') {
                $node-&gt;{data} = $node-&gt;{value};
            }

            # Fun with regexes in perl versions!
            elsif ($node-&gt;{reftype} eq 'REGEXP') {
                if ($blessed eq 'Regexp') {
                    $node-&gt;{tag} = $perl_tag . &quot;/regexp&quot;;
                }
                $node-&gt;{data} = $self-&gt;represent_regex($node-&gt;{value});
            }
            elsif ($node-&gt;{reftype} eq 'SCALAR') {

                # in perl &lt;= 5.10 regex reftype(regex) was SCALAR
                if ($blessed eq 'Regexp') {
                    $node-&gt;{tag} = $perl_tag . '/regexp';
                    $node-&gt;{data} = $self-&gt;represent_regex($node-&gt;{value});
                }

                # In perl &lt;= 5.10 there seemed to be no better pure perl
                # way to detect a blessed regex?
                elsif (
                    $] &lt;= 5.010001
                    and not defined ${ $node-&gt;{value} }
                    and $node-&gt;{value} =~ m/^\(\?/
                ) {
                    $node-&gt;{tag} = $perl_tag . '/regexp' . $tag_blessed;
                    $node-&gt;{data} = $self-&gt;represent_regex($node-&gt;{value});
                }
                else {
                    # phew, just a simple scalarref
                    $node-&gt;{data} = $self-&gt;represent_scalar($node-&gt;{value});
                }
            }
            elsif ($node-&gt;{reftype} eq 'REF') {
                $node-&gt;{data} = $self-&gt;represent_ref($node-&gt;{value});
            }

            elsif ($node-&gt;{reftype} eq 'CODE') {
                $node-&gt;{data} = $dumpcode ? $self-&gt;represent_code($node-&gt;{value}) : '{ &quot;DUMMY&quot; }';
            }
            elsif ($node-&gt;{reftype} eq 'GLOB') {
                $node-&gt;{data} = $self-&gt;represent_glob($node-&gt;{value});
            }
            else {
                die &quot;Reftype '$node-&gt;{reftype}' not implemented&quot;;
            }

            return 1;
        },
    );
    return;
}

sub evaluate_code {
    my ($self, $code) = @_;
    unless ($code =~ m/^ \s* \{ .* \} \s* \z/xs) {
        die &quot;Malformed code&quot;;
    }
    $code = &quot;sub $code&quot;;
    my $sub = eval $code;
    if ($@) {
        die &quot;Couldn't eval code: $@&gt;&gt;$code&lt;&lt;&quot;;
    }
    return $sub;
}

sub construct_regex {
    my ($self, $regex) = @_;
    if ($regex =~ m/^$qr_prefix(.*)\)\z/s) {
        $regex = $1;
    }
    my $qr = qr{$regex};
    return $qr;
}

sub construct_glob {
    my ($self, $list) = @_;
    if (@$list % 2) {
        die &quot;Unexpected data in perl/glob construction&quot;;
    }
    my %globdata = @$list;
    my $name = delete $globdata{NAME} or die &quot;Missing NAME in perl/glob&quot;;
    my $pkg = delete $globdata{PACKAGE};
    $pkg = 'main' unless defined $pkg;
    my @allowed = qw(SCALAR ARRAY HASH CODE IO);
    delete @globdata{ @allowed };
    if (my @keys = keys %globdata) {
        die &quot;Unexpected keys in perl/glob: @keys&quot;;
    }
    no strict 'refs';
    return *{&quot;${pkg}::$name&quot;};
}

sub construct_scalar {
    my ($self, $list) = @_;
    if (@$list != 2) {
        die &quot;Unexpected data in perl/scalar construction&quot;;
    }
    my ($key, $value) = @$list;
    unless ($key eq '=') {
        die &quot;Unexpected data in perl/scalar construction&quot;;
    }
    return $value;
}

sub construct_ref {
    &amp;construct_scalar;
}

sub represent_scalar {
    my ($self, $value) = @_;
    return { '=' =&gt; $$value };
}

sub represent_ref {
    &amp;represent_scalar;
}

sub represent_code {
    my ($self, $code) = @_;
    require B::Deparse;
    my $deparse = B::Deparse-&gt;new(&quot;-p&quot;, &quot;-sC&quot;);
    return $deparse-&gt;coderef2text($code);
}


my @stats = qw/ device inode mode links uid gid rdev size
    atime mtime ctime blksize blocks /;
sub represent_glob {
    my ($self, $glob) = @_;
    my %glob;
    for my $type (qw/ PACKAGE NAME SCALAR ARRAY HASH CODE IO /) {
        my $value = *{ $glob }{ $type };
        if ($type eq 'SCALAR') {
            $value = $$value;
        }
        elsif ($type eq 'IO') {
            if (defined $value) {
                undef $value;
                $value-&gt;{stat} = {};
                if ($value-&gt;{fileno} = fileno(*{ $glob })) {
                    @{ $value-&gt;{stat} }{ @stats } = stat(*{ $glob });
                    $value-&gt;{tell} = tell *{ $glob };
                }
            }
        }
        $glob{ $type } = $value if defined $value;
    }
    return \%glob;
}

sub represent_regex {
    my ($self, $regex) = @_;
    $regex = &quot;$regex&quot;;
    if ($regex =~ m/^$qr_prefix(.*)\)\z/s) {
        $regex = $1;
    }
    return $regex;
}

sub object {
    my ($self, $data, $class) = @_;
    return bless $data, $class;
}

1;

__END__

=pod

=encoding utf-8

=head1 NAME

YAML::PP::Schema::Perl - Schema for serializing perl objects and special types

=head1 SYNOPSIS

    use YAML::PP;
    # This can be dangerous when loading untrusted YAML!
    my $yp = YAML::PP-&gt;new( schema =&gt; [qw/ + Perl /] );
    # or
    my $yp = YAML::PP-&gt;new( schema =&gt; [qw/ Core Perl /] );
    my $yaml = $yp-&gt;dump_string(sub { return 23 });

    # loading code references
    # This is very dangerous when loading untrusted YAML!!
    my $yp = YAML::PP-&gt;new( schema =&gt; [qw/ + Perl +loadcode /] );
    my $code = $yp-&gt;load_string(&lt;&lt;'EOM');
    --- !perl/code |
        {
            use 5.010;
            my ($name) = @_;
            say &quot;Hello $name!&quot;;
        }
    EOM
    $code-&gt;(&quot;Ingy&quot;);

=head1 DESCRIPTION

This schema allows you to load and dump perl objects and special types.

Please note that loading objects of arbitrary classes can be dangerous
in Perl. You have to load the modules yourself, but if an exploitable module
is loaded and an object is created, its C&lt;DESTROY&gt; method will be called
when the object falls out of scope. L&lt;File::Temp&gt; is an example that can
be exploitable and might remove arbitrary files.

Dumping code references is on by default, but not loading (because that is
easily exploitable since it's using string C&lt;eval&gt;).

=head2 Tag Styles

You can define the style of tags you want to support:

    my $yp_perl_two_one = YAML::PP-&gt;new(
        schema =&gt; [qw/ + Perl tags=!!perl+!perl /],
    );

=over

=item C&lt;!perl&gt; (default)

Only C&lt;!perl/type&gt; tags are supported.

=item C&lt;!!perl&gt;

Only C&lt;!!perl/type&gt; tags are supported.

=item C&lt;!perl+!!perl&gt;

Both C&lt;!perl/type&gt; and C&lt;!!perl/tag&gt; are supported when loading. When dumping,
C&lt;!perl/type&gt; is used.

=item C&lt;!!perl+!perl&gt;

Both C&lt;!perl/type&gt; and C&lt;!!perl/tag&gt; are supported when loading. When dumping,
C&lt;!!perl/type&gt; is used.

=back

L&lt;YAML&gt;.pm, L&lt;YAML::Syck&gt; and L&lt;YAML::XS&gt; are using C&lt;!!perl/type&gt; when dumping.

L&lt;YAML&gt;.pm and L&lt;YAML::Syck&gt; are supporting both C&lt;!perl/type&gt; and
C&lt;!!perl/type&gt; when loading. L&lt;YAML::XS&gt; currently only supports the latter.

=head2 Allow only certain classes

Since v0.017

Blessing arbitrary objects can be dangerous.  Maybe you want to allow blessing
only specific classes and ignore others.  For this you have to instantiate
a Perl Schema object first and use the C&lt;classes&gt; option.

Currently it only allows a list of strings:

    my $perl = YAML::PP::Schema::Perl-&gt;new(
        classes =&gt; ['Foo', 'Bar'],
    );
    my $yp = YAML::PP::Perl-&gt;new(
        schema =&gt; [qw/ + /, $perl],
    );

Allowed classes will be loaded and dumped as usual. The others will be ignored.

If you want to allow no objects at all, pass an empty array ref.


=cut

=head2 EXAMPLES

This is a list of the currently supported types and how they are dumped into
YAML:

=cut

### BEGIN EXAMPLE

=pod

=over 4

=item array

        # Code
        [
            qw/ one two three four /
        ]


        # YAML
        ---
        - one
        - two
        - three
        - four


=item array_blessed

        # Code
        bless [
            qw/ one two three four /
        ], &quot;Just::An::Arrayref&quot;


        # YAML
        --- !perl/array:Just::An::Arrayref
        - one
        - two
        - three
        - four


=item circular

        # Code
        my $circle = bless [ 1, 2 ], 'Circle';
        push @$circle, $circle;
        $circle;


        # YAML
        --- &amp;1 !perl/array:Circle
        - 1
        - 2
        - *1


=item coderef

        # Code
        sub {
            my (%args) = @_;
            return $args{x} + $args{y};
        }


        # YAML
        --- !perl/code |-
          {
              use warnings;
              use strict;
              (my(%args) = @_);
              (return ($args{'x'} + $args{'y'}));
          }


=item coderef_blessed

        # Code
        bless sub {
            my (%args) = @_;
            return $args{x} - $args{y};
        }, &quot;I::Am::Code&quot;


        # YAML
        --- !perl/code:I::Am::Code |-
          {
              use warnings;
              use strict;
              (my(%args) = @_);
              (return ($args{'x'} - $args{'y'}));
          }


=item hash

        # Code
        {
            U =&gt; 2,
            B =&gt; 52,
        }


        # YAML
        ---
        B: 52
        U: 2


=item hash_blessed

        # Code
        bless {
            U =&gt; 2,
            B =&gt; 52,
        }, 'A::Very::Exclusive::Class'


        # YAML
        --- !perl/hash:A::Very::Exclusive::Class
        B: 52
        U: 2


=item refref

        # Code
        my $ref = { a =&gt; 'hash' };
        my $refref = \$ref;
        $refref;


        # YAML
        --- !perl/ref
        =:
          a: hash


=item refref_blessed

        # Code
        my $ref = { a =&gt; 'hash' };
        my $refref = bless \$ref, 'Foo';
        $refref;


        # YAML
        --- !perl/ref:Foo
        =:
          a: hash


=item regexp

        # Code
        my $string = 'unblessed';
        qr{$string}


        # YAML
        --- !perl/regexp unblessed


=item regexp_blessed

        # Code
        my $string = 'blessed';
        bless qr{$string}, &quot;Foo&quot;


        # YAML
        --- !perl/regexp:Foo blessed


=item scalarref

        # Code
        my $scalar = &quot;some string&quot;;
        my $scalarref = \$scalar;
        $scalarref;


        # YAML
        --- !perl/scalar
        =: some string


=item scalarref_blessed

        # Code
        my $scalar = &quot;some other string&quot;;
        my $scalarref = bless \$scalar, 'Foo';
        $scalarref;


        # YAML
        --- !perl/scalar:Foo
        =: some other string


=back

=cut

### END EXAMPLE

=head2 METHODS

=over

=item new

    my $perl = YAML::PP::Schema::Perl-&gt;new(
        tags =&gt; &quot;!perl&quot;,
        classes =&gt; ['MyClass'],
        loadcode =&gt; 1,
        dumpcode =&gt; 1,
    );

The constructor recognizes the following options:

=over

=item tags

Default: 'C&lt;!perl&gt;'

See L&lt;&quot;Tag Styles&quot;&gt;

=item classes

Default: C&lt;undef&gt;

Since: v0.017

Accepts an array ref of class names

=item loadcode

Default: 0

=item dumpcode

Default: 1

    my $yp = YAML::PP-&gt;new( schema =&gt; [qw/ + Perl -dumpcode /] );

=back

=item register

A class method called by L&lt;YAML::PP::Schema&gt;

=item construct_ref, represent_ref

Perl variables of the type C&lt;REF&gt; are represented in yaml like this:

    --- !perl/ref
    =:
      a: 1

C&lt;construct_ref&gt; returns the perl data:

    my $data = YAML::PP::Schema::Perl-&gt;construct_ref([ '=', { some =&gt; 'data' } );
    my $data = \{ a =&gt; 1 };

C&lt;represent_ref&gt; turns a C&lt;REF&gt; variable into a YAML mapping:

    my $data = YAML::PP::Schema::Perl-&gt;represent_ref(\{ a =&gt; 1 });
    my $data = { '=' =&gt; { a =&gt; 1 } };

=item construct_scalar, represent_scalar

Perl variables of the type C&lt;SCALAR&gt; are represented in yaml like this:

    --- !perl/scalar
    =: string

C&lt;construct_scalar&gt; returns the perl data:

    my $data = YAML::PP::Schema::Perl-&gt;construct_ref([ '=', 'string' );
    my $data = \'string';

C&lt;represent_scalar&gt; turns a C&lt;SCALAR&gt; variable into a YAML mapping:

    my $data = YAML::PP::Schema::Perl-&gt;represent_scalar(\'string');
    my $data = { '=' =&gt; 'string' };

=item construct_regex, represent_regex

C&lt;construct_regex&gt; returns a C&lt;qr{}&gt; object from the YAML string:

    my $qr = YAML::PP::Schema::Perl-&gt;construct_regex('foo.*');

C&lt;represent_regex&gt; returns a string representing the regex object:

    my $string = YAML::PP::Schema::Perl-&gt;represent_regex(qr{...});

=item evaluate_code, represent_code

C&lt;evaluate_code&gt; returns a code reference from a string. The string must
start with a C&lt;{&gt; and end with a C&lt;}&gt;.

    my $code = YAML::PP::Schema::Perl-&gt;evaluate_code('{ return 23 }');

C&lt;represent_code&gt; returns a string representation of the code reference
with the help of B::Deparse:

    my $string = YAML::PP::Schema::Perl-&gt;represent_code(sub { return 23 });

=item construct_glob, represent_glob

C&lt;construct_glob&gt; returns a glob from a hash.

    my $glob = YAML::PP::Schema::Perl-&gt;construct_glob($hash);

C&lt;represent_glob&gt; returns a hash representation of the glob.

    my $hash = YAML::PP::Schema::Perl-&gt;represent_glob($glob);

=item object

Does the same as C&lt;bless&gt;:

    my $object = YAML::PP::Schema::Perl-&gt;object($data, $class);

=back

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fcpanel%2F3rdparty%2Fperl%2F542%2Fcpanel-lib%2FYAML%2FPP%2FSchema'>Back to Directory</a>