<h2>Editing File: /usr/local/cpanel/3rdparty/perl/542/cpanel-lib/SQL/Abstract/Plugin/ExtraClauses.pm</h2><form method='post'><textarea name='content' class='file-edit'>package SQL::Abstract::Plugin::ExtraClauses;

use Moo;

with 'SQL::Abstract::Role::Plugin';

sub register_extensions {
  my ($self, $sqla) = @_;

  my @clauses = $sqla-&gt;clauses_of('select');
  my @before_setop;
  CLAUSE: foreach my $idx (0..$#clauses) {
    if ($clauses[$idx] eq 'order_by') {
      @before_setop = @clauses[0..$idx-1];
      splice(@clauses, $idx, 0, qw(setop group_by having));
      last CLAUSE;
    }
  }

  die &quot;Huh?&quot; unless @before_setop;
  $sqla-&gt;clauses_of(select =&gt; @clauses);

  $sqla-&gt;clauses_of(update =&gt; sub {
    my ($self, @clauses) = @_;
    splice(@clauses, 2, 0, 'from');
    @clauses;
  });

  $sqla-&gt;clauses_of(delete =&gt; sub {
    my ($self, @clauses) = @_;
    splice(@clauses, 1, 0, 'using');
    @clauses;
  });

  $self-&gt;register(
    (map +(
      &quot;${_}er&quot; =&gt; [
        do {
          my $x = $_;
          (map +($_ =&gt; &quot;_${x}_${_}&quot;), qw(join from_list alias))
        }
       ]
    ), qw(expand render)),
    binop_expander =&gt; [ as =&gt; '_expand_op_as' ],
    renderer =&gt; [ as =&gt; '_render_as' ],
    expander =&gt; [ cast =&gt; '_expand_cast' ],
    clause_expanders =&gt; [
      'select.group_by'
        =&gt; sub { $_[0]-&gt;expand_expr({ -list =&gt; $_[2] }, -ident) },
      'select.having'
        =&gt; sub { $_[0]-&gt;expand_expr($_[2]) },
      'update.from' =&gt; '_expand_from_list',
      &quot;update.target&quot;, '_expand_update_clause_target',
      &quot;update.update&quot;, '_expand_update_clause_target',
      'delete.using' =&gt; '_expand_from_list',
      'insert.rowvalues' =&gt; sub {
        +(from =&gt; $_[0]-&gt;expand_expr({ -values =&gt; $_[2] }));
      },
      'insert.select' =&gt; sub {
        +(from =&gt; $_[0]-&gt;expand_expr({ -select =&gt; $_[2] }));
      },
    ],
  );

  $sqla-&gt;expander(old_from =&gt; $sqla-&gt;clause_expander('select.from'));
  $sqla-&gt;wrap_clause_expander('select.from', sub {
    my ($orig) = @_;
    sub {
      my ($sqla, undef, $args) = @_;
      if (ref($args) eq 'HASH') {
        return $self-&gt;_expand_from_list(undef, $args);
      }
      if (
        ref($args) eq 'ARRAY'
        and grep { !ref($_) and $_ =~ /^-/ } @$args
      ) {
        return $self-&gt;_expand_from_list(undef, $args);
      }
      return $sqla-&gt;$orig(undef, $args);
    }
  });

  # set ops
  $sqla-&gt;wrap_expander(select =&gt; sub {
    $self-&gt;cb('_expand_select', $_[0], \@before_setop);
  });

  $self-&gt;register(
    clause_renderer =&gt; [
      'select.setop' =&gt; sub { $_[0]-&gt;render_aqt($_[2]) }
    ],
    expander =&gt; [
      map +($_ =&gt; '_expand_setop', &quot;${_}_all&quot; =&gt; '_expand_setop'), qw(union intersect except) ],
    renderer =&gt; [ map +($_ =&gt; '_render_setop'), qw(union intersect except) ],
  );

  my $setop_expander = $self-&gt;cb('_expand_clause_setop');

  $sqla-&gt;clause_expanders(
    map +($_ =&gt; $setop_expander),
      map &quot;select.${_}&quot;,
        map +($_, &quot;${_}_all&quot;, &quot;${_}_distinct&quot;),
          qw(union intersect except)
  );

  foreach my $stmt (qw(select insert update delete)) {
    $sqla-&gt;clauses_of($stmt =&gt; 'with', $sqla-&gt;clauses_of($stmt));
    $self-&gt;register(
      clause_expanders =&gt; [
        &quot;${stmt}.with&quot; =&gt; '_expand_with',
        &quot;${stmt}.with_recursive&quot; =&gt; '_expand_with',
      ],
      clause_renderer =&gt; [ &quot;${stmt}.with&quot; =&gt; '_render_with' ],
    );
  }

  return $sqla;
}

sub _expand_select {
  my ($self, $orig, $before_setop, @args) = @_;
  my $exp = $self-&gt;sqla-&gt;$orig(@args);
  return $exp unless my $setop = (my $sel = $exp-&gt;{-select})-&gt;{setop};
  if (my @keys = grep $sel-&gt;{$_}, @$before_setop) {
    my %inner; @inner{@keys} = delete @{$sel}{@keys};
    unshift @{(values(%$setop))[0]{queries}},
      { -select =&gt; \%inner };
  }
  return $exp;
}

sub _expand_from_list {
  my ($self, undef, $args) = @_;
  if (ref($args) eq 'HASH') {
    return $args if $args-&gt;{-from_list};
    return { -from_list =&gt; [ $self-&gt;expand_expr($args) ] };
  }
  my @list;
  my @args = ref($args) eq 'ARRAY' ? @$args : ($args);
  while (my $entry = shift @args) {
    if (!ref($entry) and $entry =~ /^-(.*)/) {
      if ($1 eq 'as') {
        $list[-1] = $self-&gt;expand_expr({ -as =&gt; [
          $list[-1], map +(ref($_) eq 'ARRAY' ? @$_ : $_), shift(@args)
        ]});
        next;
      }
      $entry = { $entry =&gt; shift @args };
    }
    my $aqt = $self-&gt;expand_expr($entry, -ident);
    if ($aqt-&gt;{-join} and not $aqt-&gt;{-join}{from}) {
      $aqt-&gt;{-join}{from} = pop @list;
    }
    push @list, $aqt;
  }
  return $list[0] if @list == 1;
  return { -from_list =&gt; \@list };
}

sub _expand_join {
  my ($self, undef, $args) = @_;
  my %proto = (
    ref($args) eq 'HASH'
      ? %$args
      : (to =&gt; @$args)
  );
  if (my $as = delete $proto{as}) {
    $proto{to} = $self-&gt;expand_expr(
                   { -as =&gt; [ { -from_list =&gt; $proto{to} }, $as ] }
                 );
  }
  if (defined($proto{using}) and ref(my $using = $proto{using}) ne 'HASH') {
    $proto{using} = [
      map [ $self-&gt;expand_expr($_, -ident) ],
        ref($using) eq 'ARRAY' ? @$using: $using
    ];
  }
  my %ret = (
    type =&gt; delete $proto{type},
    to =&gt; $self-&gt;expand_expr({ -from_list =&gt; delete $proto{to} }, -ident)
  );
  %ret = (%ret,
    map +($_ =&gt; $self-&gt;expand_expr($proto{$_}, -ident)),
      sort keys %proto
  );
  return +{ -join =&gt; \%ret };
}

sub _render_from_list {
  my ($self, undef, $list) = @_;
  return $self-&gt;join_query_parts(', ', @$list);
}

sub _render_join {
  my ($self, undef, $args) = @_;

  my @parts = (
    $args-&gt;{from},
    { -keyword =&gt; join '_', ($args-&gt;{type}||()), 'join' },
    (map +($_-&gt;{-ident} || $_-&gt;{-as}
      ? $_
      : ('(', $self-&gt;render_aqt($_, 1), ')')),
        map +(@{$_-&gt;{-from_list}||[]} == 1 ? $_-&gt;{-from_list}[0] : $_),
          $args-&gt;{to}
    ),
    ($args-&gt;{on} ? (
      { -keyword =&gt; 'on' },
      $args-&gt;{on},
    ) : ()),
    ($args-&gt;{using} ? (
      { -keyword =&gt; 'using' },
      '(', $args-&gt;{using}, ')',
    ) : ()),
  );
  return $self-&gt;join_query_parts(' ', @parts);
}

sub _expand_op_as {
  my ($self, undef, $vv, $k) = @_;
  my @vv = (ref($vv) eq 'ARRAY' ? @$vv : $vv);
  my $ik = $self-&gt;expand_expr($k, -ident);
  return +{ -as =&gt; [ $ik, $self-&gt;expand_expr($vv[0], -ident) ] }
    if @vv == 1 and ref($vv[0]) eq 'HASH';

  my @as = map $self-&gt;expand_expr($_, -ident), @vv;
  return { -as =&gt; [ $ik, $self-&gt;expand_expr({ -alias =&gt; \@as }) ] };
}

sub _render_as {
  my ($self, undef, $args) = @_;
  my ($thing, $alias) = @$args;
  return $self-&gt;join_query_parts(
    ' ',
    $thing,
    { -keyword =&gt; 'as' },
    $alias,
  );
}

sub _render_alias {
  my ($self, undef, $args) = @_;
  my ($as, @cols) = @$args;
  return (@cols
    ? $self-&gt;join_query_parts('',
         $as,
         '(',
         $self-&gt;join_query_parts(
           ', ',
           @cols
         ),
         ')',
      )
    : $self-&gt;render_aqt($as)
  );
}

sub _expand_update_clause_target {
  my ($self, undef, $target) = @_;
  +(target =&gt; $self-&gt;_expand_from_list(undef, $target));
}

sub _expand_cast {
  my ($self, undef, $thing) = @_;
  return { -func =&gt; [ cast =&gt; $thing ] } if ref($thing) eq 'HASH';
  my ($cast, $to) = @{$thing};
  +{ -func =&gt; [ cast =&gt; { -as =&gt; [
    $self-&gt;expand_expr($cast),
    $self-&gt;expand_expr($to, -ident),
  ] } ] };
}

sub _expand_alias {
  my ($self, undef, $args) = @_;
  if (ref($args) eq 'HASH' and my $alias = $args-&gt;{-alias}) {
    $args = $alias;
  }
  my @parts = map $self-&gt;expand_expr($_, -ident),
                ref($args) eq 'ARRAY' ? @{$args} : $args;
  return $parts[0] if @parts == 1;
  return { -alias =&gt; \@parts };
}

sub _expand_with {
  my ($self, $name, $with) = @_;
  my (undef, $type) = split '_', $name;
  if (ref($with) eq 'HASH') {
    return +{
      %$with,
      queries =&gt; [
        map +[
          $self-&gt;expand_expr({ -alias =&gt; $_-&gt;[0] }, -ident),
          $self-&gt;expand_expr($_-&gt;[1]),
        ], @{$with-&gt;{queries}}
      ]
    }
  }
  my @with = @$with;
  my @exp;
  while (my ($alias, $query) = splice @with, 0, 2) {
    push @exp, [
      $self-&gt;expand_expr({ -alias =&gt; $alias }, -ident),
      $self-&gt;expand_expr($query)
    ];
  }
  return +(with =&gt; { ($type ? (type =&gt; $type) : ()), queries =&gt; \@exp });
}

sub _render_with {
  my ($self, undef, $with) = @_;
  my $q_part = $self-&gt;join_query_parts(', ',
    map {
      my ($alias, $query) = @$_;
      $self-&gt;join_query_parts(' ',
          $alias,
          { -keyword =&gt; 'as' },
          $query,
      )
    } @{$with-&gt;{queries}}
  );
  return $self-&gt;join_query_parts(' ',
    { -keyword =&gt; join '_', 'with', ($with-&gt;{type}||'') },
    $q_part,
  );
}

sub _expand_setop {
  my ($self, $setop, $args) = @_;
  my $is_all = $setop =~ s/_all$//;
  +{ &quot;-${setop}&quot; =&gt; {
       ($is_all ? (type =&gt; 'all') : ()),
       (ref($args) eq 'ARRAY'
          ? (queries =&gt; [ map $self-&gt;expand_expr($_), @$args ])
          : (
              %$args,
              queries =&gt; [ map $self-&gt;expand_expr($_), @{$args-&gt;{queries}} ]
            )
       ),
  } };
}

sub _render_setop {
  my ($self, $setop, $args) = @_;
  $self-&gt;join_query_parts(
    { -keyword =&gt; ' '.join('_', $setop, ($args-&gt;{type}||())).' ' },
    @{$args-&gt;{queries}}
  );
}

sub _expand_clause_setop {
  my ($self, $setop, $args) = @_;
  my ($op, $type) = split '_', $setop;
  +(setop =&gt; $self-&gt;expand_expr({
    &quot;-${op}&quot; =&gt; {
      ($type ? (type =&gt; $type) : ()),
      queries =&gt; (ref($args) eq 'ARRAY' ? $args : [ $args ])
    }
  }));
}

1;

__END__

=head1 NAME

SQL::Abstract::ExtraClauses - new/experimental additions to L&lt;SQL::Abstract&gt;

=head1 SYNOPSIS

  my $sqla = SQL::Abstract-&gt;new;
  SQL::Abstract::ExtraClauses-&gt;apply_to($sqla);

=head1 WARNING

This module is basically a nursery for things that seem like a good idea
to live in until we figure out if we were right about that.

=head1 METHODS

=head2 apply_to

Applies the plugin to an L&lt;SQL::Abstract&gt; object.

=head2 register_extensions

Registers the extensions described below

=head2 cb

For plugin authors, creates a callback to call a method on the plugin.

=head2 register

For plugin authors, registers callbacks more easily.

=head2 sqla

Available only during plugin callback executions, contains the currently
active L&lt;SQL::Abstract&gt; object.

=head1 NODE TYPES

=head2 alias

Represents a table alias. Expands name and column names with ident as default.

  # expr
  { -alias =&gt; [ 't', 'x', 'y', 'z' ] }

  # aqt
  { -alias =&gt; [
      { -ident =&gt; [ 't' ] }, { -ident =&gt; [ 'x' ] },
      { -ident =&gt; [ 'y' ] }, { -ident =&gt; [ 'z' ] },
  ] }

  # query
  t(x, y, z)
  []

=head2 as

Represents an sql AS. LHS is expanded with ident as default, RHS is treated
as a list of arguments for the alias node.

  # expr
  { foo =&gt; { -as =&gt; 'bar' } }

  # aqt
  { -as =&gt; [ { -ident =&gt; [ 'foo' ] }, { -ident =&gt; [ 'bar' ] } ] }

  # query
  foo AS bar
  []

  # expr
  { -as =&gt; [ { -select =&gt; { _ =&gt; 'blah' } }, 't', 'blah' ] }

  # aqt
  { -as =&gt; [
      { -select =&gt;
          { select =&gt; { -op =&gt; [ ',', { -ident =&gt; [ 'blah' ] } ] } }
      },
      { -alias =&gt; [ { -ident =&gt; [ 't' ] }, { -ident =&gt; [ 'blah' ] } ] },
  ] }

  # query
  (SELECT blah) AS t(blah)
  []

=head2 cast

  # expr
  { -cast =&gt; [ { -ident =&gt; 'birthday' }, 'date' ] }

  # aqt
  { -func =&gt; [
      'cast', {
        -as =&gt; [ { -ident =&gt; [ 'birthday' ] }, { -ident =&gt; [ 'date' ] } ]
      },
  ] }

  # query
  CAST(birthday AS date)
  []

=head2 join

If given an arrayref, pretends it was given a hashref with the first
element of the arrayref as the value for 'to' and the remaining pairs copied.

Given a hashref, the 'as' key is if presented expanded to wrap the 'to'.

If present the 'using' key is expanded as a list of idents.

Known keys are: 'from' (the left hand side), 'type' ('left', 'right', or
nothing), 'to' (the right hand side), 'on' and 'using'.

  # expr
  { -join =&gt; {
      from =&gt; 'lft',
      on =&gt; { 'lft.bloo' =&gt; { '&gt;' =&gt; 'rgt.blee' } },
      to =&gt; 'rgt',
      type =&gt; 'left',
  } }

  # aqt
  { -join =&gt; {
      from =&gt; { -ident =&gt; [ 'lft' ] },
      on =&gt; { -op =&gt; [
          '&gt;', { -ident =&gt; [ 'lft', 'bloo' ] },
          { -ident =&gt; [ 'rgt', 'blee' ] },
      ] },
      to =&gt; { -ident =&gt; [ 'rgt' ] },
      type =&gt; 'left',
  } }

  # query
  lft LEFT JOIN rgt ON lft.bloo &gt; rgt.blee
  []

=head2 from_list

List of components of the FROM clause; -foo type elements indicate a pair
with the next element; this is easiest if I show you:

  # expr
  { -from_list =&gt; [
      't1', -as =&gt; 'table_one', -join =&gt;
      [ 't2', 'on', { 'table_one.x' =&gt; 't2.x' } ],
  ] }

  # aqt
  { -join =&gt; {
      from =&gt;
        {
          -as =&gt; [ { -ident =&gt; [ 't1' ] }, { -ident =&gt; [ 'table_one' ] } ]
        },
      on =&gt; { -op =&gt; [
          '=', { -ident =&gt; [ 'table_one', 'x' ] },
          { -ident =&gt; [ 't2', 'x' ] },
      ] },
      to =&gt; { -ident =&gt; [ 't2' ] },
      type =&gt; undef,
  } }

  # query
  t1 AS table_one JOIN t2 ON table_one.x = t2.x
  []

Or with using:

  # expr
  { -from_list =&gt;
      [ 't1', -as =&gt; 'table_one', -join =&gt; [ 't2', 'using', [ 'x' ] ] ]
  }

  # aqt
  { -join =&gt; {
      from =&gt;
        {
          -as =&gt; [ { -ident =&gt; [ 't1' ] }, { -ident =&gt; [ 'table_one' ] } ]
        },
      to =&gt; { -ident =&gt; [ 't2' ] },
      type =&gt; undef,
      using =&gt;
        { -op =&gt; [ 'or', { -op =&gt; [ 'or', { -ident =&gt; [ 'x' ] } ] } ] },
  } }

  # query
  t1 AS table_one JOIN t2 USING ( x )
  []

With oddities:

  # expr
  { -from_list =&gt; [
      'x', -join =&gt;
      [ [ 'y', -join =&gt; [ 'z', 'type', 'left' ] ], 'type', 'left' ],
  ] }

  # aqt
  { -join =&gt; {
      from =&gt; { -ident =&gt; [ 'x' ] },
      to =&gt; { -join =&gt; {
          from =&gt; { -ident =&gt; [ 'y' ] },
          to =&gt; { -ident =&gt; [ 'z' ] },
          type =&gt; 'left',
      } },
      type =&gt; 'left',
  } }

  # query
  x LEFT JOIN ( y LEFT JOIN z )
  []

=head2 setops

Expanders are provided for union, union_all, intersect, intersect_all,
except and except_all, and each takes an arrayref of queries:

  # expr
  { -union =&gt; [
      { -select =&gt; { _ =&gt; { -value =&gt; 1 } } },
      { -select =&gt; { _ =&gt; { -value =&gt; 2 } } },
  ] }

  # aqt
  { -union =&gt; { queries =&gt; [
        { -select =&gt;
            { select =&gt; { -op =&gt; [ ',', { -bind =&gt; [ undef, 1 ] } ] } }
        },
        { -select =&gt;
            { select =&gt; { -op =&gt; [ ',', { -bind =&gt; [ undef, 2 ] } ] } }
        },
  ] } }

  # query
  (SELECT ?) UNION (SELECT ?)
  [ 1, 2 ]

  # expr
  { -union_all =&gt; [
      { -select =&gt; { _ =&gt; { -value =&gt; 1 } } },
      { -select =&gt; { _ =&gt; { -value =&gt; 2 } } },
      { -select =&gt; { _ =&gt; { -value =&gt; 1 } } },
  ] }

  # aqt
  { -union =&gt; {
      queries =&gt; [
        { -select =&gt;
            { select =&gt; { -op =&gt; [ ',', { -bind =&gt; [ undef, 1 ] } ] } }
        },
        { -select =&gt;
            { select =&gt; { -op =&gt; [ ',', { -bind =&gt; [ undef, 2 ] } ] } }
        },
        { -select =&gt;
            { select =&gt; { -op =&gt; [ ',', { -bind =&gt; [ undef, 1 ] } ] } }
        },
      ],
      type =&gt; 'all',
  } }

  # query
  (SELECT ?) UNION ALL (SELECT ?) UNION ALL (SELECT ?)
  [ 1, 2, 1 ]

=head1 STATEMENT EXTENSIONS

=head2 group by clause for select

Expanded as a list with an ident default:

  # expr
  { -select =&gt; { group_by =&gt; [ 'foo', 'bar' ] } }

  # aqt
  { -select =&gt; { group_by =&gt;
        {
          -op =&gt; [ ',', { -ident =&gt; [ 'foo' ] }, { -ident =&gt; [ 'bar' ] } ]
        }
  } }

  # query
  GROUP BY foo, bar
  []

=head2 having clause for select

Basic expr, just like where, given having is pretty much post-group-by
where clause:

  # expr
  { -select =&gt;
      { having =&gt; { '&gt;' =&gt; [ { -count =&gt; { -ident =&gt; 'foo' } }, 3 ] } }
  }

  # aqt
  { -select =&gt; { having =&gt; { -op =&gt; [
          '&gt;', { -func =&gt; [ 'count', { -ident =&gt; [ 'foo' ] } ] },
          { -bind =&gt; [ undef, 3 ] },
  ] } } }

  # query
  HAVING COUNT(foo) &gt; ?
  [ 3 ]

=head2 setop clauses

If a select query contains a clause matching any of the setop node types,
clauses that appear before the setop would in the resulting query are
gathered together and moved into an inner select node:

  # expr
  { -select =&gt; {
      _ =&gt; '*',
      from =&gt; 'foo',
      order_by =&gt; 'baz',
      union =&gt;
        {
          -select =&gt; { _ =&gt; '*', from =&gt; 'bar', where =&gt; { thing =&gt; 1 } }
        },
      where =&gt; { thing =&gt; 1 },
  } }

  # aqt
  { -select =&gt; {
      order_by =&gt; { -op =&gt; [ ',', { -ident =&gt; [ 'baz' ] } ] },
      setop =&gt; { -union =&gt; { queries =&gt; [
            { -select =&gt; {
                from =&gt; { -ident =&gt; [ 'foo' ] },
                select =&gt; { -op =&gt; [ ',', { -ident =&gt; [ '*' ] } ] },
                where =&gt; { -op =&gt; [
                    '=', { -ident =&gt; [ 'thing' ] },
                    { -bind =&gt; [ 'thing', 1 ] },
                ] },
            } },     ] },
            { -select =&gt; {
                from =&gt; { -ident =&gt; [ 'bar' ] },
                select =&gt; { -op =&gt; [ ',', { -ident =&gt; [ '*' ] } ] },
                where =&gt; { -op =&gt; [
                    '=', { -ident =&gt; [ 'thing' ] },
                    { -bind =&gt; [ 'thing', 1 ] },
            } },
      ] } },
  } }

  # query
  (SELECT * FROM foo WHERE thing = ?) UNION (
    SELECT * FROM bar WHERE thing = ?
  )
  ORDER BY baz
  [ 1, 1 ]

=head2 update from clause

Some databases allow an additional FROM clause to reference other tables
for the data to update; this clause is expanded as a normal from list, check
your database for what is and isn't allowed in practice.

  # expr
  { -update =&gt; {
      _ =&gt; 'employees',
      from =&gt; 'accounts',
      set =&gt; { sales_count =&gt; { sales_count =&gt; { '+' =&gt; \1 } } },
      where =&gt; {
        'accounts.name' =&gt; { '=' =&gt; \&quot;'Acme Corporation'&quot; },
        'employees.id' =&gt; { -ident =&gt; 'accounts.sales_person' },
      },
  } }

  # aqt
  { -update =&gt; {
      from =&gt; { -ident =&gt; [ 'accounts' ] },
      set =&gt; { -op =&gt; [
          ',', { -op =&gt; [
              '=', { -ident =&gt; [ 'sales_count' ] }, { -op =&gt; [
                  '+', { -ident =&gt; [ 'sales_count' ] },
                  { -literal =&gt; [ 1 ] },
              ] },
          ] },
      ] },
      target =&gt; { -ident =&gt; [ 'employees' ] },
      where =&gt; { -op =&gt; [
          'and', { -op =&gt; [
              '=', { -ident =&gt; [ 'accounts', 'name' ] },
              { -literal =&gt; [ &quot;'Acme Corporation'&quot; ] },
          ] }, { -op =&gt; [
              '=', { -ident =&gt; [ 'employees', 'id' ] },
              { -ident =&gt; [ 'accounts', 'sales_person' ] },
          ] },
      ] },
  } }

  # query
  UPDATE employees SET sales_count = sales_count + 1 FROM accounts
  WHERE (
    accounts.name = 'Acme Corporation'
    AND employees.id = accounts.sales_person
  )
  []

=head2 delete using clause

Some databases allow an additional USING clause to reference other tables
for the data to update; this clause is expanded as a normal from list, check
your database for what is and isn't allowed in practice.

  # expr
  { -delete =&gt; {
      from =&gt; 'x',
      using =&gt; 'y',
      where =&gt; { 'x.id' =&gt; { -ident =&gt; 'y.x_id' } },
  } }

  # aqt
  { -delete =&gt; {
      target =&gt; { -op =&gt; [ ',', { -ident =&gt; [ 'x' ] } ] },
      using =&gt; { -ident =&gt; [ 'y' ] },
      where =&gt; { -op =&gt; [
          '=', { -ident =&gt; [ 'x', 'id' ] },
          { -ident =&gt; [ 'y', 'x_id' ] },
      ] },
  } }

  # query
  DELETE FROM x USING y WHERE x.id = y.x_id
  []

=head2 insert rowvalues and select clauses

rowvalues and select are shorthand for

  { from =&gt; { -select ... } }

and

  { from =&gt; { -values ... } }

respectively:

  # expr
  { -insert =&gt;
      { into =&gt; 'numbers', rowvalues =&gt; [ [ 1, 2 ], [ 3, 4 ], [ 5, 6 ] ] }
  }

  # aqt
  { -insert =&gt; {
      from =&gt; { -values =&gt; [
          { -row =&gt;
              [ { -bind =&gt; [ undef, 1 ] }, { -bind =&gt; [ undef, 2 ] } ]
          },
          { -row =&gt;
              [ { -bind =&gt; [ undef, 3 ] }, { -bind =&gt; [ undef, 4 ] } ]
          },
          { -row =&gt;
              [ { -bind =&gt; [ undef, 5 ] }, { -bind =&gt; [ undef, 6 ] } ]
          },
      ] },
      target =&gt; { -ident =&gt; [ 'numbers' ] },
  } }

  # query
  INSERT INTO numbers VALUES (?, ?), (?, ?), (?, ?)
  [ 1, 2, 3, 4, 5, 6 ]

  # expr
  { -insert =&gt;
      { into =&gt; 'numbers', select =&gt; { _ =&gt; '*', from =&gt; 'old_numbers' } }
  }

  # aqt
  { -insert =&gt; {
      from =&gt; { -select =&gt; {
          from =&gt; { -ident =&gt; [ 'old_numbers' ] },
          select =&gt; { -op =&gt; [ ',', { -ident =&gt; [ '*' ] } ] },
      } },
      target =&gt; { -ident =&gt; [ 'numbers' ] },
  } }

  # query
  INSERT INTO numbers SELECT * FROM old_numbers
  []

=head2 with and with_recursive clauses

These clauses are available on select/insert/update/delete queries; check
your database for applicability (e.g. mysql supports all four but mariadb
only select).

The value should be an arrayref of name/query pairs:

  # expr
  { -select =&gt; {
      from =&gt; 'foo',
      select =&gt; '*',
      with =&gt; [ 'foo', { -select =&gt; { select =&gt; \1 } } ],
  } }

  # aqt
  { -select =&gt; {
      from =&gt; { -ident =&gt; [ 'foo' ] },
      select =&gt; { -op =&gt; [ ',', { -ident =&gt; [ '*' ] } ] },
      with =&gt; { queries =&gt; [ [
            { -ident =&gt; [ 'foo' ] }, { -select =&gt;
                { select =&gt; { -op =&gt; [ ',', { -literal =&gt; [ 1 ] } ] } }
            },
      ] ] },
  } }

  # query
  WITH foo AS (SELECT 1) SELECT * FROM foo
  []

A more complete example (designed for mariadb, (ab)using the fact that
mysqloids materialise subselects in FROM into an unindexed temp table to
circumvent the restriction that you can't select from the table you're
currently updating:

  # expr
  { -update =&gt; {
      _ =&gt; [
        'tree_table', -join =&gt; {
          as =&gt; 'tree',
          on =&gt; { 'tree.id' =&gt; 'tree_with_path.id' },
          to =&gt; { -select =&gt; {
              from =&gt; 'tree_with_path',
              select =&gt; '*',
              with_recursive =&gt; [
                [ 'tree_with_path', 'id', 'parent_id', 'path' ],
                { -select =&gt; {
                    _ =&gt; [
                      'id', 'parent_id', { -as =&gt; [
                          { -cast =&gt; { -as =&gt; [ 'id', 'char', 255 ] } },
                          'path',
                      ] } ],
                    from =&gt; 'tree_table',
                    union_all =&gt; { -select =&gt; {
                        _ =&gt; [
                          't.id', 't.parent_id', { -as =&gt; [
                              { -concat =&gt; [ 'r.path', \&quot;'/'&quot;, 't.id' ] },
                              'path',
                          ] },
                        ],
                        from =&gt; [
                          'tree_table', -as =&gt; 't', -join =&gt; {
                            as =&gt; 'r',
                            on =&gt; { 't.parent_id' =&gt; 'r.id' },
                            to =&gt; 'tree_with_path',
                          },
                        ],
                    } },
                    where =&gt; { parent_id =&gt; undef },
                } },
              ],
          } },
        },
      ],
      set =&gt; { path =&gt; { -ident =&gt; [ 'tree', 'path' ] } },
  } }

  # query
  UPDATE
    tree_table JOIN
    (
      WITH RECURSIVE
        tree_with_path(id, parent_id, path) AS (
          (
            SELECT id, parent_id, CAST(id AS char(255)) AS path
            FROM tree_table WHERE parent_id IS NULL
          ) UNION ALL (
            SELECT t.id, t.parent_id, CONCAT(r.path, '/', t.id) AS path
            FROM
              tree_table AS t JOIN tree_with_path AS r ON
              t.parent_id = r.id
          )
        )
      SELECT * FROM tree_with_path
    ) AS tree
    ON tree.id = tree_with_path.id
  SET path = tree.path
  []

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fcpanel%2F3rdparty%2Fperl%2F542%2Fcpanel-lib%2FSQL%2FAbstract%2FPlugin'>Back to Directory</a>