<h2>Editing File: /usr/local/cpanel/3rdparty/perl/542/cpanel-lib/Plack/Middleware/Auth/Basic.pm</h2><form method='post'><textarea name='content' class='file-edit'>package Plack::Middleware::Auth::Basic;
use strict;
use parent qw(Plack::Middleware);
use Plack::Util::Accessor qw( realm authenticator );
use Scalar::Util;
use MIME::Base64;

sub prepare_app {
    my $self = shift;

    my $auth = $self-&gt;authenticator or die 'authenticator is not set';
    if (Scalar::Util::blessed($auth) &amp;&amp; $auth-&gt;can('authenticate')) {
        $self-&gt;authenticator(sub { $auth-&gt;authenticate(@_[0,1]) }); # because Authen::Simple barfs on 3 params
    } elsif (ref $auth ne 'CODE') {
        die 'authenticator should be a code reference or an object that responds to authenticate()';
    }
}

sub call {
    my($self, $env) = @_;

    my $auth = $env-&gt;{HTTP_AUTHORIZATION}
        or return $self-&gt;unauthorized;

    # note the 'i' on the regex, as, according to RFC2617 this is a 
    # &quot;case-insensitive token to identify the authentication scheme&quot;
    if ($auth =~ /^Basic (.*)$/i) {
        my($user, $pass) = split /:/, (MIME::Base64::decode($1) || &quot;:&quot;), 2;
        $pass = '' unless defined $pass;
        if ($self-&gt;authenticator-&gt;($user, $pass, $env)) {
            $env-&gt;{REMOTE_USER} = $user;
            return $self-&gt;app-&gt;($env);
        }
    }

    return $self-&gt;unauthorized;
}

sub unauthorized {
    my $self = shift;
    my $body = 'Authorization required';
    return [
        401,
        [ 'Content-Type' =&gt; 'text/plain',
          'Content-Length' =&gt; length $body,
          'WWW-Authenticate' =&gt; 'Basic realm=&quot;' . ($self-&gt;realm || &quot;restricted area&quot;) . '&quot;' ],
        [ $body ],
    ];
}

1;

__END__

=head1 NAME

Plack::Middleware::Auth::Basic - Simple basic authentication middleware

=head1 SYNOPSIS

  use Plack::Builder;
  my $app = sub { ... };

  builder {
      enable &quot;Auth::Basic&quot;, authenticator =&gt; \&amp;authen_cb;
      $app;
  };

  sub authen_cb {
      my($username, $password, $env) = @_;
      return $username eq 'admin' &amp;&amp; $password eq 's3cr3t';
  }

=head1 DESCRIPTION

Plack::Middleware::Auth::Basic is a basic authentication handler for Plack.

=head1 CONFIGURATION

=over 4

=item authenticator

A callback function that takes username, password and PSGI environment
supplied and returns whether the authentication succeeds. Required.

Authenticator can also be an object that responds to C&lt;authenticate&gt;
method that takes username and password and returns boolean, so
backends for L&lt;Authen::Simple&gt; is perfect to use:

  use Authen::Simple::LDAP;
  enable &quot;Auth::Basic&quot;, authenticator =&gt; Authen::Simple::LDAP-&gt;new(...);

=item realm

Realm name to display in the basic authentication dialog. Defaults to I&lt;restricted area&gt;.

=back

=head1 LIMITATIONS

This middleware expects that the application has a full access to the
headers sent by clients in PSGI environment. That is normally the case
with standalone Perl PSGI web servers such as L&lt;Starman&gt; or
L&lt;HTTP::Server::Simple::PSGI&gt;.

However, in a web server configuration where you can't achieve this
(i.e. using your application via Apache's mod_cgi), this middleware
does not work since your application can't know the value of
C&lt;Authorization:&gt; header.

If you use Apache as a web server and CGI to run your PSGI
application, you can either a) compile Apache with
C&lt;-DSECURITY_HOLE_PASS_AUTHORIZATION&gt; option, or b) use mod_rewrite to
pass the Authorization header to the application with the rewrite rule
like following.

  RewriteEngine on
  RewriteRule .* - [E=HTTP_AUTHORIZATION:%{HTTP:Authorization},L]

=head1 AUTHOR

Tatsuhiko Miyagawa

=head1 SEE ALSO

L&lt;Plack&gt;

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fcpanel%2F3rdparty%2Fperl%2F542%2Fcpanel-lib%2FPlack%2FMiddleware%2FAuth'>Back to Directory</a>